source: NEMO/branches/2019/ENHANCE-02_ISF_nemo/src/OCE/nemogcm.F90 @ 11395

Last change on this file since 11395 was 11395, checked in by mathiot, 2 years ago

ENHANCE-02_ISF_nemo : Initial commit isf simplification (add ISF directory, moved isf routine in and split isf cavity and isf parametrisation, …) (ticket #2142)

  • Property svn:keywords set to Id
File size: 35.6 KB
Line 
1MODULE nemogcm
2   !!======================================================================
3   !!                       ***  MODULE nemogcm   ***
4   !! Ocean system   : NEMO GCM (ocean dynamics, on-line tracers, biochemistry and sea-ice)
5   !!======================================================================
6   !! History :  OPA  ! 1990-10  (C. Levy, G. Madec)  Original code
7   !!            7.0  ! 1991-11  (M. Imbard, C. Levy, G. Madec)
8   !!            7.1  ! 1993-03  (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
9   !!                             P. Delecluse, C. Perigaud, G. Caniaux, B. Colot, C. Maes) release 7.1
10   !!             -   ! 1992-06  (L.Terray)  coupling implementation
11   !!             -   ! 1993-11  (M.A. Filiberti) IGLOO sea-ice
12   !!            8.0  ! 1996-03  (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
13   !!                             P. Delecluse, L.Terray, M.A. Filiberti, J. Vialar, A.M. Treguier, M. Levy) release 8.0
14   !!            8.1  ! 1997-06  (M. Imbard, G. Madec)
15   !!            8.2  ! 1999-11  (M. Imbard, H. Goosse)  sea-ice model
16   !!                 ! 1999-12  (V. Thierry, A-M. Treguier, M. Imbard, M-A. Foujols)  OPEN-MP
17   !!                 ! 2000-07  (J-M Molines, M. Imbard)  Open Boundary Conditions  (CLIPPER)
18   !!   NEMO     1.0  ! 2002-08  (G. Madec)  F90: Free form and modules
19   !!             -   ! 2004-06  (R. Redler, NEC CCRLE, Germany) add OASIS[3/4] coupled interfaces
20   !!             -   ! 2004-08  (C. Talandier) New trends organization
21   !!             -   ! 2005-06  (C. Ethe) Add the 1D configuration possibility
22   !!             -   ! 2005-11  (V. Garnier) Surface pressure gradient organization
23   !!             -   ! 2006-03  (L. Debreu, C. Mazauric)  Agrif implementation
24   !!             -   ! 2006-04  (G. Madec, R. Benshila)  Step reorganization
25   !!             -   ! 2007-07  (J. Chanut, A. Sellar) Unstructured open boundaries (BDY)
26   !!            3.2  ! 2009-08  (S. Masson)  open/write in the listing file in mpp
27   !!            3.3  ! 2010-05  (K. Mogensen, A. Weaver, M. Martin, D. Lea) Assimilation interface
28   !!             -   ! 2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase
29   !!            3.3.1! 2011-01  (A. R. Porter, STFC Daresbury) dynamical allocation
30   !!             -   ! 2011-11  (C. Harris) decomposition changes for running with CICE
31   !!            3.6  ! 2012-05  (C. Calone, J. Simeon, G. Madec, C. Ethe) Add grid coarsening
32   !!             -   ! 2014-12  (G. Madec) remove KPP scheme and cross-land advection (cla)
33   !!            4.0  ! 2016-10  (G. Madec, S. Flavoni)  domain configuration / user defined interface
34   !!----------------------------------------------------------------------
35
36   !!----------------------------------------------------------------------
37   !!   nemo_gcm      : solve ocean dynamics, tracer, biogeochemistry and/or sea-ice
38   !!   nemo_init     : initialization of the NEMO system
39   !!   nemo_ctl      : initialisation of the contol print
40   !!   nemo_closefile: close remaining open files
41   !!   nemo_alloc    : dynamical allocation
42   !!----------------------------------------------------------------------
43   USE step_oce       ! module used in the ocean time stepping module (step.F90)
44   USE phycst         ! physical constant                  (par_cst routine)
45   USE domain         ! domain initialization   (dom_init & dom_cfg routines)
46   USE closea         ! treatment of closed seas (for ln_closea)
47   USE usrdef_nam     ! user defined configuration
48   USE tideini        ! tidal components initialization   (tide_ini routine)
49   USE bdy_oce,  ONLY : ln_bdy
50   USE bdyini         ! open boundary cond. setting       (bdy_init routine)
51   USE istate         ! initial state setting          (istate_init routine)
52   USE ldfdyn         ! lateral viscosity setting      (ldfdyn_init routine)
53   USE ldftra         ! lateral diffusivity setting    (ldftra_init routine)
54   USE trdini         ! dyn/tra trends initialization     (trd_init routine)
55   USE asminc         ! assimilation increments     
56   USE asmbkg         ! writing out state trajectory
57   USE diaptr         ! poleward transports           (dia_ptr_init routine)
58   USE diadct         ! sections transports           (dia_dct_init routine)
59   USE diaobs         ! Observation diagnostics       (dia_obs_init routine)
60   USE diacfl         ! CFL diagnostics               (dia_cfl_init routine)
61   USE step           ! NEMO time-stepping                 (stp     routine)
62   USE isfmlt         ! ice shelf                     (isf_mlt_init routine)
63   USE icbini         ! handle bergs, initialisation
64   USE icbstp         ! handle bergs, calving, themodynamics and transport
65   USE cpl_oasis3     ! OASIS3 coupling
66   USE c1d            ! 1D configuration
67   USE step_c1d       ! Time stepping loop for the 1D configuration
68   USE dyndmp         ! Momentum damping
69   USE stopar         ! Stochastic param.: ???
70   USE stopts         ! Stochastic param.: ???
71   USE diurnal_bulk   ! diurnal bulk SST
72   USE step_diu       ! diurnal bulk SST timestepping (called from here if run offline)
73   USE crsini         ! initialise grid coarsening utility
74   USE diatmb         ! Top,middle,bottom output
75   USE dia25h         ! 25h mean output
76   USE sbc_oce , ONLY : lk_oasis
77   USE wet_dry        ! Wetting and drying setting   (wad_init routine)
78#if defined key_top
79   USE trcini         ! passive tracer initialisation
80#endif
81#if defined key_nemocice_decomp
82   USE ice_domain_size, only: nx_global, ny_global
83#endif
84   !
85   USE lib_mpp        ! distributed memory computing
86   USE mppini         ! shared/distributed memory setting (mpp_init routine)
87   USE lbcnfd  , ONLY : isendto, nsndto, nfsloop, nfeloop   ! Setup of north fold exchanges
88   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined)
89#if defined key_iomput
90   USE xios           ! xIOserver
91#endif
92#if defined key_agrif
93   USE agrif_all_update   ! Master Agrif update
94#endif
95
96   IMPLICIT NONE
97   PRIVATE
98
99   PUBLIC   nemo_gcm    ! called by model.F90
100   PUBLIC   nemo_init   ! needed by AGRIF
101   PUBLIC   nemo_alloc  ! needed by TAM
102
103   CHARACTER(lc) ::   cform_aaa="( /, 'AAAAAAAA', / ) "     ! flag for output listing
104
105#if defined key_mpp_mpi
106   INCLUDE 'mpif.h'
107#endif
108
109   !!----------------------------------------------------------------------
110   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
111   !! $Id$
112   !! Software governed by the CeCILL license (see ./LICENSE)
113   !!----------------------------------------------------------------------
114CONTAINS
115
116   SUBROUTINE nemo_gcm
117      !!----------------------------------------------------------------------
118      !!                     ***  ROUTINE nemo_gcm  ***
119      !!
120      !! ** Purpose :   NEMO solves the primitive equations on an orthogonal
121      !!              curvilinear mesh on the sphere.
122      !!
123      !! ** Method  : - model general initialization
124      !!              - launch the time-stepping (stp routine)
125      !!              - finalize the run by closing files and communications
126      !!
127      !! References : Madec, Delecluse, Imbard, and Levy, 1997:  internal report, IPSL.
128      !!              Madec, 2008, internal report, IPSL.
129      !!----------------------------------------------------------------------
130      INTEGER ::   istp   ! time step index
131      !!----------------------------------------------------------------------
132      !
133#if defined key_agrif
134      CALL Agrif_Init_Grids()      ! AGRIF: set the meshes
135#endif
136      !                            !-----------------------!
137      CALL nemo_init               !==  Initialisations  ==!
138      !                            !-----------------------!
139#if defined key_agrif
140      CALL Agrif_Declare_Var_dom   ! AGRIF: set the meshes for DOM
141      CALL Agrif_Declare_Var       !  "      "   "   "      "  DYN/TRA
142# if defined key_top
143      CALL Agrif_Declare_Var_top   !  "      "   "   "      "  TOP
144# endif
145# if defined key_si3
146      CALL Agrif_Declare_Var_ice   !  "      "   "   "      "  Sea ice
147# endif
148#endif
149      ! check that all process are still there... If some process have an error,
150      ! they will never enter in step and other processes will wait until the end of the cpu time!
151      CALL mpp_max( 'nemogcm', nstop )
152
153      IF(lwp) WRITE(numout,cform_aaa)   ! Flag AAAAAAA
154
155      !                            !-----------------------!
156      !                            !==   time stepping   ==!
157      !                            !-----------------------!
158      istp = nit000
159      !
160#if defined key_c1d
161      DO WHILE ( istp <= nitend .AND. nstop == 0 )    !==  C1D time-stepping  ==!
162         CALL stp_c1d( istp )
163         istp = istp + 1
164      END DO
165#else
166      !
167# if defined key_agrif
168      !                                               !==  AGRIF time-stepping  ==!
169      CALL Agrif_Regrid()
170      !
171      ! Recursive update from highest nested level to lowest:
172      CALL Agrif_step_child_adj(Agrif_Update_All)
173      !
174      DO WHILE( istp <= nitend .AND. nstop == 0 )
175         CALL stp
176         istp = istp + 1
177      END DO
178      !
179      IF( .NOT. Agrif_Root() ) THEN
180         CALL Agrif_ParentGrid_To_ChildGrid()
181         IF( ln_diaobs )   CALL dia_obs_wri
182         IF( ln_timing )   CALL timing_finalize
183         CALL Agrif_ChildGrid_To_ParentGrid()
184      ENDIF
185      !
186# else
187      !
188      IF( .NOT.ln_diurnal_only ) THEN                 !==  Standard time-stepping  ==!
189         !
190         DO WHILE( istp <= nitend .AND. nstop == 0 )
191#if defined key_mpp_mpi
192            ncom_stp = istp
193            IF ( istp == ( nit000 + 1 ) ) elapsed_time = MPI_Wtime()
194            IF ( istp ==         nitend ) elapsed_time = MPI_Wtime() - elapsed_time
195#endif
196            CALL stp        ( istp ) 
197            istp = istp + 1
198         END DO
199         !
200      ELSE                                            !==  diurnal SST time-steeping only  ==!
201         !
202         DO WHILE( istp <= nitend .AND. nstop == 0 )
203            CALL stp_diurnal( istp )   ! time step only the diurnal SST
204            istp = istp + 1
205         END DO
206         !
207      ENDIF
208      !
209# endif
210      !
211#endif
212      !
213      IF( ln_diaobs   )   CALL dia_obs_wri
214      !
215      IF( ln_icebergs )   CALL icb_end( nitend )
216
217      !                            !------------------------!
218      !                            !==  finalize the run  ==!
219      !                            !------------------------!
220      IF(lwp) WRITE(numout,cform_aaa)        ! Flag AAAAAAA
221      !
222      IF( nstop /= 0 .AND. lwp ) THEN        ! error print
223         WRITE(numout,cform_err)
224         WRITE(numout,*) '   ==>>>   nemo_gcm: a total of ', nstop, ' errors have been found'
225         WRITE(numout,*)
226      ENDIF
227      !
228      IF( ln_timing )   CALL timing_finalize
229      !
230      CALL nemo_closefile
231      !
232#if defined key_iomput
233                                    CALL xios_finalize  ! end mpp communications with xios
234      IF( lk_oasis     )            CALL cpl_finalize   ! end coupling and mpp communications with OASIS
235#else
236      IF    ( lk_oasis ) THEN   ;   CALL cpl_finalize   ! end coupling and mpp communications with OASIS
237      ELSEIF( lk_mpp   ) THEN   ;   CALL mppstop( ldfinal = .TRUE. )   ! end mpp communications
238      ENDIF
239#endif
240      !
241      IF(lwm) THEN
242         IF( nstop == 0 ) THEN   ;   STOP 0
243         ELSE                    ;   STOP 999
244         ENDIF
245      ENDIF
246      !
247   END SUBROUTINE nemo_gcm
248
249
250   SUBROUTINE nemo_init
251      !!----------------------------------------------------------------------
252      !!                     ***  ROUTINE nemo_init  ***
253      !!
254      !! ** Purpose :   initialization of the NEMO GCM
255      !!----------------------------------------------------------------------
256      INTEGER  ::   ji                 ! dummy loop indices
257      INTEGER  ::   ios, ilocal_comm   ! local integers
258      CHARACTER(len=120), DIMENSION(60) ::   cltxt, cltxt2, clnam
259      !!
260      NAMELIST/namctl/ ln_ctl   , sn_cfctl, nn_print, nn_ictls, nn_ictle,   &
261         &             nn_isplt , nn_jsplt, nn_jctls, nn_jctle,             &
262         &             ln_timing, ln_diacfl
263      NAMELIST/namcfg/ ln_read_cfg, cn_domcfg, ln_closea, ln_write_cfg, cn_domcfg_out, ln_use_jattr
264      !!----------------------------------------------------------------------
265      !
266      cltxt  = ''
267      cltxt2 = ''
268      clnam  = '' 
269      cxios_context = 'nemo'
270      !
271      !                             ! Open reference namelist and configuration namelist files
272      CALL ctl_opn( numnam_ref, 'namelist_ref', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
273      CALL ctl_opn( numnam_cfg, 'namelist_cfg', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
274      !
275      REWIND( numnam_ref )              ! Namelist namctl in reference namelist
276      READ  ( numnam_ref, namctl, IOSTAT = ios, ERR = 901 )
277901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namctl in reference namelist', .TRUE. )
278      REWIND( numnam_cfg )              ! Namelist namctl in confguration namelist
279      READ  ( numnam_cfg, namctl, IOSTAT = ios, ERR = 902 )
280902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namctl in configuration namelist', .TRUE. )
281      !
282      REWIND( numnam_ref )              ! Namelist namcfg in reference namelist
283      READ  ( numnam_ref, namcfg, IOSTAT = ios, ERR = 903 )
284903   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namcfg in reference namelist', .TRUE. )
285      REWIND( numnam_cfg )              ! Namelist namcfg in confguration namelist
286      READ  ( numnam_cfg, namcfg, IOSTAT = ios, ERR = 904 )
287904   IF( ios >  0 )   CALL ctl_nam ( ios , 'namcfg in configuration namelist', .TRUE. )   
288
289      !                             !--------------------------!
290      !                             !  Set global domain size  !   (control print return in cltxt2)
291      !                             !--------------------------!
292      IF( ln_read_cfg ) THEN              ! Read sizes in domain configuration file
293         CALL domain_cfg ( cltxt2,        cn_cfg, nn_cfg, jpiglo, jpjglo, jpkglo, jperio )
294         !
295      ELSE                                ! user-defined namelist
296         CALL usr_def_nam( cltxt2, clnam, cn_cfg, nn_cfg, jpiglo, jpjglo, jpkglo, jperio )
297      ENDIF
298      !
299      !
300      !                             !--------------------------------------------!
301      !                             !  set communicator & select the local node  !
302      !                             !  NB: mynode also opens output.namelist.dyn !
303      !                             !      on unit number numond on first proc   !
304      !                             !--------------------------------------------!
305#if defined key_iomput
306      IF( Agrif_Root() ) THEN
307         IF( lk_oasis ) THEN
308            CALL cpl_init( "oceanx", ilocal_comm )                               ! nemo local communicator given by oasis
309            CALL xios_initialize( "not used"       ,local_comm= ilocal_comm )    ! send nemo communicator to xios
310         ELSE
311            CALL xios_initialize( "for_xios_mpi_id",return_comm=ilocal_comm )    ! nemo local communicator given by xios
312         ENDIF
313      ENDIF
314      ! Nodes selection (control print return in cltxt)
315      narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop, ilocal_comm )
316#else
317      IF( lk_oasis ) THEN
318         IF( Agrif_Root() ) THEN
319            CALL cpl_init( "oceanx", ilocal_comm )          ! nemo local communicator given by oasis
320         ENDIF
321         ! Nodes selection (control print return in cltxt)
322         narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop, ilocal_comm )
323      ELSE
324         ilocal_comm = 0                                    ! Nodes selection (control print return in cltxt)
325         narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop )
326      ENDIF
327#endif
328
329      narea = narea + 1                                     ! mynode return the rank of proc (0 --> jpnij -1 )
330
331      IF( sn_cfctl%l_config ) THEN
332         ! Activate finer control of report outputs
333         ! optionally switch off output from selected areas (note this only
334         ! applies to output which does not involve global communications)
335         IF( ( narea < sn_cfctl%procmin .OR. narea > sn_cfctl%procmax  ) .OR. &
336           & ( MOD( narea - sn_cfctl%procmin, sn_cfctl%procincr ) /= 0 ) )    &
337           &   CALL nemo_set_cfctl( sn_cfctl, .FALSE., .FALSE. )
338      ELSE
339         ! Use ln_ctl to turn on or off all options.
340         CALL nemo_set_cfctl( sn_cfctl, ln_ctl, .TRUE. )
341      ENDIF
342
343      lwm = (narea == 1)                                    ! control of output namelists
344      lwp = (narea == 1) .OR. ln_ctl                        ! control of all listing output print
345
346      IF(lwm) THEN               ! write merged namelists from earlier to output namelist
347         !                       ! now that the file has been opened in call to mynode.
348         !                       ! NB: nammpp has already been written in mynode (if lk_mpp_mpi)
349         WRITE( numond, namctl )
350         WRITE( numond, namcfg )
351         IF( .NOT.ln_read_cfg ) THEN
352            DO ji = 1, SIZE(clnam)
353               IF( TRIM(clnam(ji)) /= '' )   WRITE(numond, * ) clnam(ji)     ! namusr_def print
354            END DO
355         ENDIF
356      ENDIF
357
358      IF(lwp) THEN                            ! open listing units
359         !
360         CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE., narea )
361         !
362         WRITE(numout,*)
363         WRITE(numout,*) '   CNRS - NERC - Met OFFICE - MERCATOR-ocean - INGV - CMCC'
364         WRITE(numout,*) '                       NEMO team'
365         WRITE(numout,*) '            Ocean General Circulation Model'
366         WRITE(numout,*) '                NEMO version 4.0  (2019) '
367         WRITE(numout,*)
368         WRITE(numout,*) "           ._      ._      ._      ._      ._    "
369         WRITE(numout,*) "       _.-._)`\_.-._)`\_.-._)`\_.-._)`\_.-._)`\_ "
370         WRITE(numout,*)
371         WRITE(numout,*) "           o         _,           _,             "
372         WRITE(numout,*) "            o      .' (        .-' /             "
373         WRITE(numout,*) "           o     _/..._'.    .'   /              "
374         WRITE(numout,*) "      (    o .-'`      ` '-./  _.'               "
375         WRITE(numout,*) "       )    ( o)           ;= <_         (       "
376         WRITE(numout,*) "      (      '-.,\\__ __.-;`\   '.        )      "
377         WRITE(numout,*) "       )  )       \) |`\ \)  '.   \      (   (   "
378         WRITE(numout,*) "      (  (           \_/       '-._\      )   )  "
379         WRITE(numout,*) "       )  ) jgs                     `    (   (   "
380         WRITE(numout,*) "     ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^ "
381         WRITE(numout,*)
382         
383         DO ji = 1, SIZE(cltxt)
384            IF( TRIM(cltxt (ji)) /= '' )   WRITE(numout,*) TRIM(cltxt(ji))    ! control print of mynode
385         END DO
386         WRITE(numout,*)
387         WRITE(numout,*)
388         DO ji = 1, SIZE(cltxt2)
389            IF( TRIM(cltxt2(ji)) /= '' )   WRITE(numout,*) TRIM(cltxt2(ji))   ! control print of domain size
390         END DO
391         !
392         WRITE(numout,cform_aaa)                                        ! Flag AAAAAAA
393         !
394      ENDIF
395      ! open /dev/null file to be able to supress output write easily
396      CALL ctl_opn( numnul, '/dev/null', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
397      !
398      !                                      ! Domain decomposition
399      CALL mpp_init                          ! MPP
400
401      ! Now we know the dimensions of the grid and numout has been set: we can allocate arrays
402      CALL nemo_alloc()
403
404      !                             !-------------------------------!
405      !                             !  NEMO general initialization  !
406      !                             !-------------------------------!
407
408      CALL nemo_ctl                          ! Control prints
409      !
410      !                                      ! General initialization
411      IF( ln_timing    )   CALL timing_init     ! timing
412      IF( ln_timing    )   CALL timing_start( 'nemo_init')
413      !
414                           CALL     phy_cst         ! Physical constants
415                           CALL     eos_init        ! Equation of state
416      IF( lk_c1d       )   CALL     c1d_init        ! 1D column configuration
417                           CALL     wad_init        ! Wetting and drying options
418                           CALL     dom_init("OPA") ! Domain
419      IF( ln_crs       )   CALL     crs_init        ! coarsened grid: domain initialization
420      IF( ln_ctl       )   CALL prt_ctl_init        ! Print control
421     
422      CALL diurnal_sst_bulk_init                ! diurnal sst
423      IF( ln_diurnal   )   CALL diurnal_sst_coolskin_init   ! cool skin   
424      !                           
425      IF( ln_diurnal_only ) THEN                   ! diurnal only: a subset of the initialisation routines
426         CALL  istate_init                            ! ocean initial state (Dynamics and tracers)
427         CALL     sbc_init                            ! Forcings : surface module
428         CALL tra_qsr_init                            ! penetrative solar radiation qsr
429         IF( ln_diaobs ) THEN                         ! Observation & model comparison
430            CALL dia_obs_init                            ! Initialize observational data
431            CALL dia_obs( nit000 - 1 )                   ! Observation operator for restart
432         ENDIF     
433         IF( lk_asminc )   CALL asm_inc_init          ! Assimilation increments
434         !
435         RETURN                                       ! end of initialization
436      ENDIF
437     
438                           CALL  istate_init    ! ocean initial state (Dynamics and tracers)
439
440      !                                      ! external forcing
441                           CALL    tide_init    ! tidal harmonics
442                           CALL     sbc_init    ! surface boundary conditions (including sea-ice)
443                           CALL     bdy_init    ! Open boundaries initialisation
444
445      !                                      ! Ocean physics
446                           CALL zdf_phy_init    ! Vertical physics
447                                     
448      !                                         ! Lateral physics
449                           CALL ldf_tra_init      ! Lateral ocean tracer physics
450                           CALL ldf_eiv_init      ! eddy induced velocity param.
451                           CALL ldf_dyn_init      ! Lateral ocean momentum physics
452
453      !                                      ! Active tracers
454      IF( ln_traqsr    )   CALL tra_qsr_init      ! penetrative solar radiation qsr
455      IF (ln_isf       )   CALL isf_mlt_init      ! ice shelf
456                           CALL tra_bbc_init      ! bottom heat flux
457                           CALL tra_bbl_init      ! advective (and/or diffusive) bottom boundary layer scheme
458                           CALL tra_dmp_init      ! internal tracer damping
459                           CALL tra_adv_init      ! horizontal & vertical advection
460                           CALL tra_ldf_init      ! lateral mixing
461
462      !                                      ! Dynamics
463      IF( lk_c1d       )   CALL dyn_dmp_init      ! internal momentum damping
464                           CALL dyn_adv_init      ! advection (vector or flux form)
465                           CALL dyn_vor_init      ! vorticity term including Coriolis
466                           CALL dyn_ldf_init      ! lateral mixing
467                           CALL dyn_hpg_init      ! horizontal gradient of Hydrostatic pressure
468                           CALL dyn_spg_init      ! surface pressure gradient
469
470#if defined key_top
471      !                                      ! Passive tracers
472                           CALL     trc_init
473#endif
474      IF( l_ldfslp     )   CALL ldf_slp_init    ! slope of lateral mixing
475
476      !                                      ! Icebergs
477                           CALL icb_init( rdt, nit000)   ! initialise icebergs instance
478
479      !                                      ! Misc. options
480                           CALL sto_par_init    ! Stochastic parametrization
481      IF( ln_sto_eos   )   CALL sto_pts_init    ! RRandom T/S fluctuations
482     
483      !                                      ! Diagnostics
484      IF( lk_floats    )   CALL     flo_init    ! drifting Floats
485      IF( ln_diacfl    )   CALL dia_cfl_init    ! Initialise CFL diagnostics
486                           CALL dia_ptr_init    ! Poleward TRansports initialization
487      IF( lk_diadct    )   CALL dia_dct_init    ! Sections tranports
488                           CALL dia_hsb_init    ! heat content, salt content and volume budgets
489                           CALL     trd_init    ! Mixed-layer/Vorticity/Integral constraints trends
490                           CALL dia_obs_init    ! Initialize observational data
491                           CALL dia_tmb_init    ! TMB outputs
492                           CALL dia_25h_init    ! 25h mean  outputs
493      IF( ln_diaobs    )   CALL dia_obs( nit000-1 )   ! Observation operator for restart
494
495      !                                      ! Assimilation increments
496      IF( lk_asminc    )   CALL asm_inc_init    ! Initialize assimilation increments
497      !
498      IF(lwp) WRITE(numout,cform_aaa)           ! Flag AAAAAAA
499      !
500      IF( ln_timing    )   CALL timing_stop( 'nemo_init')
501      !
502   END SUBROUTINE nemo_init
503
504
505   SUBROUTINE nemo_ctl
506      !!----------------------------------------------------------------------
507      !!                     ***  ROUTINE nemo_ctl  ***
508      !!
509      !! ** Purpose :   control print setting
510      !!
511      !! ** Method  : - print namctl information and check some consistencies
512      !!----------------------------------------------------------------------
513      !
514      IF(lwp) THEN                  ! control print
515         WRITE(numout,*)
516         WRITE(numout,*) 'nemo_ctl: Control prints'
517         WRITE(numout,*) '~~~~~~~~'
518         WRITE(numout,*) '   Namelist namctl'
519         WRITE(numout,*) '      run control (for debugging)     ln_ctl     = ', ln_ctl
520         WRITE(numout,*) '       finer control over o/p sn_cfctl%l_config  = ', sn_cfctl%l_config
521         WRITE(numout,*) '                              sn_cfctl%l_runstat = ', sn_cfctl%l_runstat
522         WRITE(numout,*) '                              sn_cfctl%l_trcstat = ', sn_cfctl%l_trcstat
523         WRITE(numout,*) '                              sn_cfctl%l_oceout  = ', sn_cfctl%l_oceout
524         WRITE(numout,*) '                              sn_cfctl%l_layout  = ', sn_cfctl%l_layout
525         WRITE(numout,*) '                              sn_cfctl%l_mppout  = ', sn_cfctl%l_mppout
526         WRITE(numout,*) '                              sn_cfctl%l_mpptop  = ', sn_cfctl%l_mpptop
527         WRITE(numout,*) '                              sn_cfctl%procmin   = ', sn_cfctl%procmin 
528         WRITE(numout,*) '                              sn_cfctl%procmax   = ', sn_cfctl%procmax 
529         WRITE(numout,*) '                              sn_cfctl%procincr  = ', sn_cfctl%procincr 
530         WRITE(numout,*) '                              sn_cfctl%ptimincr  = ', sn_cfctl%ptimincr 
531         WRITE(numout,*) '      level of print                  nn_print   = ', nn_print
532         WRITE(numout,*) '      Start i indice for SUM control  nn_ictls   = ', nn_ictls
533         WRITE(numout,*) '      End i indice for SUM control    nn_ictle   = ', nn_ictle
534         WRITE(numout,*) '      Start j indice for SUM control  nn_jctls   = ', nn_jctls
535         WRITE(numout,*) '      End j indice for SUM control    nn_jctle   = ', nn_jctle
536         WRITE(numout,*) '      number of proc. following i     nn_isplt   = ', nn_isplt
537         WRITE(numout,*) '      number of proc. following j     nn_jsplt   = ', nn_jsplt
538         WRITE(numout,*) '      timing by routine               ln_timing  = ', ln_timing
539         WRITE(numout,*) '      CFL diagnostics                 ln_diacfl  = ', ln_diacfl
540      ENDIF
541      !
542      nprint    = nn_print          ! convert DOCTOR namelist names into OLD names
543      nictls    = nn_ictls
544      nictle    = nn_ictle
545      njctls    = nn_jctls
546      njctle    = nn_jctle
547      isplt     = nn_isplt
548      jsplt     = nn_jsplt
549
550      IF(lwp) THEN                  ! control print
551         WRITE(numout,*)
552         WRITE(numout,*) '   Namelist namcfg'
553         WRITE(numout,*) '      read domain configuration file                ln_read_cfg      = ', ln_read_cfg
554         WRITE(numout,*) '         filename to be read                           cn_domcfg     = ', TRIM(cn_domcfg)
555         WRITE(numout,*) '         keep closed seas in the domain (if exist)     ln_closea     = ', ln_closea
556         WRITE(numout,*) '      create a configuration definition file        ln_write_cfg     = ', ln_write_cfg
557         WRITE(numout,*) '         filename to be written                        cn_domcfg_out = ', TRIM(cn_domcfg_out)
558         WRITE(numout,*) '      use file attribute if exists as i/p j-start   ln_use_jattr     = ', ln_use_jattr
559      ENDIF
560      IF( .NOT.ln_read_cfg )   ln_closea = .false.   ! dealing possible only with a domcfg file
561      !
562      !                             ! Parameter control
563      !
564      IF( ln_ctl ) THEN                 ! sub-domain area indices for the control prints
565         IF( lk_mpp .AND. jpnij > 1 ) THEN
566            isplt = jpni   ;   jsplt = jpnj   ;   ijsplt = jpni*jpnj   ! the domain is forced to the real split domain
567         ELSE
568            IF( isplt == 1 .AND. jsplt == 1  ) THEN
569               CALL ctl_warn( ' - isplt & jsplt are equal to 1',   &
570                  &           ' - the print control will be done over the whole domain' )
571            ENDIF
572            ijsplt = isplt * jsplt            ! total number of processors ijsplt
573         ENDIF
574         IF(lwp) WRITE(numout,*)'          - The total number of processors over which the'
575         IF(lwp) WRITE(numout,*)'            print control will be done is ijsplt : ', ijsplt
576         !
577         !                              ! indices used for the SUM control
578         IF( nictls+nictle+njctls+njctle == 0 )   THEN    ! print control done over the default area
579            lsp_area = .FALSE.
580         ELSE                                             ! print control done over a specific  area
581            lsp_area = .TRUE.
582            IF( nictls < 1 .OR. nictls > jpiglo )   THEN
583               CALL ctl_warn( '          - nictls must be 1<=nictls>=jpiglo, it is forced to 1' )
584               nictls = 1
585            ENDIF
586            IF( nictle < 1 .OR. nictle > jpiglo )   THEN
587               CALL ctl_warn( '          - nictle must be 1<=nictle>=jpiglo, it is forced to jpiglo' )
588               nictle = jpiglo
589            ENDIF
590            IF( njctls < 1 .OR. njctls > jpjglo )   THEN
591               CALL ctl_warn( '          - njctls must be 1<=njctls>=jpjglo, it is forced to 1' )
592               njctls = 1
593            ENDIF
594            IF( njctle < 1 .OR. njctle > jpjglo )   THEN
595               CALL ctl_warn( '          - njctle must be 1<=njctle>=jpjglo, it is forced to jpjglo' )
596               njctle = jpjglo
597            ENDIF
598         ENDIF
599      ENDIF
600      !
601      IF( 1._wp /= SIGN(1._wp,-0._wp)  )   CALL ctl_stop( 'nemo_ctl: The intrinsec SIGN function follows f2003 standard.',  &
602         &                                                'Compile with key_nosignedzero enabled:',   &
603         &                                                '--> add -Dkey_nosignedzero to the definition of %CPP in your arch file' )
604      !
605#if defined key_agrif
606      IF( ln_timing )   CALL ctl_stop( 'AGRIF not implemented with ln_timing = true')
607#endif
608      !
609   END SUBROUTINE nemo_ctl
610
611
612   SUBROUTINE nemo_closefile
613      !!----------------------------------------------------------------------
614      !!                     ***  ROUTINE nemo_closefile  ***
615      !!
616      !! ** Purpose :   Close the files
617      !!----------------------------------------------------------------------
618      !
619      IF( lk_mpp )   CALL mppsync
620      !
621      CALL iom_close                                 ! close all input/output files managed by iom_*
622      !
623      IF( numstp          /= -1 )   CLOSE( numstp          )   ! time-step file
624      IF( numrun          /= -1 )   CLOSE( numrun          )   ! run statistics file
625      IF( numnam_ref      /= -1 )   CLOSE( numnam_ref      )   ! oce reference namelist
626      IF( numnam_cfg      /= -1 )   CLOSE( numnam_cfg      )   ! oce configuration namelist
627      IF( lwm.AND.numond  /= -1 )   CLOSE( numond          )   ! oce output namelist
628      IF( numnam_ice_ref  /= -1 )   CLOSE( numnam_ice_ref  )   ! ice reference namelist
629      IF( numnam_ice_cfg  /= -1 )   CLOSE( numnam_ice_cfg  )   ! ice configuration namelist
630      IF( lwm.AND.numoni  /= -1 )   CLOSE( numoni          )   ! ice output namelist
631      IF( numevo_ice      /= -1 )   CLOSE( numevo_ice      )   ! ice variables (temp. evolution)
632      IF( numout          /=  6 )   CLOSE( numout          )   ! standard model output file
633      IF( numdct_vol      /= -1 )   CLOSE( numdct_vol      )   ! volume transports
634      IF( numdct_heat     /= -1 )   CLOSE( numdct_heat     )   ! heat transports
635      IF( numdct_salt     /= -1 )   CLOSE( numdct_salt     )   ! salt transports
636      !
637      numout = 6                                     ! redefine numout in case it is used after this point...
638      !
639   END SUBROUTINE nemo_closefile
640
641
642   SUBROUTINE nemo_alloc
643      !!----------------------------------------------------------------------
644      !!                     ***  ROUTINE nemo_alloc  ***
645      !!
646      !! ** Purpose :   Allocate all the dynamic arrays of the OPA modules
647      !!
648      !! ** Method  :
649      !!----------------------------------------------------------------------
650      USE diawri    , ONLY : dia_wri_alloc
651      USE dom_oce   , ONLY : dom_oce_alloc
652      USE trc_oce   , ONLY : trc_oce_alloc
653      USE bdy_oce   , ONLY : bdy_oce_alloc
654#if defined key_diadct 
655      USE diadct    , ONLY : diadct_alloc 
656#endif 
657      !
658      INTEGER :: ierr
659      !!----------------------------------------------------------------------
660      !
661      ierr =        oce_alloc    ()    ! ocean
662      ierr = ierr + dia_wri_alloc()
663      ierr = ierr + dom_oce_alloc()    ! ocean domain
664      ierr = ierr + zdf_oce_alloc()    ! ocean vertical physics
665      ierr = ierr + trc_oce_alloc()    ! shared TRC / TRA arrays
666      ierr = ierr + bdy_oce_alloc()    ! bdy masks (incl. initialization)
667      !
668#if defined key_diadct 
669      ierr = ierr + diadct_alloc ()    !
670#endif 
671      !
672      CALL mpp_sum( 'nemogcm', ierr )
673      IF( ierr /= 0 )   CALL ctl_stop( 'STOP', 'nemo_alloc: unable to allocate standard ocean arrays' )
674      !
675   END SUBROUTINE nemo_alloc
676
677   SUBROUTINE nemo_set_cfctl(sn_cfctl, setto, for_all )
678      !!----------------------------------------------------------------------
679      !!                     ***  ROUTINE nemo_set_cfctl  ***
680      !!
681      !! ** Purpose :   Set elements of the output control structure to setto.
682      !!                for_all should be .false. unless all areas are to be
683      !!                treated identically.
684      !!
685      !! ** Method  :   Note this routine can be used to switch on/off some
686      !!                types of output for selected areas but any output types
687      !!                that involve global communications (e.g. mpp_max, glob_sum)
688      !!                should be protected from selective switching by the
689      !!                for_all argument
690      !!----------------------------------------------------------------------
691      LOGICAL :: setto, for_all
692      TYPE(sn_ctl) :: sn_cfctl
693      !!----------------------------------------------------------------------
694      IF( for_all ) THEN
695         sn_cfctl%l_runstat = setto
696         sn_cfctl%l_trcstat = setto
697      ENDIF
698      sn_cfctl%l_oceout  = setto
699      sn_cfctl%l_layout  = setto
700      sn_cfctl%l_mppout  = setto
701      sn_cfctl%l_mpptop  = setto
702   END SUBROUTINE nemo_set_cfctl
703
704   !!======================================================================
705END MODULE nemogcm
706
Note: See TracBrowser for help on using the repository browser.