source: trunk/src/mem_to_file_amsu_t2.pro @ 545

;+
;
; =======================
; mem_to_file_amsu_t2.pro
; =======================
;
; .. function:: mem_to_file_amsu_t2(amsu_t2, testfilename)
;
; DESCRIPTION
; ===========
;
; Write info and data of **amsu_t2** structure to an amsu_t2 file
;
; If **testfilename** is not empty, this filename will be written, otherwise
; amsu_t2 terminology will be applied.
;
; :returns: name of the output file if ok or -1 if error
; :rtype: integer
;
; EXAMPLES
; ========
;
; Realistic example with VARAMMA file AMSU-A channel 5
; :file:`${PROJECT_ID}/AMSU/2006/08/a5_20060801.dat`::
;
;   numch='a5'
;   yyyy=2006L
;   mm=8
;   dd=1
;   testfilename=''
;   lonmin=-25.
;   lonmax=25.
;   latmin=-5.
;   latmax=20.
;   amsu_t2 = file_amsu_t2_to_mem(yyyy, mm, dd, numch, lonmin, lonmax, latmin, latmax, testfilename)
;   testfilename='./a'
;   result = mem_to_file_amsu_t2(amsu_t2, testfilename)
;
; look for differences::
;
;   $ diff ./a ${PROJECT_ID}/AMSU/2006/08/a5_20060801_060w30s_050e45n.dat
;
; SEE ALSO
; ========
;
; :ref:`extract_amsua.pro` where this function should be called
;
; :func:`file_amsu_t2_to_mem`
;
; use :func:`geolocation_to_string_idl`
;
; TODO
; ====
;
; ajouter de # dans les lignes d'entete
;
; crier sur valeur manquante de tb
;
; à intégrer dans :ref:`extract_amsua.pro`
;
; check args
;
; spécial idl : je n'arrive pas à éviter la boucle sur les lignes de data !!
;
; EVOLUTIONS
; ==========
;
; $Id: mem_to_file_amsu_t2.pro$
;
; $URL$
;
; - fplod 20120417
; 
;   * usage of key_performance
;
; - fplod 20120410
;
;   * build output directory if needed
;   * update example
;
; - fplod 20111213T143503Z aedon.locean-ipsl.upmc.fr (Darwin)
;
;   * geobox in filename
;
; - fplod 20111213T094118Z cratos (Linux)
;
;   * ajout de resol dans l'en tete
;
; - fplod 20111209T150209Z cratos (Linux)
;
;   * ajout de nbpix dans la première ligne de header
;   * ajout d'une seconde ligne d'entete avec les coordonnées de la zone
;   * suppression de parametres redondants
;
; - fplod 20111208T173432Z aedon.locean-ipsl.upmc.fr (Darwin)
;
;   * name of output file as result if ok
;
; - fplod 20111208T105205Z cratos (Linux)
;
;   * nvelle terminologie
;   * nouveau format (header + données) de fichier
;
; - fplod 20111206T163330Z cratos (Linux)
;
;   * creation thanks to http://www.idlcoyote.com/tips/ascii_column_data.html
;
;-
FUNCTION mem_to_file_amsu_t2, amsu_t2 $
                            , testfilename
;
compile_opt idl2, strictarrsubs
;
@cm_project
@common
;
s = size(SCOPE_TRACEBACK(/STRUCTURE),/DIMENSION)
routine = (SCOPE_TRACEBACK(/STRUCTURE))[s-1].Routine
;
if key_performance EQ 1 THEN BEGIN
    time1 = SYSTIME(1)
ENDIF
;
; Return to caller if errors
ON_ERROR, 2
;
result = -1
;
usage = 'result=mem_to_file_amsu_t2(amsu_t2, testfilename)'
nparam = N_PARAMS()
IF (nparam NE 2) THEN BEGIN
   ras = report(['Incorrect number of arguments.' $
         + '!C' $
         + 'Usage : ' + usage])
   return, result
ENDIF
;

if (testfilename eq '') then begin
    look = 'filename'
    scale = 1.
    geomin = geolocation_to_string_idl(amsu_t2.header2.lonmin, amsu_t2.header2.latmin, look, scale)
    geomax = geolocation_to_string_idl(amsu_t2.header2.lonmax, amsu_t2.header2.latmax, look, scale)
    fullfilename = project_id_env+ 'AMSU/' $
            + string(amsu_t2.header1.yyyy,format='(I4.4)') + '/' $
            + string(amsu_t2.header1.mm,format='(I2.2)') + '/' $
            + amsu_t2.header1.numch + '_' $
            + string(amsu_t2.header1.yyyy,format='(I4.4)') $
            + string(amsu_t2.header1.mm,format='(I2.2)') $
            + string(amsu_t2.header1.dd,format='(I2.2)') + '_' $
            + geomin + '_' $
            + geomax $
            + '.dat'
endif else begin
    fullfilename = testfilename
endelse
;
; buid the directory if needed
dirout = file_dirname(fullfilename,/MARK_DIRECTORY) 
IF (FILE_TEST(dirout, /DIRECTORY, /EXECUTABLE, /WRITE) EQ 0) THEN BEGIN
    FILE_MKDIR, dirout
ENDIF

print, 'ouverture pour ecriture de ', fullfilename
;
; build header format string
format_header1 = '(I4.4,I2.2,I2.2,1X,A2,1X,I3.3,1X,F6.3)'
format_header2 = '(1x,f8.3,1x,f8.3,1x,f8.3,1x,f8.3)'

; build data format string
format_data = '(i2,1x,f8.4,i3,1x,f8.3,1x,f8.3,1x,I1,1x,f8.3)'
;
nrows = n_elements(amsu_t2.data)
;
; open file
OPENW, lun, fullfilename, /GET_LUN, ERROR = error
IF (error NE 0) then begin
   ras = report(['eee : can not open for writing '$
         + '!C' $
         + fullfilename])
   return, result
ENDIF
;
; write header lines
header1=amsu_t2.header1
PRINTF, lun, header1, format=format_header1
header2=amsu_t2.header2
PRINTF, lun, header2, format=format_header2
;
; write data lines
for irow=0, nrows -1 do begin
    data=amsu_t2.data[irow]
    PRINTF, lun, data, format=format_data
endfor
;
; close file
FREE_LUN, lun
;
result = fullfilename
;
IF key_performance EQ 1 THEN BEGIN
   msg = report(['ppp : ' + routine + ' : durée totale ' $
               + string(SYSTIME(1)-time1,format='(F12.6)')])
ENDIF
;
return, result
;
END