New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
dynspg.F90 in NEMO/branches/2019/dev_r10742_ENHANCE-12_SimonM-Tides/src/OCE/DYN – NEMO

source: NEMO/branches/2019/dev_r10742_ENHANCE-12_SimonM-Tides/src/OCE/DYN/dynspg.F90 @ 10773

Last change on this file since 10773 was 10773, checked in by smueller, 3 years ago

Transfer of five public variables, their allocation, and two subroutines from module sbctide to module tide_mod (ticket #2194)

  • Property svn:keywords set to Id
File size: 12.1 KB
Line 
1MODULE dynspg
2   !!======================================================================
3   !!                       ***  MODULE  dynspg  ***
4   !! Ocean dynamics:  surface pressure gradient control
5   !!======================================================================
6   !! History :  1.0  ! 2005-12  (C. Talandier, G. Madec, V. Garnier)  Original code
7   !!            3.2  ! 2009-07  (R. Benshila)  Suppression of rigid-lid option
8   !!----------------------------------------------------------------------
9
10   !!----------------------------------------------------------------------
11   !!   dyn_spg     : update the dynamics trend with surface pressure gradient
12   !!   dyn_spg_init: initialization, namelist read, and parameters control
13   !!----------------------------------------------------------------------
14   USE oce            ! ocean dynamics and tracers variables
15   USE dom_oce        ! ocean space and time domain variables
16   USE c1d            ! 1D vertical configuration
17   USE phycst         ! physical constants
18   USE sbc_oce        ! surface boundary condition: ocean
19   USE sbc_ice , ONLY : snwice_mass, snwice_mass_b
20   USE sbcapr         ! surface boundary condition: atmospheric pressure
21   USE dynspg_exp     ! surface pressure gradient     (dyn_spg_exp routine)
22   USE dynspg_ts      ! surface pressure gradient     (dyn_spg_ts  routine)
23   USE sbctide        !
24   USE updtide        !
25   USE tide_mod       !
26   USE trd_oce        ! trends: ocean variables
27   USE trddyn         ! trend manager: dynamics
28   !
29   USE prtctl         ! Print control                     (prt_ctl routine)
30   USE in_out_manager ! I/O manager
31   USE lib_mpp        ! MPP library
32   USE timing         ! Timing
33
34   IMPLICIT NONE
35   PRIVATE
36
37   PUBLIC   dyn_spg        ! routine called by step module
38   PUBLIC   dyn_spg_init   ! routine called by opa module
39
40   INTEGER ::   nspg = 0   ! type of surface pressure gradient scheme defined from lk_dynspg_...
41
42   !                       ! Parameter to control the surface pressure gradient scheme
43   INTEGER, PARAMETER ::   np_TS  = 1   ! split-explicit time stepping (Time-Splitting)
44   INTEGER, PARAMETER ::   np_EXP = 0   !       explicit time stepping
45   INTEGER, PARAMETER ::   np_NO  =-1   ! no surface pressure gradient, no scheme
46
47   !! * Substitutions
48#  include "vectopt_loop_substitute.h90"
49   !!----------------------------------------------------------------------
50   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
51   !! $Id$
52   !! Software governed by the CeCILL license (see ./LICENSE)
53   !!----------------------------------------------------------------------
54CONTAINS
55
56   SUBROUTINE dyn_spg( kt )
57      !!----------------------------------------------------------------------
58      !!                  ***  ROUTINE dyn_spg  ***
59      !!
60      !! ** Purpose :   compute surface pressure gradient including the
61      !!              atmospheric pressure forcing (ln_apr_dyn=T).
62      !!
63      !! ** Method  :   Two schemes:
64      !!              - explicit       : the spg is evaluated at now
65      !!              - split-explicit : a time splitting technique is used
66      !!
67      !!              ln_apr_dyn=T : the atmospheric pressure forcing is applied
68      !!             as the gradient of the inverse barometer ssh:
69      !!                apgu = - 1/rau0 di[apr] = 0.5*grav di[ssh_ib+ssh_ibb]
70      !!                apgv = - 1/rau0 dj[apr] = 0.5*grav dj[ssh_ib+ssh_ibb]
71      !!             Note that as all external forcing a time averaging over a two rdt
72      !!             period is used to prevent the divergence of odd and even time step.
73      !!----------------------------------------------------------------------
74      INTEGER, INTENT(in) ::   kt   ! ocean time-step index
75      !
76      INTEGER  ::   ji, jj, jk                   ! dummy loop indices
77      REAL(wp) ::   z2dt, zg_2, zintp, zgrau0r, zld   ! local scalars
78      REAL(wp), ALLOCATABLE, DIMENSION(:,:)   ::   zpice
79      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) ::   ztrdu, ztrdv
80      !!----------------------------------------------------------------------
81      !
82      IF( ln_timing )   CALL timing_start('dyn_spg')
83      !
84      IF( l_trddyn )   THEN                      ! temporary save of ta and sa trends
85         ALLOCATE( ztrdu(jpi,jpj,jpk) , ztrdv(jpi,jpj,jpk) ) 
86         ztrdu(:,:,:) = ua(:,:,:)
87         ztrdv(:,:,:) = va(:,:,:)
88      ENDIF
89      !
90      IF(      ln_apr_dyn                                                &   ! atmos. pressure
91         .OR.  ( .NOT.ln_dynspg_ts .AND. (ln_tide_pot .AND. ln_tide) )   &   ! tide potential (no time slitting)
92         .OR.  ln_ice_embd ) THEN                                            ! embedded sea-ice
93         !
94         DO jj = 2, jpjm1
95            DO ji = fs_2, fs_jpim1   ! vector opt.
96               spgu(ji,jj) = 0._wp
97               spgv(ji,jj) = 0._wp
98            END DO
99         END DO         
100         !
101         IF( ln_apr_dyn .AND. .NOT.ln_dynspg_ts ) THEN   !==  Atmospheric pressure gradient (added later in time-split case) ==!
102            zg_2 = grav * 0.5
103            DO jj = 2, jpjm1                          ! gradient of Patm using inverse barometer ssh
104               DO ji = fs_2, fs_jpim1   ! vector opt.
105                  spgu(ji,jj) = spgu(ji,jj) + zg_2 * (  ssh_ib (ji+1,jj) - ssh_ib (ji,jj)    &
106                     &                                + ssh_ibb(ji+1,jj) - ssh_ibb(ji,jj)  ) * r1_e1u(ji,jj)
107                  spgv(ji,jj) = spgv(ji,jj) + zg_2 * (  ssh_ib (ji,jj+1) - ssh_ib (ji,jj)    &
108                     &                                + ssh_ibb(ji,jj+1) - ssh_ibb(ji,jj)  ) * r1_e2v(ji,jj)
109               END DO
110            END DO
111         ENDIF
112         !
113         !                                    !==  tide potential forcing term  ==!
114         IF( .NOT.ln_dynspg_ts .AND. ( ln_tide_pot .AND. ln_tide )  ) THEN   ! N.B. added directly at sub-time-step in ts-case
115            !
116            CALL upd_tide( kt )                      ! update tide potential
117            !
118            DO jj = 2, jpjm1                         ! add tide potential forcing
119               DO ji = fs_2, fs_jpim1   ! vector opt.
120                  spgu(ji,jj) = spgu(ji,jj) + grav * ( pot_astro(ji+1,jj) - pot_astro(ji,jj) ) * r1_e1u(ji,jj)
121                  spgv(ji,jj) = spgv(ji,jj) + grav * ( pot_astro(ji,jj+1) - pot_astro(ji,jj) ) * r1_e2v(ji,jj)
122               END DO
123            END DO
124            !
125            IF (ln_scal_load) THEN
126               zld = rn_scal_load * grav
127               DO jj = 2, jpjm1                    ! add scalar approximation for load potential
128                  DO ji = fs_2, fs_jpim1   ! vector opt.
129                     spgu(ji,jj) = spgu(ji,jj) + zld * ( sshn(ji+1,jj) - sshn(ji,jj) ) * r1_e1u(ji,jj)
130                     spgv(ji,jj) = spgv(ji,jj) + zld * ( sshn(ji,jj+1) - sshn(ji,jj) ) * r1_e2v(ji,jj)
131                  END DO
132               END DO
133            ENDIF
134         ENDIF
135         !
136         IF( ln_ice_embd ) THEN              !== embedded sea ice: Pressure gradient due to snow-ice mass ==!
137            ALLOCATE( zpice(jpi,jpj) )
138            zintp = REAL( MOD( kt-1, nn_fsbc ) ) / REAL( nn_fsbc )
139            zgrau0r     = - grav * r1_rau0
140            zpice(:,:) = (  zintp * snwice_mass(:,:) + ( 1.- zintp ) * snwice_mass_b(:,:)  ) * zgrau0r
141            DO jj = 2, jpjm1
142               DO ji = fs_2, fs_jpim1   ! vector opt.
143                  spgu(ji,jj) = spgu(ji,jj) + ( zpice(ji+1,jj) - zpice(ji,jj) ) * r1_e1u(ji,jj)
144                  spgv(ji,jj) = spgv(ji,jj) + ( zpice(ji,jj+1) - zpice(ji,jj) ) * r1_e2v(ji,jj)
145               END DO
146            END DO
147            DEALLOCATE( zpice )         
148         ENDIF
149         !
150         DO jk = 1, jpkm1                    !== Add all terms to the general trend
151            DO jj = 2, jpjm1
152               DO ji = fs_2, fs_jpim1   ! vector opt.
153                  ua(ji,jj,jk) = ua(ji,jj,jk) + spgu(ji,jj)
154                  va(ji,jj,jk) = va(ji,jj,jk) + spgv(ji,jj)
155               END DO
156            END DO
157         END DO   
158         !
159!!gm add here a call to dyn_trd for ice pressure gradient, the surf pressure trends ????
160         !   
161      ENDIF
162      !
163      SELECT CASE ( nspg )                   !== surface pressure gradient computed and add to the general trend ==!
164      CASE ( np_EXP )   ;   CALL dyn_spg_exp( kt )              ! explicit
165      CASE ( np_TS  )   ;   CALL dyn_spg_ts ( kt )              ! time-splitting
166      END SELECT
167      !                   
168      IF( l_trddyn )   THEN                  ! save the surface pressure gradient trends for further diagnostics
169         ztrdu(:,:,:) = ua(:,:,:) - ztrdu(:,:,:)
170         ztrdv(:,:,:) = va(:,:,:) - ztrdv(:,:,:)
171         CALL trd_dyn( ztrdu, ztrdv, jpdyn_spg, kt )
172         DEALLOCATE( ztrdu , ztrdv ) 
173      ENDIF
174      !                                      ! print mean trends (used for debugging)
175      IF(ln_ctl)   CALL prt_ctl( tab3d_1=ua, clinfo1=' spg  - Ua: ', mask1=umask, &
176         &                       tab3d_2=va, clinfo2=       ' Va: ', mask2=vmask, clinfo3='dyn' )
177      !
178      IF( ln_timing )   CALL timing_stop('dyn_spg')
179      !
180   END SUBROUTINE dyn_spg
181
182
183   SUBROUTINE dyn_spg_init
184      !!---------------------------------------------------------------------
185      !!                  ***  ROUTINE dyn_spg_init  ***
186      !!               
187      !! ** Purpose :   Control the consistency between namelist options for
188      !!              surface pressure gradient schemes
189      !!----------------------------------------------------------------------
190      INTEGER ::   ioptio, ios   ! local integers
191      !
192      NAMELIST/namdyn_spg/ ln_dynspg_exp       , ln_dynspg_ts,   &
193      &                    ln_bt_fw, ln_bt_av  , ln_bt_auto  ,   &
194      &                    nn_baro , rn_bt_cmax, nn_bt_flt, rn_bt_alpha
195      !!----------------------------------------------------------------------
196      !
197      IF(lwp) THEN
198         WRITE(numout,*)
199         WRITE(numout,*) 'dyn_spg_init : choice of the surface pressure gradient scheme'
200         WRITE(numout,*) '~~~~~~~~~~~~'
201      ENDIF
202      !
203      REWIND( numnam_ref )              ! Namelist namdyn_spg in reference namelist : Free surface
204      READ  ( numnam_ref, namdyn_spg, IOSTAT = ios, ERR = 901)
205901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namdyn_spg in reference namelist', lwp )
206      !
207      REWIND( numnam_cfg )              ! Namelist namdyn_spg in configuration namelist : Free surface
208      READ  ( numnam_cfg, namdyn_spg, IOSTAT = ios, ERR = 902 )
209902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namdyn_spg in configuration namelist', lwp )
210      IF(lwm) WRITE ( numond, namdyn_spg )
211      !
212      IF(lwp) THEN             ! Namelist print
213         WRITE(numout,*) '   Namelist : namdyn_spg                    '
214         WRITE(numout,*) '      Explicit free surface                  ln_dynspg_exp = ', ln_dynspg_exp
215         WRITE(numout,*) '      Free surface with time splitting       ln_dynspg_ts  = ', ln_dynspg_ts
216      ENDIF
217      !                          ! Control of surface pressure gradient scheme options
218                                     nspg =  np_NO    ;   ioptio = 0
219      IF( ln_dynspg_exp ) THEN   ;   nspg =  np_EXP   ;   ioptio = ioptio + 1   ;   ENDIF
220      IF( ln_dynspg_ts  ) THEN   ;   nspg =  np_TS    ;   ioptio = ioptio + 1   ;   ENDIF
221      !
222      IF( ioptio  > 1 )   CALL ctl_stop( 'Choose only one surface pressure gradient scheme' )
223      IF( ioptio == 0 )   CALL ctl_warn( 'NO surface pressure gradient trend in momentum Eqs.' )
224      IF( ln_dynspg_exp .AND. ln_isfcav )   &
225           &   CALL ctl_stop( ' dynspg_exp not tested with ice shelf cavity ' )
226      !
227      IF(lwp) THEN
228         WRITE(numout,*)
229         IF( nspg == np_EXP )   WRITE(numout,*) '   ==>>>   explicit free surface'
230         IF( nspg == np_TS  )   WRITE(numout,*) '   ==>>>   free surface with time splitting scheme'
231         IF( nspg == np_NO  )   WRITE(numout,*) '   ==>>>   No surface surface pressure gradient trend in momentum Eqs.'
232      ENDIF
233      !
234      IF( nspg == np_TS ) THEN   ! split-explicit scheme initialisation
235         CALL dyn_spg_ts_init          ! do it first: set nn_baro used to allocate some arrays later on
236      ENDIF
237      !
238   END SUBROUTINE dyn_spg_init
239
240  !!======================================================================
241END MODULE dynspg
Note: See TracBrowser for help on using the repository browser.