New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
mpp_nfd_generic.h90 in NEMO/branches/2018/dev_r10164_HPC09_ESIWACE_PREP_MERGE/src/OCE/LBC – NEMO

source: NEMO/branches/2018/dev_r10164_HPC09_ESIWACE_PREP_MERGE/src/OCE/LBC/mpp_nfd_generic.h90 @ 10337

Last change on this file since 10337 was 10337, checked in by smasson, 4 years ago

dev_r10164_HPC09_ESIWACE_PREP_MERGE: action 3d: force safe NPF (2 lines update) for field recieved from oasis, see #2133

  • Property svn:keywords set to Id
  • Property svn:mime-type set to text/x-fortran
File size: 13.0 KB
Line 
1#if defined MULTI
2#   define NAT_IN(k)                cd_nat(k)   
3#   define SGN_IN(k)                psgn(k)
4#   define F_SIZE(ptab)             kfld
5#   define LBC_ARG                  (jf)
6#   if defined DIM_2d
7#      define ARRAY_TYPE(i,j,k,l,f)    TYPE(PTR_2D)     , INTENT(inout) ::   ptab(f)
8#      define ARRAY_IN(i,j,k,l,f)      ptab(f)%pt2d(i,j)
9#      define K_SIZE(ptab)             1
10#      define L_SIZE(ptab)             1
11#   endif
12#   if defined DIM_3d
13#      define ARRAY_TYPE(i,j,k,l,f)    TYPE(PTR_3D)     , INTENT(inout) ::   ptab(f)
14#      define ARRAY_IN(i,j,k,l,f)      ptab(f)%pt3d(i,j,k)
15#      define K_SIZE(ptab)             SIZE(ptab(1)%pt3d,3)
16#      define L_SIZE(ptab)             1
17#   endif
18#   if defined DIM_4d
19#      define ARRAY_TYPE(i,j,k,l,f)    TYPE(PTR_4D)     , INTENT(inout) ::   ptab(f)
20#      define ARRAY_IN(i,j,k,l,f)      ptab(f)%pt4d(i,j,k,l)
21#      define K_SIZE(ptab)             SIZE(ptab(1)%pt4d,3)
22#      define L_SIZE(ptab)             SIZE(ptab(1)%pt4d,4)
23#   endif
24#else
25!                          !==  IN: ptab is an array  ==!
26#   define ARRAY_TYPE(i,j,k,l,f)    REAL(wp)         , INTENT(inout) ::   ARRAY_IN(i,j,k,l,f)
27#   define NAT_IN(k)                cd_nat
28#   define SGN_IN(k)                psgn
29#   define F_SIZE(ptab)             1
30#   define LBC_ARG
31#   if defined DIM_2d
32#      define ARRAY_IN(i,j,k,l,f)   ptab(i,j)
33#      define K_SIZE(ptab)          1
34#      define L_SIZE(ptab)          1
35#   endif
36#   if defined DIM_3d
37#      define ARRAY_IN(i,j,k,l,f)   ptab(i,j,k)
38#      define K_SIZE(ptab)          SIZE(ptab,3)
39#      define L_SIZE(ptab)          1
40#   endif
41#   if defined DIM_4d
42#      define ARRAY_IN(i,j,k,l,f)   ptab(i,j,k,l)
43#      define K_SIZE(ptab)          SIZE(ptab,3)
44#      define L_SIZE(ptab)          SIZE(ptab,4)
45#   endif
46#endif
47
48   SUBROUTINE ROUTINE_NFD( ptab, cd_nat, psgn, kfld )
49      !!----------------------------------------------------------------------
50      ARRAY_TYPE(:,:,:,:,:)   ! array or pointer of arrays on which the boundary condition is applied
51      CHARACTER(len=1) , INTENT(in   ) ::   NAT_IN(:)   ! nature of array grid-points
52      REAL(wp)         , INTENT(in   ) ::   SGN_IN(:)   ! sign used across the north fold boundary
53      INTEGER, OPTIONAL, INTENT(in   ) ::   kfld        ! number of pt3d arrays
54      !
55      INTEGER  ::   ji,  jj,  jk,  jl, jh, jf, jr   ! dummy loop indices
56      INTEGER  ::   ipi, ipj, ipk, ipl, ipf         ! dimension of the input array
57      INTEGER  ::   imigr, iihom, ijhom             ! local integers
58      INTEGER  ::   ierr, ibuffsize, ilci, ildi, ilei, iilb
59      INTEGER  ::   ij, iproc
60      INTEGER, DIMENSION (jpmaxngh)       ::   ml_req_nf   ! for mpi_isend when avoiding mpi_allgather
61      INTEGER                             ::   ml_err      ! for mpi_isend when avoiding mpi_allgather
62      INTEGER, DIMENSION(MPI_STATUS_SIZE) ::   ml_stat     ! for mpi_isend when avoiding mpi_allgather
63      !                                                    ! Workspace for message transfers avoiding mpi_allgather
64      INTEGER                             ::   ipf_j       ! sum of lines for all multi fields
65      INTEGER                             ::   js          ! counter
66      INTEGER, DIMENSION(:,:),          ALLOCATABLE ::   jj_s  ! position of sent lines
67      INTEGER, DIMENSION(:),            ALLOCATABLE ::   ipj_s ! number of sent lines
68      REAL(wp), DIMENSION(:,:,:)      , ALLOCATABLE ::   ztabl
69      REAL(wp), DIMENSION(:,:,:,:,:)  , ALLOCATABLE ::   ztab, ztabr
70      REAL(wp), DIMENSION(:,:,:,:,:)  , ALLOCATABLE ::   znorthloc, zfoldwk     
71      REAL(wp), DIMENSION(:,:,:,:,:,:), ALLOCATABLE ::   znorthgloio
72      !!----------------------------------------------------------------------
73      !
74      ipk = K_SIZE(ptab)   ! 3rd dimension
75      ipl = L_SIZE(ptab)   ! 4th    -
76      ipf = F_SIZE(ptab)   ! 5th    -      use in "multi" case (array of pointers)
77      !
78      IF( l_north_nogather ) THEN      !==  ????  ==!
79
80         ALLOCATE(ipj_s(ipf))
81
82         ipj      = 2            ! Max 2nd dimension of message transfers (last two j-line only)
83         ipj_s(:) = 1            ! Real 2nd dimension of message transfers (depending on perf requirement)
84                                 ! by default, only one line is exchanged
85
86         ALLOCATE( jj_s(ipf,2) )
87
88         ! re-define number of exchanged lines :
89         !  must be two during the first two time steps
90         !  to correct possible incoherent values on North fold lines from restart
91
92         ! Two lines update (slower but necessary to avoid different values ion identical grid points
93         IF ( l_full_nf_update .OR.                          &    ! if coupling fields
94              ( ncom_stp == nit000 .AND. .NOT. ln_rstart ) ) &    ! at first time step, if not restart
95            ipj_s(:) = 2
96
97         ! Index of modifying lines in input
98         DO jf = 1, ipf                      ! Loop over the number of arrays to be processed
99            !
100            SELECT CASE ( npolj )
101            !
102            CASE ( 3, 4 )                       ! *  North fold  T-point pivot
103               !
104               SELECT CASE ( NAT_IN(jf) )
105               !
106               CASE ( 'T' , 'W' ,'U' )                            ! T-, U-, W-point
107                  jj_s(jf,1) = nlcj - 2 ;  jj_s(jf,2) = nlcj - 1
108               CASE ( 'V' , 'F' )                                 ! V-, F-point
109                  jj_s(jf,1) = nlcj - 3 ;  jj_s(jf,2) = nlcj - 2
110               END SELECT
111            !
112            CASE ( 5, 6 )                        ! *  North fold  F-point pivot
113               SELECT CASE ( NAT_IN(jf) )
114               !
115               CASE ( 'T' , 'W' ,'U' )                            ! T-, U-, W-point
116                  jj_s(jf,1) = nlcj - 1     
117                  ipj_s(jf) = 1                  ! need only one line anyway
118               CASE ( 'V' , 'F' )                                 ! V-, F-point
119                  jj_s(jf,1) = nlcj - 2 ;  jj_s(jf,2) = nlcj - 1
120               END SELECT
121            !
122            END SELECT
123            !
124         ENDDO
125         !
126         ipf_j = sum (ipj_s(:))      ! Total number of lines to be exchanged
127         !
128         ALLOCATE( znorthloc(jpimax,ipf_j,ipk,ipl,1) )
129         !
130         js = 0
131         DO jf = 1, ipf                      ! Loop over the number of arrays to be processed
132            DO jj = 1, ipj_s(jf)
133               js = js + 1
134               DO jl = 1, ipl
135                  DO jk = 1, ipk
136                     znorthloc(1:jpi,js,jk,jl,1) = ARRAY_IN(1:jpi,jj_s(jf,jj),jk,jl,jf)
137                  END DO
138               END DO
139            END DO
140         END DO
141         !
142         ibuffsize = jpimax * ipf_j * ipk * ipl
143         !
144         ALLOCATE( zfoldwk(jpimax,ipf_j,ipk,ipl,1) )
145         ALLOCATE( ztabr(jpimax*jpmaxngh,ipj,ipk,ipl,ipf) ) 
146         ! when some processors of the north fold are suppressed,
147         ! values of ztab* arrays corresponding to these suppressed domain won't be defined
148         ! and we need a default definition to 0.
149         ! a better test should be: a testing if "suppressed land-processors" belongs to the north-pole folding
150         IF ( jpni*jpnj /= jpnij ) ztabr(:,:,:,:,:) = 0._wp
151         !
152         ! start waiting time measurement
153         IF( ln_timing ) CALL tic_tac(.TRUE.)
154         !
155         DO jr = 1, nsndto
156            IF( nfipproc(isendto(jr),jpnj) /= narea-1 .AND. nfipproc(isendto(jr),jpnj) /= -1 ) THEN
157               CALL mppsend( 5, znorthloc, ibuffsize, nfipproc(isendto(jr),jpnj), ml_req_nf(jr) )
158            ENDIF
159         END DO
160         !
161         DO jr = 1,nsndto
162            iproc = nfipproc(isendto(jr),jpnj)
163            IF(iproc /= -1) THEN
164               iilb = nimppt(iproc+1)
165               ilci = nlcit (iproc+1)
166               ildi = nldit (iproc+1)
167               ilei = nleit (iproc+1)
168               IF( iilb            ==      1 )   ildi = 1      ! e-w boundary already done -> force to take 1st column
169               IF( iilb + ilci - 1 == jpiglo )   ilei = ilci   ! e-w boundary already done -> force to take last column
170               iilb = nfiimpp(isendto(jr),jpnj) - nfiimpp(isendto(1),jpnj)
171            ENDIF
172            IF( iproc /= narea-1 .AND. iproc /= -1 ) THEN
173               CALL mpprecv(5, zfoldwk, ibuffsize, iproc)
174               js = 0
175               DO jf = 1, ipf ; DO jj = 1, ipj_s(jf)
176                  js = js + 1
177                  DO jl = 1, ipl
178                     DO jk = 1, ipk
179                        DO ji = ildi, ilei
180                           ztabr(iilb+ji,jj,jk,jl,jf) = zfoldwk(ji,js,jk,jl,1)
181                        END DO
182                     END DO
183                  END DO
184               END DO; END DO
185            ELSE IF( iproc == narea-1 ) THEN
186               DO jf = 1, ipf ; DO jj = 1, ipj_s(jf)
187                  DO jl = 1, ipl
188                     DO jk = 1, ipk
189                        DO ji = ildi, ilei
190                           ztabr(iilb+ji,jj,jk,jl,jf) = ARRAY_IN(ji,jj_s(jf,jj),jk,jl,jf)
191                        END DO
192                     END DO
193                  END DO
194               END DO; END DO
195            ENDIF
196         END DO
197         IF( l_isend ) THEN
198            DO jr = 1,nsndto
199               IF( nfipproc(isendto(jr),jpnj) /= narea-1 .AND. nfipproc(isendto(jr),jpnj) /= -1 ) THEN
200                  CALL mpi_wait( ml_req_nf(jr), ml_stat, ml_err )
201               ENDIF
202            END DO
203         ENDIF
204         !
205         IF( ln_timing ) CALL tic_tac(.FALSE.)
206         !
207         ! North fold boundary condition
208         !
209         DO jf = 1, ipf
210            CALL lbc_nfd_nogather(ARRAY_IN(:,:,:,:,jf), ztabr(:,1:ipj_s(jf),:,:,jf), cd_nat LBC_ARG, psgn LBC_ARG )
211         END DO
212         !
213         DEALLOCATE( zfoldwk )
214         DEALLOCATE( ztabr ) 
215         DEALLOCATE( jj_s ) 
216         DEALLOCATE( ipj_s ) 
217      ELSE                             !==  ????  ==!
218         !
219         ipj   = 4            ! 2nd dimension of message transfers (last j-lines)
220         !
221         ALLOCATE( znorthloc(jpimax,ipj,ipk,ipl,ipf) )
222         !
223         DO jf = 1, ipf                ! put in znorthloc the last ipj j-lines of ptab
224            DO jl = 1, ipl
225               DO jk = 1, ipk
226                  DO jj = nlcj - ipj +1, nlcj
227                     ij = jj - nlcj + ipj
228                     znorthloc(1:jpi,ij,jk,jl,jf) = ARRAY_IN(1:jpi,jj,jk,jl,jf)
229                  END DO
230               END DO
231            END DO
232         END DO
233         !
234         ibuffsize = jpimax * ipj * ipk * ipl * ipf
235         !
236         ALLOCATE( ztab       (jpiglo,ipj,ipk,ipl,ipf     ) )
237         ALLOCATE( znorthgloio(jpimax,ipj,ipk,ipl,ipf,jpni) )
238         !
239         ! when some processors of the north fold are suppressed,
240         ! values of ztab* arrays corresponding to these suppressed domain won't be defined
241         ! and we need a default definition to 0.
242         ! a better test should be: a testing if "suppressed land-processors" belongs to the north-pole folding
243         IF ( jpni*jpnj /= jpnij ) ztab(:,:,:,:,:) = 0._wp
244         !
245         ! start waiting time measurement
246         IF( ln_timing ) CALL tic_tac(.TRUE.)
247         CALL MPI_ALLGATHER( znorthloc  , ibuffsize, MPI_DOUBLE_PRECISION,                &
248            &                znorthgloio, ibuffsize, MPI_DOUBLE_PRECISION, ncomm_north, ierr )
249         !
250         ! stop waiting time measurement
251         IF( ln_timing ) CALL tic_tac(.FALSE.)
252         !
253         DO jr = 1, ndim_rank_north         ! recover the global north array
254            iproc = nrank_north(jr) + 1
255            iilb  = nimppt(iproc)
256            ilci  = nlcit (iproc)
257            ildi  = nldit (iproc)
258            ilei  = nleit (iproc)
259            IF( iilb            ==      1 )   ildi = 1      ! e-w boundary already done -> force to take 1st column
260            IF( iilb + ilci - 1 == jpiglo )   ilei = ilci   ! e-w boundary already done -> force to take last column
261            DO jf = 1, ipf
262               DO jl = 1, ipl
263                  DO jk = 1, ipk
264                     DO jj = 1, ipj
265                        DO ji = ildi, ilei
266                           ztab(ji+iilb-1,jj,jk,jl,jf) = znorthgloio(ji,jj,jk,jl,jf,jr)
267                        END DO
268                     END DO
269                  END DO
270               END DO
271            END DO
272         END DO
273         DO jf = 1, ipf
274            CALL lbc_nfd( ztab(:,:,:,:,jf), cd_nat LBC_ARG, psgn LBC_ARG )   ! North fold boundary condition
275         END DO
276         !
277         DO jf = 1, ipf
278            DO jl = 1, ipl
279               DO jk = 1, ipk
280                  DO jj = nlcj-ipj+1, nlcj             ! Scatter back to ARRAY_IN
281                     ij = jj - nlcj + ipj
282                     DO ji= 1, nlci
283                        ARRAY_IN(ji,jj,jk,jl,jf) = ztab(ji+nimpp-1,ij,jk,jl,jf)
284                     END DO
285                  END DO
286               END DO
287            END DO
288         END DO
289         !
290      !
291         DEALLOCATE( ztab )
292         DEALLOCATE( znorthgloio )
293      ENDIF
294      !
295      DEALLOCATE( znorthloc )
296      !
297   END SUBROUTINE ROUTINE_NFD
298
299#undef ARRAY_TYPE
300#undef NAT_IN
301#undef SGN_IN
302#undef ARRAY_IN
303#undef K_SIZE
304#undef L_SIZE
305#undef F_SIZE
306#undef LBC_ARG
Note: See TracBrowser for help on using the repository browser.