source: NEMO/branches/2019/dev_r10721_KERNEL-02_Storkey_Coward_IMMERSE_first_steps/src/TOP/TRP/trcrad.F90 @ 11480

Last change on this file since 11480 was 11480, checked in by davestorkey, 2 years ago

2019/dev_r10721_KERNEL-02_Storkey_Coward_IMMERSE_first_steps : Merge in changes from branch of branch.
Main changes:

  1. "nxt" modules renamed as "atf" and now just do Asselin time filtering. The time level swapping is achieved by swapping indices.
  2. Some additional prognostic grid variables changed to use a time dimension.

Notes:

  1. This merged branch passes SETTE tests but does not identical results to the SETTE tests with the trunk@10721 unless minor bugs to do with Euler timestepping and the OFF timestepping are fixed in the trunk (NEMO tickets #2310 and #2311).
  2. The nn_dttrc > 1 option for TOP (TOP has a different timestep to OCE) doesn't work. But it doesn't work in the trunk or NEMO 4.0 release either.
  • Property svn:keywords set to Id
File size: 12.3 KB
Line 
1MODULE trcrad
2   !!======================================================================
3   !!                       ***  MODULE  trcrad  ***
4   !! Ocean passive tracers:  correction of negative concentrations
5   !!======================================================================
6   !! History :   -   !  01-01  (O. Aumont & E. Kestenare)  Original code
7   !!            1.0  !  04-03  (C. Ethe)  free form F90
8   !!----------------------------------------------------------------------
9#if defined key_top
10   !!----------------------------------------------------------------------
11   !!   'key_top'                                                TOP models
12   !!----------------------------------------------------------------------
13   !!   trc_rad    : correction of negative concentrations
14   !!----------------------------------------------------------------------
15   USE par_trc             ! need jptra, number of passive tracers
16   USE oce_trc             ! ocean dynamics and tracers variables
17   USE trc                 ! ocean passive tracers variables
18   USE trd_oce
19   USE trdtra
20   USE prtctl_trc          ! Print control for debbuging
21   USE lib_fortran
22
23   IMPLICIT NONE
24   PRIVATE
25
26   PUBLIC trc_rad     
27   PUBLIC trc_rad_ini 
28
29   LOGICAL , PUBLIC ::   ln_trcrad           !: flag to artificially correct negative concentrations
30   REAL(wp), DIMENSION(:,:), ALLOCATABLE::   gainmass
31
32   !!----------------------------------------------------------------------
33   !! NEMO/TOP 4.0 , NEMO Consortium (2018)
34   !! $Id$
35   !! Software governed by the CeCILL license (see ./LICENSE)
36   !!----------------------------------------------------------------------
37CONTAINS
38
39   SUBROUTINE trc_rad( kt, Kbb, Kmm, ptr )
40      !!----------------------------------------------------------------------
41      !!                  ***  ROUTINE trc_rad  ***
42      !!
43      !! ** Purpose :   "crappy" routine to correct artificial negative
44      !!              concentrations due to isopycnal scheme
45      !!
46      !! ** Method  : - PISCES or LOBSTER: Set negative concentrations to zero
47      !!                while computing the corresponding tracer content that
48      !!                is added to the tracers. Then, adjust the tracer
49      !!                concentration using a multiplicative factor so that
50      !!                the total tracer concentration is preserved.
51      !!              - CFC: simply set to zero the negative CFC concentration
52      !!                (the total CFC content is not strictly preserved)
53      !!----------------------------------------------------------------------
54      INTEGER,                                    INTENT(in   ) :: kt         ! ocean time-step index
55      INTEGER,                                    INTENT(in   ) :: Kbb, Kmm   ! time level indices
56      REAL(wp), DIMENSION(jpi,jpj,jpk,jptra,jpt), INTENT(inout) :: ptr        ! passive tracers and RHS of tracer equation
57      !
58      CHARACTER (len=22) :: charout
59      !!----------------------------------------------------------------------
60      !
61      IF( ln_timing )   CALL timing_start('trc_rad')
62      !
63      IF( ln_age     )   CALL trc_rad_sms( kt, Kbb, Kmm, ptr, jp_age , jp_age                )  !  AGE
64      IF( ll_cfc     )   CALL trc_rad_sms( kt, Kbb, Kmm, ptr, jp_cfc0, jp_cfc1               )  !  CFC model
65      IF( ln_c14     )   CALL trc_rad_sms( kt, Kbb, Kmm, ptr, jp_c14 , jp_c14                )  !  C14
66      IF( ln_pisces  )   CALL trc_rad_sms( kt, Kbb, Kmm, ptr, jp_pcs0, jp_pcs1, cpreserv='Y' )  !  PISCES model
67      IF( ln_my_trc  )   CALL trc_rad_sms( kt, Kbb, Kmm, ptr, jp_myt0, jp_myt1               )  !  MY_TRC model
68      !
69      IF(ln_ctl) THEN      ! print mean trends (used for debugging)
70         WRITE(charout, FMT="('rad')")
71         CALL prt_ctl_trc_info( charout )
72         CALL prt_ctl_trc( tab4d=ptr(:,:,:,:,Kbb), mask=tmask, clinfo=ctrcnm )
73      ENDIF
74      !
75      IF( ln_timing )   CALL timing_stop('trc_rad')
76      !
77   END SUBROUTINE trc_rad
78
79
80   SUBROUTINE trc_rad_ini
81      !!---------------------------------------------------------------------
82      !!                  ***  ROUTINE trc _rad_ini ***
83      !!
84      !! ** Purpose :   read  namelist options
85      !!----------------------------------------------------------------------
86      INTEGER ::   ios   ! Local integer output status for namelist read
87      !!
88      NAMELIST/namtrc_rad/ ln_trcrad
89      !!----------------------------------------------------------------------
90      !
91      REWIND( numnat_ref )              ! namtrc_rad in reference namelist
92      READ  ( numnat_ref, namtrc_rad, IOSTAT = ios, ERR = 907)
93907   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namtrc_rad in reference namelist', lwp )
94      REWIND( numnat_cfg )              ! namtrc_rad in configuration namelist
95      READ  ( numnat_cfg, namtrc_rad, IOSTAT = ios, ERR = 908 )
96908   IF( ios > 0 )   CALL ctl_nam ( ios , 'namtrc_rad in configuration namelist', lwp )
97      IF(lwm) WRITE( numont, namtrc_rad )
98
99      IF(lwp) THEN                     !   ! Control print
100         WRITE(numout,*)
101         WRITE(numout,*) 'trc_rad : Correct artificial negative concentrations '
102         WRITE(numout,*) '~~~~~~~ '
103         WRITE(numout,*) '   Namelist namtrc_rad : treatment of negative concentrations'
104         WRITE(numout,*) '      correct artificially negative concen. or not   ln_trcrad = ', ln_trcrad
105         WRITE(numout,*)
106         IF( ln_trcrad ) THEN   ;   WRITE(numout,*) '      ===>>   ensure the global tracer conservation'
107         ELSE                   ;   WRITE(numout,*) '      ===>>   NO strict global tracer conservation'     
108         ENDIF
109      ENDIF
110      !
111      ALLOCATE( gainmass(jptra,2) )
112      gainmass(:,:) = 0.
113      !
114   END SUBROUTINE trc_rad_ini
115
116
117   SUBROUTINE trc_rad_sms( kt, Kbb, Kmm, ptr, jp_sms0, jp_sms1, cpreserv )
118     !!-----------------------------------------------------------------------------
119     !!                  ***  ROUTINE trc_rad_sms  ***
120     !!
121     !! ** Purpose :   "crappy" routine to correct artificial negative
122     !!              concentrations due to isopycnal scheme
123     !!
124     !! ** Method  : 2 cases :
125     !!                - Set negative concentrations to zero while computing
126     !!                  the corresponding tracer content that is added to the
127     !!                  tracers. Then, adjust the tracer concentration using
128     !!                  a multiplicative factor so that the total tracer
129     !!                  concentration is preserved.
130     !!                - simply set to zero the negative CFC concentration
131     !!                  (the total content of concentration is not strictly preserved)
132     !!--------------------------------------------------------------------------------
133     INTEGER                                    , INTENT(in   ) ::   kt                 ! ocean time-step index
134     INTEGER                                    , INTENT(in   ) ::   Kbb, Kmm           ! time level indices
135     INTEGER                                    , INTENT(in   ) ::   jp_sms0, jp_sms1   ! First & last index of the passive tracer model
136     REAL(wp), DIMENSION (jpi,jpj,jpk,jptra,jpt), INTENT(inout) ::   ptr                ! before and now traceur concentration
137     CHARACTER( len = 1), OPTIONAL              , INTENT(in   ) ::   cpreserv           ! flag to preserve content or not
138     !
139     INTEGER ::   ji, ji2, jj, jj2, jk, jn, jt ! dummy loop indices
140     INTEGER ::   icnt, itime
141     LOGICAL ::   lldebug = .FALSE.            ! local logical
142     REAL(wp)::   zcoef, zs2rdt, ztotmass
143     REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) ::   ztrneg, ztrpos
144     REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) ::   ztrtrd   ! workspace arrays
145     !!----------------------------------------------------------------------
146     !
147     IF( l_trdtrc )   ALLOCATE( ztrtrd(jpi,jpj,jpk) )
148     zs2rdt = 1. / ( 2. * rdt * REAL( nn_dttrc, wp ) )
149     !
150     DO jt = 1,2  ! Loop over time indices since exactly the same fix is applied to "now" and "after" fields
151        IF( jt == 1 ) itime = Kbb
152        IF( jt == 2 ) itime = Kmm
153
154        IF( PRESENT( cpreserv )  ) THEN     !==  total tracer concentration is preserved  ==!
155           !
156           ALLOCATE( ztrneg(1:jpi,1:jpj,jp_sms0:jp_sms1), ztrpos(1:jpi,1:jpj,jp_sms0:jp_sms1) )
157
158           DO jn = jp_sms0, jp_sms1
159              ztrneg(:,:,jn) = SUM( MIN( 0., ptr(:,:,:,jn,itime) ) * cvol(:,:,:), dim = 3 )   ! sum of the negative values
160              ztrpos(:,:,jn) = SUM( MAX( 0., ptr(:,:,:,jn,itime) ) * cvol(:,:,:), dim = 3 )   ! sum of the positive values
161           END DO
162           CALL sum3x3( ztrneg )
163           CALL sum3x3( ztrpos )
164
165           DO jn = jp_sms0, jp_sms1
166              !
167              IF( l_trdtrc )   ztrtrd(:,:,:) = ptr(:,:,:,jn,itime)                       ! save input tr(:,:,:,:,Kbb) for trend computation           
168              !
169              DO jk = 1, jpkm1
170                 DO jj = 1, jpj
171                    DO ji = 1, jpi
172                       IF( ztrneg(ji,jj,jn) /= 0. ) THEN                                 ! if negative values over the 3x3 box
173                          !
174                          ptr(ji,jj,jk,jn,itime) = ptr(ji,jj,jk,jn,itime) * tmask(ji,jj,jk)   ! really needed?
175                          IF( ptr(ji,jj,jk,jn,itime) < 0. ) ptr(ji,jj,jk,jn,itime) = 0.       ! suppress negative values
176                          IF( ptr(ji,jj,jk,jn,itime) > 0. ) THEN                    ! use positive values to compensate mass gain
177                             zcoef = 1. + ztrneg(ji,jj,jn) / ztrpos(ji,jj,jn)       ! ztrpos > 0 as ptr > 0
178                             ptr(ji,jj,jk,jn,itime) = ptr(ji,jj,jk,jn,itime) * zcoef
179                             IF( zcoef < 0. ) THEN                                  ! if the compensation exceed the positive value
180                                gainmass(jn,1) = gainmass(jn,1) - ptr(ji,jj,jk,jn,itime) * cvol(ji,jj,jk)   ! we are adding mass...
181                                ptr(ji,jj,jk,jn,itime) = 0.                         ! limit the compensation to keep positive value
182                             ENDIF
183                          ENDIF
184                          !
185                       ENDIF
186                    END DO
187                 END DO
188              END DO
189              !
190              IF( l_trdtrc ) THEN
191                 ztrtrd(:,:,:) = ( ptr(:,:,:,jn,itime) - ztrtrd(:,:,:) ) * zs2rdt
192                 CALL trd_tra( kt, Kbb, Kmm, 'TRC', jn, jptra_radb, ztrtrd )       ! Asselin-like trend handling
193              ENDIF
194              !
195           END DO
196
197           IF( kt == nitend ) THEN
198              CALL mpp_sum( 'trcrad', gainmass(:,1) )
199              DO jn = jp_sms0, jp_sms1
200                 IF( gainmass(jn,1) > 0. ) THEN
201                    ztotmass = glob_sum( 'trcrad', ptr(:,:,:,jn,itime) * cvol(:,:,:) )
202                    IF(lwp) WRITE(numout, '(a, i2, a, D23.16, a, D23.16)') 'trcrad ptrb, traceur ', jn  &
203                         &        , ' total mass : ', ztotmass, ', mass gain : ',  gainmass(jn,1)
204                 END IF
205              END DO
206           ENDIF
207
208           DEALLOCATE( ztrneg, ztrpos )
209           !
210        ELSE                                !==  total CFC content is NOT strictly preserved  ==!
211           !
212           DO jn = jp_sms0, jp_sms1 
213              !
214              IF( l_trdtrc )   ztrtrd(:,:,:) = ptr(:,:,:,jn,itime)                 ! save input tr for trend computation
215              !
216              WHERE( ptr(:,:,:,jn,itime) < 0. )   ptr(:,:,:,jn,itime) = 0.
217              !
218              IF( l_trdtrc ) THEN
219                 ztrtrd(:,:,:) = ( ptr(:,:,:,jn,itime) - ztrtrd(:,:,:) ) * zs2rdt
220                 CALL trd_tra( kt, Kbb, Kmm, 'TRC', jn, jptra_radb, ztrtrd )       ! Asselin-like trend handling
221              ENDIF
222              !
223           END DO
224           !
225        ENDIF
226        !
227      END DO
228      !
229      IF( l_trdtrc )  DEALLOCATE( ztrtrd )
230      !
231   END SUBROUTINE trc_rad_sms
232
233#else
234   !!----------------------------------------------------------------------
235   !!   Dummy module :                                         NO TOP model
236   !!----------------------------------------------------------------------
237CONTAINS
238   SUBROUTINE trc_rad( kt, Kbb, Kmm )              ! Empty routine
239      INTEGER, INTENT(in) ::   kt
240      INTEGER, INTENT(in) ::   Kbb, Kmm  ! time level indices
241      WRITE(*,*) 'trc_rad: You should not have seen this print! error?', kt
242   END SUBROUTINE trc_rad
243#endif
244   
245   !!======================================================================
246END MODULE trcrad
Note: See TracBrowser for help on using the repository browser.