New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
tide_mod.F90 in NEMO/branches/2019/dev_r10742_ENHANCE-12_SimonM-Tides/src/OCE/TDE – NEMO

source: NEMO/branches/2019/dev_r10742_ENHANCE-12_SimonM-Tides/src/OCE/TDE/tide_mod.F90 @ 10777

Last change on this file since 10777 was 10777, checked in by smueller, 3 years ago

Removal of module updtide and inclusion of its contents into module tide_mod (ticket #2194)

  • Property svn:keywords set to Id
File size: 26.6 KB
Line 
1MODULE tide_mod
2   !!======================================================================
3   !!                       ***  MODULE  tide_mod  ***
4   !! Compute nodal modulations corrections and pulsations
5   !!======================================================================
6   !! History :  1.0  !  2007  (O. Le Galloudec)  Original code
7   !!----------------------------------------------------------------------
8   USE oce            ! ocean dynamics and tracers variables
9   USE dom_oce        ! ocean space and time domain
10   USE phycst         ! physical constant
11   USE daymod         ! calendar
12   !
13   USE in_out_manager ! I/O units
14   USE iom            ! xIOs server
15   USE ioipsl         ! NetCDF IPSL library
16   USE lbclnk         ! ocean lateral boundary conditions (or mpp link)
17
18   IMPLICIT NONE
19   PRIVATE
20
21   PUBLIC   tide_init
22   PUBLIC   tide_harmo       ! called by tideini and diaharm modules
23   PUBLIC   tide_init_Wave   ! called by tideini and diaharm modules
24   PUBLIC   tide_init_load
25   PUBLIC   tide_init_potential
26   PUBLIC   upd_tide         ! called in dynspg_... modules
27
28   INTEGER, PUBLIC, PARAMETER ::   jpmax_harmo = 19   !: maximum number of harmonic
29
30   TYPE, PUBLIC ::    tide
31      CHARACTER(LEN=4) ::   cname_tide
32      REAL(wp)         ::   equitide
33      INTEGER          ::   nutide
34      INTEGER          ::   nt, ns, nh, np, np1, shift
35      INTEGER          ::   nksi, nnu0, nnu1, nnu2, R
36      INTEGER          ::   nformula
37   END TYPE tide
38
39   TYPE(tide), PUBLIC, DIMENSION(jpmax_harmo) ::   Wave   !:
40
41   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:) ::   omega_tide   !:
42   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:) ::   v0tide       !:
43   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:) ::   utide        !:
44   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:) ::   ftide        !:
45
46   LOGICAL , PUBLIC ::   ln_tide         !:
47   LOGICAL , PUBLIC ::   ln_tide_pot     !:
48   LOGICAL , PUBLIC ::   ln_read_load    !:
49   LOGICAL , PUBLIC ::   ln_scal_load    !:
50   LOGICAL , PUBLIC ::   ln_tide_ramp    !:
51   INTEGER , PUBLIC ::   nb_harmo        !:
52   INTEGER , PUBLIC ::   kt_tide         !:
53   REAL(wp), PUBLIC ::   rdttideramp     !:
54   REAL(wp), PUBLIC ::   rn_scal_load    !:
55   CHARACTER(lc), PUBLIC ::   cn_tide_load   !:
56
57   INTEGER , PUBLIC, ALLOCATABLE, DIMENSION(:) ::   ntide   !:
58
59   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:)   ::   pot_astro !: tidal potential
60   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:,:) ::   amp_pot, phi_pot
61   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:,:) ::   amp_load, phi_load
62
63
64   REAL(wp) ::   sh_T, sh_s, sh_h, sh_p, sh_p1             ! astronomic angles
65   REAL(wp) ::   sh_xi, sh_nu, sh_nuprim, sh_nusec, sh_R   !
66   REAL(wp) ::   sh_I, sh_x1ra, sh_N                       !
67
68   !!----------------------------------------------------------------------
69   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
70   !! $Id$
71   !! Software governed by the CeCILL license (see ./LICENSE)
72   !!----------------------------------------------------------------------
73CONTAINS
74
75   SUBROUTINE tide_init
76      !!----------------------------------------------------------------------
77      !!                 ***  ROUTINE tide_init  ***
78      !!----------------------------------------------------------------------     
79      INTEGER  :: ji, jk
80      CHARACTER(LEN=4), DIMENSION(jpmax_harmo) :: clname
81      INTEGER  ::   ios                 ! Local integer output status for namelist read
82      !
83      NAMELIST/nam_tide/ln_tide, ln_tide_pot, ln_scal_load, ln_read_load, cn_tide_load, &
84                  &     ln_tide_ramp, rn_scal_load, rdttideramp, clname
85      !!----------------------------------------------------------------------
86      !
87      ! Read Namelist nam_tide
88      REWIND( numnam_ref )              ! Namelist nam_tide in reference namelist : Tides
89      READ  ( numnam_ref, nam_tide, IOSTAT = ios, ERR = 901)
90901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'nam_tide in reference namelist', lwp )
91      !
92      REWIND( numnam_cfg )              ! Namelist nam_tide in configuration namelist : Tides
93      READ  ( numnam_cfg, nam_tide, IOSTAT = ios, ERR = 902 )
94902   IF( ios >  0 )   CALL ctl_nam ( ios , 'nam_tide in configuration namelist', lwp )
95      IF(lwm) WRITE ( numond, nam_tide )
96      !
97      IF( ln_tide ) THEN
98         IF (lwp) THEN
99            WRITE(numout,*)
100            WRITE(numout,*) 'tide_init : Initialization of the tidal components'
101            WRITE(numout,*) '~~~~~~~~~ '
102            WRITE(numout,*) '   Namelist nam_tide'
103            WRITE(numout,*) '      Use tidal components                       ln_tide      = ', ln_tide
104            WRITE(numout,*) '         Apply astronomical potential            ln_tide_pot  = ', ln_tide_pot
105            WRITE(numout,*) '         Use scalar approx. for load potential   ln_scal_load = ', ln_scal_load
106            WRITE(numout,*) '         Read load potential from file           ln_read_load = ', ln_read_load
107            WRITE(numout,*) '         Apply ramp on tides at startup          ln_tide_ramp = ', ln_tide_ramp
108            WRITE(numout,*) '         Fraction of SSH used in scal. approx.   rn_scal_load = ', rn_scal_load
109            WRITE(numout,*) '         Duration (days) of ramp                 rdttideramp  = ', rdttideramp
110         ENDIF
111      ELSE
112         rn_scal_load = 0._wp 
113
114         IF(lwp) WRITE(numout,*)
115         IF(lwp) WRITE(numout,*) 'tide_init : tidal components not used (ln_tide = F)'
116         IF(lwp) WRITE(numout,*) '~~~~~~~~~ '
117         RETURN
118      ENDIF
119      !
120      CALL tide_init_Wave
121      !
122      nb_harmo=0
123      DO jk = 1, jpmax_harmo
124         DO ji = 1,jpmax_harmo
125            IF( TRIM(clname(jk)) == Wave(ji)%cname_tide )   nb_harmo = nb_harmo + 1
126         END DO
127      END DO
128      !       
129      ! Ensure that tidal components have been set in namelist_cfg
130      IF( nb_harmo == 0 )   CALL ctl_stop( 'tide_init : No tidal components set in nam_tide' )
131      !
132      IF( ln_read_load.AND.(.NOT.ln_tide_pot) ) &
133          &   CALL ctl_stop('ln_read_load requires ln_tide_pot')
134      IF( ln_scal_load.AND.(.NOT.ln_tide_pot) ) &
135          &   CALL ctl_stop('ln_scal_load requires ln_tide_pot')
136      IF( ln_scal_load.AND.ln_read_load ) &
137          &   CALL ctl_stop('Choose between ln_scal_load and ln_read_load')
138      IF( ln_tide_ramp.AND.((nitend-nit000+1)*rdt/rday < rdttideramp) )   &
139         &   CALL ctl_stop('rdttideramp must be lower than run duration')
140      IF( ln_tide_ramp.AND.(rdttideramp<0.) ) &
141         &   CALL ctl_stop('rdttideramp must be positive')
142      !
143      ALLOCATE( ntide(nb_harmo) )
144      DO jk = 1, nb_harmo
145         DO ji = 1, jpmax_harmo
146            IF( TRIM(clname(jk)) == Wave(ji)%cname_tide ) THEN
147               ntide(jk) = ji
148               EXIT
149            ENDIF
150         END DO
151      END DO
152      !
153      ALLOCATE( omega_tide(nb_harmo), v0tide    (nb_harmo),   &
154         &      utide     (nb_harmo), ftide     (nb_harmo)  )
155      kt_tide = nit000
156      !
157      IF (.NOT.ln_scal_load ) rn_scal_load = 0._wp
158      !
159      ALLOCATE( amp_pot(jpi,jpj,nb_harmo),                      &
160           &      phi_pot(jpi,jpj,nb_harmo), pot_astro(jpi,jpj)   )
161      IF( ln_read_load ) THEN
162         ALLOCATE( amp_load(jpi,jpj,nb_harmo), phi_load(jpi,jpj,nb_harmo) )
163      ENDIF
164      !
165   END SUBROUTINE tide_init
166
167
168   SUBROUTINE tide_init_Wave
169#     include "tide.h90"
170   END SUBROUTINE tide_init_Wave
171
172
173   SUBROUTINE tide_init_potential
174      !!----------------------------------------------------------------------
175      !!                 ***  ROUTINE tide_init_potential  ***
176      !!----------------------------------------------------------------------
177      INTEGER  ::   ji, jj, jk   ! dummy loop indices
178      REAL(wp) ::   zcons, ztmp1, ztmp2, zlat, zlon, ztmp, zamp, zcs   ! local scalar
179      !!----------------------------------------------------------------------
180
181      DO jk = 1, nb_harmo
182         zcons = 0.7_wp * Wave(ntide(jk))%equitide * ftide(jk)
183         DO ji = 1, jpi
184            DO jj = 1, jpj
185               ztmp1 =  ftide(jk) * amp_pot(ji,jj,jk) * COS( phi_pot(ji,jj,jk) + v0tide(jk) + utide(jk) )
186               ztmp2 = -ftide(jk) * amp_pot(ji,jj,jk) * SIN( phi_pot(ji,jj,jk) + v0tide(jk) + utide(jk) )
187               zlat = gphit(ji,jj)*rad !! latitude en radian
188               zlon = glamt(ji,jj)*rad !! longitude en radian
189               ztmp = v0tide(jk) + utide(jk) + Wave(ntide(jk))%nutide * zlon
190               ! le potentiel est composé des effets des astres:
191               IF    ( Wave(ntide(jk))%nutide == 1 )  THEN  ;  zcs = zcons * SIN( 2._wp*zlat )
192               ELSEIF( Wave(ntide(jk))%nutide == 2 )  THEN  ;  zcs = zcons * COS( zlat )**2
193               ELSE                                         ;  zcs = 0._wp
194               ENDIF
195               ztmp1 = ztmp1 + zcs * COS( ztmp )
196               ztmp2 = ztmp2 - zcs * SIN( ztmp )
197               zamp = SQRT( ztmp1*ztmp1 + ztmp2*ztmp2 )
198               amp_pot(ji,jj,jk) = zamp
199               phi_pot(ji,jj,jk) = ATAN2( -ztmp2 / MAX( 1.e-10_wp , zamp ) ,   &
200                  &                        ztmp1 / MAX( 1.e-10_wp,  zamp )   )
201            END DO
202         END DO
203      END DO
204      !
205   END SUBROUTINE tide_init_potential
206
207
208   SUBROUTINE tide_init_load
209      !!----------------------------------------------------------------------
210      !!                 ***  ROUTINE tide_init_load  ***
211      !!----------------------------------------------------------------------
212      INTEGER :: inum                 ! Logical unit of input file
213      INTEGER :: ji, jj, itide        ! dummy loop indices
214      REAL(wp), DIMENSION(jpi,jpj) ::   ztr, zti   !: workspace to read in tidal harmonics data
215      !!----------------------------------------------------------------------
216      IF(lwp) THEN
217         WRITE(numout,*)
218         WRITE(numout,*) 'tide_init_load : Initialization of load potential from file'
219         WRITE(numout,*) '~~~~~~~~~~~~~~ '
220      ENDIF
221      !
222      CALL iom_open ( cn_tide_load , inum )
223      !
224      DO itide = 1, nb_harmo
225         CALL iom_get  ( inum, jpdom_data,TRIM(Wave(ntide(itide))%cname_tide)//'_z1', ztr(:,:) )
226         CALL iom_get  ( inum, jpdom_data,TRIM(Wave(ntide(itide))%cname_tide)//'_z2', zti(:,:) )
227         !
228         DO ji=1,jpi
229            DO jj=1,jpj
230               amp_load(ji,jj,itide) =  SQRT( ztr(ji,jj)**2. + zti(ji,jj)**2. )
231               phi_load(ji,jj,itide) = ATAN2(-zti(ji,jj), ztr(ji,jj) )
232            END DO
233         END DO
234         !
235      END DO
236      CALL iom_close( inum )
237      !
238   END SUBROUTINE tide_init_load
239
240
241   SUBROUTINE tide_harmo( pomega, pvt, put , pcor, ktide ,kc)
242      !!----------------------------------------------------------------------
243      !!----------------------------------------------------------------------
244      INTEGER , DIMENSION(kc), INTENT(in ) ::   ktide            ! Indice of tidal constituents
245      INTEGER                , INTENT(in ) ::   kc               ! Total number of tidal constituents
246      REAL(wp), DIMENSION(kc), INTENT(out) ::   pomega           ! pulsation in radians/s
247      REAL(wp), DIMENSION(kc), INTENT(out) ::   pvt, put, pcor   !
248      !!----------------------------------------------------------------------
249      !
250      CALL astronomic_angle
251      CALL tide_pulse( pomega, ktide ,kc )
252      CALL tide_vuf  ( pvt, put, pcor, ktide ,kc )
253      !
254   END SUBROUTINE tide_harmo
255
256
257   SUBROUTINE astronomic_angle
258      !!----------------------------------------------------------------------
259      !!  tj is time elapsed since 1st January 1900, 0 hour, counted in julian
260      !!  century (e.g. time in days divide by 36525)
261      !!----------------------------------------------------------------------
262      REAL(wp) ::   cosI, p, q, t2, t4, sin2I, s2, tgI2, P1, sh_tgn2, at1, at2
263      REAL(wp) ::   zqy , zsy, zday, zdj, zhfrac
264      !!----------------------------------------------------------------------
265      !
266      zqy = AINT( (nyear-1901.)/4. )
267      zsy = nyear - 1900.
268      !
269      zdj  = dayjul( nyear, nmonth, nday )
270      zday = zdj + zqy - 1.
271      !
272      zhfrac = nsec_day / 3600.
273      !
274      !----------------------------------------------------------------------
275      !  Sh_n Longitude of ascending lunar node
276      !----------------------------------------------------------------------
277      sh_N=(259.1560564-19.328185764*zsy-.0529539336*zday-.0022064139*zhfrac)*rad
278      !----------------------------------------------------------------------
279      ! T mean solar angle (Greenwhich time)
280      !----------------------------------------------------------------------
281      sh_T=(180.+zhfrac*(360./24.))*rad
282      !----------------------------------------------------------------------
283      ! h mean solar Longitude
284      !----------------------------------------------------------------------
285      sh_h=(280.1895014-.238724988*zsy+.9856473288*zday+.0410686387*zhfrac)*rad
286      !----------------------------------------------------------------------
287      ! s mean lunar Longitude
288      !----------------------------------------------------------------------
289      sh_s=(277.0256206+129.38482032*zsy+13.176396768*zday+.549016532*zhfrac)*rad
290      !----------------------------------------------------------------------
291      ! p1 Longitude of solar perigee
292      !----------------------------------------------------------------------
293      sh_p1=(281.2208569+.01717836*zsy+.000047064*zday+.000001961*zhfrac)*rad
294      !----------------------------------------------------------------------
295      ! p Longitude of lunar perigee
296      !----------------------------------------------------------------------
297      sh_p=(334.3837214+40.66246584*zsy+.111404016*zday+.004641834*zhfrac)*rad
298
299      sh_N = MOD( sh_N ,2*rpi )
300      sh_s = MOD( sh_s ,2*rpi )
301      sh_h = MOD( sh_h, 2*rpi )
302      sh_p = MOD( sh_p, 2*rpi )
303      sh_p1= MOD( sh_p1,2*rpi )
304
305      cosI = 0.913694997 -0.035692561 *cos(sh_N)
306
307      sh_I = ACOS( cosI )
308
309      sin2I   = sin(sh_I)
310      sh_tgn2 = tan(sh_N/2.0)
311
312      at1=atan(1.01883*sh_tgn2)
313      at2=atan(0.64412*sh_tgn2)
314
315      sh_xi=-at1-at2+sh_N
316
317      IF( sh_N > rpi )   sh_xi=sh_xi-2.0*rpi
318
319      sh_nu = at1 - at2
320
321      !----------------------------------------------------------------------
322      ! For constituents l2 k1 k2
323      !----------------------------------------------------------------------
324
325      tgI2 = tan(sh_I/2.0)
326      P1   = sh_p-sh_xi
327
328      t2 = tgI2*tgI2
329      t4 = t2*t2
330      sh_x1ra = sqrt( 1.0-12.0*t2*cos(2.0*P1)+36.0*t4 )
331
332      p = sin(2.0*P1)
333      q = 1.0/(6.0*t2)-cos(2.0*P1)
334      sh_R = atan(p/q)
335
336      p = sin(2.0*sh_I)*sin(sh_nu)
337      q = sin(2.0*sh_I)*cos(sh_nu)+0.3347
338      sh_nuprim = atan(p/q)
339
340      s2 = sin(sh_I)*sin(sh_I)
341      p  = s2*sin(2.0*sh_nu)
342      q  = s2*cos(2.0*sh_nu)+0.0727
343      sh_nusec = 0.5*atan(p/q)
344      !
345   END SUBROUTINE astronomic_angle
346
347
348   SUBROUTINE tide_pulse( pomega, ktide ,kc )
349      !!----------------------------------------------------------------------
350      !!                     ***  ROUTINE tide_pulse  ***
351      !!                     
352      !! ** Purpose : Compute tidal frequencies
353      !!----------------------------------------------------------------------
354      INTEGER                , INTENT(in ) ::   kc       ! Total number of tidal constituents
355      INTEGER , DIMENSION(kc), INTENT(in ) ::   ktide    ! Indice of tidal constituents
356      REAL(wp), DIMENSION(kc), INTENT(out) ::   pomega   ! pulsation in radians/s
357      !
358      INTEGER  ::   jh
359      REAL(wp) ::   zscale
360      REAL(wp) ::   zomega_T =  13149000.0_wp
361      REAL(wp) ::   zomega_s =    481267.892_wp
362      REAL(wp) ::   zomega_h =     36000.76892_wp
363      REAL(wp) ::   zomega_p =      4069.0322056_wp
364      REAL(wp) ::   zomega_n =      1934.1423972_wp
365      REAL(wp) ::   zomega_p1=         1.719175_wp
366      !!----------------------------------------------------------------------
367      !
368      zscale =  rad / ( 36525._wp * 86400._wp ) 
369      !
370      DO jh = 1, kc
371         pomega(jh) = (  zomega_T * Wave( ktide(jh) )%nT   &
372            &          + zomega_s * Wave( ktide(jh) )%ns   &
373            &          + zomega_h * Wave( ktide(jh) )%nh   &
374            &          + zomega_p * Wave( ktide(jh) )%np   &
375            &          + zomega_p1* Wave( ktide(jh) )%np1  ) * zscale
376      END DO
377      !
378   END SUBROUTINE tide_pulse
379
380
381   SUBROUTINE tide_vuf( pvt, put, pcor, ktide ,kc )
382      !!----------------------------------------------------------------------
383      !!                     ***  ROUTINE tide_vuf  ***
384      !!                     
385      !! ** Purpose : Compute nodal modulation corrections
386      !!
387      !! ** Outputs : vt: Phase of tidal potential relative to Greenwich (radians)
388      !!              ut: Phase correction u due to nodal motion (radians)
389      !!              ft: Nodal correction factor
390      !!----------------------------------------------------------------------
391      INTEGER                , INTENT(in ) ::   kc               ! Total number of tidal constituents
392      INTEGER , DIMENSION(kc), INTENT(in ) ::   ktide            ! Indice of tidal constituents
393      REAL(wp), DIMENSION(kc), INTENT(out) ::   pvt, put, pcor   !
394      !
395      INTEGER ::   jh   ! dummy loop index
396      !!----------------------------------------------------------------------
397      !
398      DO jh = 1, kc
399         !  Phase of the tidal potential relative to the Greenwhich
400         !  meridian (e.g. the position of the fictuous celestial body). Units are radian:
401         pvt(jh) = sh_T * Wave( ktide(jh) )%nT    &
402            &    + sh_s * Wave( ktide(jh) )%ns    &
403            &    + sh_h * Wave( ktide(jh) )%nh    &
404            &    + sh_p * Wave( ktide(jh) )%np    &
405            &    + sh_p1* Wave( ktide(jh) )%np1   &
406            &    +        Wave( ktide(jh) )%shift * rad
407         !
408         !  Phase correction u due to nodal motion. Units are radian:
409         put(jh) = sh_xi     * Wave( ktide(jh) )%nksi   &
410            &    + sh_nu     * Wave( ktide(jh) )%nnu0   &
411            &    + sh_nuprim * Wave( ktide(jh) )%nnu1   &
412            &    + sh_nusec  * Wave( ktide(jh) )%nnu2   &
413            &    + sh_R      * Wave( ktide(jh) )%R
414
415         !  Nodal correction factor:
416         pcor(jh) = nodal_factort( Wave( ktide(jh) )%nformula )
417      END DO
418      !
419   END SUBROUTINE tide_vuf
420
421
422   RECURSIVE FUNCTION nodal_factort( kformula ) RESULT( zf )
423      !!----------------------------------------------------------------------
424      !!----------------------------------------------------------------------
425      INTEGER, INTENT(in) :: kformula
426      !
427      REAL(wp) :: zf
428      REAL(wp) :: zs, zf1, zf2
429      !!----------------------------------------------------------------------
430      !
431      SELECT CASE( kformula )
432      !
433      CASE( 0 )                  !==  formule 0, solar waves
434         zf = 1.0
435         !
436      CASE( 1 )                  !==  formule 1, compound waves (78 x 78)
437         zf=nodal_factort(78)
438         zf = zf * zf
439         !
440      CASE ( 2 )                 !==  formule 2, compound waves (78 x 0)  ===  (78)
441       zf1= nodal_factort(78)
442       zf = nodal_factort( 0)
443       zf = zf1 * zf
444       !
445      CASE ( 4 )                 !==  formule 4,  compound waves (78 x 235)
446         zf1 = nodal_factort( 78)
447         zf  = nodal_factort(235)
448         zf  = zf1 * zf
449         !
450      CASE ( 5 )                 !==  formule 5,  compound waves (78 *78 x 235)
451         zf1 = nodal_factort( 78)
452         zf  = nodal_factort(235)
453         zf  = zf * zf1 * zf1
454         !
455      CASE ( 6 )                 !==  formule 6,  compound waves (78 *78 x 0)
456         zf1 = nodal_factort(78)
457         zf  = nodal_factort( 0)
458         zf  = zf * zf1 * zf1 
459         !
460      CASE( 7 )                  !==  formule 7, compound waves (75 x 75)
461         zf = nodal_factort(75)
462         zf = zf * zf
463         !
464      CASE( 8 )                  !==  formule 8,  compound waves (78 x 0 x 235)
465         zf  = nodal_factort( 78)
466         zf1 = nodal_factort(  0)
467         zf2 = nodal_factort(235)
468         zf  = zf * zf1 * zf2
469         !
470      CASE( 9 )                  !==  formule 9,  compound waves (78 x 0 x 227)
471         zf  = nodal_factort( 78)
472         zf1 = nodal_factort(  0)
473         zf2 = nodal_factort(227)
474         zf  = zf * zf1 * zf2
475         !
476      CASE( 10 )                 !==  formule 10,  compound waves (78 x 227)
477         zf  = nodal_factort( 78)
478         zf1 = nodal_factort(227)
479         zf  = zf * zf1
480         !
481      CASE( 11 )                 !==  formule 11,  compound waves (75 x 0)
482!!gm bug???? zf 2 fois !
483         zf = nodal_factort(75)
484         zf1 = nodal_factort( 0)
485         zf = zf * zf1
486         !
487      CASE( 12 )                 !==  formule 12,  compound waves (78 x 78 x 78 x 0)
488         zf1 = nodal_factort(78)
489         zf  = nodal_factort( 0)
490         zf  = zf * zf1 * zf1 * zf1
491         !
492      CASE( 13 )                 !==  formule 13, compound waves (78 x 75)
493         zf1 = nodal_factort(78)
494         zf  = nodal_factort(75)
495         zf  = zf * zf1
496         !
497      CASE( 14 )                 !==  formule 14, compound waves (235 x 0)  ===  (235)
498         zf  = nodal_factort(235)
499         zf1 = nodal_factort(  0)
500         zf  = zf * zf1
501         !
502      CASE( 15 )                 !==  formule 15, compound waves (235 x 75)
503         zf  = nodal_factort(235)
504         zf1 = nodal_factort( 75)
505         zf  = zf * zf1
506         !
507      CASE( 16 )                 !==  formule 16, compound waves (78 x 0 x 0)  ===  (78)
508         zf  = nodal_factort(78)
509         zf1 = nodal_factort( 0)
510         zf  = zf * zf1 * zf1
511         !
512      CASE( 17 )                 !==  formule 17,  compound waves (227 x 0)
513         zf1 = nodal_factort(227)
514         zf  = nodal_factort(  0)
515         zf  = zf * zf1
516         !
517      CASE( 18 )                 !==  formule 18,  compound waves (78 x 78 x 78 )
518         zf1 = nodal_factort(78)
519         zf  = zf1 * zf1 * zf1
520         !
521      CASE( 19 )                 !==  formule 19, compound waves (78 x 0 x 0 x 0)  ===  (78)
522!!gm bug2 ==>>>   here identical to formule 16,  a third multiplication by zf1 is missing
523         zf  = nodal_factort(78)
524         zf1 = nodal_factort( 0)
525         zf = zf * zf1 * zf1
526         !
527      CASE( 73 )                 !==  formule 73
528         zs = sin(sh_I)
529         zf = (2./3.-zs*zs)/0.5021
530         !
531      CASE( 74 )                 !==  formule 74
532         zs = sin(sh_I)
533         zf = zs * zs / 0.1578
534         !
535      CASE( 75 )                 !==  formule 75
536         zs = cos(sh_I/2)
537         zf = sin(sh_I) * zs * zs / 0.3800
538         !
539      CASE( 76 )                 !==  formule 76
540         zf = sin(2*sh_I) / 0.7214
541         !
542      CASE( 77 )                 !==  formule 77
543         zs = sin(sh_I/2)
544         zf = sin(sh_I) * zs * zs / 0.0164
545         !
546      CASE( 78 )                 !==  formule 78
547         zs = cos(sh_I/2)
548         zf = zs * zs * zs * zs / 0.9154
549         !
550      CASE( 79 )                 !==  formule 79
551         zs = sin(sh_I)
552         zf = zs * zs / 0.1565
553         !
554      CASE( 144 )                !==  formule 144
555         zs = sin(sh_I/2)
556         zf = ( 1-10*zs*zs+15*zs*zs*zs*zs ) * cos(sh_I/2) / 0.5873
557         !
558      CASE( 149 )                !==  formule 149
559         zs = cos(sh_I/2)
560         zf = zs*zs*zs*zs*zs*zs / 0.8758
561         !
562      CASE( 215 )                !==  formule 215
563         zs = cos(sh_I/2)
564         zf = zs*zs*zs*zs / 0.9154 * sh_x1ra
565         !
566      CASE( 227 )                !==  formule 227
567         zs = sin(2*sh_I)
568         zf = sqrt( 0.8965*zs*zs+0.6001*zs*cos (sh_nu)+0.1006 )
569         !
570      CASE ( 235 )               !==  formule 235
571         zs = sin(sh_I)
572         zf = sqrt( 19.0444*zs*zs*zs*zs + 2.7702*zs*zs*cos(2*sh_nu) + .0981 )
573         !
574      END SELECT
575      !
576   END FUNCTION nodal_factort
577
578
579   FUNCTION dayjul( kyr, kmonth, kday )
580      !!----------------------------------------------------------------------
581      !!  *** THIS ROUTINE COMPUTES THE JULIAN DAY (AS A REAL VARIABLE)
582      !!----------------------------------------------------------------------
583      INTEGER,INTENT(in) ::   kyr, kmonth, kday
584      !
585      INTEGER,DIMENSION(12) ::  idayt, idays
586      INTEGER  ::   inc, ji
587      REAL(wp) ::   dayjul, zyq
588      !
589      DATA idayt/0.,31.,59.,90.,120.,151.,181.,212.,243.,273.,304.,334./
590      !!----------------------------------------------------------------------
591      !
592      idays(1) = 0.
593      idays(2) = 31.
594      inc = 0.
595      zyq = MOD( kyr-1900. , 4. )
596      IF( zyq == 0.)   inc = 1.
597      DO ji = 3, 12
598         idays(ji)=idayt(ji)+inc
599      END DO
600      dayjul = idays(kmonth) + kday
601      !
602   END FUNCTION dayjul
603
604
605   SUBROUTINE upd_tide( kt, kit, time_offset )
606      !!----------------------------------------------------------------------
607      !!                 ***  ROUTINE upd_tide  ***
608      !!
609      !! ** Purpose :   provide at each time step the astronomical potential
610      !!
611      !! ** Method  :   computed from pulsation and amplitude of all tide components
612      !!
613      !! ** Action  :   pot_astro   actronomical potential
614      !!----------------------------------------------------------------------     
615      INTEGER, INTENT(in)           ::   kt      ! ocean time-step index
616      INTEGER, INTENT(in), OPTIONAL ::   kit     ! external mode sub-time-step index (lk_dynspg_ts=T)
617      INTEGER, INTENT(in), OPTIONAL ::   time_offset ! time offset in number
618                                                     ! of internal steps             (lk_dynspg_ts=F)
619                                                     ! of external steps             (lk_dynspg_ts=T)
620      !
621      INTEGER  ::   joffset      ! local integer
622      INTEGER  ::   ji, jj, jk   ! dummy loop indices
623      REAL(wp) ::   zt, zramp    ! local scalar
624      REAL(wp), DIMENSION(nb_harmo) ::   zwt 
625      !!----------------------------------------------------------------------     
626      !
627      !                               ! tide pulsation at model time step (or sub-time-step)
628      zt = ( kt - kt_tide ) * rdt
629      !
630      joffset = 0
631      IF( PRESENT( time_offset ) )   joffset = time_offset
632      !
633      IF( PRESENT( kit ) )   THEN
634         zt = zt + ( kit +  joffset - 1 ) * rdt / REAL( nn_baro, wp )
635      ELSE
636         zt = zt + joffset * rdt
637      ENDIF
638      !
639      zwt(:) = omega_tide(:) * zt
640
641      pot_astro(:,:) = 0._wp          ! update tidal potential (sum of all harmonics)
642      DO jk = 1, nb_harmo   
643         pot_astro(:,:) = pot_astro(:,:) + amp_pot(:,:,jk) * COS( zwt(jk) + phi_pot(:,:,jk) )     
644      END DO
645      !
646      IF( ln_tide_ramp ) THEN         ! linear increase if asked
647         zt = ( kt - nit000 ) * rdt
648         IF( PRESENT( kit ) )   zt = zt + ( kit + joffset -1) * rdt / REAL( nn_baro, wp )
649         zramp = MIN(  MAX( zt / (rdttideramp*rday) , 0._wp ) , 1._wp  )
650         pot_astro(:,:) = zramp * pot_astro(:,:)
651      ENDIF
652      !
653   END SUBROUTINE upd_tide
654
655   !!======================================================================
656END MODULE tide_mod
Note: See TracBrowser for help on using the repository browser.