source: SCHWARZ_ORCA2LIM3/SOURCES/NEMO/sbcmod.F90 @ 6

Last change on this file since 6 was 6, checked in by snguyen, 3 years ago

updated SOURCES/NEMO for schwarz

File size: 32.2 KB
Line 
1MODULE sbcmod
2   !!======================================================================
3   !!                       ***  MODULE  sbcmod  ***
4   !! Surface module :  provide to the ocean its surface boundary condition
5   !!======================================================================
6   !! History :  3.0  ! 2006-07  (G. Madec)  Original code
7   !!            3.1  ! 2008-08  (S. Masson, A. Caubel, E. Maisonnave, G. Madec) coupled interface
8   !!            3.3  ! 2010-04  (M. Leclair, G. Madec)  Forcing averaged over 2 time steps
9   !!            3.3  ! 2010-10  (S. Masson)  add diurnal cycle
10   !!            3.3  ! 2010-09  (D. Storkey) add ice boundary conditions (BDY)
11   !!             -   ! 2010-11  (G. Madec) ice-ocean stress always computed at each ocean time-step
12   !!             -   ! 2010-10  (J. Chanut, C. Bricaud, G. Madec)  add the surface pressure forcing
13   !!            3.4  ! 2011-11  (C. Harris) CICE added as an option
14   !!            3.5  ! 2012-11  (A. Coward, G. Madec) Rethink of heat, mass and salt surface fluxes
15   !!            3.6  ! 2014-11  (P. Mathiot, C. Harris) add ice shelves melting                   
16   !!----------------------------------------------------------------------
17
18   !!----------------------------------------------------------------------
19   !!   sbc_init       : read namsbc namelist
20   !!   sbc            : surface ocean momentum, heat and freshwater boundary conditions
21   !!----------------------------------------------------------------------
22   USE oce              ! ocean dynamics and tracers
23   USE dom_oce          ! ocean space and time domain
24   USE phycst           ! physical constants
25   USE sbc_oce          ! Surface boundary condition: ocean fields
26   USE trc_oce          ! shared ocean-passive tracers variables
27   USE sbc_ice          ! Surface boundary condition: ice fields
28   USE sbcdcy           ! surface boundary condition: diurnal cycle
29   USE sbcssm           ! surface boundary condition: sea-surface mean variables
30   USE sbcapr           ! surface boundary condition: atmospheric pressure
31   USE sbcana           ! surface boundary condition: analytical formulation
32   USE sbcflx           ! surface boundary condition: flux formulation
33   USE sbcblk_clio      ! surface boundary condition: bulk formulation : CLIO
34   USE sbcblk_core      ! surface boundary condition: bulk formulation : CORE
35   USE sbcblk_mfs       ! surface boundary condition: bulk formulation : MFS
36   USE sbcice_if        ! surface boundary condition: ice-if sea-ice model
37   USE sbcice_lim       ! surface boundary condition: LIM 3.0 sea-ice model
38   USE sbcice_lim_2     ! surface boundary condition: LIM 2.0 sea-ice model
39   USE sbcice_cice      ! surface boundary condition: CICE    sea-ice model
40   USE sbccpl           ! surface boundary condition: coupled florulation
41   USE cpl_oasis3       ! OASIS routines for coupling
42   USE sbcssr           ! surface boundary condition: sea surface restoring
43   USE sbcrnf           ! surface boundary condition: runoffs
44   USE sbcisf           ! surface boundary condition: ice shelf
45   USE sbcfwb           ! surface boundary condition: freshwater budget
46   USE closea           ! closed sea
47   USE icbstp           ! Icebergs!
48
49   USE prtctl           ! Print control                    (prt_ctl routine)
50   USE iom              ! IOM library
51   USE in_out_manager   ! I/O manager
52   USE lib_mpp          ! MPP library
53   USE timing           ! Timing
54   USE sbcwave          ! Wave module
55   USE bdy_par          ! Require lk_bdy
56
57   USE schwarz
58
59   IMPLICIT NONE
60   PRIVATE
61
62   PUBLIC   sbc        ! routine called by step.F90
63   PUBLIC   sbc_init   ! routine called by opa.F90
64   
65   INTEGER ::   nsbc   ! type of surface boundary condition (deduced from namsbc informations)
66     
67   !! * Substitutions
68#  include "domzgr_substitute.h90"
69   !!----------------------------------------------------------------------
70   !! NEMO/OPA 4.0 , NEMO-consortium (2011)
71   !! $Id: sbcmod.F90 7784 2017-03-10 16:12:32Z cetlod $
72   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
73   !!----------------------------------------------------------------------
74CONTAINS
75
76   SUBROUTINE sbc_init
77      !!---------------------------------------------------------------------
78      !!                    ***  ROUTINE sbc_init ***
79      !!
80      !! ** Purpose :   Initialisation of the ocean surface boundary computation
81      !!
82      !! ** Method  :   Read the namsbc namelist and set derived parameters
83      !!                Call init routines for all other SBC modules that have one
84      !!
85      !! ** Action  : - read namsbc parameters
86      !!              - nsbc: type of sbc
87      !!----------------------------------------------------------------------
88      INTEGER ::   icpt   ! local integer
89      !!
90      NAMELIST/namsbc/ nn_fsbc   , ln_ana    , ln_flx, ln_blk_clio, ln_blk_core, ln_mixcpl,   &
91         &             ln_blk_mfs, ln_apr_dyn, nn_ice, nn_ice_embd, ln_dm2dc   , ln_rnf   ,   &
92         &             ln_ssr    , nn_isf    , nn_fwb, ln_cdgw    , ln_wave    , ln_sdw   ,   &
93         &             nn_lsm    , nn_limflx , nn_components, ln_cpl
94      INTEGER  ::   ios
95      INTEGER  ::   ierr, ierr0, ierr1, ierr2, ierr3, jpm
96      LOGICAL  ::   ll_purecpl
97      !!----------------------------------------------------------------------
98
99      IF(lwp) THEN
100         WRITE(numout,*)
101         WRITE(numout,*) 'sbc_init : surface boundary condition setting'
102         WRITE(numout,*) '~~~~~~~~ '
103      ENDIF
104
105      REWIND( numnam_ref )              ! Namelist namsbc in reference namelist : Surface boundary
106      READ  ( numnam_ref, namsbc, IOSTAT = ios, ERR = 901)
107901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc in reference namelist', lwp )
108
109      REWIND( numnam_cfg )              ! Namelist namsbc in configuration namelist : Parameters of the run
110      READ  ( numnam_cfg, namsbc, IOSTAT = ios, ERR = 902 )
111902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc in configuration namelist', lwp )
112      IF(lwm) WRITE ( numond, namsbc )
113
114      !                          ! overwrite namelist parameter using CPP key information
115      IF( Agrif_Root() ) THEN                ! AGRIF zoom
116        IF( lk_lim2 )   nn_ice      = 2
117        IF( lk_lim3 )   nn_ice      = 3
118        IF( lk_cice )   nn_ice      = 4
119      ENDIF
120      IF( cp_cfg == 'gyre' ) THEN            ! GYRE configuration
121          ln_ana      = .TRUE.   
122          nn_ice      =   0
123      ENDIF
124
125      IF(lwp) THEN               ! Control print
126         WRITE(numout,*) '        Namelist namsbc (partly overwritten with CPP key setting)'
127         WRITE(numout,*) '           frequency update of sbc (and ice)             nn_fsbc     = ', nn_fsbc
128         WRITE(numout,*) '           Type of sbc : '
129         WRITE(numout,*) '              analytical formulation                     ln_ana      = ', ln_ana
130         WRITE(numout,*) '              flux       formulation                     ln_flx      = ', ln_flx
131         WRITE(numout,*) '              CLIO bulk  formulation                     ln_blk_clio = ', ln_blk_clio
132         WRITE(numout,*) '              CORE bulk  formulation                     ln_blk_core = ', ln_blk_core
133         WRITE(numout,*) '              MFS  bulk  formulation                     ln_blk_mfs  = ', ln_blk_mfs
134         WRITE(numout,*) '              ocean-atmosphere coupled formulation       ln_cpl      = ', ln_cpl
135         WRITE(numout,*) '              forced-coupled mixed formulation           ln_mixcpl   = ', ln_mixcpl
136         WRITE(numout,*) '              OASIS coupling (with atm or sas)           lk_oasis    = ', lk_oasis
137         WRITE(numout,*) '              components of your executable              nn_components = ', nn_components
138         WRITE(numout,*) '              Multicategory heat flux formulation (LIM3) nn_limflx   = ', nn_limflx
139         WRITE(numout,*) '           Misc. options of sbc : '
140         WRITE(numout,*) '              Patm gradient added in ocean & ice Eqs.    ln_apr_dyn  = ', ln_apr_dyn
141         WRITE(numout,*) '              ice management in the sbc (=0/1/2/3)       nn_ice      = ', nn_ice 
142         WRITE(numout,*) '              ice-ocean embedded/levitating (=0/1/2)     nn_ice_embd = ', nn_ice_embd
143         WRITE(numout,*) '              daily mean to diurnal cycle qsr            ln_dm2dc    = ', ln_dm2dc 
144         WRITE(numout,*) '              runoff / runoff mouths                     ln_rnf      = ', ln_rnf
145         WRITE(numout,*) '              iceshelf formulation                       nn_isf      = ', nn_isf
146         WRITE(numout,*) '              Sea Surface Restoring on SST and/or SSS    ln_ssr      = ', ln_ssr
147         WRITE(numout,*) '              FreshWater Budget control  (=0/1/2)        nn_fwb      = ', nn_fwb
148         WRITE(numout,*) '              closed sea (=0/1) (set in namdom)          nn_closea   = ', nn_closea
149         WRITE(numout,*) '              n. of iterations if land-sea-mask applied  nn_lsm      = ', nn_lsm
150      ENDIF
151
152      ! LIM3 Multi-category heat flux formulation
153      SELECT CASE ( nn_limflx)
154      CASE ( -1 )
155         IF(lwp) WRITE(numout,*) '              Use of per-category fluxes (nn_limflx = -1) '
156      CASE ( 0  )
157         IF(lwp) WRITE(numout,*) '              Average per-category fluxes (nn_limflx = 0) ' 
158      CASE ( 1  )
159         IF(lwp) WRITE(numout,*) '              Average then redistribute per-category fluxes (nn_limflx = 1) '
160      CASE ( 2  )
161         IF(lwp) WRITE(numout,*) '              Redistribute a single flux over categories (nn_limflx = 2) '
162      END SELECT
163      !
164      IF ( nn_components /= jp_iam_nemo .AND. .NOT. lk_oasis )   &
165         &      CALL ctl_stop( 'STOP', 'sbc_init : OPA-SAS coupled via OASIS, but key_oasis3 disabled' )
166      IF ( nn_components == jp_iam_opa .AND. ln_cpl )   &
167         &      CALL ctl_stop( 'STOP', 'sbc_init : OPA-SAS coupled via OASIS, but ln_cpl = T in OPA' )
168      IF ( nn_components == jp_iam_opa .AND. ln_mixcpl )   &
169         &      CALL ctl_stop( 'STOP', 'sbc_init : OPA-SAS coupled via OASIS, but ln_mixcpl = T in OPA' )
170      IF ( ln_cpl .AND. .NOT. lk_oasis )    &
171         &      CALL ctl_stop( 'STOP', 'sbc_init : OASIS-coupled atmosphere model, but key_oasis3 disabled' )
172      IF( ln_mixcpl .AND. .NOT. lk_oasis )    &
173         &      CALL ctl_stop( 'the forced-coupled mixed mode (ln_mixcpl) requires the cpp key key_oasis3' )
174      IF( ln_mixcpl .AND. .NOT. ln_cpl )    &
175         &      CALL ctl_stop( 'the forced-coupled mixed mode (ln_mixcpl) requires ln_cpl = T' )
176      IF( ln_mixcpl .AND. nn_components /= jp_iam_nemo )    &
177         &      CALL ctl_stop( 'the forced-coupled mixed mode (ln_mixcpl) is not yet working with sas-opa coupling via oasis' )
178
179      !                              ! allocate sbc arrays
180      IF( sbc_oce_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'sbc_init : unable to allocate sbc_oce arrays' )
181
182      !                          ! Checks:
183      IF( nn_isf .EQ. 0 ) THEN                      ! variable initialisation if no ice shelf
184         IF( sbc_isf_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'sbc_init : unable to allocate sbc_isf arrays' )
185         fwfisf  (:,:)   = 0.0_wp ; fwfisf_b  (:,:)   = 0.0_wp
186         risf_tsc(:,:,:) = 0.0_wp ; risf_tsc_b(:,:,:) = 0.0_wp
187         rdivisf       = 0.0_wp
188      END IF
189      IF( nn_ice == 0 .AND. nn_components /= jp_iam_opa )   fr_i(:,:) = 0.e0 ! no ice in the domain, ice fraction is always zero
190
191      sfx(:,:) = 0.0_wp                            ! the salt flux due to freezing/melting will be computed (i.e. will be non-zero)
192                                                   ! only if sea-ice is present
193 
194      fmmflx(:,:) = 0.0_wp                        ! freezing-melting array initialisation
195     
196      taum(:,:) = 0.0_wp                           ! Initialise taum for use in gls in case of reduced restart
197
198      !                                            ! restartability   
199      IF( ( nn_ice == 2 .OR. nn_ice ==3 ) .AND. .NOT.( ln_blk_clio .OR. ln_blk_core .OR. ln_cpl ) )   &
200         &   CALL ctl_stop( 'LIM sea-ice model requires a bulk formulation or coupled configuration' )
201      IF( nn_ice == 4 .AND. .NOT.( ln_blk_core .OR. ln_cpl ) )   &
202         &   CALL ctl_stop( 'CICE sea-ice model requires ln_blk_core or ln_cpl' )
203      IF( nn_ice == 4 .AND. lk_agrif )   &
204         &   CALL ctl_stop( 'CICE sea-ice model not currently available with AGRIF' )
205      IF( ( nn_ice == 3 .OR. nn_ice == 4 ) .AND. nn_ice_embd == 0 )   &
206         &   CALL ctl_stop( 'LIM3 and CICE sea-ice models require nn_ice_embd = 1 or 2' )
207      IF( ( nn_ice /= 3 ) .AND. ( nn_limflx >= 0 ) )   &
208         &   WRITE(numout,*) 'The nn_limflx>=0 option has no effect if sea ice model is not LIM3'
209      IF( ( nn_ice == 3 ) .AND. ( ln_cpl ) .AND. ( ( nn_limflx == -1 ) .OR. ( nn_limflx == 1 ) ) )   &
210         &   CALL ctl_stop( 'The chosen nn_limflx for LIM3 in coupled mode must be 0 or 2' )
211      IF( ( nn_ice == 3 ) .AND. ( .NOT. ln_cpl ) .AND. ( nn_limflx == 2 ) )   &
212         &   CALL ctl_stop( 'The chosen nn_limflx for LIM3 in forced mode cannot be 2' )
213
214      IF( ln_dm2dc )   nday_qsr = -1   ! initialisation flag
215
216      IF( ln_dm2dc .AND. .NOT.( ln_flx .OR. ln_blk_core ) .AND. nn_components /= jp_iam_opa )   &
217         &   CALL ctl_stop( 'diurnal cycle into qsr field from daily values requires a flux or core-bulk formulation' )
218     
219      IF ( ln_wave ) THEN
220      !Activated wave module but neither drag nor stokes drift activated
221         IF ( .NOT.(ln_cdgw .OR. ln_sdw) )   THEN
222            CALL ctl_warn( 'Ask for wave coupling but nor drag coefficient (ln_cdgw=F) neither stokes drift activated (ln_sdw=F)' )
223      !drag coefficient read from wave model definable only with mfs bulk formulae and core
224         ELSEIF (ln_cdgw .AND. .NOT.(ln_blk_mfs .OR. ln_blk_core) )       THEN       
225             CALL ctl_stop( 'drag coefficient read from wave model definable only with mfs bulk formulae and core')
226         ENDIF
227      ELSE
228      IF ( ln_cdgw .OR. ln_sdw  )                                         & 
229         &   CALL ctl_stop('Not Activated Wave Module (ln_wave=F) but     &
230         & asked coupling with drag coefficient (ln_cdgw =T) or Stokes drift (ln_sdw=T) ')
231      ENDIF 
232      !                          ! Choice of the Surface Boudary Condition (set nsbc)
233      ll_purecpl = ln_cpl .AND. .NOT. ln_mixcpl
234      !
235      icpt = 0
236      IF( ln_ana          ) THEN   ;   nsbc = jp_ana     ; icpt = icpt + 1   ;   ENDIF       ! analytical           formulation
237      IF( ln_flx          ) THEN   ;   nsbc = jp_flx     ; icpt = icpt + 1   ;   ENDIF       ! flux                 formulation
238      IF( ln_blk_clio     ) THEN   ;   nsbc = jp_clio    ; icpt = icpt + 1   ;   ENDIF       ! CLIO bulk            formulation
239      IF( ln_blk_core     ) THEN   ;   nsbc = jp_core    ; icpt = icpt + 1   ;   ENDIF       ! CORE bulk            formulation
240      IF( ln_blk_mfs      ) THEN   ;   nsbc = jp_mfs     ; icpt = icpt + 1   ;   ENDIF       ! MFS  bulk            formulation
241      IF( ll_purecpl      ) THEN   ;   nsbc = jp_purecpl ; icpt = icpt + 1   ;   ENDIF       ! Pure Coupled         formulation
242      IF( cp_cfg == 'gyre') THEN   ;   nsbc = jp_gyre                        ;   ENDIF       ! GYRE analytical      formulation
243      IF( nn_components == jp_iam_opa )   &
244         &                  THEN   ;   nsbc = jp_none    ; icpt = icpt + 1   ;   ENDIF       ! opa coupling via SAS module
245      IF( lk_esopa        )            nsbc = jp_esopa                                       ! esopa test, ALL formulations
246      !
247      IF( icpt /= 1 .AND. .NOT.lk_esopa ) THEN
248         WRITE(numout,*)
249         WRITE(numout,*) '           E R R O R in setting the sbc, one and only one namelist/CPP key option '
250         WRITE(numout,*) '                     must be choosen. You choose ', icpt, ' option(s)'
251         WRITE(numout,*) '                     We stop'
252         nstop = nstop + 1
253      ENDIF
254      IF(lwp) THEN
255         WRITE(numout,*)
256         IF( nsbc == jp_esopa   )   WRITE(numout,*) '              ESOPA test All surface boundary conditions'
257         IF( nsbc == jp_gyre    )   WRITE(numout,*) '              GYRE analytical formulation'
258         IF( nsbc == jp_ana     )   WRITE(numout,*) '              analytical formulation'
259         IF( nsbc == jp_flx     )   WRITE(numout,*) '              flux formulation'
260         IF( nsbc == jp_clio    )   WRITE(numout,*) '              CLIO bulk formulation'
261         IF( nsbc == jp_core    )   WRITE(numout,*) '              CORE bulk formulation'
262         IF( nsbc == jp_purecpl )   WRITE(numout,*) '              pure coupled formulation'
263         IF( nsbc == jp_mfs     )   WRITE(numout,*) '              MFS Bulk formulation'
264         IF( nsbc == jp_none    )   WRITE(numout,*) '              OPA coupled to SAS via oasis'
265         IF( ln_mixcpl          )   WRITE(numout,*) '              + forced-coupled mixed formulation'
266         IF( nn_components/= jp_iam_nemo )  &
267            &                       WRITE(numout,*) '              + OASIS coupled SAS'
268      ENDIF
269      !
270      IF( lk_oasis )   CALL sbc_cpl_init (nn_ice)   ! OASIS initialisation. must be done before: (1) first time step
271      !                                                     !                                            (2) the use of nn_fsbc
272
273!     nn_fsbc initialization if OPA-SAS coupling via OASIS
274!     sas model time step has to be declared in OASIS (mandatory) -> nn_fsbc has to be modified accordingly
275      IF ( nn_components /= jp_iam_nemo ) THEN
276
277         IF ( nn_components == jp_iam_opa ) nn_fsbc = cpl_freq('O_SFLX') / NINT(rdt)
278         IF ( nn_components == jp_iam_sas ) nn_fsbc = cpl_freq('I_SFLX') / NINT(rdt)
279         !
280         IF(lwp)THEN
281            WRITE(numout,*)
282            WRITE(numout,*)"   OPA-SAS coupled via OASIS : nn_fsbc re-defined from OASIS namcouple ", nn_fsbc
283            WRITE(numout,*)
284         ENDIF
285      ENDIF
286
287      IF( MOD( nitend - nit000 + 1, nn_fsbc) /= 0 .OR.   &
288          MOD( nstock             , nn_fsbc) /= 0 ) THEN
289         WRITE(ctmp1,*) 'experiment length (', nitend - nit000 + 1, ') or nstock (', nstock,   &
290            &           ' is NOT a multiple of nn_fsbc (', nn_fsbc, ')'
291         CALL ctl_stop( ctmp1, 'Impossible to properly do model restart' )
292      ENDIF
293      !
294      IF( MOD( rday, REAL(nn_fsbc, wp) * rdt ) /= 0 )   &
295         &  CALL ctl_warn( 'nn_fsbc is NOT a multiple of the number of time steps in a day' )
296      !
297      IF( ln_dm2dc .AND. ( ( NINT(rday) / ( nn_fsbc * NINT(rdt) ) )  < 8 ) )   &
298         &   CALL ctl_warn( 'diurnal cycle for qsr: the sampling of the diurnal cycle is too small...' )
299
300                               CALL sbc_ssm_init               ! Sea-surface mean fields initialisation
301      !
302      IF( ln_ssr           )   CALL sbc_ssr_init               ! Sea-Surface Restoring initialisation
303      !
304      IF( nn_isf   /= 0    )   CALL sbc_isf_init               ! Compute iceshelves
305
306                               CALL sbc_rnf_init               ! Runof initialisation
307      !
308      IF( nn_ice == 3      )   CALL sbc_lim_init               ! LIM3 initialisation
309
310      IF( nn_ice == 4      )   CALL cice_sbc_init( nsbc )      ! CICE initialisation
311     
312   END SUBROUTINE sbc_init
313
314
315   SUBROUTINE sbc( kt )
316      !!---------------------------------------------------------------------
317      !!                    ***  ROUTINE sbc  ***
318      !!             
319      !! ** Purpose :   provide at each time-step the ocean surface boundary
320      !!                condition (momentum, heat and freshwater fluxes)
321      !!
322      !! ** Method  :   blah blah  to be written ?????????
323      !!                CAUTION : never mask the surface stress field (tke sbc)
324      !!
325      !! ** Action  : - set the ocean surface boundary condition at before and now
326      !!                time step, i.e. 
327      !!                utau_b, vtau_b, qns_b, qsr_b, emp_n, sfx_b, qrp_b, erp_b
328      !!                utau  , vtau  , qns  , qsr  , emp  , sfx  , qrp  , erp
329      !!              - updte the ice fraction : fr_i
330      !!----------------------------------------------------------------------
331      INTEGER, INTENT(in) ::   kt       ! ocean time step
332      !!---------------------------------------------------------------------
333      !
334      IF( nn_timing == 1 )  CALL timing_start('sbc')
335      !
336      !                                               
337      IF( .NOT. ( kt == nit000 .AND. kswr == 1 ) &
338        & .AND. .NOT. ( MOD (kt - nit000, ntsinswr) == 0 .AND. kswr > 1 ) & ! ---------------------------------------- !
339        &                                                            ) THEN !          Swap of forcing fields          !
340         !                                                                  ! ---------------------------------------- !
341         utau_b(:,:) = utau(:,:)                         ! Swap the ocean forcing fields
342         vtau_b(:,:) = vtau(:,:)                         ! (except at nit000 where before fields
343         qns_b (:,:) = qns (:,:)                         !  are set at the end of the routine)
344         ! The 3D heat content due to qsr forcing is treated in traqsr
345         ! qsr_b (:,:) = qsr (:,:)
346         emp_b(:,:) = emp(:,:)
347         sfx_b(:,:) = sfx(:,:)
348         IF ( ln_rnf ) THEN
349            rnf_b    (:,:  ) = rnf    (:,:  )
350            rnf_tsc_b(:,:,:) = rnf_tsc(:,:,:)
351         ENDIF
352         IF( nn_isf /= 0  )  THEN
353            fwfisf_b  (:,:  ) = fwfisf  (:,:  )               
354            risf_tsc_b(:,:,:) = risf_tsc(:,:,:)             
355         ENDIF
356      ENDIF
357      !                                            ! ---------------------------------------- !
358      !                                            !        forcing field computation         !
359      !                                            ! ---------------------------------------- !
360      !
361      IF ( .NOT. lk_bdy ) then
362         IF( ln_apr_dyn ) CALL sbc_apr( kt )                ! atmospheric pressure provided at kt+0.5*nn_fsbc
363      ENDIF
364                                                         ! (caution called before sbc_ssm)
365      !
366      IF( nn_components /= jp_iam_sas )   CALL sbc_ssm( kt )   ! ocean sea surface variables (sst_m, sss_m, ssu_m, ssv_m)
367      !                                                        ! averaged over nf_sbc time-step
368
369      IF (ln_wave) CALL sbc_wave( kt )
370                                                   !==  sbc formulation  ==!
371                                                           
372      SELECT CASE( nsbc )                                ! Compute ocean surface boundary condition
373      !                                                  ! (i.e. utau,vtau, qns, qsr, emp, sfx)
374      CASE( jp_gyre  )   ;   CALL sbc_gyre    ( kt )                    ! analytical formulation : GYRE configuration
375      CASE( jp_ana   )   ;   CALL sbc_ana     ( kt )                    ! analytical formulation : uniform sbc
376      CASE( jp_flx   )   ;   CALL sbc_flx     ( kt )                    ! flux formulation
377      CASE( jp_clio  )   ;   CALL sbc_blk_clio( kt )                    ! bulk formulation : CLIO for the ocean
378      CASE( jp_core  )   
379         IF( nn_components == jp_iam_sas ) &
380            &                CALL sbc_cpl_rcv ( kt, nn_fsbc, nn_ice )   ! OPA-SAS coupling: SAS receiving fields from OPA
381                             CALL sbc_blk_core( kt )                    ! bulk formulation : CORE for the ocean
382                                                                        ! from oce: sea surface variables (sst_m, sss_m,  ssu_m,  ssv_m)
383      CASE( jp_purecpl )  ;  CALL sbc_cpl_rcv ( kt, nn_fsbc, nn_ice )   ! pure coupled formulation
384                                                                        !
385      CASE( jp_mfs   )   ;   CALL sbc_blk_mfs ( kt )                    ! bulk formulation : MFS for the ocean
386      CASE( jp_none  ) 
387         IF( nn_components == jp_iam_opa ) &
388                             CALL sbc_cpl_rcv ( kt, nn_fsbc, nn_ice )   ! OPA-SAS coupling: OPA receiving fields from SAS
389      CASE( jp_esopa )                               
390                             CALL sbc_ana     ( kt )                    ! ESOPA, test ALL the formulations
391                             CALL sbc_gyre    ( kt )                    !
392                             CALL sbc_flx     ( kt )                    !
393                             CALL sbc_blk_clio( kt )                    !
394                             CALL sbc_blk_core( kt )                    !
395                             CALL sbc_cpl_rcv ( kt, nn_fsbc, nn_ice )   !
396      END SELECT
397
398      IF( ln_mixcpl )        CALL sbc_cpl_rcv ( kt, nn_fsbc, nn_ice )   ! forced-coupled mixed formulation after forcing
399
400
401      !                                            !==  Misc. Options  ==!
402     
403      SELECT CASE( nn_ice )                                       ! Update heat and freshwater fluxes over sea-ice areas
404      CASE(  1 )   ;         CALL sbc_ice_if   ( kt )                ! Ice-cover climatology ("Ice-if" model)
405      CASE(  2 )   ;         CALL sbc_ice_lim_2( kt, nsbc )          ! LIM-2 ice model
406      CASE(  3 )   ;         CALL sbc_ice_lim  ( kt, nsbc )          ! LIM-3 ice model
407      CASE(  4 )   ;         CALL sbc_ice_cice ( kt, nsbc )          ! CICE ice model
408      END SELECT                                             
409
410      IF( ln_icebergs    )   CALL icb_stp( kt )                   ! compute icebergs
411
412      IF( nn_isf   /= 0  )   CALL sbc_isf( kt )                    ! compute iceshelves
413
414      IF( ln_rnf         )   CALL sbc_rnf( kt )                   ! add runoffs to fresh water fluxes
415 
416      IF( ln_ssr         )   CALL sbc_ssr( kt )                   ! add SST/SSS damping term
417
418      IF( nn_fwb    /= 0 )   CALL sbc_fwb( kt, nn_fwb, nn_fsbc )  ! control the freshwater budget
419
420      IF( nn_closea == 1 )   CALL sbc_clo( kt )                   ! treatment of closed sea in the model domain
421      !                                                           ! (update freshwater fluxes)
422!RBbug do not understand why see ticket 667
423!clem: it looks like it is necessary for the north fold (in certain circumstances). Don't know why.
424      CALL lbc_lnk( emp, 'T', 1. )
425      !
426      IF( kt == nit000 .AND. kswr == 1 ) THEN                          !   set the forcing field at nit000 - 1    !
427         !                                             ! ---------------------------------------- !
428         IF( ln_rstart .AND.    &                               !* Restart: read in restart file
429            & iom_varid( numror, 'utau_b', ldstop = .FALSE. ) > 0 ) THEN
430            IF(lwp) WRITE(numout,*) '          nit000-1 surface forcing fields red in the restart file'
431            CALL iom_get( numror, jpdom_autoglo, 'utau_b', utau_b )   ! before i-stress  (U-point)
432            CALL iom_get( numror, jpdom_autoglo, 'vtau_b', vtau_b )   ! before j-stress  (V-point)
433            CALL iom_get( numror, jpdom_autoglo, 'qns_b' , qns_b  )   ! before non solar heat flux (T-point)
434            ! The 3D heat content due to qsr forcing is treated in traqsr
435            ! CALL iom_get( numror, jpdom_autoglo, 'qsr_b' , qsr_b  ) ! before     solar heat flux (T-point)
436            CALL iom_get( numror, jpdom_autoglo, 'emp_b', emp_b  )    ! before     freshwater flux (T-point)
437            ! To ensure restart capability with 3.3x/3.4 restart files    !! to be removed in v3.6
438            IF( iom_varid( numror, 'sfx_b', ldstop = .FALSE. ) > 0 ) THEN
439               CALL iom_get( numror, jpdom_autoglo, 'sfx_b', sfx_b )  ! before salt flux (T-point)
440            ELSE
441               sfx_b (:,:) = sfx(:,:)
442            ENDIF
443         ELSE                                                   !* no restart: set from nit000 values
444            IF(lwp) WRITE(numout,*) '          nit000-1 surface forcing fields set to nit000'
445            utau_b(:,:) = utau(:,:) 
446            vtau_b(:,:) = vtau(:,:)
447            qns_b (:,:) = qns (:,:)
448            emp_b (:,:) = emp(:,:)
449            sfx_b (:,:) = sfx(:,:)
450         ENDIF
451      ELSE IF( MOD ( kt - nit000, ntsinswr ) == 0 .AND. kswr > 1 )  THEN
452         CALL swz_restore_sbcmod
453      ENDIF
454      !
455      IF( MOD ( kt - nit000, ntsinswr ) == 0 .AND. kswr == 1 ) THEN
456         CALL swz_store_sbcmod
457      ENDIF
458      !                                                ! ---------------------------------------- !
459      IF( lrst_oce ) THEN                              !      Write in the ocean restart file     !
460         !                                             ! ---------------------------------------- !
461         IF(lwp) WRITE(numout,*)
462         IF(lwp) WRITE(numout,*) 'sbc : ocean surface forcing fields written in ocean restart file ',   &
463            &                    'at it= ', kt,' date= ', ndastp
464         IF(lwp) WRITE(numout,*) '~~~~'
465         CALL iom_rstput( kt, nitrst, numrow, 'utau_b' , utau )
466         CALL iom_rstput( kt, nitrst, numrow, 'vtau_b' , vtau )
467
468         ! The 3D heat content due to qsr forcing is treated in traqsr
469         ! CALL iom_rstput( kt, nitrst, numrow, 'qsr_b'  , qsr  )
470         CALL iom_rstput( kt, nitrst, numrow, 'emp_b'  , emp  )
471         CALL iom_rstput( kt, nitrst, numrow, 'sfx_b'  , sfx  )
472      ENDIF
473
474      !                                                ! ---------------------------------------- !
475      !                                                !        Outputs and control print         !
476      !                                                ! ---------------------------------------- !
477      IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN
478         CALL iom_put( "empmr"  , emp    - rnf )                ! upward water flux
479         CALL iom_put( "empbmr" , emp_b  - rnf )                ! before upward water flux ( needed to recalculate the time evolution of ssh in offline )
480         CALL iom_put( "saltflx", sfx  )                        ! downward salt flux 
481                                                                ! (includes virtual salt flux beneath ice
482                                                                ! in linear free surface case)
483         CALL iom_put( "fmmflx", fmmflx  )                      ! Freezing-melting water flux
484         CALL iom_put( "qt"    , qns  + qsr )                   ! total heat flux
485         CALL iom_put( "qns"   , qns        )                   ! solar heat flux
486         CALL iom_put( "qsr"   ,       qsr  )                   ! solar heat flux
487         IF( nn_ice > 0 .OR. nn_components == jp_iam_opa )   CALL iom_put( "ice_cover", fr_i )   ! ice fraction
488         CALL iom_put( "taum"  , taum       )                   ! wind stress module
489         CALL iom_put( "wspd"  , wndm       )                   ! wind speed  module over free ocean or leads in presence of sea-ice
490      ENDIF
491      !
492      CALL iom_put( "utau", utau )   ! i-wind stress   (stress can be updated at
493      CALL iom_put( "vtau", vtau )   ! j-wind stress    each time step in sea-ice)
494      !
495      IF(ln_ctl) THEN         ! print mean trends (used for debugging)
496         CALL prt_ctl(tab2d_1=fr_i              , clinfo1=' fr_i     - : ', mask1=tmask, ovlap=1 )
497         CALL prt_ctl(tab2d_1=(emp-rnf + fwfisf), clinfo1=' emp-rnf  - : ', mask1=tmask, ovlap=1 )
498         CALL prt_ctl(tab2d_1=(sfx-rnf + fwfisf), clinfo1=' sfx-rnf  - : ', mask1=tmask, ovlap=1 )
499         CALL prt_ctl(tab2d_1=qns              , clinfo1=' qns      - : ', mask1=tmask, ovlap=1 )
500         CALL prt_ctl(tab2d_1=qsr              , clinfo1=' qsr      - : ', mask1=tmask, ovlap=1 )
501         CALL prt_ctl(tab3d_1=tmask            , clinfo1=' tmask    - : ', mask1=tmask, ovlap=1, kdim=jpk )
502         CALL prt_ctl(tab3d_1=tsn(:,:,:,jp_tem), clinfo1=' sst      - : ', mask1=tmask, ovlap=1, kdim=1   )
503         CALL prt_ctl(tab3d_1=tsn(:,:,:,jp_sal), clinfo1=' sss      - : ', mask1=tmask, ovlap=1, kdim=1   )
504         CALL prt_ctl(tab2d_1=utau             , clinfo1=' utau     - : ', mask1=umask,                      &
505            &         tab2d_2=vtau             , clinfo2=' vtau     - : ', mask2=vmask, ovlap=1 )
506      ENDIF
507
508      IF( kt == nitend .AND. kswr == mswr )   CALL sbc_final         ! Close down surface module if necessary
509      !
510      IF( nn_timing == 1 )  CALL timing_stop('sbc')
511      !
512   END SUBROUTINE sbc
513
514
515   SUBROUTINE sbc_final
516      !!---------------------------------------------------------------------
517      !!                    ***  ROUTINE sbc_final  ***
518      !!
519      !! ** Purpose :   Finalize CICE (if used)
520      !!---------------------------------------------------------------------
521      !
522      IF( nn_ice == 4 )   CALL cice_sbc_final
523      !
524   END SUBROUTINE sbc_final
525
526   !!======================================================================
527END MODULE sbcmod
Note: See TracBrowser for help on using the repository browser.