New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
zdftke.F90 in NEMO/branches/2019/dev_r10721_KERNEL-02_Storkey_Coward_IMMERSE_first_steps/src/OCE/ZDF – NEMO

source: NEMO/branches/2019/dev_r10721_KERNEL-02_Storkey_Coward_IMMERSE_first_steps/src/OCE/ZDF/zdftke.F90 @ 10883

Last change on this file since 10883 was 10883, checked in by davestorkey, 3 years ago

branches/2019/dev_r10721_KERNEL-02_Storkey_Coward_IMMERSE_first_steps: some of the ocean physics modules.

  • Property svn:keywords set to Id
File size: 43.7 KB
Line 
1MODULE zdftke
2   !!======================================================================
3   !!                       ***  MODULE  zdftke  ***
4   !! Ocean physics:  vertical mixing coefficient computed from the tke
5   !!                 turbulent closure parameterization
6   !!=====================================================================
7   !! History :  OPA  !  1991-03  (b. blanke)  Original code
8   !!            7.0  !  1991-11  (G. Madec)   bug fix
9   !!            7.1  !  1992-10  (G. Madec)   new mixing length and eav
10   !!            7.2  !  1993-03  (M. Guyon)   symetrical conditions
11   !!            7.3  !  1994-08  (G. Madec, M. Imbard)  nn_pdl flag
12   !!            7.5  !  1996-01  (G. Madec)   s-coordinates
13   !!            8.0  !  1997-07  (G. Madec)   lbc
14   !!            8.1  !  1999-01  (E. Stretta) new option for the mixing length
15   !!  NEMO      1.0  !  2002-06  (G. Madec) add tke_init routine
16   !!             -   !  2004-10  (C. Ethe )  1D configuration
17   !!            2.0  !  2006-07  (S. Masson)  distributed restart using iom
18   !!            3.0  !  2008-05  (C. Ethe,  G.Madec) : update TKE physics:
19   !!                 !           - tke penetration (wind steering)
20   !!                 !           - suface condition for tke & mixing length
21   !!                 !           - Langmuir cells
22   !!             -   !  2008-05  (J.-M. Molines, G. Madec)  2D form of avtb
23   !!             -   !  2008-06  (G. Madec)  style + DOCTOR name for namelist parameters
24   !!             -   !  2008-12  (G. Reffray) stable discretization of the production term
25   !!            3.2  !  2009-06  (G. Madec, S. Masson) TKE restart compatible with key_cpl
26   !!                 !                                + cleaning of the parameters + bugs correction
27   !!            3.3  !  2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase
28   !!            3.6  !  2014-11  (P. Mathiot) add ice shelf capability
29   !!            4.0  !  2017-04  (G. Madec)  remove CPP ddm key & avm at t-point only
30   !!             -   !  2017-05  (G. Madec)  add top/bottom friction as boundary condition (ln_drg)
31   !!----------------------------------------------------------------------
32
33   !!----------------------------------------------------------------------
34   !!   zdf_tke       : update momentum and tracer Kz from a tke scheme
35   !!   tke_tke       : tke time stepping: update tke at now time step (en)
36   !!   tke_avn       : compute mixing length scale and deduce avm and avt
37   !!   zdf_tke_init  : initialization, namelist read, and parameters control
38   !!   tke_rst       : read/write tke restart in ocean restart file
39   !!----------------------------------------------------------------------
40   USE oce            ! ocean: dynamics and active tracers variables
41   USE phycst         ! physical constants
42   USE dom_oce        ! domain: ocean
43   USE domvvl         ! domain: variable volume layer
44   USE sbc_oce        ! surface boundary condition: ocean
45   USE zdfdrg         ! vertical physics: top/bottom drag coef.
46   USE zdfmxl         ! vertical physics: mixed layer
47   !
48   USE in_out_manager ! I/O manager
49   USE iom            ! I/O manager library
50   USE lib_mpp        ! MPP library
51   USE lbclnk         ! ocean lateral boundary conditions (or mpp link)
52   USE prtctl         ! Print control
53   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
54
55   IMPLICIT NONE
56   PRIVATE
57
58   PUBLIC   zdf_tke        ! routine called in step module
59   PUBLIC   zdf_tke_init   ! routine called in opa module
60   PUBLIC   tke_rst        ! routine called in step module
61
62   !                      !!** Namelist  namzdf_tke  **
63   LOGICAL  ::   ln_mxl0   ! mixing length scale surface value as function of wind stress or not
64   INTEGER  ::   nn_mxl    ! type of mixing length (=0/1/2/3)
65   REAL(wp) ::   rn_mxl0   ! surface  min value of mixing length (kappa*z_o=0.4*0.1 m)  [m]
66   INTEGER  ::   nn_pdl    ! Prandtl number or not (ratio avt/avm) (=0/1)
67   REAL(wp) ::   rn_ediff  ! coefficient for avt: avt=rn_ediff*mxl*sqrt(e)
68   REAL(wp) ::   rn_ediss  ! coefficient of the Kolmogoroff dissipation
69   REAL(wp) ::   rn_ebb    ! coefficient of the surface input of tke
70   REAL(wp) ::   rn_emin   ! minimum value of tke           [m2/s2]
71   REAL(wp) ::   rn_emin0  ! surface minimum value of tke   [m2/s2]
72   REAL(wp) ::   rn_bshear ! background shear (>0) currently a numerical threshold (do not change it)
73   LOGICAL  ::   ln_drg    ! top/bottom friction forcing flag
74   INTEGER  ::   nn_etau   ! type of depth penetration of surface tke (=0/1/2/3)
75   INTEGER  ::      nn_htau   ! type of tke profile of penetration (=0/1)
76   REAL(wp) ::      rn_efr    ! fraction of TKE surface value which penetrates in the ocean
77   REAL(wp) ::      rn_eice   ! =0 ON below sea-ice, =4 OFF when ice fraction > 1/4   
78   LOGICAL  ::   ln_lc     ! Langmuir cells (LC) as a source term of TKE or not
79   REAL(wp) ::      rn_lc     ! coef to compute vertical velocity of Langmuir cells
80
81   REAL(wp) ::   ri_cri    ! critic Richardson number (deduced from rn_ediff and rn_ediss values)
82   REAL(wp) ::   rmxl_min  ! minimum mixing length value (deduced from rn_ediff and rn_emin values)  [m]
83   REAL(wp) ::   rhftau_add = 1.e-3_wp     ! add offset   applied to HF part of taum  (nn_etau=3)
84   REAL(wp) ::   rhftau_scl = 1.0_wp       ! scale factor applied to HF part of taum  (nn_etau=3)
85
86   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   htau    ! depth of tke penetration (nn_htau)
87   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   dissl   ! now mixing lenght of dissipation
88   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   apdlr   ! now mixing lenght of dissipation
89
90   !! * Substitutions
91#  include "vectopt_loop_substitute.h90"
92   !!----------------------------------------------------------------------
93   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
94   !! $Id$
95   !! Software governed by the CeCILL license (see ./LICENSE)
96   !!----------------------------------------------------------------------
97CONTAINS
98
99   INTEGER FUNCTION zdf_tke_alloc()
100      !!----------------------------------------------------------------------
101      !!                ***  FUNCTION zdf_tke_alloc  ***
102      !!----------------------------------------------------------------------
103      ALLOCATE( htau(jpi,jpj) , dissl(jpi,jpj,jpk) , apdlr(jpi,jpj,jpk) ,   STAT= zdf_tke_alloc )
104      !
105      CALL mpp_sum ( 'zdftke', zdf_tke_alloc )
106      IF( zdf_tke_alloc /= 0 )   CALL ctl_stop( 'STOP', 'zdf_tke_alloc: failed to allocate arrays' )
107      !
108   END FUNCTION zdf_tke_alloc
109
110
111   SUBROUTINE zdf_tke( kt, Kbb, Kmm, p_sh2, p_avm, p_avt )
112      !!----------------------------------------------------------------------
113      !!                   ***  ROUTINE zdf_tke  ***
114      !!
115      !! ** Purpose :   Compute the vertical eddy viscosity and diffusivity
116      !!              coefficients using a turbulent closure scheme (TKE).
117      !!
118      !! ** Method  :   The time evolution of the turbulent kinetic energy (tke)
119      !!              is computed from a prognostic equation :
120      !!         d(en)/dt = avm (d(u)/dz)**2             ! shear production
121      !!                  + d( avm d(en)/dz )/dz         ! diffusion of tke
122      !!                  + avt N^2                      ! stratif. destruc.
123      !!                  - rn_ediss / emxl en**(2/3)    ! Kolmogoroff dissipation
124      !!      with the boundary conditions:
125      !!         surface: en = max( rn_emin0, rn_ebb * taum )
126      !!         bottom : en = rn_emin
127      !!      The associated critical Richardson number is: ri_cri = 2/(2+rn_ediss/rn_ediff)
128      !!
129      !!        The now Turbulent kinetic energy is computed using the following
130      !!      time stepping: implicit for vertical diffusion term, linearized semi
131      !!      implicit for kolmogoroff dissipation term, and explicit forward for
132      !!      both buoyancy and shear production terms. Therefore a tridiagonal
133      !!      linear system is solved. Note that buoyancy and shear terms are
134      !!      discretized in a energy conserving form (Bruchard 2002).
135      !!
136      !!        The dissipative and mixing length scale are computed from en and
137      !!      the stratification (see tke_avn)
138      !!
139      !!        The now vertical eddy vicosity and diffusivity coefficients are
140      !!      given by:
141      !!              avm = max( avtb, rn_ediff * zmxlm * en^1/2 )
142      !!              avt = max( avmb, pdl * avm                 ) 
143      !!              eav = max( avmb, avm )
144      !!      where pdl, the inverse of the Prandtl number is 1 if nn_pdl=0 and
145      !!      given by an empirical funtion of the localRichardson number if nn_pdl=1
146      !!
147      !! ** Action  :   compute en (now turbulent kinetic energy)
148      !!                update avt, avm (before vertical eddy coef.)
149      !!
150      !! References : Gaspar et al., JGR, 1990,
151      !!              Blanke and Delecluse, JPO, 1991
152      !!              Mellor and Blumberg, JPO 2004
153      !!              Axell, JGR, 2002
154      !!              Bruchard OM 2002
155      !!----------------------------------------------------------------------
156      INTEGER                   , INTENT(in   ) ::   kt             ! ocean time step
157      INTEGER                   , INTENT(in   ) ::   Kbb, Kmm       ! ocean time level indices
158      REAL(wp), DIMENSION(:,:,:), INTENT(in   ) ::   p_sh2          ! shear production term
159      REAL(wp), DIMENSION(:,:,:), INTENT(inout) ::   p_avm, p_avt   !  momentum and tracer Kz (w-points)
160      !!----------------------------------------------------------------------
161      !
162      CALL tke_tke( Kbb, Kmm, p_sh2, p_avm, p_avt )   ! now tke (en)
163      !
164      CALL tke_avn( Kbb, Kmm,        p_avm, p_avt )   ! now avt, avm, dissl
165      !
166  END SUBROUTINE zdf_tke
167
168
169   SUBROUTINE tke_tke( Kbb, Kmm, p_sh2, p_avm, p_avt )
170      !!----------------------------------------------------------------------
171      !!                   ***  ROUTINE tke_tke  ***
172      !!
173      !! ** Purpose :   Compute the now Turbulente Kinetic Energy (TKE)
174      !!
175      !! ** Method  : - TKE surface boundary condition
176      !!              - source term due to Langmuir cells (Axell JGR 2002) (ln_lc=T)
177      !!              - source term due to shear (= Kz dz[Ub] * dz[Un] )
178      !!              - Now TKE : resolution of the TKE equation by inverting
179      !!                a tridiagonal linear system by a "methode de chasse"
180      !!              - increase TKE due to surface and internal wave breaking
181      !!             NB: when sea-ice is present, both LC parameterization
182      !!                 and TKE penetration are turned off when the ice fraction
183      !!                 is smaller than 0.25
184      !!
185      !! ** Action  : - en : now turbulent kinetic energy)
186      !! ---------------------------------------------------------------------
187      USE zdf_oce , ONLY : en   ! ocean vertical physics
188      !!
189      INTEGER                    , INTENT(in   ) ::   Kbb, Kmm       ! ocean time level indices
190      REAL(wp), DIMENSION(:,:,:) , INTENT(in   ) ::   p_sh2          ! shear production term
191      REAL(wp), DIMENSION(:,:,:) , INTENT(in   ) ::   p_avm, p_avt   ! vertical eddy viscosity & diffusivity (w-points)
192      !
193      INTEGER ::   ji, jj, jk              ! dummy loop arguments
194      REAL(wp) ::   zetop, zebot, zmsku, zmskv ! local scalars
195      REAL(wp) ::   zrhoa  = 1.22              ! Air density kg/m3
196      REAL(wp) ::   zcdrag = 1.5e-3            ! drag coefficient
197      REAL(wp) ::   zbbrau, zri                ! local scalars
198      REAL(wp) ::   zfact1, zfact2, zfact3     !   -         -
199      REAL(wp) ::   ztx2  , zty2  , zcof       !   -         -
200      REAL(wp) ::   ztau  , zdif               !   -         -
201      REAL(wp) ::   zus   , zwlc  , zind       !   -         -
202      REAL(wp) ::   zzd_up, zzd_lw             !   -         -
203      INTEGER , DIMENSION(jpi,jpj)     ::   imlc
204      REAL(wp), DIMENSION(jpi,jpj)     ::   zhlc, zfr_i
205      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zpelc, zdiag, zd_up, zd_lw
206      !!--------------------------------------------------------------------
207      !
208      zbbrau = rn_ebb / rau0       ! Local constant initialisation
209      zfact1 = -.5_wp * rdt 
210      zfact2 = 1.5_wp * rdt * rn_ediss
211      zfact3 = 0.5_wp       * rn_ediss
212      !
213      !                     !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
214      !                     !  Surface/top/bottom boundary condition on tke
215      !                     !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
216     
217      DO jj = 2, jpjm1            ! en(1)   = rn_ebb taum / rau0  (min value rn_emin0)
218         DO ji = fs_2, fs_jpim1   ! vector opt.
219            en(ji,jj,1) = MAX( rn_emin0, zbbrau * taum(ji,jj) ) * tmask(ji,jj,1)
220         END DO
221      END DO
222      IF ( ln_isfcav ) THEN
223         DO jj = 2, jpjm1            ! en(mikt(ji,jj))   = rn_emin
224            DO ji = fs_2, fs_jpim1   ! vector opt.
225               en(ji,jj,mikt(ji,jj)) = rn_emin * tmask(ji,jj,1)
226            END DO
227         END DO
228      ENDIF
229      !
230      !                     !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
231      !                     !  Bottom boundary condition on tke
232      !                     !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
233      !
234      !   en(bot)   = (ebb0/rau0)*0.5*sqrt(u_botfr^2+v_botfr^2) (min value rn_emin)
235      ! where ebb0 does not includes surface wave enhancement (i.e. ebb0=3.75)
236      ! Note that stress averaged is done using an wet-only calculation of u and v at t-point like in zdfsh2
237      !
238      IF( ln_drg ) THEN       !== friction used as top/bottom boundary condition on TKE
239         !
240         DO jj = 2, jpjm1           ! bottom friction
241            DO ji = fs_2, fs_jpim1     ! vector opt.
242               zmsku = ( 2. - umask(ji-1,jj,mbkt(ji,jj)) * umask(ji,jj,mbkt(ji,jj)) )
243               zmskv = ( 2. - vmask(ji,jj-1,mbkt(ji,jj)) * vmask(ji,jj,mbkt(ji,jj)) )
244               !                       ! where 0.001875 = (rn_ebb0/rau0) * 0.5 = 3.75*0.5/1000. (CAUTION CdU<0)
245               zebot = - 0.001875_wp * rCdU_bot(ji,jj) * SQRT(  ( zmsku*( uu(ji,jj,mbkt(ji,jj),Kbb)+uu(ji-1,jj,mbkt(ji,jj),Kbb) ) )**2  &
246                  &                                           + ( zmskv*( vv(ji,jj,mbkt(ji,jj),Kbb)+vv(ji,jj-1,mbkt(ji,jj),Kbb) ) )**2  )
247               en(ji,jj,mbkt(ji,jj)+1) = MAX( zebot, rn_emin ) * ssmask(ji,jj)
248            END DO
249         END DO
250         IF( ln_isfcav ) THEN       ! top friction
251            DO jj = 2, jpjm1
252               DO ji = fs_2, fs_jpim1   ! vector opt.
253                  zmsku = ( 2. - umask(ji-1,jj,mikt(ji,jj)) * umask(ji,jj,mikt(ji,jj)) )
254                  zmskv = ( 2. - vmask(ji,jj-1,mikt(ji,jj)) * vmask(ji,jj,mikt(ji,jj)) )
255                  !                             ! where 0.001875 = (rn_ebb0/rau0) * 0.5 = 3.75*0.5/1000.  (CAUTION CdU<0)
256                  zetop = - 0.001875_wp * rCdU_top(ji,jj) * SQRT(  ( zmsku*( uu(ji,jj,mikt(ji,jj),Kbb)+uu(ji-1,jj,mikt(ji,jj),Kbb) ) )**2  &
257                     &                                           + ( zmskv*( vv(ji,jj,mikt(ji,jj),Kbb)+vv(ji,jj-1,mikt(ji,jj),Kbb) ) )**2  )
258                  en(ji,jj,mikt(ji,jj)) = MAX( zetop, rn_emin ) * (1._wp - tmask(ji,jj,1))   ! masked at ocean surface
259               END DO
260            END DO
261         ENDIF
262         !
263      ENDIF
264      !
265      !                     !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
266      IF( ln_lc ) THEN      !  Langmuir circulation source term added to tke   !   (Axell JGR 2002)
267         !                  !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
268         !
269         !                        !* total energy produce by LC : cumulative sum over jk
270         zpelc(:,:,1) =  MAX( rn2b(:,:,1), 0._wp ) * gdepw(:,:,1,Kmm) * e3w(:,:,1,Kmm)
271         DO jk = 2, jpk
272            zpelc(:,:,jk)  = zpelc(:,:,jk-1) + MAX( rn2b(:,:,jk), 0._wp ) * gdepw(:,:,jk,Kmm) * e3w(:,:,jk,Kmm)
273         END DO
274         !                        !* finite Langmuir Circulation depth
275         zcof = 0.5 * 0.016 * 0.016 / ( zrhoa * zcdrag )
276         imlc(:,:) = mbkt(:,:) + 1       ! Initialization to the number of w ocean point (=2 over land)
277         DO jk = jpkm1, 2, -1
278            DO jj = 1, jpj               ! Last w-level at which zpelc>=0.5*us*us
279               DO ji = 1, jpi            !      with us=0.016*wind(starting from jpk-1)
280                  zus  = zcof * taum(ji,jj)
281                  IF( zpelc(ji,jj,jk) > zus )   imlc(ji,jj) = jk
282               END DO
283            END DO
284         END DO
285         !                               ! finite LC depth
286         DO jj = 1, jpj 
287            DO ji = 1, jpi
288               zhlc(ji,jj) = gdepw(ji,jj,imlc(ji,jj),Kmm)
289            END DO
290         END DO
291         zcof = 0.016 / SQRT( zrhoa * zcdrag )
292         DO jj = 2, jpjm1
293            DO ji = fs_2, fs_jpim1   ! vector opt.
294               zus  = zcof * SQRT( taum(ji,jj) )           ! Stokes drift
295               zfr_i(ji,jj) = ( 1._wp - 4._wp * fr_i(ji,jj) ) * zus * zus * zus * tmask(ji,jj,1) ! zus > 0. ok
296               IF (zfr_i(ji,jj) < 0. ) zfr_i(ji,jj) = 0.
297            END DO
298         END DO         
299         DO jk = 2, jpkm1         !* TKE Langmuir circulation source term added to en
300            DO jj = 2, jpjm1
301               DO ji = fs_2, fs_jpim1   ! vector opt.
302                  IF ( zfr_i(ji,jj) /= 0. ) THEN               
303                     ! vertical velocity due to LC   
304                     IF ( gdepw(ji,jj,jk,Kmm) - zhlc(ji,jj) < 0 .AND. wmask(ji,jj,jk) /= 0. ) THEN
305                        !                                           ! vertical velocity due to LC
306                        zwlc = rn_lc * SIN( rpi * gdepw(ji,jj,jk,Kmm) / zhlc(ji,jj) )   ! warning: optimization: zus^3 is in zfr_i
307                        !                                           ! TKE Langmuir circulation source term
308                        en(ji,jj,jk) = en(ji,jj,jk) + rdt * zfr_i(ji,jj) * ( zwlc * zwlc * zwlc ) / zhlc(ji,jj)
309                     ENDIF
310                  ENDIF
311               END DO
312            END DO
313         END DO
314         !
315      ENDIF
316      !
317      !                     !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
318      !                     !  Now Turbulent kinetic energy (output in en)
319      !                     !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
320      !                     ! Resolution of a tridiagonal linear system by a "methode de chasse"
321      !                     ! computation from level 2 to jpkm1  (e(1) already computed and e(jpk)=0 ).
322      !                     ! zdiag : diagonal zd_up : upper diagonal zd_lw : lower diagonal
323      !
324      IF( nn_pdl == 1 ) THEN      !* Prandtl number = F( Ri )
325         DO jk = 2, jpkm1
326            DO jj = 2, jpjm1
327               DO ji = 2, jpim1
328                  !                             ! local Richardson number
329                  zri = MAX( rn2b(ji,jj,jk), 0._wp ) * p_avm(ji,jj,jk) / ( p_sh2(ji,jj,jk) + rn_bshear )
330                  !                             ! inverse of Prandtl number
331                  apdlr(ji,jj,jk) = MAX(  0.1_wp,  ri_cri / MAX( ri_cri , zri )  )
332               END DO
333            END DO
334         END DO
335      ENDIF
336      !         
337      DO jk = 2, jpkm1           !* Matrix and right hand side in en
338         DO jj = 2, jpjm1
339            DO ji = fs_2, fs_jpim1   ! vector opt.
340               zcof   = zfact1 * tmask(ji,jj,jk)
341               !                                   ! A minimum of 2.e-5 m2/s is imposed on TKE vertical
342               !                                   ! eddy coefficient (ensure numerical stability)
343               zzd_up = zcof * MAX(  p_avm(ji,jj,jk+1) + p_avm(ji,jj,jk  ) , 2.e-5_wp  )   &  ! upper diagonal
344                  &          /    (  e3t(ji,jj,jk  ,Kmm) * e3w(ji,jj,jk  ,Kmm)  )
345               zzd_lw = zcof * MAX(  p_avm(ji,jj,jk  ) + p_avm(ji,jj,jk-1) , 2.e-5_wp  )   &  ! lower diagonal
346                  &          /    (  e3t(ji,jj,jk-1,Kmm) * e3w(ji,jj,jk  ,Kmm)  )
347               !
348               zd_up(ji,jj,jk) = zzd_up            ! Matrix (zdiag, zd_up, zd_lw)
349               zd_lw(ji,jj,jk) = zzd_lw
350               zdiag(ji,jj,jk) = 1._wp - zzd_lw - zzd_up + zfact2 * dissl(ji,jj,jk) * wmask(ji,jj,jk)
351               !
352               !                                   ! right hand side in en
353               en(ji,jj,jk) = en(ji,jj,jk) + rdt * (  p_sh2(ji,jj,jk)                          &   ! shear
354                  &                                 - p_avt(ji,jj,jk) * rn2(ji,jj,jk)          &   ! stratification
355                  &                                 + zfact3 * dissl(ji,jj,jk) * en(ji,jj,jk)  &   ! dissipation
356                  &                                ) * wmask(ji,jj,jk)
357            END DO
358         END DO
359      END DO
360      !                          !* Matrix inversion from level 2 (tke prescribed at level 1)
361      DO jk = 3, jpkm1                             ! First recurrence : Dk = Dk - Lk * Uk-1 / Dk-1
362         DO jj = 2, jpjm1
363            DO ji = fs_2, fs_jpim1    ! vector opt.
364               zdiag(ji,jj,jk) = zdiag(ji,jj,jk) - zd_lw(ji,jj,jk) * zd_up(ji,jj,jk-1) / zdiag(ji,jj,jk-1)
365            END DO
366         END DO
367      END DO
368      DO jj = 2, jpjm1                             ! Second recurrence : Lk = RHSk - Lk / Dk-1 * Lk-1
369         DO ji = fs_2, fs_jpim1   ! vector opt.
370            zd_lw(ji,jj,2) = en(ji,jj,2) - zd_lw(ji,jj,2) * en(ji,jj,1)    ! Surface boudary conditions on tke
371         END DO
372      END DO
373      DO jk = 3, jpkm1
374         DO jj = 2, jpjm1
375            DO ji = fs_2, fs_jpim1    ! vector opt.
376               zd_lw(ji,jj,jk) = en(ji,jj,jk) - zd_lw(ji,jj,jk) / zdiag(ji,jj,jk-1) *zd_lw(ji,jj,jk-1)
377            END DO
378         END DO
379      END DO
380      DO jj = 2, jpjm1                             ! thrid recurrence : Ek = ( Lk - Uk * Ek+1 ) / Dk
381         DO ji = fs_2, fs_jpim1   ! vector opt.
382            en(ji,jj,jpkm1) = zd_lw(ji,jj,jpkm1) / zdiag(ji,jj,jpkm1)
383         END DO
384      END DO
385      DO jk = jpk-2, 2, -1
386         DO jj = 2, jpjm1
387            DO ji = fs_2, fs_jpim1    ! vector opt.
388               en(ji,jj,jk) = ( zd_lw(ji,jj,jk) - zd_up(ji,jj,jk) * en(ji,jj,jk+1) ) / zdiag(ji,jj,jk)
389            END DO
390         END DO
391      END DO
392      DO jk = 2, jpkm1                             ! set the minimum value of tke
393         DO jj = 2, jpjm1
394            DO ji = fs_2, fs_jpim1   ! vector opt.
395               en(ji,jj,jk) = MAX( en(ji,jj,jk), rn_emin ) * wmask(ji,jj,jk)
396            END DO
397         END DO
398      END DO
399      !
400      !                            !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
401      !                            !  TKE due to surface and internal wave breaking
402      !                            !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
403!!gm BUG : in the exp  remove the depth of ssh !!!
404!!gm       i.e. use gde3w in argument (gdepw(:,:,:,Kmm))
405     
406     
407      IF( nn_etau == 1 ) THEN           !* penetration below the mixed layer (rn_efr fraction)
408         DO jk = 2, jpkm1                       ! rn_eice =0 ON below sea-ice, =4 OFF when ice fraction > 0.25
409            DO jj = 2, jpjm1
410               DO ji = fs_2, fs_jpim1   ! vector opt.
411                  en(ji,jj,jk) = en(ji,jj,jk) + rn_efr * en(ji,jj,1) * EXP( -gdepw(ji,jj,jk,Kmm) / htau(ji,jj) )   &
412                     &                                 * MAX(0.,1._wp - rn_eice *fr_i(ji,jj) )  * wmask(ji,jj,jk) * tmask(ji,jj,1)
413               END DO
414            END DO
415         END DO
416      ELSEIF( nn_etau == 2 ) THEN       !* act only at the base of the mixed layer (jk=nmln)  (rn_efr fraction)
417         DO jj = 2, jpjm1
418            DO ji = fs_2, fs_jpim1   ! vector opt.
419               jk = nmln(ji,jj)
420               en(ji,jj,jk) = en(ji,jj,jk) + rn_efr * en(ji,jj,1) * EXP( -gdepw(ji,jj,jk,Kmm) / htau(ji,jj) )   &
421                  &                                 * MAX(0.,1._wp - rn_eice *fr_i(ji,jj) )  * wmask(ji,jj,jk) * tmask(ji,jj,1)
422            END DO
423         END DO
424      ELSEIF( nn_etau == 3 ) THEN       !* penetration belox the mixed layer (HF variability)
425         DO jk = 2, jpkm1
426            DO jj = 2, jpjm1
427               DO ji = fs_2, fs_jpim1   ! vector opt.
428                  ztx2 = utau(ji-1,jj  ) + utau(ji,jj)
429                  zty2 = vtau(ji  ,jj-1) + vtau(ji,jj)
430                  ztau = 0.5_wp * SQRT( ztx2 * ztx2 + zty2 * zty2 ) * tmask(ji,jj,1)    ! module of the mean stress
431                  zdif = taum(ji,jj) - ztau                            ! mean of modulus - modulus of the mean
432                  zdif = rhftau_scl * MAX( 0._wp, zdif + rhftau_add )  ! apply some modifications...
433                  en(ji,jj,jk) = en(ji,jj,jk) + zbbrau * zdif * EXP( -gdepw(ji,jj,jk,Kmm) / htau(ji,jj) )   &
434                     &                        * MAX(0.,1._wp - rn_eice *fr_i(ji,jj) ) * wmask(ji,jj,jk) * tmask(ji,jj,1)
435               END DO
436            END DO
437         END DO
438      ENDIF
439      !
440   END SUBROUTINE tke_tke
441
442
443   SUBROUTINE tke_avn( Kbb, Kmm, p_avm, p_avt )
444      !!----------------------------------------------------------------------
445      !!                   ***  ROUTINE tke_avn  ***
446      !!
447      !! ** Purpose :   Compute the vertical eddy viscosity and diffusivity
448      !!
449      !! ** Method  :   At this stage, en, the now TKE, is known (computed in
450      !!              the tke_tke routine). First, the now mixing lenth is
451      !!      computed from en and the strafification (N^2), then the mixings
452      !!      coefficients are computed.
453      !!              - Mixing length : a first evaluation of the mixing lengh
454      !!      scales is:
455      !!                      mxl = sqrt(2*en) / N 
456      !!      where N is the brunt-vaisala frequency, with a minimum value set
457      !!      to rmxl_min (rn_mxl0) in the interior (surface) ocean.
458      !!        The mixing and dissipative length scale are bound as follow :
459      !!         nn_mxl=0 : mxl bounded by the distance to surface and bottom.
460      !!                        zmxld = zmxlm = mxl
461      !!         nn_mxl=1 : mxl bounded by the e3w and zmxld = zmxlm = mxl
462      !!         nn_mxl=2 : mxl bounded such that the vertical derivative of mxl is
463      !!                    less than 1 (|d/dz(mxl)|<1) and zmxld = zmxlm = mxl
464      !!         nn_mxl=3 : mxl is bounded from the surface to the bottom usings
465      !!                    |d/dz(xml)|<1 to obtain lup, and from the bottom to
466      !!                    the surface to obtain ldown. the resulting length
467      !!                    scales are:
468      !!                        zmxld = sqrt( lup * ldown )
469      !!                        zmxlm = min ( lup , ldown )
470      !!              - Vertical eddy viscosity and diffusivity:
471      !!                      avm = max( avtb, rn_ediff * zmxlm * en^1/2 )
472      !!                      avt = max( avmb, pdlr * avm ) 
473      !!      with pdlr=1 if nn_pdl=0, pdlr=1/pdl=F(Ri) otherwise.
474      !!
475      !! ** Action  : - avt, avm : now vertical eddy diffusivity and viscosity (w-point)
476      !!----------------------------------------------------------------------
477      USE zdf_oce , ONLY : en, avtb, avmb, avtb_2d   ! ocean vertical physics
478      !!
479      INTEGER                   , INTENT(in   ) ::   Kbb, Kmm       ! ocean time level indices
480      REAL(wp), DIMENSION(:,:,:), INTENT(  out) ::   p_avm, p_avt   ! vertical eddy viscosity & diffusivity (w-points)
481      !
482      INTEGER  ::   ji, jj, jk   ! dummy loop indices
483      REAL(wp) ::   zrn2, zraug, zcoef, zav   ! local scalars
484      REAL(wp) ::   zdku,   zdkv, zsqen       !   -      -
485      REAL(wp) ::   zemxl, zemlm, zemlp       !   -      -
486      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zmxlm, zmxld   ! 3D workspace
487      !!--------------------------------------------------------------------
488      !
489      !                     !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
490      !                     !  Mixing length
491      !                     !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
492      !
493      !                     !* Buoyancy length scale: l=sqrt(2*e/n**2)
494      !
495      ! initialisation of interior minimum value (avoid a 2d loop with mikt)
496      zmxlm(:,:,:)  = rmxl_min   
497      zmxld(:,:,:)  = rmxl_min
498      !
499      IF( ln_mxl0 ) THEN            ! surface mixing length = F(stress) : l=vkarmn*2.e5*taum/(rau0*g)
500         zraug = vkarmn * 2.e5_wp / ( rau0 * grav )
501         DO jj = 2, jpjm1
502            DO ji = fs_2, fs_jpim1
503               zmxlm(ji,jj,1) = MAX( rn_mxl0, zraug * taum(ji,jj) * tmask(ji,jj,1) )
504            END DO
505         END DO
506      ELSE
507         zmxlm(:,:,1) = rn_mxl0
508      ENDIF
509      !
510      DO jk = 2, jpkm1              ! interior value : l=sqrt(2*e/n^2)
511         DO jj = 2, jpjm1
512            DO ji = fs_2, fs_jpim1   ! vector opt.
513               zrn2 = MAX( rn2(ji,jj,jk), rsmall )
514               zmxlm(ji,jj,jk) = MAX(  rmxl_min,  SQRT( 2._wp * en(ji,jj,jk) / zrn2 )  )
515            END DO
516         END DO
517      END DO
518      !
519      !                     !* Physical limits for the mixing length
520      !
521      zmxld(:,:, 1 ) = zmxlm(:,:,1)   ! surface set to the minimum value
522      zmxld(:,:,jpk) = rmxl_min       ! last level  set to the minimum value
523      !
524      SELECT CASE ( nn_mxl )
525      !
526 !!gm Not sure of that coding for ISF....
527      ! where wmask = 0 set zmxlm == e3w(:,:,:,Kmm)
528      CASE ( 0 )           ! bounded by the distance to surface and bottom
529         DO jk = 2, jpkm1
530            DO jj = 2, jpjm1
531               DO ji = fs_2, fs_jpim1   ! vector opt.
532                  zemxl = MIN( gdepw(ji,jj,jk,Kmm) - gdepw(ji,jj,mikt(ji,jj),Kmm), zmxlm(ji,jj,jk),   &
533                  &            gdepw(ji,jj,mbkt(ji,jj)+1,Kmm) - gdepw(ji,jj,jk,Kmm) )
534                  ! wmask prevent zmxlm = 0 if jk = mikt(ji,jj)
535                  zmxlm(ji,jj,jk) = zemxl * wmask(ji,jj,jk) + MIN( zmxlm(ji,jj,jk) , e3w(ji,jj,jk,Kmm) ) * (1 - wmask(ji,jj,jk))
536                  zmxld(ji,jj,jk) = zemxl * wmask(ji,jj,jk) + MIN( zmxlm(ji,jj,jk) , e3w(ji,jj,jk,Kmm) ) * (1 - wmask(ji,jj,jk))
537               END DO
538            END DO
539         END DO
540         !
541      CASE ( 1 )           ! bounded by the vertical scale factor
542         DO jk = 2, jpkm1
543            DO jj = 2, jpjm1
544               DO ji = fs_2, fs_jpim1   ! vector opt.
545                  zemxl = MIN( e3w(ji,jj,jk,Kmm), zmxlm(ji,jj,jk) )
546                  zmxlm(ji,jj,jk) = zemxl
547                  zmxld(ji,jj,jk) = zemxl
548               END DO
549            END DO
550         END DO
551         !
552      CASE ( 2 )           ! |dk[xml]| bounded by e3t :
553         DO jk = 2, jpkm1         ! from the surface to the bottom :
554            DO jj = 2, jpjm1
555               DO ji = fs_2, fs_jpim1   ! vector opt.
556                  zmxlm(ji,jj,jk) = MIN( zmxlm(ji,jj,jk-1) + e3t(ji,jj,jk-1,Kmm), zmxlm(ji,jj,jk) )
557               END DO
558            END DO
559         END DO
560         DO jk = jpkm1, 2, -1     ! from the bottom to the surface :
561            DO jj = 2, jpjm1
562               DO ji = fs_2, fs_jpim1   ! vector opt.
563                  zemxl = MIN( zmxlm(ji,jj,jk+1) + e3t(ji,jj,jk+1,Kmm), zmxlm(ji,jj,jk) )
564                  zmxlm(ji,jj,jk) = zemxl
565                  zmxld(ji,jj,jk) = zemxl
566               END DO
567            END DO
568         END DO
569         !
570      CASE ( 3 )           ! lup and ldown, |dk[xml]| bounded by e3t :
571         DO jk = 2, jpkm1         ! from the surface to the bottom : lup
572            DO jj = 2, jpjm1
573               DO ji = fs_2, fs_jpim1   ! vector opt.
574                  zmxld(ji,jj,jk) = MIN( zmxld(ji,jj,jk-1) + e3t(ji,jj,jk-1,Kmm), zmxlm(ji,jj,jk) )
575               END DO
576            END DO
577         END DO
578         DO jk = jpkm1, 2, -1     ! from the bottom to the surface : ldown
579            DO jj = 2, jpjm1
580               DO ji = fs_2, fs_jpim1   ! vector opt.
581                  zmxlm(ji,jj,jk) = MIN( zmxlm(ji,jj,jk+1) + e3t(ji,jj,jk+1,Kmm), zmxlm(ji,jj,jk) )
582               END DO
583            END DO
584         END DO
585         DO jk = 2, jpkm1
586            DO jj = 2, jpjm1
587               DO ji = fs_2, fs_jpim1   ! vector opt.
588                  zemlm = MIN ( zmxld(ji,jj,jk),  zmxlm(ji,jj,jk) )
589                  zemlp = SQRT( zmxld(ji,jj,jk) * zmxlm(ji,jj,jk) )
590                  zmxlm(ji,jj,jk) = zemlm
591                  zmxld(ji,jj,jk) = zemlp
592               END DO
593            END DO
594         END DO
595         !
596      END SELECT
597      !
598      !                     !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
599      !                     !  Vertical eddy viscosity and diffusivity  (avm and avt)
600      !                     !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
601      DO jk = 1, jpkm1            !* vertical eddy viscosity & diffivity at w-points
602         DO jj = 2, jpjm1
603            DO ji = fs_2, fs_jpim1   ! vector opt.
604               zsqen = SQRT( en(ji,jj,jk) )
605               zav   = rn_ediff * zmxlm(ji,jj,jk) * zsqen
606               p_avm(ji,jj,jk) = MAX( zav,                  avmb(jk) ) * wmask(ji,jj,jk)
607               p_avt(ji,jj,jk) = MAX( zav, avtb_2d(ji,jj) * avtb(jk) ) * wmask(ji,jj,jk)
608               dissl(ji,jj,jk) = zsqen / zmxld(ji,jj,jk)
609            END DO
610         END DO
611      END DO
612      !
613      !
614      IF( nn_pdl == 1 ) THEN      !* Prandtl number case: update avt
615         DO jk = 2, jpkm1
616            DO jj = 2, jpjm1
617               DO ji = fs_2, fs_jpim1   ! vector opt.
618                  p_avt(ji,jj,jk)   = MAX( apdlr(ji,jj,jk) * p_avt(ji,jj,jk), avtb_2d(ji,jj) * avtb(jk) ) * tmask(ji,jj,jk)
619              END DO
620            END DO
621         END DO
622      ENDIF
623      !
624      IF(ln_ctl) THEN
625         CALL prt_ctl( tab3d_1=en   , clinfo1=' tke  - e: ', tab3d_2=p_avt, clinfo2=' t: ', kdim=jpk)
626         CALL prt_ctl( tab3d_1=p_avm, clinfo1=' tke  - m: ', kdim=jpk )
627      ENDIF
628      !
629   END SUBROUTINE tke_avn
630
631
632   SUBROUTINE zdf_tke_init
633      !!----------------------------------------------------------------------
634      !!                  ***  ROUTINE zdf_tke_init  ***
635      !!                     
636      !! ** Purpose :   Initialization of the vertical eddy diffivity and
637      !!              viscosity when using a tke turbulent closure scheme
638      !!
639      !! ** Method  :   Read the namzdf_tke namelist and check the parameters
640      !!              called at the first timestep (nit000)
641      !!
642      !! ** input   :   Namlist namzdf_tke
643      !!
644      !! ** Action  :   Increase by 1 the nstop flag is setting problem encounter
645      !!----------------------------------------------------------------------
646      USE zdf_oce , ONLY : ln_zdfiwm   ! Internal Wave Mixing flag
647      !!
648      INTEGER ::   ji, jj, jk   ! dummy loop indices
649      INTEGER ::   ios
650      !!
651      NAMELIST/namzdf_tke/ rn_ediff, rn_ediss , rn_ebb , rn_emin  ,          &
652         &                 rn_emin0, rn_bshear, nn_mxl , ln_mxl0  ,          &
653         &                 rn_mxl0 , nn_pdl   , ln_drg , ln_lc    , rn_lc,   &
654         &                 nn_etau , nn_htau  , rn_efr , rn_eice 
655      !!----------------------------------------------------------------------
656      !
657      REWIND( numnam_ref )              ! Namelist namzdf_tke in reference namelist : Turbulent Kinetic Energy
658      READ  ( numnam_ref, namzdf_tke, IOSTAT = ios, ERR = 901)
659901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namzdf_tke in reference namelist', lwp )
660
661      REWIND( numnam_cfg )              ! Namelist namzdf_tke in configuration namelist : Turbulent Kinetic Energy
662      READ  ( numnam_cfg, namzdf_tke, IOSTAT = ios, ERR = 902 )
663902   IF( ios >  0 ) CALL ctl_nam ( ios , 'namzdf_tke in configuration namelist', lwp )
664      IF(lwm) WRITE ( numond, namzdf_tke )
665      !
666      ri_cri   = 2._wp    / ( 2._wp + rn_ediss / rn_ediff )   ! resulting critical Richardson number
667      !
668      IF(lwp) THEN                    !* Control print
669         WRITE(numout,*)
670         WRITE(numout,*) 'zdf_tke_init : tke turbulent closure scheme - initialisation'
671         WRITE(numout,*) '~~~~~~~~~~~~'
672         WRITE(numout,*) '   Namelist namzdf_tke : set tke mixing parameters'
673         WRITE(numout,*) '      coef. to compute avt                        rn_ediff  = ', rn_ediff
674         WRITE(numout,*) '      Kolmogoroff dissipation coef.               rn_ediss  = ', rn_ediss
675         WRITE(numout,*) '      tke surface input coef.                     rn_ebb    = ', rn_ebb
676         WRITE(numout,*) '      minimum value of tke                        rn_emin   = ', rn_emin
677         WRITE(numout,*) '      surface minimum value of tke                rn_emin0  = ', rn_emin0
678         WRITE(numout,*) '      prandl number flag                          nn_pdl    = ', nn_pdl
679         WRITE(numout,*) '      background shear (>0)                       rn_bshear = ', rn_bshear
680         WRITE(numout,*) '      mixing length type                          nn_mxl    = ', nn_mxl
681         WRITE(numout,*) '         surface mixing length = F(stress) or not    ln_mxl0   = ', ln_mxl0
682         WRITE(numout,*) '         surface  mixing length minimum value        rn_mxl0   = ', rn_mxl0
683         WRITE(numout,*) '      top/bottom friction forcing flag            ln_drg    = ', ln_drg
684         WRITE(numout,*) '      Langmuir cells parametrization              ln_lc     = ', ln_lc
685         WRITE(numout,*) '         coef to compute vertical velocity of LC     rn_lc  = ', rn_lc
686         WRITE(numout,*) '      test param. to add tke induced by wind      nn_etau   = ', nn_etau
687         WRITE(numout,*) '          type of tke penetration profile            nn_htau   = ', nn_htau
688         WRITE(numout,*) '          fraction of TKE that penetrates            rn_efr    = ', rn_efr
689         WRITE(numout,*) '          below sea-ice:  =0 ON                      rn_eice   = ', rn_eice
690         WRITE(numout,*) '          =4 OFF when ice fraction > 1/4   '
691         IF( ln_drg ) THEN
692            WRITE(numout,*)
693            WRITE(numout,*) '   Namelist namdrg_top/_bot:   used values:'
694            WRITE(numout,*) '      top    ocean cavity roughness (m)          rn_z0(_top)= ', r_z0_top
695            WRITE(numout,*) '      Bottom seafloor     roughness (m)          rn_z0(_bot)= ', r_z0_bot
696         ENDIF
697         WRITE(numout,*)
698         WRITE(numout,*) '   ==>>>   critical Richardson nb with your parameters  ri_cri = ', ri_cri
699         WRITE(numout,*)
700      ENDIF
701      !
702      IF( ln_zdfiwm ) THEN          ! Internal wave-driven mixing
703         rn_emin  = 1.e-10_wp             ! specific values of rn_emin & rmxl_min are used
704         rmxl_min = 1.e-03_wp             ! associated avt minimum = molecular salt diffusivity (10^-9 m2/s)
705         IF(lwp) WRITE(numout,*) '   ==>>>   Internal wave-driven mixing case:   force   rn_emin = 1.e-10 and rmxl_min = 1.e-3'
706      ELSE                          ! standard case : associated avt minimum = molecular viscosity (10^-6 m2/s)
707         rmxl_min = 1.e-6_wp / ( rn_ediff * SQRT( rn_emin ) )    ! resulting minimum length to recover molecular viscosity
708         IF(lwp) WRITE(numout,*) '   ==>>>   minimum mixing length with your parameters rmxl_min = ', rmxl_min
709      ENDIF
710      !
711      !                              ! allocate tke arrays
712      IF( zdf_tke_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'zdf_tke_init : unable to allocate arrays' )
713      !
714      !                               !* Check of some namelist values
715      IF( nn_mxl  < 0   .OR.  nn_mxl  > 3 )   CALL ctl_stop( 'bad flag: nn_mxl is  0, 1 or 2 ' )
716      IF( nn_pdl  < 0   .OR.  nn_pdl  > 1 )   CALL ctl_stop( 'bad flag: nn_pdl is  0 or 1    ' )
717      IF( nn_htau < 0   .OR.  nn_htau > 1 )   CALL ctl_stop( 'bad flag: nn_htau is 0, 1 or 2 ' )
718      IF( nn_etau == 3 .AND. .NOT. ln_cpl )   CALL ctl_stop( 'nn_etau == 3 : HF taum only known in coupled mode' )
719      !
720      IF( ln_mxl0 ) THEN
721         IF(lwp) WRITE(numout,*)
722         IF(lwp) WRITE(numout,*) '   ==>>>   use a surface mixing length = F(stress) :   set rn_mxl0 = rmxl_min'
723         rn_mxl0 = rmxl_min
724      ENDIF
725     
726      IF( nn_etau == 2  )   CALL zdf_mxl( nit000 )      ! Initialization of nmln
727
728      !                               !* depth of penetration of surface tke
729      IF( nn_etau /= 0 ) THEN     
730         SELECT CASE( nn_htau )             ! Choice of the depth of penetration
731         CASE( 0 )                                 ! constant depth penetration (here 10 meters)
732            htau(:,:) = 10._wp
733         CASE( 1 )                                 ! F(latitude) : 0.5m to 30m poleward of 40 degrees
734            htau(:,:) = MAX(  0.5_wp, MIN( 30._wp, 45._wp* ABS( SIN( rpi/180._wp * gphit(:,:) ) ) )   )           
735         END SELECT
736      ENDIF
737      !                                !* read or initialize all required files
738      CALL tke_rst( nit000, 'READ' )      ! (en, avt_k, avm_k, dissl)
739      !
740      IF( lwxios ) THEN
741         CALL iom_set_rstw_var_active('en')
742         CALL iom_set_rstw_var_active('avt_k')
743         CALL iom_set_rstw_var_active('avm_k')
744         CALL iom_set_rstw_var_active('dissl')
745      ENDIF
746   END SUBROUTINE zdf_tke_init
747
748
749   SUBROUTINE tke_rst( kt, cdrw )
750      !!---------------------------------------------------------------------
751      !!                   ***  ROUTINE tke_rst  ***
752      !!                     
753      !! ** Purpose :   Read or write TKE file (en) in restart file
754      !!
755      !! ** Method  :   use of IOM library
756      !!                if the restart does not contain TKE, en is either
757      !!                set to rn_emin or recomputed
758      !!----------------------------------------------------------------------
759      USE zdf_oce , ONLY : en, avt_k, avm_k   ! ocean vertical physics
760      !!
761      INTEGER         , INTENT(in) ::   kt     ! ocean time-step
762      CHARACTER(len=*), INTENT(in) ::   cdrw   ! "READ"/"WRITE" flag
763      !
764      INTEGER ::   jit, jk              ! dummy loop indices
765      INTEGER ::   id1, id2, id3, id4   ! local integers
766      !!----------------------------------------------------------------------
767      !
768      IF( TRIM(cdrw) == 'READ' ) THEN        ! Read/initialise
769         !                                   ! ---------------
770         IF( ln_rstart ) THEN                   !* Read the restart file
771            id1 = iom_varid( numror, 'en'   , ldstop = .FALSE. )
772            id2 = iom_varid( numror, 'avt_k', ldstop = .FALSE. )
773            id3 = iom_varid( numror, 'avm_k', ldstop = .FALSE. )
774            id4 = iom_varid( numror, 'dissl', ldstop = .FALSE. )
775            !
776            IF( MIN( id1, id2, id3, id4 ) > 0 ) THEN      ! fields exist
777               CALL iom_get( numror, jpdom_autoglo, 'en'   , en   , ldxios = lrxios )
778               CALL iom_get( numror, jpdom_autoglo, 'avt_k', avt_k, ldxios = lrxios )
779               CALL iom_get( numror, jpdom_autoglo, 'avm_k', avm_k, ldxios = lrxios )
780               CALL iom_get( numror, jpdom_autoglo, 'dissl', dissl, ldxios = lrxios )
781            ELSE                                          ! start TKE from rest
782               IF(lwp) WRITE(numout,*)
783               IF(lwp) WRITE(numout,*) '   ==>>>   previous run without TKE scheme, set en to background values'
784               en   (:,:,:) = rn_emin * wmask(:,:,:)
785               dissl(:,:,:) = 1.e-12_wp
786               ! avt_k, avm_k already set to the background value in zdf_phy_init
787            ENDIF
788         ELSE                                   !* Start from rest
789            IF(lwp) WRITE(numout,*)
790            IF(lwp) WRITE(numout,*) '   ==>>>   start from rest: set en to the background value'
791            en   (:,:,:) = rn_emin * wmask(:,:,:)
792            dissl(:,:,:) = 1.e-12_wp
793            ! avt_k, avm_k already set to the background value in zdf_phy_init
794         ENDIF
795         !
796      ELSEIF( TRIM(cdrw) == 'WRITE' ) THEN   ! Create restart file
797         !                                   ! -------------------
798         IF(lwp) WRITE(numout,*) '---- tke_rst ----'
799         IF( lwxios ) CALL iom_swap(      cwxios_context          ) 
800         CALL iom_rstput( kt, nitrst, numrow, 'en'   , en   , ldxios = lwxios )
801         CALL iom_rstput( kt, nitrst, numrow, 'avt_k', avt_k, ldxios = lwxios )
802         CALL iom_rstput( kt, nitrst, numrow, 'avm_k', avm_k, ldxios = lwxios )
803         CALL iom_rstput( kt, nitrst, numrow, 'dissl', dissl, ldxios = lwxios )
804         IF( lwxios ) CALL iom_swap(      cxios_context          )
805         !
806      ENDIF
807      !
808   END SUBROUTINE tke_rst
809
810   !!======================================================================
811END MODULE zdftke
Note: See TracBrowser for help on using the repository browser.