source: SCHWARZ_ORCA2LIM3/SOURCES/NEMO/nemogcm.F90 @ 11

Last change on this file since 11 was 11, checked in by snguyen, 2 years ago

removed bug : not writing restart when doing several periods of computation

File size: 42.3 KB
Line 
1MODULE nemogcm
2   !!======================================================================
3   !!                       ***  MODULE nemogcm   ***
4   !! Ocean system   : NEMO GCM (ocean dynamics, on-line tracers, biochemistry and sea-ice)
5   !!======================================================================
6   !! History :  OPA  ! 1990-10  (C. Levy, G. Madec)  Original code
7   !!            7.0  ! 1991-11  (M. Imbard, C. Levy, G. Madec)
8   !!            7.1  ! 1993-03  (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
9   !!                             P. Delecluse, C. Perigaud, G. Caniaux, B. Colot, C. Maes) release 7.1
10   !!             -   ! 1992-06  (L.Terray)  coupling implementation
11   !!             -   ! 1993-11  (M.A. Filiberti) IGLOO sea-ice
12   !!            8.0  ! 1996-03  (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
13   !!                             P. Delecluse, L.Terray, M.A. Filiberti, J. Vialar, A.M. Treguier, M. Levy) release 8.0
14   !!            8.1  ! 1997-06  (M. Imbard, G. Madec)
15   !!            8.2  ! 1999-11  (M. Imbard, H. Goosse)  LIM sea-ice model
16   !!                 ! 1999-12  (V. Thierry, A-M. Treguier, M. Imbard, M-A. Foujols)  OPEN-MP
17   !!                 ! 2000-07  (J-M Molines, M. Imbard)  Open Boundary Conditions  (CLIPPER)
18   !!   NEMO     1.0  ! 2002-08  (G. Madec)  F90: Free form and modules
19   !!             -   ! 2004-06  (R. Redler, NEC CCRLE, Germany) add OASIS[3/4] coupled interfaces
20   !!             -   ! 2004-08  (C. Talandier) New trends organization
21   !!             -   ! 2005-06  (C. Ethe) Add the 1D configuration possibility
22   !!             -   ! 2005-11  (V. Garnier) Surface pressure gradient organization
23   !!             -   ! 2006-03  (L. Debreu, C. Mazauric)  Agrif implementation
24   !!             -   ! 2006-04  (G. Madec, R. Benshila)  Step reorganization
25   !!             -   ! 2007-07  (J. Chanut, A. Sellar) Unstructured open boundaries (BDY)
26   !!            3.2  ! 2009-08  (S. Masson)  open/write in the listing file in mpp
27   !!            3.3  ! 2010-05  (K. Mogensen, A. Weaver, M. Martin, D. Lea) Assimilation interface
28   !!             -   ! 2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase
29   !!            3.3.1! 2011-01  (A. R. Porter, STFC Daresbury) dynamical allocation
30   !!            3.4  ! 2011-11  (C. Harris) decomposition changes for running with CICE
31   !!                 ! 2012-05  (C. Calone, J. Simeon, G. Madec, C. Ethe) Add grid coarsening
32   !!----------------------------------------------------------------------
33
34   !!----------------------------------------------------------------------
35   !!   nemo_gcm       : solve ocean dynamics, tracer, biogeochemistry and/or sea-ice
36   !!   nemo_init      : initialization of the NEMO system
37   !!   nemo_ctl       : initialisation of the contol print
38   !!   nemo_closefile : close remaining open files
39   !!   nemo_alloc     : dynamical allocation
40   !!   nemo_partition : calculate MPP domain decomposition
41   !!   factorise      : calculate the factors of the no. of MPI processes
42   !!----------------------------------------------------------------------
43   USE dom_oce, ONLY : rdt
44   USE in_out_manager, ONLY : kswr, ksout, mswr, kall, ntsinswr, nsloops, iswloop, lwp, nitrst
45   USE schwarz         ! schwarz subroutines
46   USE step_oce        ! module used in the ocean time stepping module
47   USE cla             ! cross land advection               (tra_cla routine)
48   USE domcfg          ! domain configuration               (dom_cfg routine)
49   USE mppini          ! shared/distributed memory setting (mpp_init routine)
50   USE domain          ! domain initialization             (dom_init routine)
51#if defined key_nemocice_decomp
52   USE ice_domain_size, only: nx_global, ny_global
53#endif
54   USE tideini         ! tidal components initialization   (tide_ini routine)
55   USE bdyini          ! open boundary cond. setting       (bdy_init routine)
56   USE bdydta          ! open boundary cond. setting   (bdy_dta_init routine)
57   USE bdytides        ! open boundary cond. setting   (bdytide_init routine)
58   USE istate          ! initial state setting          (istate_init routine)
59   USE ldfdyn          ! lateral viscosity setting      (ldfdyn_init routine)
60   USE ldftra          ! lateral diffusivity setting    (ldftra_init routine)
61   USE zdfini          ! vertical physics setting          (zdf_init routine)
62   USE phycst          ! physical constant                  (par_cst routine)
63   USE trdini          ! dyn/tra trends initialization     (trd_init routine)
64   USE asminc          ! assimilation increments     
65   USE asmbkg          ! writing out state trajectory
66   USE diaptr          ! poleward transports           (dia_ptr_init routine)
67   USE diadct          ! sections transports           (dia_dct_init routine)
68   USE diaobs          ! Observation diagnostics       (dia_obs_init routine)
69   USE lib_fortran     ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined)
70   USE step            ! NEMO time-stepping                 (stp     routine)
71   USE icbini          ! handle bergs, initialisation
72   USE icbstp          ! handle bergs, calving, themodynamics and transport
73   USE cpl_oasis3      ! OASIS3 coupling
74   USE c1d             ! 1D configuration
75   USE step_c1d        ! Time stepping loop for the 1D configuration
76   USE dyndmp          ! Momentum damping
77#if defined key_top
78   USE trcini          ! passive tracer initialisation
79#endif
80   USE lib_mpp         ! distributed memory computing
81#if defined key_iomput
82   USE xios
83#endif
84   USE sbctide, ONLY: lk_tide
85   USE crsini          ! initialise grid coarsening utility
86   USE lbcnfd, ONLY: isendto, nsndto, nfsloop, nfeloop ! Setup of north fold exchanges
87   USE sbc_oce, ONLY: lk_oasis
88   USE stopar
89   USE stopts
90
91   IMPLICIT NONE
92   PRIVATE
93
94   PUBLIC   nemo_gcm    ! called by model.F90
95   PUBLIC   nemo_init   ! needed by AGRIF
96   PUBLIC   nemo_alloc  ! needed by TAM
97
98   INTEGER :: ncplfrq   ! coupling frequency in seconds : integer
99   CHARACTER(lc) ::   cform_aaa="( /, 'AAAAAAAA', / ) "     ! flag for output listing
100
101   !!----------------------------------------------------------------------
102   !! NEMO/OPA 4.0 , NEMO Consortium (2011)
103   !! $Id: nemogcm.F90 8566 2017-09-27 13:15:25Z mchekki $
104   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
105   !!----------------------------------------------------------------------
106CONTAINS
107
108   SUBROUTINE nemo_gcm
109      !!----------------------------------------------------------------------
110      !!                     ***  ROUTINE nemo_gcm  ***
111      !!
112      !! ** Purpose :   NEMO solves the primitive equations on an orthogonal
113      !!              curvilinear mesh on the sphere.
114      !!
115      !! ** Method  : - model general initialization
116      !!              - launch the time-stepping (stp routine)
117      !!              - finalize the run by closing files and communications
118      !!
119      !! References : Madec, Delecluse, Imbard, and Levy, 1997:  internal report, IPSL.
120      !!              Madec, 2008, internal report, IPSL.
121      !!----------------------------------------------------------------------
122      INTEGER ::   istp       ! time step index
123      !!----------------------------------------------------------------------
124      !
125#if defined key_agrif
126      CALL Agrif_Init_Grids()      ! AGRIF: set the meshes
127#endif
128
129      ntsinswr = 1 !! set to allow fldread in nemo_init before computation of schwarz indices
130      kswr = 0     !! set here to allow day_init to set nitrst properly
131
132      WRITE(numout,*) "ntsinswr = ",ntsinswr
133
134      !                            !-----------------------!
135      CALL nemo_init               !==  Initialisations  ==!
136      !                            !-----------------------!
137
138      !! set integer constants for computation
139      ncplfrq  = 86400 !cpl_freq( 'O_QnsMix' )
140      ntsinswr = ncplfrq / INT(rdt)
141      nsloops  = (nitend-nit000+1)/ntsinswr
142
143      !! outputs to check values
144      IF(lwp) THEN                  ! control print
145         WRITE(numout,*)
146         WRITE(numout,*) ' computation of loop indices for schwarz computation '
147         WRITE(numout,*) '   nit000   = ',nit000
148         WRITE(numout,*) '   nitend   = ',nitend
149         WRITE(numout,*) '   rdt      = ',rdt
150         WRITE(numout,*) '   ncplfrq  = ',ncplfrq
151         WRITE(numout,*) '   ntsinswr = ',ntsinswr
152         WRITE(numout,*) '   nsloops  = ',nsloops 
153         WRITE(numout,*) '   mswr     = ',mswr
154         WRITE(numout,*) '   nitrst   = ',nitrst
155      ENDIF
156
157!      CALL swz_store ! store initial state
158
159
160!      WRITE (extmsg, "(A7,I3)") "narea =", narea
161!      STOP "montest" !extmsg
162!      Write(*,'(A7,I3)') "narea =",narea
163
164!      CALL mppsync   
165
166!      CALL nemo_closefile
167!      CALL xios_finalize
168
169!      CALL cpl_finalize
170
171!      CALL mppstop
172
173!      STOP
174
175#if defined key_agrif
176      CALL Agrif_Declare_Var_dom   ! AGRIF: set the meshes for DOM
177      CALL Agrif_Declare_Var       !  "      "   "   "      "  DYN/TRA
178# if defined key_top
179      CALL Agrif_Declare_Var_top   !  "      "   "   "      "  TOP
180# endif
181# if defined key_lim2
182      CALL Agrif_Declare_Var_lim2  !  "      "   "   "      "  LIM
183# endif
184#endif
185      ! check that all process are still there... If some process have an error,
186      ! they will never enter in step and other processes will wait until the end of the cpu time!
187      IF( lk_mpp )   CALL mpp_max( nstop )
188
189      IF(lwp) WRITE(numout,cform_aaa)   ! Flag AAAAAAA
190
191      !                            !-----------------------!
192      !                            !==   time stepping   ==!
193      !                            !-----------------------!
194      istp = nit000
195#if defined key_c1d
196         DO WHILE ( istp <= nitend .AND. nstop == 0 )
197            CALL stp_c1d( istp )
198            istp = istp + 1
199         END DO
200#else
201          IF( lk_asminc ) THEN
202             IF( ln_bkgwri ) CALL asm_bkg_wri( nit000 - 1 )    ! Output background fields
203             IF( ln_asmdin ) THEN                        ! Direct initialization
204                IF( ln_trainc ) CALL tra_asm_inc( nit000 - 1 )    ! Tracers
205                IF( ln_dyninc ) CALL dyn_asm_inc( nit000 - 1 )    ! Dynamics
206                IF( ln_sshinc ) CALL ssh_asm_inc( nit000 - 1 )    ! SSH
207             ENDIF
208          ENDIF
209
210#if defined key_agrif
211          CALL Agrif_Regrid()
212#endif
213
214         iswloop = 1
215         IF (lwp) WRITE(numout,*) 'init iswloop =',iswloop
216
217         DO WHILE ( iswloop <= nsloops .AND. nstop == 0 ) ! iterate on n schwarz loops
218
219         kswr = 1
220         IF (lwp) THEN
221            WRITE(numout,*) '*** schwarz loops ***'
222            WRITE(numout,*) 'iswloop =',iswloop
223            WRITE(numout,*) 'kswr = ',kswr
224         ENDIF
225         
226         CALL swz_store  ! store Ocean state at first schwarz iteration before first time step
227         CALL swz_store_lim3 ! store lim3 variables state
228         CALL swz_store_limdiahsb ! store limdiahsb variables
229         IF(lwp) WRITE(numout,*) 'store schwarz initial state '
230
231         DO WHILE ( kswr <= mswr .AND. nstop == 0 )
232
233         IF (lwp) WRITE(numout,*) '  kswr = ',kswr
234         istp = nit000 + (iswloop-1)*ntsinswr ! set time step to first value for iswloop (current schwarz loop)
235
236         IF ( kswr > 1 ) CALL swz_reinit(istp) ! reset Ocean state to first time step for new schwarz iteration
237
238         IF (lwp) WRITE(numout,*) 'maxistp  = ',nit000+iswloop*ntsinswr-1
239         DO WHILE ( istp <= nit000+iswloop*ntsinswr-1 .AND. nstop == 0 )
240
241            IF (lwp) WRITE(numout,*) '    istp = ',istp
242#if defined key_agrif
243            CALL stp                         ! AGRIF: time stepping
244#else
245            CALL stp( istp )                 ! standard time stepping
246#endif
247            istp = istp + 1
248            IF( lk_mpp )   CALL mpp_max( nstop )
249         END DO ! istp
250         
251         kswr = kswr + 1
252
253         END DO ! kswr
254
255         iswloop = iswloop +1
256
257         END DO ! iswloop
258
259#endif
260
261      IF( lk_diaobs   )   CALL dia_obs_wri
262      !
263      IF( ln_icebergs )   CALL icb_end( nitend )
264
265      !                            !------------------------!
266      !                            !==  finalize the run  ==!
267      !                            !------------------------!
268      IF(lwp) WRITE(numout,cform_aaa)   ! Flag AAAAAAA
269      !
270      IF( nstop /= 0 .AND. lwp ) THEN   ! error print
271         WRITE(numout,cform_err)
272         WRITE(numout,*) nstop, ' error have been found'
273      ENDIF
274      !
275#if defined key_agrif
276      CALL Agrif_ParentGrid_To_ChildGrid()
277      IF( lk_diaobs ) CALL dia_obs_wri
278      IF( nn_timing == 1 )   CALL timing_finalize
279      CALL Agrif_ChildGrid_To_ParentGrid()
280#endif
281      IF( nn_timing == 1 )   CALL timing_finalize
282      !
283      CALL nemo_closefile
284      !
285#if defined key_iomput
286      CALL xios_finalize                ! end mpp communications with xios
287      IF( lk_oasis ) CALL cpl_finalize    ! end coupling and mpp communications with OASIS
288#else
289      IF( lk_oasis ) THEN
290         CALL cpl_finalize              ! end coupling and mpp communications with OASIS
291      ELSE
292         IF( lk_mpp )   CALL mppstop    ! end mpp communications
293      ENDIF
294#endif
295      !
296   END SUBROUTINE nemo_gcm
297
298
299   SUBROUTINE nemo_init
300      !!----------------------------------------------------------------------
301      !!                     ***  ROUTINE nemo_init  ***
302      !!
303      !! ** Purpose :   initialization of the NEMO GCM
304      !!----------------------------------------------------------------------
305      INTEGER ::   ji            ! dummy loop indices
306      INTEGER ::   ilocal_comm   ! local integer
307      INTEGER ::   ios
308      CHARACTER(len=80), DIMENSION(16) ::   cltxt
309      !
310      NAMELIST/namctl/ ln_ctl  , nn_print, nn_ictls, nn_ictle,   &
311         &             nn_isplt, nn_jsplt, nn_jctls, nn_jctle,   &
312         &             nn_bench, nn_timing
313      NAMELIST/namcfg/ cp_cfg, cp_cfz, jp_cfg, jpidta, jpjdta, jpkdta, jpiglo, jpjglo, &
314         &             jpizoom, jpjzoom, jperio, ln_use_jattr
315      !!----------------------------------------------------------------------
316      !
317      cltxt = ''
318      cxios_context = 'nemo'
319      !
320      !                             ! Open reference namelist and configuration namelist files
321      CALL ctl_opn( numnam_ref, 'namelist_ref', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
322      CALL ctl_opn( numnam_cfg, 'namelist_cfg', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
323      !
324      REWIND( numnam_ref )              ! Namelist namctl in reference namelist : Control prints & Benchmark
325      READ  ( numnam_ref, namctl, IOSTAT = ios, ERR = 901 )
326901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namctl in reference namelist', .TRUE. )
327
328      REWIND( numnam_cfg )              ! Namelist namctl in confguration namelist : Control prints & Benchmark
329      READ  ( numnam_cfg, namctl, IOSTAT = ios, ERR = 902 )
330902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namctl in configuration namelist', .TRUE. )
331
332      !
333      REWIND( numnam_ref )              ! Namelist namcfg in reference namelist : Control prints & Benchmark
334      READ  ( numnam_ref, namcfg, IOSTAT = ios, ERR = 903 )
335903   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namcfg in reference namelist', .TRUE. )
336
337      REWIND( numnam_cfg )              ! Namelist namcfg in confguration namelist : Control prints & Benchmark
338      READ  ( numnam_cfg, namcfg, IOSTAT = ios, ERR = 904 )
339904   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namcfg in configuration namelist', .TRUE. )   
340
341! Force values for AGRIF zoom (cf. agrif_user.F90)
342#if defined key_agrif
343   IF( .NOT. Agrif_Root() ) THEN
344      jpiglo  = nbcellsx + 2 + 2*nbghostcells
345      jpjglo  = nbcellsy + 2 + 2*nbghostcells
346      jpi     = ( jpiglo-2*jpreci + (jpni-1+0) ) / jpni + 2*jpreci
347      jpj     = ( jpjglo-2*jprecj + (jpnj-1+0) ) / jpnj + 2*jprecj
348      jpidta  = jpiglo
349      jpjdta  = jpjglo
350      jpizoom = 1
351      jpjzoom = 1
352      nperio  = 0
353      jperio  = 0
354      ln_use_jattr = .false.
355   ENDIF
356#endif
357      !
358      !                             !--------------------------------------------!
359      !                             !  set communicator & select the local node  !
360      !                             !  NB: mynode also opens output.namelist.dyn !
361      !                             !      on unit number numond on first proc   !
362      !                             !--------------------------------------------!
363#if defined key_iomput
364      IF( Agrif_Root() ) THEN
365         IF( lk_oasis ) THEN
366            CALL cpl_init( "oceanx", ilocal_comm )                     ! nemo local communicator given by oasis
367            CALL xios_initialize( "not used",local_comm=ilocal_comm )    ! send nemo communicator to xios
368         ELSE
369            CALL  xios_initialize( "for_xios_mpi_id",return_comm=ilocal_comm )    ! nemo local communicator given by xios
370         ENDIF
371      ENDIF
372      ! Nodes selection (control print return in cltxt)
373      narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop, ilocal_comm )
374#else
375      IF( lk_oasis ) THEN
376         IF( Agrif_Root() ) THEN
377            CALL cpl_init( "oceanx", ilocal_comm )                      ! nemo local communicator given by oasis
378         ENDIF
379         ! Nodes selection (control print return in cltxt)
380         narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop, ilocal_comm )
381      ELSE
382         ilocal_comm = 0
383         ! Nodes selection (control print return in cltxt)
384         narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop )
385      ENDIF
386#endif
387      narea = narea + 1                                     ! mynode return the rank of proc (0 --> jpnij -1 )
388
389      lwm = (narea == 1)                                    ! control of output namelists
390      lwp = (narea == 1) .OR. ln_ctl                        ! control of all listing output print
391
392      IF(lwm) THEN
393         ! write merged namelists from earlier to output namelist now that the
394         ! file has been opened in call to mynode. nammpp has already been
395         ! written in mynode (if lk_mpp_mpi)
396         WRITE( numond, namctl )
397         WRITE( numond, namcfg )
398      ENDIF
399
400      ! If dimensions of processor grid weren't specified in the namelist file
401      ! then we calculate them here now that we have our communicator size
402      IF( (jpni < 1) .OR. (jpnj < 1) )THEN
403#if   defined key_mpp_mpi
404         IF( Agrif_Root() ) CALL nemo_partition(mppsize)
405#else
406         jpni  = 1
407         jpnj  = 1
408         jpnij = jpni*jpnj
409#endif
410      END IF
411
412      ! Calculate domain dimensions given calculated jpni and jpnj
413      ! This used to be done in par_oce.F90 when they were parameters rather
414      ! than variables
415      IF( Agrif_Root() ) THEN
416#if defined key_nemocice_decomp
417         jpi = ( nx_global+2-2*jpreci + (jpni-1) ) / jpni + 2*jpreci ! first  dim.
418         jpj = ( ny_global+2-2*jprecj + (jpnj-1) ) / jpnj + 2*jprecj ! second dim.
419#else
420         jpi = ( jpiglo-2*jpreci + (jpni-1) ) / jpni + 2*jpreci   ! first  dim.
421         jpj = ( jpjglo-2*jprecj + (jpnj-1) ) / jpnj + 2*jprecj   ! second dim.
422#endif
423      ENDIF         
424         jpk = jpkdta                                             ! third dim
425#if defined key_agrif
426         ! simple trick to use same vertical grid as parent
427         ! but different number of levels:
428         ! Save maximum number of levels in jpkdta, then define all vertical grids
429         ! with this number.
430         ! Suppress once vertical online interpolation is ok
431         IF(.NOT.Agrif_Root()) jpkdta = Agrif_Parent(jpkdta)
432#endif
433         jpim1 = jpi-1                                            ! inner domain indices
434         jpjm1 = jpj-1                                            !   "           "
435         jpkm1 = jpk-1                                            !   "           "
436         jpij  = jpi*jpj                                          !  jpi x j
437
438      IF(lwp) THEN                            ! open listing units
439         !
440         CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE., narea )
441         !
442         WRITE(numout,*)
443         WRITE(numout,*) '   CNRS - NERC - Met OFFICE - MERCATOR-ocean - INGV - CMCC'
444         WRITE(numout,*) '                       NEMO team'
445         WRITE(numout,*) '            Ocean General Circulation Model'
446         WRITE(numout,*) '                  version 3.6  (2015) '
447         WRITE(numout,*)
448         WRITE(numout,*)
449         DO ji = 1, SIZE(cltxt)
450            IF( TRIM(cltxt(ji)) /= '' )   WRITE(numout,*) cltxt(ji)      ! control print of mynode
451         END DO
452         WRITE(numout,cform_aaa)                                         ! Flag AAAAAAA
453         !
454      ENDIF
455
456      ! Now we know the dimensions of the grid and numout has been set we can
457      ! allocate arrays
458      CALL nemo_alloc()
459
460      !                             !-------------------------------!
461      !                             !  NEMO general initialization  !
462      !                             !-------------------------------!
463
464      CALL nemo_ctl                          ! Control prints & Benchmark
465
466      !                                      ! Domain decomposition
467      IF( jpni*jpnj == jpnij ) THEN   ;   CALL mpp_init      ! standard cutting out
468      ELSE                            ;   CALL mpp_init2     ! eliminate land processors
469      ENDIF
470      !
471      IF( nn_timing == 1 )  CALL timing_init
472      !
473      !                                      ! General initialization
474                            CALL     phy_cst    ! Physical constants
475                            CALL     eos_init   ! Equation of state
476      IF( lk_c1d        )   CALL     c1d_init   ! 1D column configuration
477                            CALL     dom_cfg    ! Domain configuration
478                            CALL     dom_init   ! Domain
479
480      IF( ln_nnogather )    CALL nemo_northcomms   ! Initialise the northfold neighbour lists (must be done after the masks are defined)
481
482      IF( ln_ctl        )   CALL prt_ctl_init   ! Print control
483
484                            CALL  istate_init   ! ocean initial state (Dynamics and tracers)
485
486      IF( lk_tide       )   CALL    tide_init( nit000 )    ! Initialisation of the tidal harmonics
487
488                            CALL     sbc_init   ! Forcings : surface module (clem: moved here for bdy purpose)
489
490      IF( lk_bdy        )   CALL     bdy_init   ! Open boundaries initialisation
491      IF( lk_bdy        )   CALL bdy_dta_init   ! Open boundaries initialisation of external data arrays
492      IF( lk_bdy .AND. lk_tide )   &
493         &                  CALL bdytide_init   ! Open boundaries initialisation of tidal harmonic forcing
494
495                            CALL dyn_nept_init  ! simplified form of Neptune effect
496      !     
497      IF( ln_crs        )   CALL     crs_init   ! Domain initialization of coarsened grid
498      !
499                                ! Ocean physics
500      !                                         ! Vertical physics
501                            CALL     zdf_init      ! namelist read
502                            CALL zdf_bfr_init      ! bottom friction
503      IF( lk_zdfric     )   CALL zdf_ric_init      ! Richardson number dependent Kz
504      IF( lk_zdftke     )   CALL zdf_tke_init      ! TKE closure scheme
505      IF( lk_zdfgls     )   CALL zdf_gls_init      ! GLS closure scheme
506      IF( lk_zdfkpp     )   CALL zdf_kpp_init      ! KPP closure scheme
507      IF( lk_zdftmx     )   CALL zdf_tmx_init      ! tidal vertical mixing
508      IF( lk_zdfddm .AND. .NOT. lk_zdfkpp )   &
509         &                  CALL zdf_ddm_init      ! double diffusive mixing
510      !                                         ! Lateral physics
511                            CALL ldf_tra_init      ! Lateral ocean tracer physics
512                            CALL ldf_dyn_init      ! Lateral ocean momentum physics
513      IF( lk_ldfslp     )   CALL ldf_slp_init      ! slope of lateral mixing
514
515      !                                     ! Active tracers
516                            CALL tra_qsr_init   ! penetrative solar radiation qsr
517                            CALL tra_bbc_init   ! bottom heat flux
518      IF( lk_trabbl     )   CALL tra_bbl_init   ! advective (and/or diffusive) bottom boundary layer scheme
519                            CALL tra_dmp_init   ! internal damping trends- tracers
520                            CALL tra_adv_init   ! horizontal & vertical advection
521                            CALL tra_ldf_init   ! lateral mixing
522                            CALL tra_zdf_init   ! vertical mixing and after tracer fields
523
524      !                                     ! Dynamics
525      IF( lk_c1d        )   CALL dyn_dmp_init   ! internal damping trends- momentum
526                            CALL dyn_adv_init   ! advection (vector or flux form)
527                            CALL dyn_vor_init   ! vorticity term including Coriolis
528                            CALL dyn_ldf_init   ! lateral mixing
529                            CALL dyn_hpg_init   ! horizontal gradient of Hydrostatic pressure
530                            CALL dyn_zdf_init   ! vertical diffusion
531                            CALL dyn_spg_init   ! surface pressure gradient
532
533      !                                     ! Misc. options
534      IF( nn_cla == 1 .AND. cp_cfg == 'orca' .AND. jp_cfg == 2 )   CALL cla_init       ! Cross Land Advection
535                            CALL icb_init( rdt, nit000)   ! initialise icebergs instance
536                            CALL sto_par_init   ! Stochastic parametrization
537      IF( ln_sto_eos     )  CALL sto_pts_init   ! RRandom T/S fluctuations
538     
539#if defined key_top
540      !                                     ! Passive tracers
541                            CALL     trc_init
542#endif
543      !                                     ! Diagnostics
544      IF( lk_floats     )   CALL     flo_init   ! drifting Floats
545                            CALL dia_ptr_init   ! Poleward TRansports initialization
546      IF( lk_diadct     )   CALL dia_dct_init   ! Sections tranports
547                            CALL dia_hsb_init   ! heat content, salt content and volume budgets
548                            CALL     trd_init   ! Mixed-layer/Vorticity/Integral constraints trends
549      IF( lk_diaobs     ) THEN                  ! Observation & model comparison
550                            CALL dia_obs_init            ! Initialize observational data
551                            CALL dia_obs( nit000 - 1 )   ! Observation operator for restart
552      ENDIF
553
554      !                                     ! Assimilation increments
555      IF( lk_asminc     )   CALL asm_inc_init   ! Initialize assimilation increments
556      IF(lwp) WRITE(numout,*) 'Euler time step switch is ', neuler
557      !
558   END SUBROUTINE nemo_init
559
560
561   SUBROUTINE nemo_ctl
562      !!----------------------------------------------------------------------
563      !!                     ***  ROUTINE nemo_ctl  ***
564      !!
565      !! ** Purpose :   control print setting
566      !!
567      !! ** Method  : - print namctl information and check some consistencies
568      !!----------------------------------------------------------------------
569      !
570      IF(lwp) THEN                  ! control print
571         WRITE(numout,*)
572         WRITE(numout,*) 'nemo_ctl: Control prints & Benchmark'
573         WRITE(numout,*) '~~~~~~~ '
574         WRITE(numout,*) '   Namelist namctl'
575         WRITE(numout,*) '      run control (for debugging)     ln_ctl     = ', ln_ctl
576         WRITE(numout,*) '      level of print                  nn_print   = ', nn_print
577         WRITE(numout,*) '      Start i indice for SUM control  nn_ictls   = ', nn_ictls
578         WRITE(numout,*) '      End i indice for SUM control    nn_ictle   = ', nn_ictle
579         WRITE(numout,*) '      Start j indice for SUM control  nn_jctls   = ', nn_jctls
580         WRITE(numout,*) '      End j indice for SUM control    nn_jctle   = ', nn_jctle
581         WRITE(numout,*) '      number of proc. following i     nn_isplt   = ', nn_isplt
582         WRITE(numout,*) '      number of proc. following j     nn_jsplt   = ', nn_jsplt
583         WRITE(numout,*) '      benchmark parameter (0/1)       nn_bench   = ', nn_bench
584         WRITE(numout,*) '      timing activated    (0/1)       nn_timing  = ', nn_timing
585      ENDIF
586      !
587      nprint    = nn_print          ! convert DOCTOR namelist names into OLD names
588      nictls    = nn_ictls
589      nictle    = nn_ictle
590      njctls    = nn_jctls
591      njctle    = nn_jctle
592      isplt     = nn_isplt
593      jsplt     = nn_jsplt
594      nbench    = nn_bench
595
596      IF(lwp) THEN                  ! control print
597         WRITE(numout,*)
598         WRITE(numout,*) 'namcfg  : configuration initialization through namelist read'
599         WRITE(numout,*) '~~~~~~~ '
600         WRITE(numout,*) '   Namelist namcfg'
601         WRITE(numout,*) '      configuration name              cp_cfg      = ', TRIM(cp_cfg)
602         WRITE(numout,*) '      configuration zoom name         cp_cfz      = ', TRIM(cp_cfz)
603         WRITE(numout,*) '      configuration resolution        jp_cfg      = ', jp_cfg
604         WRITE(numout,*) '      1st lateral dimension ( >= jpi ) jpidta     = ', jpidta
605         WRITE(numout,*) '      2nd    "         "    ( >= jpj ) jpjdta     = ', jpjdta
606         WRITE(numout,*) '      3nd    "         "               jpkdta     = ', jpkdta
607         WRITE(numout,*) '      1st dimension of global domain in i jpiglo  = ', jpiglo
608         WRITE(numout,*) '      2nd    -                  -    in j jpjglo  = ', jpjglo
609         WRITE(numout,*) '      left bottom i index of the zoom (in data domain) jpizoom = ', jpizoom
610         WRITE(numout,*) '      left bottom j index of the zoom (in data domain) jpizoom = ', jpjzoom
611         WRITE(numout,*) '      lateral cond. type (between 0 and 6) jperio = ', jperio   
612         WRITE(numout,*) '      use file attribute if exists as i/p j-start ln_use_jattr = ', ln_use_jattr
613      ENDIF
614      !                             ! Parameter control
615      !
616      IF( ln_ctl ) THEN                 ! sub-domain area indices for the control prints
617         IF( lk_mpp .AND. jpnij > 1 ) THEN
618            isplt = jpni   ;   jsplt = jpnj   ;   ijsplt = jpni*jpnj   ! the domain is forced to the real split domain
619         ELSE
620            IF( isplt == 1 .AND. jsplt == 1  ) THEN
621               CALL ctl_warn( ' - isplt & jsplt are equal to 1',   &
622                  &           ' - the print control will be done over the whole domain' )
623            ENDIF
624            ijsplt = isplt * jsplt            ! total number of processors ijsplt
625         ENDIF
626         IF(lwp) WRITE(numout,*)'          - The total number of processors over which the'
627         IF(lwp) WRITE(numout,*)'            print control will be done is ijsplt : ', ijsplt
628         !
629         !                              ! indices used for the SUM control
630         IF( nictls+nictle+njctls+njctle == 0 )   THEN    ! print control done over the default area
631            lsp_area = .FALSE.
632         ELSE                                             ! print control done over a specific  area
633            lsp_area = .TRUE.
634            IF( nictls < 1 .OR. nictls > jpiglo )   THEN
635               CALL ctl_warn( '          - nictls must be 1<=nictls>=jpiglo, it is forced to 1' )
636               nictls = 1
637            ENDIF
638            IF( nictle < 1 .OR. nictle > jpiglo )   THEN
639               CALL ctl_warn( '          - nictle must be 1<=nictle>=jpiglo, it is forced to jpiglo' )
640               nictle = jpiglo
641            ENDIF
642            IF( njctls < 1 .OR. njctls > jpjglo )   THEN
643               CALL ctl_warn( '          - njctls must be 1<=njctls>=jpjglo, it is forced to 1' )
644               njctls = 1
645            ENDIF
646            IF( njctle < 1 .OR. njctle > jpjglo )   THEN
647               CALL ctl_warn( '          - njctle must be 1<=njctle>=jpjglo, it is forced to jpjglo' )
648               njctle = jpjglo
649            ENDIF
650         ENDIF
651      ENDIF
652      !
653      IF( nbench == 1 ) THEN              ! Benchmark
654         SELECT CASE ( cp_cfg )
655         CASE ( 'gyre' )   ;   CALL ctl_warn( ' The Benchmark is activated ' )
656         CASE DEFAULT      ;   CALL ctl_stop( ' The Benchmark is based on the GYRE configuration:',   &
657            &                                 ' cp_cfg = "gyre" in namelist &namcfg or set nbench = 0' )
658         END SELECT
659      ENDIF
660      !
661      IF( 1_wp /= SIGN(1._wp,-0._wp)  )   CALL ctl_stop( 'nemo_ctl: The intrinsec SIGN function follows ',  &
662         &                                               'f2003 standard. '                              ,  &
663         &                                               'Compile with key_nosignedzero enabled' )
664      !
665   END SUBROUTINE nemo_ctl
666
667
668   SUBROUTINE nemo_closefile
669      !!----------------------------------------------------------------------
670      !!                     ***  ROUTINE nemo_closefile  ***
671      !!
672      !! ** Purpose :   Close the files
673      !!----------------------------------------------------------------------
674      !
675      IF( lk_mpp )   CALL mppsync
676      !
677      CALL iom_close                                 ! close all input/output files managed by iom_*
678      !
679      IF( numstp          /= -1 )   CLOSE( numstp          )   ! time-step file
680      IF( numsol          /= -1 )   CLOSE( numsol          )   ! solver file
681      IF( numnam_ref      /= -1 )   CLOSE( numnam_ref      )   ! oce reference namelist
682      IF( numnam_cfg      /= -1 )   CLOSE( numnam_cfg      )   ! oce configuration namelist
683      IF( lwm.AND.numond  /= -1 )   CLOSE( numond          )   ! oce output namelist
684      IF( numnam_ice_ref  /= -1 )   CLOSE( numnam_ice_ref  )   ! ice reference namelist
685      IF( numnam_ice_cfg  /= -1 )   CLOSE( numnam_ice_cfg  )   ! ice configuration namelist
686      IF( lwm.AND.numoni  /= -1 )   CLOSE( numoni          )   ! ice output namelist
687      IF( numevo_ice      /= -1 )   CLOSE( numevo_ice      )   ! ice variables (temp. evolution)
688      IF( numout          /=  6 )   CLOSE( numout          )   ! standard model output file
689      IF( numdct_vol      /= -1 )   CLOSE( numdct_vol      )   ! volume transports
690      IF( numdct_heat     /= -1 )   CLOSE( numdct_heat     )   ! heat transports
691      IF( numdct_salt     /= -1 )   CLOSE( numdct_salt     )   ! salt transports
692
693      !
694      numout = 6                                     ! redefine numout in case it is used after this point...
695      !
696   END SUBROUTINE nemo_closefile
697
698
699   SUBROUTINE nemo_alloc
700      !!----------------------------------------------------------------------
701      !!                     ***  ROUTINE nemo_alloc  ***
702      !!
703      !! ** Purpose :   Allocate all the dynamic arrays of the OPA modules
704      !!
705      !! ** Method  :
706      !!----------------------------------------------------------------------
707      USE diawri    , ONLY: dia_wri_alloc
708      USE dom_oce   , ONLY: dom_oce_alloc
709      USE ldfdyn_oce, ONLY: ldfdyn_oce_alloc
710      USE ldftra_oce, ONLY: ldftra_oce_alloc
711      USE trc_oce   , ONLY: trc_oce_alloc
712#if defined key_diadct 
713      USE diadct    , ONLY: diadct_alloc 
714#endif 
715#if defined key_bdy
716      USE bdy_oce   , ONLY: bdy_oce_alloc
717#endif
718      !
719      INTEGER :: ierr
720      !!----------------------------------------------------------------------
721      !
722      ierr =        oce_alloc       ()          ! ocean
723      ierr = ierr + dia_wri_alloc   ()
724      ierr = ierr + dom_oce_alloc   ()          ! ocean domain
725      ierr = ierr + ldfdyn_oce_alloc()          ! ocean lateral  physics : dynamics
726      ierr = ierr + ldftra_oce_alloc()          ! ocean lateral  physics : tracers
727      ierr = ierr + zdf_oce_alloc   ()          ! ocean vertical physics
728      !
729      ierr = ierr + trc_oce_alloc   ()          ! shared TRC / TRA arrays
730      !
731#if defined key_diadct 
732      ierr = ierr + diadct_alloc    ()          !
733#endif 
734#if defined key_bdy
735      ierr = ierr + bdy_oce_alloc   ()          ! bdy masks (incl. initialization)
736#endif
737      !
738      IF( lk_mpp    )   CALL mpp_sum( ierr )
739      IF( ierr /= 0 )   CALL ctl_stop( 'STOP', 'nemo_alloc : unable to allocate standard ocean arrays' )
740      !
741   END SUBROUTINE nemo_alloc
742
743
744   SUBROUTINE nemo_partition( num_pes )
745      !!----------------------------------------------------------------------
746      !!                 ***  ROUTINE nemo_partition  ***
747      !!
748      !! ** Purpose :
749      !!
750      !! ** Method  :
751      !!----------------------------------------------------------------------
752      INTEGER, INTENT(in) ::   num_pes   ! The number of MPI processes we have
753      !
754      INTEGER, PARAMETER :: nfactmax = 20
755      INTEGER :: nfact ! The no. of factors returned
756      INTEGER :: ierr  ! Error flag
757      INTEGER :: ji
758      INTEGER :: idiff, mindiff, imin ! For choosing pair of factors that are closest in value
759      INTEGER, DIMENSION(nfactmax) :: ifact ! Array of factors
760      !!----------------------------------------------------------------------
761      !
762      ierr = 0
763      !
764      CALL factorise( ifact, nfactmax, nfact, num_pes, ierr )
765      !
766      IF( nfact <= 1 ) THEN
767         WRITE (numout, *) 'WARNING: factorisation of number of PEs failed'
768         WRITE (numout, *) '       : using grid of ',num_pes,' x 1'
769         jpnj = 1
770         jpni = num_pes
771      ELSE
772         ! Search through factors for the pair that are closest in value
773         mindiff = 1000000
774         imin    = 1
775         DO ji = 1, nfact-1, 2
776            idiff = ABS( ifact(ji) - ifact(ji+1) )
777            IF( idiff < mindiff ) THEN
778               mindiff = idiff
779               imin = ji
780            ENDIF
781         END DO
782         jpnj = ifact(imin)
783         jpni = ifact(imin + 1)
784      ENDIF
785      !
786      jpnij = jpni*jpnj
787      !
788   END SUBROUTINE nemo_partition
789
790
791   SUBROUTINE factorise( kfax, kmaxfax, knfax, kn, kerr )
792      !!----------------------------------------------------------------------
793      !!                     ***  ROUTINE factorise  ***
794      !!
795      !! ** Purpose :   return the prime factors of n.
796      !!                knfax factors are returned in array kfax which is of
797      !!                maximum dimension kmaxfax.
798      !! ** Method  :
799      !!----------------------------------------------------------------------
800      INTEGER                    , INTENT(in   ) ::   kn, kmaxfax
801      INTEGER                    , INTENT(  out) ::   kerr, knfax
802      INTEGER, DIMENSION(kmaxfax), INTENT(  out) ::   kfax
803      !
804      INTEGER :: ifac, jl, inu
805      INTEGER, PARAMETER :: ntest = 14
806      INTEGER, DIMENSION(ntest) :: ilfax
807      !
808      ! ilfax contains the set of allowed factors.
809      ilfax(:) = (/(2**jl,jl=ntest,1,-1)/)
810
811      ! Clear the error flag and initialise output vars
812      kerr = 0
813      kfax = 1
814      knfax = 0
815
816      ! Find the factors of n.
817      IF( kn == 1 )   GOTO 20
818
819      ! nu holds the unfactorised part of the number.
820      ! knfax holds the number of factors found.
821      ! l points to the allowed factor list.
822      ! ifac holds the current factor.
823
824      inu   = kn
825      knfax = 0
826
827      DO jl = ntest, 1, -1
828         !
829         ifac = ilfax(jl)
830         IF( ifac > inu )   CYCLE
831
832         ! Test whether the factor will divide.
833
834         IF( MOD(inu,ifac) == 0 ) THEN
835            !
836            knfax = knfax + 1            ! Add the factor to the list
837            IF( knfax > kmaxfax ) THEN
838               kerr = 6
839               write (*,*) 'FACTOR: insufficient space in factor array ', knfax
840               return
841            ENDIF
842            kfax(knfax) = ifac
843            ! Store the other factor that goes with this one
844            knfax = knfax + 1
845            kfax(knfax) = inu / ifac
846            !WRITE (*,*) 'ARPDBG, factors ',knfax-1,' & ',knfax,' are ', kfax(knfax-1),' and ',kfax(knfax)
847         ENDIF
848         !
849      END DO
850
851   20 CONTINUE      ! Label 20 is the exit point from the factor search loop.
852      !
853   END SUBROUTINE factorise
854
855#if defined key_mpp_mpi
856
857   SUBROUTINE nemo_northcomms
858      !!======================================================================
859      !!                     ***  ROUTINE  nemo_northcomms  ***
860      !! nemo_northcomms    :  Setup for north fold exchanges with explicit
861      !!                       point-to-point messaging
862      !!=====================================================================
863      !!----------------------------------------------------------------------
864      !!
865      !! ** Purpose :   Initialization of the northern neighbours lists.
866      !!----------------------------------------------------------------------
867      !!    1.0  ! 2011-10  (A. C. Coward, NOCS & J. Donners, PRACE)
868      !!    2.0  ! 2013-06 Setup avoiding MPI communication (I. Epicoco, S. Mocavero, CMCC)
869      !!----------------------------------------------------------------------
870
871      INTEGER  ::   sxM, dxM, sxT, dxT, jn
872      INTEGER  ::   njmppmax
873
874      njmppmax = MAXVAL( njmppt )
875   
876      !initializes the north-fold communication variables
877      isendto(:) = 0
878      nsndto = 0
879
880      !if I am a process in the north
881      IF ( njmpp == njmppmax ) THEN
882          !sxM is the first point (in the global domain) needed to compute the
883          !north-fold for the current process
884          sxM = jpiglo - nimppt(narea) - nlcit(narea) + 1
885          !dxM is the last point (in the global domain) needed to compute the
886          !north-fold for the current process
887          dxM = jpiglo - nimppt(narea) + 2
888
889          !loop over the other north-fold processes to find the processes
890          !managing the points belonging to the sxT-dxT range
891 
892          DO jn = 1, jpni
893                !sxT is the first point (in the global domain) of the jn
894                !process
895                sxT = nfiimpp(jn, jpnj)
896                !dxT is the last point (in the global domain) of the jn
897                !process
898                dxT = nfiimpp(jn, jpnj) + nfilcit(jn, jpnj) - 1
899                IF ((sxM .gt. sxT) .AND. (sxM .lt. dxT)) THEN
900                   nsndto = nsndto + 1
901                     isendto(nsndto) = jn
902                ELSEIF ((sxM .le. sxT) .AND. (dxM .ge. dxT)) THEN
903                   nsndto = nsndto + 1
904                     isendto(nsndto) = jn
905                ELSEIF ((dxM .lt. dxT) .AND. (sxT .lt. dxM)) THEN
906                   nsndto = nsndto + 1
907                     isendto(nsndto) = jn
908                END IF
909          END DO
910          nfsloop = 1
911          nfeloop = nlci
912          DO jn = 2,jpni-1
913           IF(nfipproc(jn,jpnj) .eq. (narea - 1)) THEN
914              IF (nfipproc(jn - 1 ,jpnj) .eq. -1) THEN
915                 nfsloop = nldi
916              ENDIF
917              IF (nfipproc(jn + 1,jpnj) .eq. -1) THEN
918                 nfeloop = nlei
919              ENDIF
920           ENDIF
921        END DO
922
923      ENDIF
924      l_north_nogather = .TRUE.
925   END SUBROUTINE nemo_northcomms
926#else
927   SUBROUTINE nemo_northcomms      ! Dummy routine
928      WRITE(*,*) 'nemo_northcomms: You should not have seen this print! error?'
929   END SUBROUTINE nemo_northcomms
930#endif
931
932   !!======================================================================
933END MODULE nemogcm
934
935
Note: See TracBrowser for help on using the repository browser.