source: SCHWARZ_ORCA2LIM3/SOURCES/NEMO/nemogcm.F90 @ 6

Last change on this file since 6 was 6, checked in by snguyen, 3 years ago

updated SOURCES/NEMO for schwarz

File size: 42.2 KB
Line 
1MODULE nemogcm
2   !!======================================================================
3   !!                       ***  MODULE nemogcm   ***
4   !! Ocean system   : NEMO GCM (ocean dynamics, on-line tracers, biochemistry and sea-ice)
5   !!======================================================================
6   !! History :  OPA  ! 1990-10  (C. Levy, G. Madec)  Original code
7   !!            7.0  ! 1991-11  (M. Imbard, C. Levy, G. Madec)
8   !!            7.1  ! 1993-03  (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
9   !!                             P. Delecluse, C. Perigaud, G. Caniaux, B. Colot, C. Maes) release 7.1
10   !!             -   ! 1992-06  (L.Terray)  coupling implementation
11   !!             -   ! 1993-11  (M.A. Filiberti) IGLOO sea-ice
12   !!            8.0  ! 1996-03  (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
13   !!                             P. Delecluse, L.Terray, M.A. Filiberti, J. Vialar, A.M. Treguier, M. Levy) release 8.0
14   !!            8.1  ! 1997-06  (M. Imbard, G. Madec)
15   !!            8.2  ! 1999-11  (M. Imbard, H. Goosse)  LIM sea-ice model
16   !!                 ! 1999-12  (V. Thierry, A-M. Treguier, M. Imbard, M-A. Foujols)  OPEN-MP
17   !!                 ! 2000-07  (J-M Molines, M. Imbard)  Open Boundary Conditions  (CLIPPER)
18   !!   NEMO     1.0  ! 2002-08  (G. Madec)  F90: Free form and modules
19   !!             -   ! 2004-06  (R. Redler, NEC CCRLE, Germany) add OASIS[3/4] coupled interfaces
20   !!             -   ! 2004-08  (C. Talandier) New trends organization
21   !!             -   ! 2005-06  (C. Ethe) Add the 1D configuration possibility
22   !!             -   ! 2005-11  (V. Garnier) Surface pressure gradient organization
23   !!             -   ! 2006-03  (L. Debreu, C. Mazauric)  Agrif implementation
24   !!             -   ! 2006-04  (G. Madec, R. Benshila)  Step reorganization
25   !!             -   ! 2007-07  (J. Chanut, A. Sellar) Unstructured open boundaries (BDY)
26   !!            3.2  ! 2009-08  (S. Masson)  open/write in the listing file in mpp
27   !!            3.3  ! 2010-05  (K. Mogensen, A. Weaver, M. Martin, D. Lea) Assimilation interface
28   !!             -   ! 2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase
29   !!            3.3.1! 2011-01  (A. R. Porter, STFC Daresbury) dynamical allocation
30   !!            3.4  ! 2011-11  (C. Harris) decomposition changes for running with CICE
31   !!                 ! 2012-05  (C. Calone, J. Simeon, G. Madec, C. Ethe) Add grid coarsening
32   !!----------------------------------------------------------------------
33
34   !!----------------------------------------------------------------------
35   !!   nemo_gcm       : solve ocean dynamics, tracer, biogeochemistry and/or sea-ice
36   !!   nemo_init      : initialization of the NEMO system
37   !!   nemo_ctl       : initialisation of the contol print
38   !!   nemo_closefile : close remaining open files
39   !!   nemo_alloc     : dynamical allocation
40   !!   nemo_partition : calculate MPP domain decomposition
41   !!   factorise      : calculate the factors of the no. of MPI processes
42   !!----------------------------------------------------------------------
43   USE dom_oce, ONLY : rdt
44   USE in_out_manager, ONLY : kswr, ksout, mswr, kall, ntsinswr, nsloops, iswloop, lwp
45   USE schwarz         ! schwarz subroutines
46   USE step_oce        ! module used in the ocean time stepping module
47   USE cla             ! cross land advection               (tra_cla routine)
48   USE domcfg          ! domain configuration               (dom_cfg routine)
49   USE mppini          ! shared/distributed memory setting (mpp_init routine)
50   USE domain          ! domain initialization             (dom_init routine)
51#if defined key_nemocice_decomp
52   USE ice_domain_size, only: nx_global, ny_global
53#endif
54   USE tideini         ! tidal components initialization   (tide_ini routine)
55   USE bdyini          ! open boundary cond. setting       (bdy_init routine)
56   USE bdydta          ! open boundary cond. setting   (bdy_dta_init routine)
57   USE bdytides        ! open boundary cond. setting   (bdytide_init routine)
58   USE istate          ! initial state setting          (istate_init routine)
59   USE ldfdyn          ! lateral viscosity setting      (ldfdyn_init routine)
60   USE ldftra          ! lateral diffusivity setting    (ldftra_init routine)
61   USE zdfini          ! vertical physics setting          (zdf_init routine)
62   USE phycst          ! physical constant                  (par_cst routine)
63   USE trdini          ! dyn/tra trends initialization     (trd_init routine)
64   USE asminc          ! assimilation increments     
65   USE asmbkg          ! writing out state trajectory
66   USE diaptr          ! poleward transports           (dia_ptr_init routine)
67   USE diadct          ! sections transports           (dia_dct_init routine)
68   USE diaobs          ! Observation diagnostics       (dia_obs_init routine)
69   USE lib_fortran     ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined)
70   USE step            ! NEMO time-stepping                 (stp     routine)
71   USE icbini          ! handle bergs, initialisation
72   USE icbstp          ! handle bergs, calving, themodynamics and transport
73   USE cpl_oasis3      ! OASIS3 coupling
74   USE c1d             ! 1D configuration
75   USE step_c1d        ! Time stepping loop for the 1D configuration
76   USE dyndmp          ! Momentum damping
77#if defined key_top
78   USE trcini          ! passive tracer initialisation
79#endif
80   USE lib_mpp         ! distributed memory computing
81#if defined key_iomput
82   USE xios
83#endif
84   USE sbctide, ONLY: lk_tide
85   USE crsini          ! initialise grid coarsening utility
86   USE lbcnfd, ONLY: isendto, nsndto, nfsloop, nfeloop ! Setup of north fold exchanges
87   USE sbc_oce, ONLY: lk_oasis
88   USE stopar
89   USE stopts
90
91   IMPLICIT NONE
92   PRIVATE
93
94   PUBLIC   nemo_gcm    ! called by model.F90
95   PUBLIC   nemo_init   ! needed by AGRIF
96   PUBLIC   nemo_alloc  ! needed by TAM
97
98   INTEGER :: ncplfrq   ! coupling frequency in seconds : integer
99   CHARACTER(lc) ::   cform_aaa="( /, 'AAAAAAAA', / ) "     ! flag for output listing
100
101   !!----------------------------------------------------------------------
102   !! NEMO/OPA 4.0 , NEMO Consortium (2011)
103   !! $Id: nemogcm.F90 8566 2017-09-27 13:15:25Z mchekki $
104   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
105   !!----------------------------------------------------------------------
106CONTAINS
107
108   SUBROUTINE nemo_gcm
109      !!----------------------------------------------------------------------
110      !!                     ***  ROUTINE nemo_gcm  ***
111      !!
112      !! ** Purpose :   NEMO solves the primitive equations on an orthogonal
113      !!              curvilinear mesh on the sphere.
114      !!
115      !! ** Method  : - model general initialization
116      !!              - launch the time-stepping (stp routine)
117      !!              - finalize the run by closing files and communications
118      !!
119      !! References : Madec, Delecluse, Imbard, and Levy, 1997:  internal report, IPSL.
120      !!              Madec, 2008, internal report, IPSL.
121      !!----------------------------------------------------------------------
122      INTEGER ::   istp       ! time step index
123      !!----------------------------------------------------------------------
124      !
125#if defined key_agrif
126      CALL Agrif_Init_Grids()      ! AGRIF: set the meshes
127#endif
128
129      ntsinswr = 1 !! set to allow fldread in nemo_init before computation of schwarz indices
130
131      WRITE(numout,*) "ntsinswr = ",ntsinswr
132
133      !                            !-----------------------!
134      CALL nemo_init               !==  Initialisations  ==!
135      !                            !-----------------------!
136
137      !! set integer constants for computation
138      ncplfrq  = 86400 !cpl_freq( 'O_QnsMix' )
139      ntsinswr = ncplfrq / INT(rdt)
140      nsloops  = (nitend-nit000+1)/ntsinswr
141
142      !! outputs to check values
143      IF(lwp) THEN                  ! control print
144         WRITE(numout,*)
145         WRITE(numout,*) ' computation of loop indices for schwarz computation '
146         WRITE(numout,*) '   nit000   = ',nit000
147         WRITE(numout,*) '   nitend   = ',nitend
148         WRITE(numout,*) '   rdt      = ',rdt
149         WRITE(numout,*) '   ncplfrq  = ',ncplfrq
150         WRITE(numout,*) '   ntsinswr = ',ntsinswr
151         WRITE(numout,*) '   nsloops  = ',nsloops 
152         WRITE(numout,*) '   mswr     = ',mswr
153      ENDIF
154
155!      CALL swz_store ! store initial state
156
157
158!      WRITE (extmsg, "(A7,I3)") "narea =", narea
159!      STOP "montest" !extmsg
160!      Write(*,'(A7,I3)') "narea =",narea
161
162!      CALL mppsync   
163
164!      CALL nemo_closefile
165!      CALL xios_finalize
166
167!      CALL cpl_finalize
168
169!      CALL mppstop
170
171!      STOP
172
173#if defined key_agrif
174      CALL Agrif_Declare_Var_dom   ! AGRIF: set the meshes for DOM
175      CALL Agrif_Declare_Var       !  "      "   "   "      "  DYN/TRA
176# if defined key_top
177      CALL Agrif_Declare_Var_top   !  "      "   "   "      "  TOP
178# endif
179# if defined key_lim2
180      CALL Agrif_Declare_Var_lim2  !  "      "   "   "      "  LIM
181# endif
182#endif
183      ! check that all process are still there... If some process have an error,
184      ! they will never enter in step and other processes will wait until the end of the cpu time!
185      IF( lk_mpp )   CALL mpp_max( nstop )
186
187      IF(lwp) WRITE(numout,cform_aaa)   ! Flag AAAAAAA
188
189      !                            !-----------------------!
190      !                            !==   time stepping   ==!
191      !                            !-----------------------!
192      istp = nit000
193#if defined key_c1d
194         DO WHILE ( istp <= nitend .AND. nstop == 0 )
195            CALL stp_c1d( istp )
196            istp = istp + 1
197         END DO
198#else
199          IF( lk_asminc ) THEN
200             IF( ln_bkgwri ) CALL asm_bkg_wri( nit000 - 1 )    ! Output background fields
201             IF( ln_asmdin ) THEN                        ! Direct initialization
202                IF( ln_trainc ) CALL tra_asm_inc( nit000 - 1 )    ! Tracers
203                IF( ln_dyninc ) CALL dyn_asm_inc( nit000 - 1 )    ! Dynamics
204                IF( ln_sshinc ) CALL ssh_asm_inc( nit000 - 1 )    ! SSH
205             ENDIF
206          ENDIF
207
208#if defined key_agrif
209          CALL Agrif_Regrid()
210#endif
211
212         iswloop = 1
213         IF (lwp) WRITE(numout,*) 'init iswloop =',iswloop
214
215         DO WHILE ( iswloop <= nsloops .AND. nstop == 0 ) ! iterate on n schwarz loops
216
217         kswr = 1
218         IF (lwp) THEN
219            WRITE(numout,*) '*** schwarz loops ***'
220            WRITE(numout,*) 'iswloop =',iswloop
221            WRITE(numout,*) 'kswr = ',kswr
222         ENDIF
223         
224         CALL swz_store  ! store Ocean state at first schwarz iteration before first time step
225         CALL swz_store_lim3 ! store lim3 variables state
226         CALL swz_store_limdiahsb ! store limdiahsb variables
227         IF(lwp) WRITE(numout,*) 'store schwarz initial state '
228
229         DO WHILE ( kswr <= mswr .AND. nstop == 0 )
230
231         IF (lwp) WRITE(numout,*) '  kswr = ',kswr
232         istp = nit000 + (iswloop-1)*ntsinswr ! set time step to first value for iswloop (current schwarz loop)
233
234         IF ( kswr > 1 ) CALL swz_reinit(istp) ! reset Ocean state to first time step for new schwarz iteration
235
236         IF (lwp) WRITE(numout,*) 'maxistp  = ',nit000+iswloop*ntsinswr-1
237         DO WHILE ( istp <= nit000+iswloop*ntsinswr-1 .AND. nstop == 0 )
238
239            IF (lwp) WRITE(numout,*) '    istp = ',istp
240#if defined key_agrif
241            CALL stp                         ! AGRIF: time stepping
242#else
243            CALL stp( istp )                 ! standard time stepping
244#endif
245            istp = istp + 1
246            IF( lk_mpp )   CALL mpp_max( nstop )
247         END DO ! istp
248         
249         kswr = kswr + 1
250
251         END DO ! kswr
252
253         iswloop = iswloop +1
254
255         END DO ! iswloop
256
257#endif
258
259      IF( lk_diaobs   )   CALL dia_obs_wri
260      !
261      IF( ln_icebergs )   CALL icb_end( nitend )
262
263      !                            !------------------------!
264      !                            !==  finalize the run  ==!
265      !                            !------------------------!
266      IF(lwp) WRITE(numout,cform_aaa)   ! Flag AAAAAAA
267      !
268      IF( nstop /= 0 .AND. lwp ) THEN   ! error print
269         WRITE(numout,cform_err)
270         WRITE(numout,*) nstop, ' error have been found'
271      ENDIF
272      !
273#if defined key_agrif
274      CALL Agrif_ParentGrid_To_ChildGrid()
275      IF( lk_diaobs ) CALL dia_obs_wri
276      IF( nn_timing == 1 )   CALL timing_finalize
277      CALL Agrif_ChildGrid_To_ParentGrid()
278#endif
279      IF( nn_timing == 1 )   CALL timing_finalize
280      !
281      CALL nemo_closefile
282      !
283#if defined key_iomput
284      CALL xios_finalize                ! end mpp communications with xios
285      IF( lk_oasis ) CALL cpl_finalize    ! end coupling and mpp communications with OASIS
286#else
287      IF( lk_oasis ) THEN
288         CALL cpl_finalize              ! end coupling and mpp communications with OASIS
289      ELSE
290         IF( lk_mpp )   CALL mppstop    ! end mpp communications
291      ENDIF
292#endif
293      !
294   END SUBROUTINE nemo_gcm
295
296
297   SUBROUTINE nemo_init
298      !!----------------------------------------------------------------------
299      !!                     ***  ROUTINE nemo_init  ***
300      !!
301      !! ** Purpose :   initialization of the NEMO GCM
302      !!----------------------------------------------------------------------
303      INTEGER ::   ji            ! dummy loop indices
304      INTEGER ::   ilocal_comm   ! local integer
305      INTEGER ::   ios
306      CHARACTER(len=80), DIMENSION(16) ::   cltxt
307      !
308      NAMELIST/namctl/ ln_ctl  , nn_print, nn_ictls, nn_ictle,   &
309         &             nn_isplt, nn_jsplt, nn_jctls, nn_jctle,   &
310         &             nn_bench, nn_timing
311      NAMELIST/namcfg/ cp_cfg, cp_cfz, jp_cfg, jpidta, jpjdta, jpkdta, jpiglo, jpjglo, &
312         &             jpizoom, jpjzoom, jperio, ln_use_jattr
313      !!----------------------------------------------------------------------
314      !
315      cltxt = ''
316      cxios_context = 'nemo'
317      !
318      !                             ! Open reference namelist and configuration namelist files
319      CALL ctl_opn( numnam_ref, 'namelist_ref', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
320      CALL ctl_opn( numnam_cfg, 'namelist_cfg', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
321      !
322      REWIND( numnam_ref )              ! Namelist namctl in reference namelist : Control prints & Benchmark
323      READ  ( numnam_ref, namctl, IOSTAT = ios, ERR = 901 )
324901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namctl in reference namelist', .TRUE. )
325
326      REWIND( numnam_cfg )              ! Namelist namctl in confguration namelist : Control prints & Benchmark
327      READ  ( numnam_cfg, namctl, IOSTAT = ios, ERR = 902 )
328902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namctl in configuration namelist', .TRUE. )
329
330      !
331      REWIND( numnam_ref )              ! Namelist namcfg in reference namelist : Control prints & Benchmark
332      READ  ( numnam_ref, namcfg, IOSTAT = ios, ERR = 903 )
333903   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namcfg in reference namelist', .TRUE. )
334
335      REWIND( numnam_cfg )              ! Namelist namcfg in confguration namelist : Control prints & Benchmark
336      READ  ( numnam_cfg, namcfg, IOSTAT = ios, ERR = 904 )
337904   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namcfg in configuration namelist', .TRUE. )   
338
339! Force values for AGRIF zoom (cf. agrif_user.F90)
340#if defined key_agrif
341   IF( .NOT. Agrif_Root() ) THEN
342      jpiglo  = nbcellsx + 2 + 2*nbghostcells
343      jpjglo  = nbcellsy + 2 + 2*nbghostcells
344      jpi     = ( jpiglo-2*jpreci + (jpni-1+0) ) / jpni + 2*jpreci
345      jpj     = ( jpjglo-2*jprecj + (jpnj-1+0) ) / jpnj + 2*jprecj
346      jpidta  = jpiglo
347      jpjdta  = jpjglo
348      jpizoom = 1
349      jpjzoom = 1
350      nperio  = 0
351      jperio  = 0
352      ln_use_jattr = .false.
353   ENDIF
354#endif
355      !
356      !                             !--------------------------------------------!
357      !                             !  set communicator & select the local node  !
358      !                             !  NB: mynode also opens output.namelist.dyn !
359      !                             !      on unit number numond on first proc   !
360      !                             !--------------------------------------------!
361#if defined key_iomput
362      IF( Agrif_Root() ) THEN
363         IF( lk_oasis ) THEN
364            CALL cpl_init( "oceanx", ilocal_comm )                     ! nemo local communicator given by oasis
365            CALL xios_initialize( "not used",local_comm=ilocal_comm )    ! send nemo communicator to xios
366         ELSE
367            CALL  xios_initialize( "for_xios_mpi_id",return_comm=ilocal_comm )    ! nemo local communicator given by xios
368         ENDIF
369      ENDIF
370      ! Nodes selection (control print return in cltxt)
371      narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop, ilocal_comm )
372#else
373      IF( lk_oasis ) THEN
374         IF( Agrif_Root() ) THEN
375            CALL cpl_init( "oceanx", ilocal_comm )                      ! nemo local communicator given by oasis
376         ENDIF
377         ! Nodes selection (control print return in cltxt)
378         narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop, ilocal_comm )
379      ELSE
380         ilocal_comm = 0
381         ! Nodes selection (control print return in cltxt)
382         narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop )
383      ENDIF
384#endif
385      narea = narea + 1                                     ! mynode return the rank of proc (0 --> jpnij -1 )
386
387      lwm = (narea == 1)                                    ! control of output namelists
388      lwp = (narea == 1) .OR. ln_ctl                        ! control of all listing output print
389
390      IF(lwm) THEN
391         ! write merged namelists from earlier to output namelist now that the
392         ! file has been opened in call to mynode. nammpp has already been
393         ! written in mynode (if lk_mpp_mpi)
394         WRITE( numond, namctl )
395         WRITE( numond, namcfg )
396      ENDIF
397
398      ! If dimensions of processor grid weren't specified in the namelist file
399      ! then we calculate them here now that we have our communicator size
400      IF( (jpni < 1) .OR. (jpnj < 1) )THEN
401#if   defined key_mpp_mpi
402         IF( Agrif_Root() ) CALL nemo_partition(mppsize)
403#else
404         jpni  = 1
405         jpnj  = 1
406         jpnij = jpni*jpnj
407#endif
408      END IF
409
410      ! Calculate domain dimensions given calculated jpni and jpnj
411      ! This used to be done in par_oce.F90 when they were parameters rather
412      ! than variables
413      IF( Agrif_Root() ) THEN
414#if defined key_nemocice_decomp
415         jpi = ( nx_global+2-2*jpreci + (jpni-1) ) / jpni + 2*jpreci ! first  dim.
416         jpj = ( ny_global+2-2*jprecj + (jpnj-1) ) / jpnj + 2*jprecj ! second dim.
417#else
418         jpi = ( jpiglo-2*jpreci + (jpni-1) ) / jpni + 2*jpreci   ! first  dim.
419         jpj = ( jpjglo-2*jprecj + (jpnj-1) ) / jpnj + 2*jprecj   ! second dim.
420#endif
421      ENDIF         
422         jpk = jpkdta                                             ! third dim
423#if defined key_agrif
424         ! simple trick to use same vertical grid as parent
425         ! but different number of levels:
426         ! Save maximum number of levels in jpkdta, then define all vertical grids
427         ! with this number.
428         ! Suppress once vertical online interpolation is ok
429         IF(.NOT.Agrif_Root()) jpkdta = Agrif_Parent(jpkdta)
430#endif
431         jpim1 = jpi-1                                            ! inner domain indices
432         jpjm1 = jpj-1                                            !   "           "
433         jpkm1 = jpk-1                                            !   "           "
434         jpij  = jpi*jpj                                          !  jpi x j
435
436      IF(lwp) THEN                            ! open listing units
437         !
438         CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE., narea )
439         !
440         WRITE(numout,*)
441         WRITE(numout,*) '   CNRS - NERC - Met OFFICE - MERCATOR-ocean - INGV - CMCC'
442         WRITE(numout,*) '                       NEMO team'
443         WRITE(numout,*) '            Ocean General Circulation Model'
444         WRITE(numout,*) '                  version 3.6  (2015) '
445         WRITE(numout,*)
446         WRITE(numout,*)
447         DO ji = 1, SIZE(cltxt)
448            IF( TRIM(cltxt(ji)) /= '' )   WRITE(numout,*) cltxt(ji)      ! control print of mynode
449         END DO
450         WRITE(numout,cform_aaa)                                         ! Flag AAAAAAA
451         !
452      ENDIF
453
454      ! Now we know the dimensions of the grid and numout has been set we can
455      ! allocate arrays
456      CALL nemo_alloc()
457
458      !                             !-------------------------------!
459      !                             !  NEMO general initialization  !
460      !                             !-------------------------------!
461
462      CALL nemo_ctl                          ! Control prints & Benchmark
463
464      !                                      ! Domain decomposition
465      IF( jpni*jpnj == jpnij ) THEN   ;   CALL mpp_init      ! standard cutting out
466      ELSE                            ;   CALL mpp_init2     ! eliminate land processors
467      ENDIF
468      !
469      IF( nn_timing == 1 )  CALL timing_init
470      !
471      !                                      ! General initialization
472                            CALL     phy_cst    ! Physical constants
473                            CALL     eos_init   ! Equation of state
474      IF( lk_c1d        )   CALL     c1d_init   ! 1D column configuration
475                            CALL     dom_cfg    ! Domain configuration
476                            CALL     dom_init   ! Domain
477
478      IF( ln_nnogather )    CALL nemo_northcomms   ! Initialise the northfold neighbour lists (must be done after the masks are defined)
479
480      IF( ln_ctl        )   CALL prt_ctl_init   ! Print control
481
482                            CALL  istate_init   ! ocean initial state (Dynamics and tracers)
483
484      IF( lk_tide       )   CALL    tide_init( nit000 )    ! Initialisation of the tidal harmonics
485
486                            CALL     sbc_init   ! Forcings : surface module (clem: moved here for bdy purpose)
487
488      IF( lk_bdy        )   CALL     bdy_init   ! Open boundaries initialisation
489      IF( lk_bdy        )   CALL bdy_dta_init   ! Open boundaries initialisation of external data arrays
490      IF( lk_bdy .AND. lk_tide )   &
491         &                  CALL bdytide_init   ! Open boundaries initialisation of tidal harmonic forcing
492
493                            CALL dyn_nept_init  ! simplified form of Neptune effect
494      !     
495      IF( ln_crs        )   CALL     crs_init   ! Domain initialization of coarsened grid
496      !
497                                ! Ocean physics
498      !                                         ! Vertical physics
499                            CALL     zdf_init      ! namelist read
500                            CALL zdf_bfr_init      ! bottom friction
501      IF( lk_zdfric     )   CALL zdf_ric_init      ! Richardson number dependent Kz
502      IF( lk_zdftke     )   CALL zdf_tke_init      ! TKE closure scheme
503      IF( lk_zdfgls     )   CALL zdf_gls_init      ! GLS closure scheme
504      IF( lk_zdfkpp     )   CALL zdf_kpp_init      ! KPP closure scheme
505      IF( lk_zdftmx     )   CALL zdf_tmx_init      ! tidal vertical mixing
506      IF( lk_zdfddm .AND. .NOT. lk_zdfkpp )   &
507         &                  CALL zdf_ddm_init      ! double diffusive mixing
508      !                                         ! Lateral physics
509                            CALL ldf_tra_init      ! Lateral ocean tracer physics
510                            CALL ldf_dyn_init      ! Lateral ocean momentum physics
511      IF( lk_ldfslp     )   CALL ldf_slp_init      ! slope of lateral mixing
512
513      !                                     ! Active tracers
514                            CALL tra_qsr_init   ! penetrative solar radiation qsr
515                            CALL tra_bbc_init   ! bottom heat flux
516      IF( lk_trabbl     )   CALL tra_bbl_init   ! advective (and/or diffusive) bottom boundary layer scheme
517                            CALL tra_dmp_init   ! internal damping trends- tracers
518                            CALL tra_adv_init   ! horizontal & vertical advection
519                            CALL tra_ldf_init   ! lateral mixing
520                            CALL tra_zdf_init   ! vertical mixing and after tracer fields
521
522      !                                     ! Dynamics
523      IF( lk_c1d        )   CALL dyn_dmp_init   ! internal damping trends- momentum
524                            CALL dyn_adv_init   ! advection (vector or flux form)
525                            CALL dyn_vor_init   ! vorticity term including Coriolis
526                            CALL dyn_ldf_init   ! lateral mixing
527                            CALL dyn_hpg_init   ! horizontal gradient of Hydrostatic pressure
528                            CALL dyn_zdf_init   ! vertical diffusion
529                            CALL dyn_spg_init   ! surface pressure gradient
530
531      !                                     ! Misc. options
532      IF( nn_cla == 1 .AND. cp_cfg == 'orca' .AND. jp_cfg == 2 )   CALL cla_init       ! Cross Land Advection
533                            CALL icb_init( rdt, nit000)   ! initialise icebergs instance
534                            CALL sto_par_init   ! Stochastic parametrization
535      IF( ln_sto_eos     )  CALL sto_pts_init   ! RRandom T/S fluctuations
536     
537#if defined key_top
538      !                                     ! Passive tracers
539                            CALL     trc_init
540#endif
541      !                                     ! Diagnostics
542      IF( lk_floats     )   CALL     flo_init   ! drifting Floats
543                            CALL dia_ptr_init   ! Poleward TRansports initialization
544      IF( lk_diadct     )   CALL dia_dct_init   ! Sections tranports
545                            CALL dia_hsb_init   ! heat content, salt content and volume budgets
546                            CALL     trd_init   ! Mixed-layer/Vorticity/Integral constraints trends
547      IF( lk_diaobs     ) THEN                  ! Observation & model comparison
548                            CALL dia_obs_init            ! Initialize observational data
549                            CALL dia_obs( nit000 - 1 )   ! Observation operator for restart
550      ENDIF
551
552      !                                     ! Assimilation increments
553      IF( lk_asminc     )   CALL asm_inc_init   ! Initialize assimilation increments
554      IF(lwp) WRITE(numout,*) 'Euler time step switch is ', neuler
555      !
556   END SUBROUTINE nemo_init
557
558
559   SUBROUTINE nemo_ctl
560      !!----------------------------------------------------------------------
561      !!                     ***  ROUTINE nemo_ctl  ***
562      !!
563      !! ** Purpose :   control print setting
564      !!
565      !! ** Method  : - print namctl information and check some consistencies
566      !!----------------------------------------------------------------------
567      !
568      IF(lwp) THEN                  ! control print
569         WRITE(numout,*)
570         WRITE(numout,*) 'nemo_ctl: Control prints & Benchmark'
571         WRITE(numout,*) '~~~~~~~ '
572         WRITE(numout,*) '   Namelist namctl'
573         WRITE(numout,*) '      run control (for debugging)     ln_ctl     = ', ln_ctl
574         WRITE(numout,*) '      level of print                  nn_print   = ', nn_print
575         WRITE(numout,*) '      Start i indice for SUM control  nn_ictls   = ', nn_ictls
576         WRITE(numout,*) '      End i indice for SUM control    nn_ictle   = ', nn_ictle
577         WRITE(numout,*) '      Start j indice for SUM control  nn_jctls   = ', nn_jctls
578         WRITE(numout,*) '      End j indice for SUM control    nn_jctle   = ', nn_jctle
579         WRITE(numout,*) '      number of proc. following i     nn_isplt   = ', nn_isplt
580         WRITE(numout,*) '      number of proc. following j     nn_jsplt   = ', nn_jsplt
581         WRITE(numout,*) '      benchmark parameter (0/1)       nn_bench   = ', nn_bench
582         WRITE(numout,*) '      timing activated    (0/1)       nn_timing  = ', nn_timing
583      ENDIF
584      !
585      nprint    = nn_print          ! convert DOCTOR namelist names into OLD names
586      nictls    = nn_ictls
587      nictle    = nn_ictle
588      njctls    = nn_jctls
589      njctle    = nn_jctle
590      isplt     = nn_isplt
591      jsplt     = nn_jsplt
592      nbench    = nn_bench
593
594      IF(lwp) THEN                  ! control print
595         WRITE(numout,*)
596         WRITE(numout,*) 'namcfg  : configuration initialization through namelist read'
597         WRITE(numout,*) '~~~~~~~ '
598         WRITE(numout,*) '   Namelist namcfg'
599         WRITE(numout,*) '      configuration name              cp_cfg      = ', TRIM(cp_cfg)
600         WRITE(numout,*) '      configuration zoom name         cp_cfz      = ', TRIM(cp_cfz)
601         WRITE(numout,*) '      configuration resolution        jp_cfg      = ', jp_cfg
602         WRITE(numout,*) '      1st lateral dimension ( >= jpi ) jpidta     = ', jpidta
603         WRITE(numout,*) '      2nd    "         "    ( >= jpj ) jpjdta     = ', jpjdta
604         WRITE(numout,*) '      3nd    "         "               jpkdta     = ', jpkdta
605         WRITE(numout,*) '      1st dimension of global domain in i jpiglo  = ', jpiglo
606         WRITE(numout,*) '      2nd    -                  -    in j jpjglo  = ', jpjglo
607         WRITE(numout,*) '      left bottom i index of the zoom (in data domain) jpizoom = ', jpizoom
608         WRITE(numout,*) '      left bottom j index of the zoom (in data domain) jpizoom = ', jpjzoom
609         WRITE(numout,*) '      lateral cond. type (between 0 and 6) jperio = ', jperio   
610         WRITE(numout,*) '      use file attribute if exists as i/p j-start ln_use_jattr = ', ln_use_jattr
611      ENDIF
612      !                             ! Parameter control
613      !
614      IF( ln_ctl ) THEN                 ! sub-domain area indices for the control prints
615         IF( lk_mpp .AND. jpnij > 1 ) THEN
616            isplt = jpni   ;   jsplt = jpnj   ;   ijsplt = jpni*jpnj   ! the domain is forced to the real split domain
617         ELSE
618            IF( isplt == 1 .AND. jsplt == 1  ) THEN
619               CALL ctl_warn( ' - isplt & jsplt are equal to 1',   &
620                  &           ' - the print control will be done over the whole domain' )
621            ENDIF
622            ijsplt = isplt * jsplt            ! total number of processors ijsplt
623         ENDIF
624         IF(lwp) WRITE(numout,*)'          - The total number of processors over which the'
625         IF(lwp) WRITE(numout,*)'            print control will be done is ijsplt : ', ijsplt
626         !
627         !                              ! indices used for the SUM control
628         IF( nictls+nictle+njctls+njctle == 0 )   THEN    ! print control done over the default area
629            lsp_area = .FALSE.
630         ELSE                                             ! print control done over a specific  area
631            lsp_area = .TRUE.
632            IF( nictls < 1 .OR. nictls > jpiglo )   THEN
633               CALL ctl_warn( '          - nictls must be 1<=nictls>=jpiglo, it is forced to 1' )
634               nictls = 1
635            ENDIF
636            IF( nictle < 1 .OR. nictle > jpiglo )   THEN
637               CALL ctl_warn( '          - nictle must be 1<=nictle>=jpiglo, it is forced to jpiglo' )
638               nictle = jpiglo
639            ENDIF
640            IF( njctls < 1 .OR. njctls > jpjglo )   THEN
641               CALL ctl_warn( '          - njctls must be 1<=njctls>=jpjglo, it is forced to 1' )
642               njctls = 1
643            ENDIF
644            IF( njctle < 1 .OR. njctle > jpjglo )   THEN
645               CALL ctl_warn( '          - njctle must be 1<=njctle>=jpjglo, it is forced to jpjglo' )
646               njctle = jpjglo
647            ENDIF
648         ENDIF
649      ENDIF
650      !
651      IF( nbench == 1 ) THEN              ! Benchmark
652         SELECT CASE ( cp_cfg )
653         CASE ( 'gyre' )   ;   CALL ctl_warn( ' The Benchmark is activated ' )
654         CASE DEFAULT      ;   CALL ctl_stop( ' The Benchmark is based on the GYRE configuration:',   &
655            &                                 ' cp_cfg = "gyre" in namelist &namcfg or set nbench = 0' )
656         END SELECT
657      ENDIF
658      !
659      IF( 1_wp /= SIGN(1._wp,-0._wp)  )   CALL ctl_stop( 'nemo_ctl: The intrinsec SIGN function follows ',  &
660         &                                               'f2003 standard. '                              ,  &
661         &                                               'Compile with key_nosignedzero enabled' )
662      !
663   END SUBROUTINE nemo_ctl
664
665
666   SUBROUTINE nemo_closefile
667      !!----------------------------------------------------------------------
668      !!                     ***  ROUTINE nemo_closefile  ***
669      !!
670      !! ** Purpose :   Close the files
671      !!----------------------------------------------------------------------
672      !
673      IF( lk_mpp )   CALL mppsync
674      !
675      CALL iom_close                                 ! close all input/output files managed by iom_*
676      !
677      IF( numstp          /= -1 )   CLOSE( numstp          )   ! time-step file
678      IF( numsol          /= -1 )   CLOSE( numsol          )   ! solver file
679      IF( numnam_ref      /= -1 )   CLOSE( numnam_ref      )   ! oce reference namelist
680      IF( numnam_cfg      /= -1 )   CLOSE( numnam_cfg      )   ! oce configuration namelist
681      IF( lwm.AND.numond  /= -1 )   CLOSE( numond          )   ! oce output namelist
682      IF( numnam_ice_ref  /= -1 )   CLOSE( numnam_ice_ref  )   ! ice reference namelist
683      IF( numnam_ice_cfg  /= -1 )   CLOSE( numnam_ice_cfg  )   ! ice configuration namelist
684      IF( lwm.AND.numoni  /= -1 )   CLOSE( numoni          )   ! ice output namelist
685      IF( numevo_ice      /= -1 )   CLOSE( numevo_ice      )   ! ice variables (temp. evolution)
686      IF( numout          /=  6 )   CLOSE( numout          )   ! standard model output file
687      IF( numdct_vol      /= -1 )   CLOSE( numdct_vol      )   ! volume transports
688      IF( numdct_heat     /= -1 )   CLOSE( numdct_heat     )   ! heat transports
689      IF( numdct_salt     /= -1 )   CLOSE( numdct_salt     )   ! salt transports
690
691      !
692      numout = 6                                     ! redefine numout in case it is used after this point...
693      !
694   END SUBROUTINE nemo_closefile
695
696
697   SUBROUTINE nemo_alloc
698      !!----------------------------------------------------------------------
699      !!                     ***  ROUTINE nemo_alloc  ***
700      !!
701      !! ** Purpose :   Allocate all the dynamic arrays of the OPA modules
702      !!
703      !! ** Method  :
704      !!----------------------------------------------------------------------
705      USE diawri    , ONLY: dia_wri_alloc
706      USE dom_oce   , ONLY: dom_oce_alloc
707      USE ldfdyn_oce, ONLY: ldfdyn_oce_alloc
708      USE ldftra_oce, ONLY: ldftra_oce_alloc
709      USE trc_oce   , ONLY: trc_oce_alloc
710#if defined key_diadct 
711      USE diadct    , ONLY: diadct_alloc 
712#endif 
713#if defined key_bdy
714      USE bdy_oce   , ONLY: bdy_oce_alloc
715#endif
716      !
717      INTEGER :: ierr
718      !!----------------------------------------------------------------------
719      !
720      ierr =        oce_alloc       ()          ! ocean
721      ierr = ierr + dia_wri_alloc   ()
722      ierr = ierr + dom_oce_alloc   ()          ! ocean domain
723      ierr = ierr + ldfdyn_oce_alloc()          ! ocean lateral  physics : dynamics
724      ierr = ierr + ldftra_oce_alloc()          ! ocean lateral  physics : tracers
725      ierr = ierr + zdf_oce_alloc   ()          ! ocean vertical physics
726      !
727      ierr = ierr + trc_oce_alloc   ()          ! shared TRC / TRA arrays
728      !
729#if defined key_diadct 
730      ierr = ierr + diadct_alloc    ()          !
731#endif 
732#if defined key_bdy
733      ierr = ierr + bdy_oce_alloc   ()          ! bdy masks (incl. initialization)
734#endif
735      !
736      IF( lk_mpp    )   CALL mpp_sum( ierr )
737      IF( ierr /= 0 )   CALL ctl_stop( 'STOP', 'nemo_alloc : unable to allocate standard ocean arrays' )
738      !
739   END SUBROUTINE nemo_alloc
740
741
742   SUBROUTINE nemo_partition( num_pes )
743      !!----------------------------------------------------------------------
744      !!                 ***  ROUTINE nemo_partition  ***
745      !!
746      !! ** Purpose :
747      !!
748      !! ** Method  :
749      !!----------------------------------------------------------------------
750      INTEGER, INTENT(in) ::   num_pes   ! The number of MPI processes we have
751      !
752      INTEGER, PARAMETER :: nfactmax = 20
753      INTEGER :: nfact ! The no. of factors returned
754      INTEGER :: ierr  ! Error flag
755      INTEGER :: ji
756      INTEGER :: idiff, mindiff, imin ! For choosing pair of factors that are closest in value
757      INTEGER, DIMENSION(nfactmax) :: ifact ! Array of factors
758      !!----------------------------------------------------------------------
759      !
760      ierr = 0
761      !
762      CALL factorise( ifact, nfactmax, nfact, num_pes, ierr )
763      !
764      IF( nfact <= 1 ) THEN
765         WRITE (numout, *) 'WARNING: factorisation of number of PEs failed'
766         WRITE (numout, *) '       : using grid of ',num_pes,' x 1'
767         jpnj = 1
768         jpni = num_pes
769      ELSE
770         ! Search through factors for the pair that are closest in value
771         mindiff = 1000000
772         imin    = 1
773         DO ji = 1, nfact-1, 2
774            idiff = ABS( ifact(ji) - ifact(ji+1) )
775            IF( idiff < mindiff ) THEN
776               mindiff = idiff
777               imin = ji
778            ENDIF
779         END DO
780         jpnj = ifact(imin)
781         jpni = ifact(imin + 1)
782      ENDIF
783      !
784      jpnij = jpni*jpnj
785      !
786   END SUBROUTINE nemo_partition
787
788
789   SUBROUTINE factorise( kfax, kmaxfax, knfax, kn, kerr )
790      !!----------------------------------------------------------------------
791      !!                     ***  ROUTINE factorise  ***
792      !!
793      !! ** Purpose :   return the prime factors of n.
794      !!                knfax factors are returned in array kfax which is of
795      !!                maximum dimension kmaxfax.
796      !! ** Method  :
797      !!----------------------------------------------------------------------
798      INTEGER                    , INTENT(in   ) ::   kn, kmaxfax
799      INTEGER                    , INTENT(  out) ::   kerr, knfax
800      INTEGER, DIMENSION(kmaxfax), INTENT(  out) ::   kfax
801      !
802      INTEGER :: ifac, jl, inu
803      INTEGER, PARAMETER :: ntest = 14
804      INTEGER, DIMENSION(ntest) :: ilfax
805      !
806      ! ilfax contains the set of allowed factors.
807      ilfax(:) = (/(2**jl,jl=ntest,1,-1)/)
808
809      ! Clear the error flag and initialise output vars
810      kerr = 0
811      kfax = 1
812      knfax = 0
813
814      ! Find the factors of n.
815      IF( kn == 1 )   GOTO 20
816
817      ! nu holds the unfactorised part of the number.
818      ! knfax holds the number of factors found.
819      ! l points to the allowed factor list.
820      ! ifac holds the current factor.
821
822      inu   = kn
823      knfax = 0
824
825      DO jl = ntest, 1, -1
826         !
827         ifac = ilfax(jl)
828         IF( ifac > inu )   CYCLE
829
830         ! Test whether the factor will divide.
831
832         IF( MOD(inu,ifac) == 0 ) THEN
833            !
834            knfax = knfax + 1            ! Add the factor to the list
835            IF( knfax > kmaxfax ) THEN
836               kerr = 6
837               write (*,*) 'FACTOR: insufficient space in factor array ', knfax
838               return
839            ENDIF
840            kfax(knfax) = ifac
841            ! Store the other factor that goes with this one
842            knfax = knfax + 1
843            kfax(knfax) = inu / ifac
844            !WRITE (*,*) 'ARPDBG, factors ',knfax-1,' & ',knfax,' are ', kfax(knfax-1),' and ',kfax(knfax)
845         ENDIF
846         !
847      END DO
848
849   20 CONTINUE      ! Label 20 is the exit point from the factor search loop.
850      !
851   END SUBROUTINE factorise
852
853#if defined key_mpp_mpi
854
855   SUBROUTINE nemo_northcomms
856      !!======================================================================
857      !!                     ***  ROUTINE  nemo_northcomms  ***
858      !! nemo_northcomms    :  Setup for north fold exchanges with explicit
859      !!                       point-to-point messaging
860      !!=====================================================================
861      !!----------------------------------------------------------------------
862      !!
863      !! ** Purpose :   Initialization of the northern neighbours lists.
864      !!----------------------------------------------------------------------
865      !!    1.0  ! 2011-10  (A. C. Coward, NOCS & J. Donners, PRACE)
866      !!    2.0  ! 2013-06 Setup avoiding MPI communication (I. Epicoco, S. Mocavero, CMCC)
867      !!----------------------------------------------------------------------
868
869      INTEGER  ::   sxM, dxM, sxT, dxT, jn
870      INTEGER  ::   njmppmax
871
872      njmppmax = MAXVAL( njmppt )
873   
874      !initializes the north-fold communication variables
875      isendto(:) = 0
876      nsndto = 0
877
878      !if I am a process in the north
879      IF ( njmpp == njmppmax ) THEN
880          !sxM is the first point (in the global domain) needed to compute the
881          !north-fold for the current process
882          sxM = jpiglo - nimppt(narea) - nlcit(narea) + 1
883          !dxM is the last point (in the global domain) needed to compute the
884          !north-fold for the current process
885          dxM = jpiglo - nimppt(narea) + 2
886
887          !loop over the other north-fold processes to find the processes
888          !managing the points belonging to the sxT-dxT range
889 
890          DO jn = 1, jpni
891                !sxT is the first point (in the global domain) of the jn
892                !process
893                sxT = nfiimpp(jn, jpnj)
894                !dxT is the last point (in the global domain) of the jn
895                !process
896                dxT = nfiimpp(jn, jpnj) + nfilcit(jn, jpnj) - 1
897                IF ((sxM .gt. sxT) .AND. (sxM .lt. dxT)) THEN
898                   nsndto = nsndto + 1
899                     isendto(nsndto) = jn
900                ELSEIF ((sxM .le. sxT) .AND. (dxM .ge. dxT)) THEN
901                   nsndto = nsndto + 1
902                     isendto(nsndto) = jn
903                ELSEIF ((dxM .lt. dxT) .AND. (sxT .lt. dxM)) THEN
904                   nsndto = nsndto + 1
905                     isendto(nsndto) = jn
906                END IF
907          END DO
908          nfsloop = 1
909          nfeloop = nlci
910          DO jn = 2,jpni-1
911           IF(nfipproc(jn,jpnj) .eq. (narea - 1)) THEN
912              IF (nfipproc(jn - 1 ,jpnj) .eq. -1) THEN
913                 nfsloop = nldi
914              ENDIF
915              IF (nfipproc(jn + 1,jpnj) .eq. -1) THEN
916                 nfeloop = nlei
917              ENDIF
918           ENDIF
919        END DO
920
921      ENDIF
922      l_north_nogather = .TRUE.
923   END SUBROUTINE nemo_northcomms
924#else
925   SUBROUTINE nemo_northcomms      ! Dummy routine
926      WRITE(*,*) 'nemo_northcomms: You should not have seen this print! error?'
927   END SUBROUTINE nemo_northcomms
928#endif
929
930   !!======================================================================
931END MODULE nemogcm
932
933
Note: See TracBrowser for help on using the repository browser.