source: trunk/src/lwr_correction_ncdf.pro

;+
;
; =======================
; lwr_correction_ncdf.pro
; =======================
;
; .. function:: lwr_correction_ncdf(yyyymmddb,yyyymmdde)
;
; DESCRIPTION
; ===========
;
; Correction of lwr on OAFLUX grid
;
; :file:`${PROJECT_OD}/erai_lwr_{yyyymmdd}_{yyyymmdd}_oafluxgrid.nc`
; containing
; ++
; have been produced by
; :func:`interp_erai_lwr` and :ref:`add_19890101.sh`.
;
; Corrected lwr on OAFLUX grid
; is written in
; :file:`${PROJECT_OD}/TropFlux_lwr_{yyyymmdd}_{yyyymmdd}.nc`
; if this file not already exists.
;
; This output file
; :file:`${PROJECT_OD}/TropFlux_lwr_{yyyymmdd}_{yyyymmdd}.nc`
; will be used by
; :func:`tropflux`.
;
; .. only:: man
;
;    Figure is visible on PDF and HTML documents only.
;
; .. only:: html or latex
;
;     .. graphviz::
;
;        digraph lwr_correction_ncdf {
;
;           file_in [shape=ellipse,fontname=Courier,label="${PROJECT_OD}/erai_lwr_{yyyymmdd}_{yyyymmdd}_oafluxgrid.nc"];
;           file_out [shape=ellipse,fontname=Courier,label="${PROJECT_OD}/TropFlux_lwr_{yyyymmdd}_{yyyymmdd}.nc"];
;
;           lwr_correction_ncdf [shape=box,
;           fontname=Courier,
;           color=blue,
;           URL="http://forge.ipsl.jussieu.fr/tropflux/browser/trunk/src/lwr_correction_ncdf.pro",
;           label="${PROJECT}/src/lwr_correction_ncdf.pro"];
;
;           {file_in} -> {lwr_correction_ncdf} -> {file_out}
;
;        }
;
; SEE ALSO
; ========
;
; :ref:`mooring_corrections`
;
; Used by :ref:`tropflux.sh`
;
; :ref:`project_profile.sh`
;
; :func:`interp_erai_lwr` and :ref:`add_19890101.sh`
;
; :func:`initncdf <saxo:initncdf>`
; :func:`read_ncdf <saxo:read_ncdf>`
; :func:`grossemoyenne <saxo:grossemoyenne>`
; :func:`julday <saxo:julday>`
; :func:`caldat <saxo:caldat>`
; :func:`ncdf_quickwrite <saxo:ncdf_quickwrite>`
;
; EXAMPLES
; ========
;
; .. code-block:: idl
;
;    yyyymmddb = 20000101L
;    yyyymmdde = 20001231L
;    result = lwr_correction_ncdf(yyyymmddb, yyyymmdde)
;    print, result
;
; TODO
; ====
;
; coding rules
;
; lwr long name 'Air Temperature at 2m" : ???
;
; remove hard coded time
;
; add_19890101.sh sould not be the previous step in a near future
;
; KNOWN ISSUES
; ============
;
; test of existence of fullfilename_in not very efficient because
; MUST_EXIST keyword of :func:`isafile <saxo:isafile>` not yet implemented
;
; EVOLUTIONS
; ==========
;
; $Id: lwr_correction_ncdf.pro 88 2011-08-19 15:40:14Z pinsard $
;
; $URL$
;
; - fplod 20120322
;
;   * taking project_overwrite into account
;   * try to add compile_opt seems to be incompatible with ncdf_quickwrite
;   * pro -> function
;   * hard coded da1 and da2 replaced by yyyymmddb and yyyymmdde parameters
;   * get rid of timegen
;
; - fplod 20110819T105050Z aedon.locean-ipsl.upmc.fr (Darwin)
;
;   * replace previous step interp_erai_lwr_1989_2009.pro
;     by :ref:`add_19890101.sh`
;   * change 19890102 to 19890101
;
; - fplod 20110808T120234Z cratos (Linux)
;
;   * usage of ${PROJECT_OD}
;   * complete description
;   * replace erai_lwr_19890102_20091231_oafluxgrid.nc by erai_lwr_19890101_20091231
;   * remove v1 in output filename
;
; - fplod 20101215T113707Z aedon.locean-ipsl.upmc.fr (Darwin)
;
;   * add graph in header
;
; - fplod 20101214T093615Z aedon.locean-ipsl.upmc.fr (Darwin)
;
;   * minimal header
;
; - pbk 2008
;
;   * creation
;
;-
function lwr_correction_ncdf $
, yyyymmddb $
, yyyymmdde
;
;++compile_opt idl2, strictarrsubs, logical_predicate
;
@cm_4cal
@cm_4data
@cm_4mesh
@cm_4data
@cm_project
;
; Return to caller if errors
ON_ERROR, 2
;
result = -1
;
usage = 'result = lwr_correction_ncdf(yyyymmddb, yyyymmdde)'
nparam = N_PARAMS()
IF (nparam NE 2) THEN BEGIN
    ras = report(['Incorrect number of arguments.' $
    + '!C' $
    + 'Usage : ' + usage])
    return, result
ENDIF
;
; test if ${PROJECT_OD} defined
CASE project_od_env OF
    '' : BEGIN
        msg = 'eee : ${PROJECT_OD} is not defined'
        ras = report(msg)
        return, result
    END
    ELSE : BEGIN
        msg = 'iii : ${PROJECT_OD} is ' + project_od_env
        ras = report(msg)
    END
ENDCASE
;
; check if output data will be possible
iodirout = isadirectory(project_od_env)
;
; existence and protection for reading
IF (FILE_TEST(iodirout, /DIRECTORY, /EXECUTABLE, /READ) EQ 0) THEN BEGIN
    msg = 'eee : the directory' + iodirout + ' is not accessible.'
    ras = report(msg)
    return, result
ENDIF
;
; existence and protection for writing
IF (FILE_TEST(iodirout, /DIRECTORY, /WRITE) EQ 0) THEN BEGIN
    msg = 'eee : the directory' + iodirout + ' was not found.'
    ras = report(msg)
    return, result
ENDIF
;
; build data filename
filename='erai_lwr_' + string(yyyymmddb,format='(I8.8)') + '_' + string(yyyymmdde,format='(I8.8)') + '_oafluxgrid.nc'
;
; check if this file exists
msg='iii : looking for ' + filename
ras = report(msg)
fullfilename = isafile(iodirout + filename, NEW=0, /MUST_EXIST)
IF fullfilename[0] EQ '' THEN BEGIN
    msg = 'eee : the file ' + fullfilename + ' was not found.'
    ras = report(msg)
    return, result
ENDIF
;
; build output filename
filename_out = 'TropFlux_lwr_' + string(yyyymmddb,format='(I8.8)') + '_' + string(yyyymmdde,format='(I8.8)') + '.nc'
fullfilename_out = iodirout + filename_out
; in order to avoid unexpected overwritten
IF ((FILE_TEST(fullfilename_out) EQ 1)  AND (project_overwrite EQ 0)) THEN BEGIN
    msg = 'eee : the file ' + fullfilename_out  + ' already exists.'
    ras = report(msg)
    return, result
ENDIF
;
initncdf, fullfilename
lwr=read_ncdf('lwr',yyyymmddb-.5d,yyyymmdde,file=fullfilename,/nostr)
timein=24.d*(time-julday(1,1,1957,0,0,0))
jpt=n_elements(timein)
da=jul2date(time[0])
cda0=string(da,format='(i8.8)')
da=jul2date(time[jpt-1])
cda1=string(da,format='(i8.8)')
print, 'lwr in lwr_correction_ncdf first date ', cda0
print, 'lwr in lwr_correction_ncdf last date ' , cda1
;
help, lwr
;
lwr_mean=grossemoyenne(lwr,'t',/nan)
help,lwr_mean
;
jpt=n_elements(time)
caldat, time,mon,day,yea
lwr_m=lwr*0.
;
for jt=0,jpt-1 do begin
    jtt=(time[jt]-julday(1,1,yea[jt])) < 364
    t=reform(lwr_mean[*,*])
    lwr_m[*,*,jt]=t
endfor
help, lwr_m
;
lwr_ano=lwr-lwr_m
;
; correction for mean based on scatter
lwr_m=lwr_m+4.61667
;
help, lwr_ano
;
; applying the correction for variability based on the scatter
lwr_ano=lwr_ano*(1/0.760667)
;
; applying the correction for variability based on the scatter
;
lwr_new=lwr_m+lwr_ano
help, lwr_new
;
;writing field
lat=reform(gphit[0,0:jpj-1])
lon=reform(glamt[0:jpi-1,0])
;
ncfile='!' + fullfilename_out
lon_attr={units:'degrees_east',long_name:'Longitude'}
lat_attr={units:'degrees_north',long_name:'Latitude'}
time_attr={units:'days since 1950-01-01 00:00:00',long_name:'Time axis',time_origin:'1950-JAN-01 00:00:00'}
globattr={source:'Basic data obtained from ERAI. Mean correction for bias and correction for variability are applied',timerange:cda0+' - '+cda1}
lwr_attr={units:'degK',missing_value:1.e20,long_name:'Air Temperature at 2m',short_name:'lwr',axis:'TYX'}
;
ncfields = 'lwr[longitude,latitude,*time]=lwr_new:lwr_attr; ' $
+ 'longitude[]=lon:lon_attr; ' $
+ 'latitude[]=lat:lat_attr; ' $
+ 'time[]=timein:time_attr ' $
+ ' @ globattr'
;
@ncdf_quickwrite
;
result = 0
return, result
;
end