source: CONFIG/UNIFORM/v6/IPSLCM6/SOURCES/NEMO/trcini.F90 @ 2865

Last change on this file since 2865 was 2865, checked in by cetlod, 5 years ago

Bugfix on passive tracers restoring in closed seas, before new NEMO revision

  • Property svn:executable set to *
File size: 9.6 KB
Line 
1MODULE trcini
2   !!======================================================================
3   !!                         ***  MODULE trcini  ***
4   !! TOP :   Manage the passive tracer initialization
5   !!======================================================================
6   !! History :   -   ! 1991-03 (O. Marti)  original code
7   !!            1.0  ! 2005-03 (O. Aumont, A. El Moussaoui) F90
8   !!            2.0  ! 2005-10 (C. Ethe, G. Madec) revised architecture
9   !!            4.0  ! 2011-01 (A. R. Porter, STFC Daresbury) dynamical allocation
10   !!----------------------------------------------------------------------
11#if defined key_top
12   !!----------------------------------------------------------------------
13   !!   'key_top'                                                TOP models
14   !!----------------------------------------------------------------------
15   !!   trc_init  :   Initialization for passive tracer
16   !!   top_alloc :   allocate the TOP arrays
17   !!----------------------------------------------------------------------
18   USE oce_trc         ! shared variables between ocean and passive tracers
19   USE trc             ! passive tracers common variables
20   USE trcrst          ! passive tracers restart
21   USE trcnam          ! Namelist read
22   USE trcini_cfc      ! CFC      initialisation
23   USE trcini_pisces   ! PISCES   initialisation
24   USE trcini_c14b     ! C14 bomb initialisation
25   USE trcini_my_trc   ! MY_TRC   initialisation
26   USE trcdta          ! initialisation from files
27   USE daymod          ! calendar manager
28   USE zpshde          ! partial step: hor. derivative   (zps_hde routine)
29   USE prtctl_trc      ! Print control passive tracers (prt_ctl_trc_init routine)
30   USE trcsub          ! variables to substep passive tracers
31   USE lib_mpp         ! distribued memory computing library
32   USE wrk_nemo
33   USE sbc_oce
34   USE trcice          ! tracers in sea ice
35 
36   IMPLICIT NONE
37   PRIVATE
38   
39   PUBLIC   trc_init   ! called by opa
40
41    !! * Substitutions
42#  include "domzgr_substitute.h90"
43   !!----------------------------------------------------------------------
44   !! NEMO/TOP 4.0 , NEMO Consortium (2011)
45   !! $Id: trcini.F90 6308 2016-02-12 11:32:54Z cetlod $
46   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
47   !!----------------------------------------------------------------------
48CONTAINS
49   
50   SUBROUTINE trc_init
51      !!---------------------------------------------------------------------
52      !!                     ***  ROUTINE trc_init  ***
53      !!
54      !! ** Purpose :   Initialization of the passive tracer fields
55      !!
56      !! ** Method  : - read namelist
57      !!              - control the consistancy
58      !!              - compute specific initialisations
59      !!              - set initial tracer fields (either read restart
60      !!                or read data or analytical formulation
61      !!---------------------------------------------------------------------
62      INTEGER ::   jk, jn, jl    ! dummy loop indices
63      CHARACTER (len=25) :: charout
64      REAL(wp), POINTER, DIMENSION(:,:,:,:) :: ztrcdta
65      !!---------------------------------------------------------------------
66      !
67      IF( nn_timing == 1 )   CALL timing_start('trc_init')
68      !
69      IF(lwp) WRITE(numout,*)
70      IF(lwp) WRITE(numout,*) 'trc_init : initial set up of the passive tracers'
71      IF(lwp) WRITE(numout,*) '~~~~~~~'
72
73      CALL top_alloc()              ! allocate TOP arrays
74
75      l_trcdm2dc = ln_dm2dc .OR. ( ln_cpl .AND. ncpl_qsr_freq /= 1 )
76      l_trcdm2dc = l_trcdm2dc  .AND. .NOT. lk_offline
77      IF( l_trcdm2dc .AND. lwp ) &
78         &   CALL ctl_warn(' Coupling with passive tracers and used of diurnal cycle. &
79         & Computation of a daily mean shortwave for some biogeochemical models) ')
80
81      IF( nn_cla == 1 )   &
82         &  CALL ctl_stop( ' Cross Land Advection not yet implemented with passive tracer ; nn_cla must be 0' )
83
84      CALL trc_nam      ! read passive tracers namelists
85      !
86      IF(lwp) WRITE(numout,*)
87      !
88      IF( ln_rsttr .AND. .NOT. lk_offline ) CALL trc_rst_cal( nit000, 'READ' )   ! calendar
89      !
90      IF(lwp) WRITE(numout,*)
91                                                              ! masked grid volume
92      !                                                              ! masked grid volume
93      DO jk = 1, jpk
94         cvol(:,:,jk) = e1e2t(:,:) * fse3t(:,:,jk) * tmask(:,:,jk)
95      END DO
96      IF( lk_degrad ) cvol(:,:,:) = cvol(:,:,:) * facvol(:,:,:)      ! degrad option: reduction by facvol
97      !                                                              ! total volume of the ocean
98      areatot = glob_sum( cvol(:,:,:) )
99
100      IF( lk_pisces  )       CALL trc_ini_pisces       ! PISCES  bio-model
101      IF( lk_cfc     )       CALL trc_ini_cfc          ! CFC     tracers
102      IF( lk_c14b    )       CALL trc_ini_c14b         ! C14 bomb  tracer
103      IF( lk_my_trc  )       CALL trc_ini_my_trc       ! MY_TRC  tracers
104
105      CALL trc_ice_ini                                 ! Tracers in sea ice
106
107      IF( lwp ) THEN
108         !
109         CALL ctl_opn( numstr, 'tracer.stat', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, numout, lwp , narea )
110         !
111      ENDIF
112
113      IF( ln_trcdta )      CALL trc_dta_init(jptra)
114
115
116      IF( ln_rsttr ) THEN
117        !
118        CALL trc_rst_read              ! restart from a file
119        !
120      ELSE
121        !
122        IF( ln_trcdta .AND. nb_trcdta > 0 ) THEN  ! Initialisation of tracer from a file that may also be used for damping
123            !
124            CALL wrk_alloc( jpi, jpj, jpk, nb_trcdta, ztrcdta )
125            !
126            CALL trc_dta( nit000, ztrcdta )   ! read tracer data at nit000
127            !
128            DO jn = 1, jptra
129               IF( ln_trc_ini(jn) ) THEN      ! update passive tracers arrays with input data read from file
130                  jl = n_trc_index(jn) 
131                  trn(:,:,:,jn) = ztrcdta(:,:,:,jl) * rf_trfac(jl)
132               ENDIF
133            ENDDO
134            !
135            CALL wrk_dealloc( jpi, jpj, jpk, nb_trcdta, ztrcdta )
136            !
137        ENDIF
138        !
139        trb(:,:,:,:) = trn(:,:,:,:)
140        !
141      ENDIF
142 
143      tra(:,:,:,:) = 0._wp
144      IF( ln_zps .AND. .NOT. lk_c1d .AND. .NOT. ln_isfcav )   &              ! Partial steps: before horizontal gradient of passive
145        &    CALL zps_hde    ( nit000, jptra, trn, gtru, gtrv  )  ! Partial steps: before horizontal gradient
146      IF( ln_zps .AND. .NOT. lk_c1d .AND.       ln_isfcav )   &
147        &    CALL zps_hde_isf( nit000, jptra, trn, pgtu=gtru, pgtv=gtrv, pgtui=gtrui, pgtvi=gtrvi )       ! tracers at the bottom ocean level
148
149
150      !
151      IF( nn_dttrc /= 1 )        CALL trc_sub_ini      ! Initialize variables for substepping passive tracers
152      !
153
154      trai(:) = 0._wp                                                   ! initial content of all tracers
155      DO jn = 1, jptra
156         trai(jn) = trai(jn) + glob_sum( trn(:,:,:,jn) * cvol(:,:,:)   )
157      END DO
158
159      IF(lwp) THEN               ! control print
160         WRITE(numout,*)
161         WRITE(numout,*)
162         WRITE(numout,*) '          *** Total number of passive tracer jptra = ', jptra
163         WRITE(numout,*) '          *** Total volume of ocean                = ', areatot
164         WRITE(numout,*) '          *** Total inital content of all tracers '
165         WRITE(numout,*)
166         DO jn = 1, jptra
167            WRITE(numout,9000) jn, TRIM( ctrcnm(jn) ), trai(jn)
168         ENDDO
169         WRITE(numout,*)
170      ENDIF
171      IF(lwp) WRITE(numout,*)
172      IF(ln_ctl) THEN            ! print mean trends (used for debugging)
173         CALL prt_ctl_trc_init
174         WRITE(charout, FMT="('ini ')")
175         CALL prt_ctl_trc_info( charout )
176         CALL prt_ctl_trc( tab4d=trn, mask=tmask, clinfo=ctrcnm )
177      ENDIF
1789000  FORMAT(' tracer nb : ',i2,'      name :',a10,'      initial content :',e18.10)
179      !
180      IF( nn_timing == 1 )   CALL timing_stop('trc_init')
181      !
182   END SUBROUTINE trc_init
183
184
185   SUBROUTINE top_alloc
186      !!----------------------------------------------------------------------
187      !!                     ***  ROUTINE top_alloc  ***
188      !!
189      !! ** Purpose :   Allocate all the dynamic arrays of the OPA modules
190      !!----------------------------------------------------------------------
191      USE trcadv        , ONLY:   trc_adv_alloc          ! TOP-related alloc routines...
192      USE trc           , ONLY:   trc_alloc
193      USE trcnxt        , ONLY:   trc_nxt_alloc
194      USE trczdf        , ONLY:   trc_zdf_alloc
195      USE trdtrc_oce    , ONLY:   trd_trc_oce_alloc
196#if defined key_trdmxl_trc 
197      USE trdmxl_trc    , ONLY:   trd_mxl_trc_alloc
198#endif
199      !
200      INTEGER :: ierr
201      !!----------------------------------------------------------------------
202      !
203      ierr =        trc_adv_alloc()          ! Start of TOP-related alloc routines...
204      ierr = ierr + trc_alloc    ()
205      ierr = ierr + trc_nxt_alloc()
206      ierr = ierr + trc_zdf_alloc()
207      ierr = ierr + trd_trc_oce_alloc()
208#if defined key_trdmxl_trc 
209      ierr = ierr + trd_mxl_trc_alloc()
210#endif
211      !
212      IF( lk_mpp    )   CALL mpp_sum( ierr )
213      IF( ierr /= 0 )   CALL ctl_stop( 'STOP', 'top_alloc : unable to allocate standard ocean arrays' )
214      !
215   END SUBROUTINE top_alloc
216
217#else
218   !!----------------------------------------------------------------------
219   !!  Empty module :                                     No passive tracer
220   !!----------------------------------------------------------------------
221CONTAINS
222   SUBROUTINE trc_init                      ! Dummy routine   
223   END SUBROUTINE trc_init
224#endif
225
226   !!======================================================================
227END MODULE trcini
Note: See TracBrowser for help on using the repository browser.