;+
; ================
; lwdown_clark.pro
; ================
;
; .. function:: lwdown_clark(sst, qair, cld, tair, ps)
;
; DESCRIPTION
; ===========
;
; Net longwave from the Clark et al. (1974) bulk formula
; Clark, N. E., L. Eber, R. M. Laurs, J. A. Renner, and J. F. T. Saur,
; 1974: Heat exchange between ocean and atmosphere in the
; eastern North Pacific for 1961-71. NOAA Tech. Rep. NMRS
; SSRF-682, National Oceanic and Atmospheric Administration,
; U.S. Department of Commerce, Washington, DC, 108 pp.
;
; See also Gill, p34.
;
; INPUTS
;   sst :    Sea surface temperature (degC)
;   qair:    specific humidity (g/kg)
;   cld :    cloud cover
;   tair:    surface air temperature (degC)
;   ps  :    surface pressure (mb)
; OUTPUT
;   lw :    estimated longwave (W/m2)
;
; EVOLUTIONS
; ==========
;
; $Id$
;
; $URL$
;
; - fplod 20120319
;
;   * minimal header
;
;-
function lwdown_clark, sst,qair,cld,tair,ps
;
@common
;
eps=.97            ; emissivity of sea-water
sig=5.67e-8        ; Stefan-Boltzman constant (W/m2/K4)
Ts=(sst+273.15)     ; SST in K
Ta=(tair+273.15)      ; Tair in K
q=qair/1000.            ; specific humidity (kg/kg)
r=q/(1-q)        ; Mixing ratio
ea=ps*r/(r+.62197)      ; Specific humidity into vapor pressure
;
lw=    eps*sig*Ts^4*(.39-.05*ea^.5)*(1.-.51*cld^2) $
   +4.*eps*sig*Ts^3*(Ts-Ta)
;
lwup=eps*sig*Ts^4
;
lwdown=lwup-lw
;
return, lwdown
;
end