source: trunk/src/interp_erai_ws.pro @ 172

;+
;
;
; ==================
; interp_erai_ws.pro
; ==================
;
; .. function:: interp_erai_ws(yyyymmddb,yyyymmdde)
;
; DESCRIPTION
; ===========
;
; Interpolation of u10 and v10 from ERA-I grid to OAFLUX grid
;
; :file:`${PROJECT_ID}/20c3m_erai_u10_TROP_1989_2009.nc`
; containing
; u10 from ERA-I
; has been produced by
; :ref:`compute_erai_daily_region_2d.sh`.
;
; :file:`${PROJECT_ID}/20c3m_erai_v10_TROP_1989_2009.nc`
; containing
; v10 from ERA-I
; has been produced by
; :ref:`compute_erai_daily_region_2d.sh`.
;
; :file:`${PROJECT_ID}/mask_oaflux_30N30S.nc`
; containing OAFLUX grid
; has been produced by
; :func:`oaflux_mask_30n30s`.
;
; Interpolated u10 and v10 are written in
; :file:`${PROJECT_OD}/erai_ws_19890101_20091231_oafluxgrid.nc`
; if this file not already exists.
;
; This output file
; :file:`${PROJECT_OD}/erai_ws_19890101_20091231_oafluxgrid.nc`
; must be processed after by
; :ref:`ws_correction_ncdf.pro`.
;
; .. only:: man
;
;    Figure is visible on PDF and HTML documents only.
;
; .. only:: html or latex
;
;     .. graphviz::
;
;        digraph interp_erai_ws {
;
;           file_u10 [shape=ellipse,fontname=Courier,label="${PROJECT_ID}/20c3m_erai_u10_TROP_1989_2009.nc"];
;           file_v10 [shape=ellipse,fontname=Courier,label="${PROJECT_ID}/20c3m_erai_v10_TROP_1989_2009.nc"];
;           mask [shape=ellipse,fontname=Courier,label="${PROJECT_ID}/mask_oaflux_30N30S.nc"];
;           file_out [shape=ellipse,fontname=Courier,label="${PROJECT_OD}/erai_ws_19890101_20091231_oafluxgrid.nc"];
;
;           interp_erai_ws [shape=box,
;           fontname=Courier,
;           color=blue,
;           URL="http://forge.ipsl.jussieu.fr/tropflux/browser/trunk/src/interp_erai_ws.pro",
;           label="${PROJECT}/src/interp_erai_ws.pro"];
;
;           {file_u10 file_v10 mask} -> {interp_erai_ws} -> {file_out}
;
;        }
;
; SEE ALSO
; ========
;
; :ref:`interpolate_data`
;
; :ref:`project_profile.sh`
;
; Used by :ref:`tropflux.sh`
;
; :func:`report <saxo:report>`
; :func:`isadirectory <saxo:isadirectory>`
; :func:`isafile <saxo:isafile>`
; :func:`initncdf <saxo:initncdf>`
; :func:`read_ncdf <saxo:read_ncdf>`
; :func:`domdef <saxo:domdef>`
; :func:`call_interp2d <saxo:call_interp2d>`
; :func:`ncdf_quickwrite <saxo:ncdf_quickwrite>`
;
; :ref:`ws_correction_ncdf.pro`
;
; EXAMPLES
; ========
;
; ::
;
;  IDL> .compile file_interp
;  IDL> yyyymmddb = 20000101L
;  IDL> yyyymmdde = 20001231L
;  IDL> result = interp_erai_ws(yyyymmddb, yyyymmdde)
;  IDL> print, result
;
; TODO
; ====
;
; compare time between u10 and v10 after reading
;
; make it work : pb on loholt1 idl8
;
; reach end but bad values et nb timestep 4581::
;
;     ncks -v u10  -d time,0,1 -d latitude,0,1 -d longitude,0,1 /homedata/pinsard/tropflux_d/erai_ws_19890101_20091231_oafluxgrid.nc
;     latitude[0]=-29.5 degrees_north
;     latitude[1]=-28.5 degrees_north
;
;     longitude[0]=30.5 degrees_east
;     longitude[1]=31.5 degrees_east
;
;     time[0] latitude[0]=-29.5 longitude[0]=30.5 u10[0]=9.96921e+36 m/s
;     time[0] latitude[0]=-29.5 longitude[1]=31.5 u10[1]=9.96921e+36 m/s
;     time[0] latitude[1]=-28.5 longitude[0]=30.5 u10[350]=9.96921e+36 m/s
;     time[0] latitude[1]=-28.5 longitude[1]=31.5 u10[351]=9.96921e+36 m/s
;     time[1] latitude[0]=-29.5 longitude[0]=30.5 u10[21000]=9.96921e+36 m/s
;     time[1] latitude[0]=-29.5 longitude[1]=31.5 u10[21001]=9.96921e+36 m/s
;     time[1] latitude[1]=-28.5 longitude[0]=30.5 u10[21350]=9.96921e+36 m/s
;     time[1] latitude[1]=-28.5 longitude[1]=31.5 u10[21351]=9.96921e+36 m/s
;
; make it work : pb on loholt1 idl6::
;
;   Writing fields:
;   u10[longitude,latitude,time]=u10out:u10_attr; v10[longitude,latitude,time]=v10out:v10_attr; longitude[]=xlon:lon_attr; latitude[]=ylat:lat_attr; tt[*time]=tt:time_attr  @ globattr
;   % NCDF_VARPUT: Operation Failed, bad file (6) or variable [0] id ?
;                  (NC_ERROR=-31)
;   % Stop encountered: INTERP_ERAI_WS_1989_2009    1
;
; check OUTMASK_IND and SET_OUTMSKVAL added to call_interp2d call
;
; use real output of :ref:`compute_erai_daily_region_2d.sh`.
;
; coding rules
;
; check [yyyymmddb,yyyymmdde] validity
;
; check if [yyyymmddb,yyyymmdde] is included in ERA-I file
;
; what happen if yyyymmdde > 20091231 : need to read an other ERA-I file
;
; KNOWN ISSUES
; ============
;
; test of existence of fullfilename_msk not very efficient because
; MUST_EXIST keyword of :func:`isafile <saxo:isafile>` not yet implemented
;
; EVOLUTIONS
; ==========
;
; $Id$
;
; $URL: svn+ssh://pinsard@forge.ipsl.jussieu.fr/ipsl/forge/projets/tropflux/svn/trunk/src/interp_erai_ws.pro $
;
; - fplod 20120320
;
;   * taking project_overwite into account
;   * try to add compile_opt seems to be incompatible with ncdf_quickwrite
;   * pro -> function
;   * hard coded st and en replaced by yyyymmddb and yyyymmdde parameters
;   * start to homogenize time handling regarding :func:`interp_erai_t2m`
;
; - fplod 20110830T135212Z cratos (Linux)
;
;   * replace tt by time
;
; - pinsard 2011-08-23T09:09:16Z loholt1.ipsl.polytechnique.fr (Linux)
;
;   * retry on loholt1 with idl8 and idl6
;
; - fplod 20110808T094156Z cratos (Linux)
;
;   * add OUTMASK_IND and SET_OUTMSKVAL to call_interp2d call
;
; - pinsard 2011-07-05T07:33:36Z loholt1.ipsl.polytechnique.fr (Linux)
;
;   * usage of $PROJECT_ID and $PROJECT_OD
;
; - fplod 20101217T140745Z aedon.locean-ipsl.upmc.fr (Darwin)
;
;   * remove hard coded directory for mask_oaflux_30N30S.nc
;
; - fplod 20101215T112657Z aedon.locean-ipsl.upmc.fr (Darwin)
;
;   * add graph in header
;
; - fplod 20101214T093615Z aedon.locean-ipsl.upmc.fr (Darwin)
;
;   * minimal header
;
; - pbk 2008
;
;   * creation
;
;-
function interp_erai_ws $
         , yyyymmddb $
         , yyyymmdde
;
;++compile_opt idl2, strictarrsubs, logical_predicate
;
; Return to caller if errors
ON_ERROR, 2
;
result = -1
;
usage = 'result = interp_erai_lwr(yyyymmddb, yyyymmdde)'
nparam = N_PARAMS()
IF (nparam NE 2) THEN BEGIN
ras = report(['Incorrect number of arguments.' $
      + '!C' $
      + 'Usage : ' + usage])
      return, result
ENDIF
;
@cm_4cal
@cm_4data
@cm_4mesh
@cm_4data
@cm_project
;
; check for input directory
;
; test if ${PROJECT_ID} defined
CASE project_id_env OF
    ''  :  BEGIN
     msg = 'eee : ${PROJECT_ID} is not defined'
     ras = report(msg)
     return, result
           END
 ELSE: BEGIN
     msg = 'iii : ${PROJECT_ID} is ' + project_id_env
     ras = report(msg)
       END
ENDCASE
;
iodirin = isadirectory(project_id_env)
;
; existence and protection of ${PROJECT_ID}
IF (FILE_TEST(iodirin, /DIRECTORY, /EXECUTABLE, /READ) EQ 0) THEN BEGIN
   msg = 'eee : the directory' + iodirin  + ' is not accessible.'
   ras = report(msg)
   return, result
ENDIF
;
; build mask filename
filename_msk='mask_oaflux_30N30S.nc'
;
; check if this file exists
msg='iii : looking for ' + filename_msk
ras = report(msg)
fullfilename_msk = isafile(iodirin + filename_msk, NEW=0, /MUST_EXIST)
IF fullfilename_msk[0] EQ '' THEN BEGIN
   msg = 'eee : the file ' + fullfilename_msk + ' was not found.'
   ras = report(msg)
   return, result
ENDIF
;
; build u10 data filename
filename='20c3m_erai_u10_TROP_1989_2009.nc'
;
; check if this file exists
msg='iii : looking for ' + filename
ras = report(msg)
fullfilename = isafile(iodirin + filename, NEW=0, /MUST_EXIST)
IF fullfilename[0] EQ '' THEN BEGIN
   msg = 'eee : the file ' + fullfilename + ' was not found.'
   ras = report(msg)
   return, result
ENDIF
;
; test if ${PROJECT_OD} defined
CASE project_od_env OF
  '' : BEGIN
         msg = 'eee : ${PROJECT_OD} is not defined'
         ras = report(msg)
       return, result
       END
  ELSE: BEGIN
          msg = 'iii : ${PROJECT_OD} is ' + project_od_env
          ras = report(msg)
        END
 ENDCASE
;
; check if output data will be possible
iodirout = isadirectory(project_od_env)
;
; existence and protection
IF (FILE_TEST(iodirout, /DIRECTORY, /WRITE) EQ 0) THEN BEGIN
    msg = 'eee : the directory' + iodirout  + ' was not found.'
    ras = report(msg)
    return, result
ENDIF
;
; build output filename
filename_out = 'erai_ws_' + string(yyyymmddb,format='(I8.8)') + '_' + string(yyyymmdde,format='(I8.8)') + '_oafluxgrid.nc'
fullfilename_out = iodirout + filename_out
; in order to avoid unexpected overwritten
IF ((FILE_TEST(fullfilename_out) EQ 1)  AND (project_overwrite EQ 0)) THEN BEGIN
   msg = 'eee : the file ' + fullfilename_out  + ' already exists.'
   ras = report(msg)
   return, result
ENDIF
;
initncdf, fullfilename
u10in=read_ncdf("u10", yyyymmddb - .5d, yyyymmdde, file=fullfilename,/nostr)
;
timein=24.d*(time-julday(1,1,1957,0,0,0)) 
jpt=n_elements(timein)
da=jul2date(time[0])
cda0=string(da,format='(i8.8)')
da=jul2date(time[jpt-1]) 
cda1=string(da,format='(i8.8)')
print, 'u10 first date ', cda0
print, 'u10 last date ' , cda1
;
; build v10 data filename
filename='20c3m_erai_v10_TROP_1989_2009.nc'
;
; check if this file exists
msg='iii : looking for ' + filename
ras = report(msg)
fullfilename = isafile(iodirin + filename, NEW=0, /MUST_EXIST)
IF fullfilename[0] EQ '' THEN BEGIN
   msg = 'eee : the file ' + fullfilename + ' was not found.'
   ras = report(msg)
   return, result
ENDIF
initncdf, fullfilename
v10in=read_ncdf("v10", yyyymmddb - .5d, yyyymmdde, file=fullfilename,/nostr)
;
initncdf, fullfilename
domdef
latin=reform(gphit[0,*])
lonin=reform(glamt[*,0])
print, 'lat grid ',min(latin),max(latin),latin[1]-latin[0]
print, 'lon grid ',min(lonin),max(lonin),lonin[1]-lonin[0]
;
timein=24.d*(time-julday(1,1,1957,0,0,0))
jptin=n_elements(timein)
da=jul2date(time[0])
cda0=string(da,format='(i8.8)')
da=jul2date(time[jpt-1])
cda1=string(da,format='(i8.8)')
print, 'v10 first date ', cda0
print, 'v10 last date ' , cda1
help, v10in
;
tab=u10in[*,*,0]
mskin=glamt*0.+1.
;
initncdf, fullfilename_msk
domdef
latout=reform(gphit[0,*])
lonout=reform(glamt[*,0])
print, 'lat grid ',min(latout),max(latout),latout[1]-latout[0]
print, 'lon grid ',min(lonout),max(lonout),lonout[1]-lonout[0]
mskout=read_ncdf("msk", file=fullfilename_msk,/nostr)
;
help, u10in, v10in,lonin,latin,mskin,lonout,latout,mskout
;
u10out=fltarr(jpi,jpj,jptin)
v10out=fltarr(jpi,jpj,jptin)
;
for jt=0,jptin-1 do begin
  ; ++print, 'Interpolation jt=',jt,' / ',jptin-1
  tab=reform(u10in[*,*,jt])
  u10out[*,*,jt]=call_interp2d(tab,lonin,latin,mskin $
      , lonout,latout,method='bilinear' $
      , OUTMASK_IND=mskout, SET_OUTMSKVAL=mskout)
  u10out[*,*,jt]=u10out[*,*,jt]*mskout+(1.-mskout)*1.e20
;
  tab=reform(v10in[*,*,jt])
  v10out[*,*,jt]=call_interp2d(tab,lonin,latin,mskin $
      , lonout,latout,method='bilinear' $
      , OUTMASK_IND=mskout, SET_OUTMSKVAL=mskout)
  v10out[*,*,jt]=v10out[*,*,jt]*mskout+(1.-mskout)*1.e20
;
endfor
;
xlon=reform(glamt[*,0] )
ylat=reform(gphit[0,*])
;
initncdf, fullfilename_msk
valmask=1.e20
;
ylat=latout
xlon=lonout
ncfile='!' + fullfilename_out
lon_attr={units:'degrees_east',long_name:'Longitude'}
lat_attr={units:'degrees_north',long_name:'Latitude'}
time_attr={units:'days since 1950-01-01 00:00:00',long_name:'Time axis',time_origin:'1950-JAN-01 00:00:00'}
globattr={source:'Tropical ocean winds obtained from ERA Interim',timerange:cda0+' - '+cda1}
u10_attr={units:'m/s',missing_value:valmask,long_name:'10 metre u wind component',short_name:'u10',axis:'TYX'}
v10_attr={units:'m/s',missing_value:valmask,long_name:'10 metre v wind component',short_name:'v10',axis:'TYX'}
;
help, u10out
help, v10out
help, timein
;
ncfields = 'u10[longitude,latitude,*time]=u10out:u10_attr; ' $
          +'v10[longitude,latitude,*time]=v10out:v10_attr; ' $
                      + 'longitude[]=xlon:lon_attr; ' $
                      + 'latitude[]=ylat:lat_attr; ' $
                      + 'time[]=timein:time_attr ' $
                      + ' @ globattr'
;
@ncdf_quickwrite
;
result = 0
return, result
;
end