source: NEMO/branches/2018/dev_r9838_ENHANCE04_RK3/src/OCE/TRA/trasbc.F90 @ 10009

Last change on this file since 10009 was 10009, checked in by gm, 2 years ago

#1911 (ENHANCE-04): RK3 branch - step II.1 time-level dimension on ssh

  • Property svn:keywords set to Id
File size: 13.7 KB
Line 
1MODULE trasbc
2   !!==============================================================================
3   !!                       ***  MODULE  trasbc  ***
4   !! Ocean active tracers:  surface boundary condition
5   !!==============================================================================
6   !! History :  OPA  !  1998-10  (G. Madec, G. Roullet, M. Imbard)  Original code
7   !!            8.2  !  2001-02  (D. Ludicone)  sea ice and free surface
8   !!  NEMO      1.0  !  2002-06  (G. Madec)  F90: Free form and module
9   !!            3.3  !  2010-04  (M. Leclair, G. Madec)  Forcing averaged over 2 time steps
10   !!             -   !  2010-09  (C. Ethe, G. Madec) Merge TRA-TRC
11   !!            3.6  !  2014-11  (P. Mathiot) isf melting forcing
12   !!----------------------------------------------------------------------
13
14   !!----------------------------------------------------------------------
15   !!   tra_sbc       : update the tracer trend at ocean surface
16   !!----------------------------------------------------------------------
17   USE oce            ! ocean dynamics and active tracers
18   USE sbc_oce        ! surface boundary condition: ocean
19   USE dom_oce        ! ocean space domain variables
20   USE phycst         ! physical constant
21   USE eosbn2         ! Equation Of State
22   USE sbcmod         ! ln_rnf 
23   USE sbcrnf         ! River runoff 
24   USE sbcisf         ! Ice shelf   
25   USE iscplini       ! Ice sheet coupling
26   USE traqsr         ! solar radiation penetration
27   USE trd_oce        ! trends: ocean variables
28   USE trdtra         ! trends manager: tracers
29   USE wet_dry,  ONLY : ll_wd, rn_wdmin1, r_rn_wdmin1   ! Wetting and drying
30#if defined key_asminc   
31   USE asminc         ! Assimilation increment
32#endif
33   !
34   USE in_out_manager ! I/O manager
35   USE prtctl         ! Print control
36   USE iom            ! xIOS server
37   USE lbclnk         ! ocean lateral boundary conditions (or mpp link)
38   USE timing         ! Timing
39
40   IMPLICIT NONE
41   PRIVATE
42
43   PUBLIC   tra_sbc   ! routine called by step.F90
44
45   !! * Substitutions
46#  include "vectopt_loop_substitute.h90"
47   !!----------------------------------------------------------------------
48   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
49   !! $Id$
50   !! Software governed by the CeCILL licence     (./LICENSE)
51   !!----------------------------------------------------------------------
52CONTAINS
53
54   SUBROUTINE tra_sbc ( kt )
55      !!----------------------------------------------------------------------
56      !!                  ***  ROUTINE tra_sbc  ***
57      !!                   
58      !! ** Purpose :   Compute the tracer surface boundary condition trend of
59      !!      (flux through the interface, concentration/dilution effect)
60      !!      and add it to the general trend of tracer equations.
61      !!
62      !! ** Method :   The (air+ice)-sea flux has two components:
63      !!      (1) Fext, external forcing (i.e. flux through the (air+ice)-sea interface);
64      !!      (2) Fwe , tracer carried with the water that is exchanged with air+ice.
65      !!               The input forcing fields (emp, rnf, sfx, isf) contain Fext+Fwe,
66      !!             they are simply added to the tracer trend (tsa).
67      !!               In linear free surface case (ln_linssh=T), the volume of the
68      !!             ocean does not change with the water exchanges at the (air+ice)-sea
69      !!             interface. Therefore another term has to be added, to mimic the
70      !!             concentration/dilution effect associated with water exchanges.
71      !!
72      !! ** Action  : - Update tsa with the surface boundary condition trend
73      !!              - send trends to trdtra module for further diagnostics(l_trdtra=T)
74      !!----------------------------------------------------------------------
75      INTEGER, INTENT(in) ::   kt   ! ocean time-step index
76      !
77      INTEGER  ::   ji, jj, jk, jn              ! dummy loop indices 
78      INTEGER  ::   ikt, ikb                    ! local integers
79      REAL(wp) ::   zfact, z1_e3t, zdep, ztim   ! local scalar
80      REAL(wp), DIMENSION(:,:,:,:), ALLOCATABLE ::   ztrd   ! 4D workspace
81      !!----------------------------------------------------------------------
82      !
83      IF( ln_timing )   CALL timing_start('tra_sbc')
84      !
85      IF( kt == nit000 ) THEN
86         IF(lwp) WRITE(numout,*)
87         IF(lwp) WRITE(numout,*) 'tra_sbc : TRAcer Surface Boundary Condition'
88         IF(lwp) WRITE(numout,*) '~~~~~~~ '
89      ENDIF
90      !
91      IF( l_trdtra ) THEN                    !* Save input tsa trends
92         ALLOCATE( ztrd(jpi,jpj,jpk,jpts) ) 
93         ztrd(:,:,:,:) = tsa(:,:,:,:)
94      ENDIF
95      !
96!!gm  This should be moved into sbcmod.F90 module ? (especially now that ln_traqsr is read in namsbc namelist)
97      IF( .NOT.ln_traqsr ) THEN     ! no solar radiation penetration
98         qns(:,:) = qns(:,:) + qsr(:,:)      ! total heat flux in qns
99         qsr(:,:) = 0._wp                    ! qsr set to zero
100      ENDIF
101
102      !----------------------------------------
103      !        EMP, SFX and QNS effects
104      !----------------------------------------
105      !                             !==  Set before sbc tracer content fields  ==!
106      IF( kt == nit000 ) THEN             !* 1st time-step
107         IF( ln_rstart .AND.    &               ! Restart: read in restart file
108              & iom_varid( numror, 'sbc_hc_b', ldstop = .FALSE. ) > 0 ) THEN
109            IF(lwp) WRITE(numout,*) '          nit000-1 sbc tracer content field read in the restart file'
110            zfact = 0.5_wp
111            sbc_tsc(:,:,:) = 0._wp
112            CALL iom_get( numror, jpdom_autoglo, 'sbc_hc_b', sbc_tsc_b(:,:,jp_tem), ldxios = lrxios )   ! before heat content sbc trend
113            CALL iom_get( numror, jpdom_autoglo, 'sbc_sc_b', sbc_tsc_b(:,:,jp_sal), ldxios = lrxios )   ! before salt content sbc trend
114         ELSE                                   ! No restart or restart not found: Euler forward time stepping
115            zfact = 1._wp
116            sbc_tsc(:,:,:) = 0._wp
117            sbc_tsc_b(:,:,:) = 0._wp
118         ENDIF
119      ELSE                                !* other time-steps: swap of forcing fields
120         zfact = 0.5_wp
121         sbc_tsc_b(:,:,:) = sbc_tsc(:,:,:)
122      ENDIF
123      !                             !==  Now sbc tracer content fields  ==!
124      DO jj = 2, jpj
125         DO ji = fs_2, fs_jpim1   ! vector opt.
126            IF ( ll_wd ) THEN     ! If near WAD point limit the flux for now
127               IF ( ssh(ji,jj,Nnn) + ht_0(ji,jj) >  2._wp * rn_wdmin1 ) THEN
128                  sbc_tsc(ji,jj,jp_tem) = r1_rho0_rcp * qns(ji,jj)   ! non solar heat flux
129               ELSE IF ( ssh(ji,jj,Nnn) + ht_0(ji,jj) >  rn_wdmin1 ) THEN
130                  sbc_tsc(ji,jj,jp_tem) = r1_rho0_rcp * qns(ji,jj) &
131                     &                  * tanh ( 5._wp * ( ( ssh(ji,jj,Nnn) + ht_0(ji,jj) - rn_wdmin1 ) * r_rn_wdmin1 ) )
132               ELSE
133                  sbc_tsc(ji,jj,jp_tem) = 0._wp
134               ENDIF
135            ELSE
136               sbc_tsc(ji,jj,jp_tem) = r1_rho0_rcp * qns(ji,jj)   ! non solar heat flux
137            ENDIF
138
139            sbc_tsc(ji,jj,jp_sal) = r1_rho0     * sfx(ji,jj)   ! salt flux due to freezing/melting
140         END DO
141      END DO
142      IF( ln_linssh ) THEN                !* linear free surface 
143         DO jj = 2, jpj                         !==>> add concentration/dilution effect due to constant volume cell
144            DO ji = fs_2, fs_jpim1   ! vector opt.
145               sbc_tsc(ji,jj,jp_tem) = sbc_tsc(ji,jj,jp_tem) + r1_rho0 * emp(ji,jj) * tsn(ji,jj,1,jp_tem)
146               sbc_tsc(ji,jj,jp_sal) = sbc_tsc(ji,jj,jp_sal) + r1_rho0 * emp(ji,jj) * tsn(ji,jj,1,jp_sal)
147            END DO
148         END DO                                 !==>> output c./d. term
149         IF( iom_use('emp_x_sst') )   CALL iom_put( "emp_x_sst", emp (:,:) * tsn(:,:,1,jp_tem) )
150         IF( iom_use('emp_x_sss') )   CALL iom_put( "emp_x_sss", emp (:,:) * tsn(:,:,1,jp_sal) )
151      ENDIF
152      !
153      DO jn = 1, jpts               !==  update tracer trend  ==!
154         DO jj = 2, jpj
155            DO ji = fs_2, fs_jpim1   ! vector opt. 
156               tsa(ji,jj,1,jn) = tsa(ji,jj,1,jn) + zfact * ( sbc_tsc_b(ji,jj,jn) + sbc_tsc(ji,jj,jn) ) / e3t_n(ji,jj,1)
157            END DO
158         END DO
159      END DO
160      !                 
161      IF( lrst_oce ) THEN           !==  write sbc_tsc in the ocean restart file  ==!
162         IF( lwxios ) CALL iom_swap(      cwxios_context          )
163         CALL iom_rstput( kt, nitrst, numrow, 'sbc_hc_b', sbc_tsc(:,:,jp_tem), ldxios = lwxios )
164         CALL iom_rstput( kt, nitrst, numrow, 'sbc_sc_b', sbc_tsc(:,:,jp_sal), ldxios = lwxios )
165         IF( lwxios ) CALL iom_swap(      cxios_context          )
166      ENDIF
167      !
168      !----------------------------------------
169      !       Ice Shelf effects (ISF)
170      !     tbl treated as in Losh (2008) JGR
171      !----------------------------------------
172      !
173!!gm BUG ?   Why no differences between non-linear and linear free surface ?
174!!gm         probably taken into account in r1_hisf_tbl : to be verified
175      IF( ln_isf ) THEN
176         zfact = 0.5_wp
177         DO jj = 2, jpj
178            DO ji = fs_2, fs_jpim1
179               !
180               ikt = misfkt(ji,jj)
181               ikb = misfkb(ji,jj)
182               !
183               ! level fully include in the ice shelf boundary layer
184               ! sign - because fwf sign of evapo (rnf sign of precip)
185               DO jk = ikt, ikb - 1
186               ! compute trend
187                  tsa(ji,jj,jk,jp_tem) = tsa(ji,jj,jk,jp_tem)                                                &
188                     &           + zfact * ( risf_tsc_b(ji,jj,jp_tem) + risf_tsc(ji,jj,jp_tem) )             &
189                     &           * r1_hisf_tbl(ji,jj)
190               END DO
191   
192               ! level partially include in ice shelf boundary layer
193               ! compute trend
194               tsa(ji,jj,ikb,jp_tem) = tsa(ji,jj,ikb,jp_tem)                                                 &
195                  &              + zfact * ( risf_tsc_b(ji,jj,jp_tem) + risf_tsc(ji,jj,jp_tem) )             &
196                  &              * r1_hisf_tbl(ji,jj) * ralpha(ji,jj)
197
198            END DO
199         END DO
200      END IF
201      !
202      !----------------------------------------
203      !        River Runoff effects
204      !----------------------------------------
205      !
206      IF( ln_rnf ) THEN         ! input of heat and salt due to river runoff
207         zfact = 0.5_wp
208         DO jj = 2, jpj 
209            DO ji = fs_2, fs_jpim1
210               IF( rnf(ji,jj) /= 0._wp ) THEN
211                  zdep = zfact / h_rnf(ji,jj)
212                  DO jk = 1, nk_rnf(ji,jj)
213                                        tsa(ji,jj,jk,jp_tem) = tsa(ji,jj,jk,jp_tem)                                 &
214                                           &                 +  ( rnf_tsc_b(ji,jj,jp_tem) + rnf_tsc(ji,jj,jp_tem) ) * zdep
215                     IF( ln_rnf_sal )   tsa(ji,jj,jk,jp_sal) = tsa(ji,jj,jk,jp_sal)                                 &
216                                           &                 +  ( rnf_tsc_b(ji,jj,jp_sal) + rnf_tsc(ji,jj,jp_sal) ) * zdep 
217                  END DO
218               ENDIF
219            END DO 
220         END DO 
221      ENDIF
222
223      IF( iom_use('rnf_x_sst') )   CALL iom_put( "rnf_x_sst", rnf*tsn(:,:,1,jp_tem) )   ! runoff term on sst
224      IF( iom_use('rnf_x_sss') )   CALL iom_put( "rnf_x_sss", rnf*tsn(:,:,1,jp_sal) )   ! runoff term on sss
225
226#if defined key_asminc
227      !
228      !----------------------------------------
229      !        Assmilation effects
230      !----------------------------------------
231      !
232      IF( ln_sshinc ) THEN         ! input of heat and salt due to assimilation
233          !
234         IF( ln_linssh ) THEN
235            DO jj = 2, jpj 
236               DO ji = fs_2, fs_jpim1
237                  ztim = ssh_iau(ji,jj) / e3t_n(ji,jj,1)
238                  tsa(ji,jj,1,jp_tem) = tsa(ji,jj,1,jp_tem) + tsn(ji,jj,1,jp_tem) * ztim
239                  tsa(ji,jj,1,jp_sal) = tsa(ji,jj,1,jp_sal) + tsn(ji,jj,1,jp_sal) * ztim
240               END DO
241            END DO
242         ELSE
243            DO jj = 2, jpj 
244               DO ji = fs_2, fs_jpim1
245                  ztim = ssh_iau(ji,jj) / ( ht_n(ji,jj) + 1. - ssmask(ji, jj) )
246                  tsa(ji,jj,:,jp_tem) = tsa(ji,jj,:,jp_tem) + tsn(ji,jj,:,jp_tem) * ztim
247                  tsa(ji,jj,:,jp_sal) = tsa(ji,jj,:,jp_sal) + tsn(ji,jj,:,jp_sal) * ztim
248               END DO 
249            END DO 
250         ENDIF
251         !
252      ENDIF
253      !
254#endif
255      !
256      !----------------------------------------
257      !        Ice Sheet coupling imbalance correction to have conservation
258      !----------------------------------------
259      !
260      IF( ln_iscpl .AND. ln_hsb) THEN         ! input of heat and salt due to river runoff
261         DO jk = 1,jpk
262            DO jj = 2, jpj 
263               DO ji = fs_2, fs_jpim1
264                  zdep = 1._wp / e3t_n(ji,jj,jk) 
265                  tsa(ji,jj,jk,jp_tem) = tsa(ji,jj,jk,jp_tem) - htsc_iscpl(ji,jj,jk,jp_tem) * zdep
266                  tsa(ji,jj,jk,jp_sal) = tsa(ji,jj,jk,jp_sal) - htsc_iscpl(ji,jj,jk,jp_sal) * zdep 
267               END DO 
268            END DO 
269         END DO
270      ENDIF
271
272      IF( l_trdtra )   THEN                      ! save the horizontal diffusive trends for further diagnostics
273         ztrd(:,:,:,:) = tsa(:,:,:,:) - ztrd(:,:,:,:)
274         CALL trd_tra( kt, 'TRA', jp_tem, jptra_nsr, ztrd(:,:,:,jp_tem) )
275         CALL trd_tra( kt, 'TRA', jp_sal, jptra_nsr, ztrd(:,:,:,jp_sal) )
276         DEALLOCATE( ztrd ) 
277      ENDIF
278      !
279      IF(ln_ctl)   CALL prt_ctl( tab3d_1=tsa(:,:,:,jp_tem), clinfo1=' sbc  - Ta: ', mask1=tmask,   &
280         &                       tab3d_2=tsa(:,:,:,jp_sal), clinfo2=       ' Sa: ', mask2=tmask, clinfo3='tra' )
281      !
282      IF( ln_timing )   CALL timing_stop('tra_sbc')
283      !
284   END SUBROUTINE tra_sbc
285
286   !!======================================================================
287END MODULE trasbc
Note: See TracBrowser for help on using the repository browser.