source: NEMO/branches/2019/dev_r10984_HPC-13_IRRMANN_BDY_optimization/src/OCE/BDY/bdytra.F90 @ 11067

Last change on this file since 11067 was 11067, checked in by girrmann, 2 years ago

dev_r10984_HPC-13 : new implementation of lbc_bdy_lnk in prevision of step 2, regroup communications, see #2285

  • Property svn:keywords set to Id
File size: 8.1 KB
Line 
1MODULE bdytra
2   !!======================================================================
3   !!                       ***  MODULE  bdytra  ***
4   !! Ocean tracers:   Apply boundary conditions for tracers
5   !!======================================================================
6   !! History :  1.0  !  2005-01  (J. Chanut, A. Sellar)  Original code
7   !!            3.0  !  2008-04  (NEMO team)  add in the reference version
8   !!            3.4  !  2011     (D. Storkey) rewrite in preparation for OBC-BDY merge
9   !!            3.5  !  2012     (S. Mocavero, I. Epicoco) Optimization of BDY communications
10   !!            4.0  !  2016     (T. Lovato) Generalize OBC structure
11   !!----------------------------------------------------------------------
12   !!   bdy_tra       : Apply open boundary conditions & damping to T and S
13   !!----------------------------------------------------------------------
14   USE oce            ! ocean dynamics and tracers variables
15   USE dom_oce        ! ocean space and time domain variables
16   USE bdy_oce        ! ocean open boundary conditions
17   USE bdylib         ! for orlanski library routines
18   !
19   USE in_out_manager ! I/O manager
20   USE lbclnk         ! ocean lateral boundary conditions (or mpp link)
21   USE lib_mpp, ONLY: ctl_stop
22   USE timing         ! Timing
23
24   IMPLICIT NONE
25   PRIVATE
26
27   ! Local structure to rearrange tracers data
28   TYPE, PUBLIC ::   ztrabdy
29      REAL(wp), POINTER, DIMENSION(:,:) ::  tra
30   END TYPE
31
32   PUBLIC   bdy_tra      ! called in tranxt.F90
33   PUBLIC   bdy_tra_dmp  ! called in step.F90
34
35   !!----------------------------------------------------------------------
36   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
37   !! $Id$
38   !! Software governed by the CeCILL license (see ./LICENSE)
39   !!----------------------------------------------------------------------
40CONTAINS
41
42   SUBROUTINE bdy_tra( kt )
43      !!----------------------------------------------------------------------
44      !!                  ***  SUBROUTINE bdy_tra  ***
45      !!
46      !! ** Purpose : - Apply open boundary conditions for temperature and salinity
47      !!
48      !!----------------------------------------------------------------------
49      INTEGER, INTENT(in) ::   kt   ! Main time step counter
50      !
51      INTEGER                        :: ib_bdy, jn, igrd   ! Loop indeces
52      TYPE(ztrabdy), DIMENSION(jpts) :: zdta               ! Temporary data structure
53      LOGICAL, DIMENSION(4)          :: lsend1, lrecv1     ! indicate how communications are to be carried out
54      !!----------------------------------------------------------------------
55      igrd = 1 
56
57      DO ib_bdy=1, nb_bdy
58         !
59         zdta(1)%tra => dta_bdy(ib_bdy)%tem
60         zdta(2)%tra => dta_bdy(ib_bdy)%sal
61         !
62         DO jn = 1, jpts
63            !
64            SELECT CASE( TRIM(cn_tra(ib_bdy)) )
65            CASE('none'        )   ;   CYCLE
66            CASE('frs'         )   ;   CALL bdy_frs ( idx_bdy(ib_bdy),                tsa(:,:,:,jn), zdta(jn)%tra )
67            CASE('specified'   )   ;   CALL bdy_spe ( idx_bdy(ib_bdy),                tsa(:,:,:,jn), zdta(jn)%tra )
68            CASE('neumann'     )   ;   CALL bdy_nmn ( idx_bdy(ib_bdy), igrd         , tsa(:,:,:,jn)               )   ! tsa masked
69            CASE('orlanski'    )   ;   CALL bdy_orl ( idx_bdy(ib_bdy), tsb(:,:,:,jn), tsa(:,:,:,jn), zdta(jn)%tra, ll_npo=.false. )
70            CASE('orlanski_npo')   ;   CALL bdy_orl ( idx_bdy(ib_bdy), tsb(:,:,:,jn), tsa(:,:,:,jn), zdta(jn)%tra, ll_npo=.true. )
71            CASE('runoff'      )   ;   CALL bdy_rnf ( idx_bdy(ib_bdy),                tsa(:,:,:,jn),               jn )
72            CASE DEFAULT           ;   CALL ctl_stop( 'bdy_tra : unrecognised option for open boundaries for T and S' )
73            END SELECT
74            !
75         END DO
76      END DO
77      !
78      lsend1(:) = .false.
79      lrecv1(:) = .false.
80      DO ib_bdy=1, nb_bdy
81         SELECT CASE( TRIM(cn_tra(ib_bdy)) )
82         CASE('neumann')
83            lsend1(:) = lsend1(:) .OR. lsend_bdy(ib_bdy,1,:)   ! to   every bdy neighbour, T points
84            lrecv1(:) = lrecv1(:) .OR. lrecv_bdy(ib_bdy,1,:)   ! from every bdy neighbour, T points
85         CASE('orlanski')
86            lsend1(:) = lsend1(:) .OR. lsend_bdy(ib_bdy,1,:)   ! to   every bdy neighbour, T points
87            lrecv1(:) = lrecv1(:) .OR. lrecv_bdy(ib_bdy,1,:)   ! from every bdy neighbour, T points
88         CASE('orlanski_npo')
89            lsend1(:) = lsend1(:) .OR. lsend_bdy(ib_bdy,1,:)   ! to   every bdy neighbour, T points
90            lrecv1(:) = lrecv1(:) .OR. lrecv_bdy(ib_bdy,1,:)   ! from every bdy neighbour, T points
91         CASE('runoff')
92            lsend1(:) = lsend1(:) .OR. lsend_bdy(ib_bdy,1,:)   ! to   every bdy neighbour, T points
93            lrecv1(:) = lrecv1(:) .OR. lrecv_bdy(ib_bdy,1,:)   ! from every bdy neighbour, T points
94         END SELECT
95      END DO
96      IF( ANY(lsend1) .OR. ANY(lrecv1) ) THEN   ! if need to send/recv in at least one direction
97         CALL lbc_bdy_lnk( 'bdytra', lsend1, lrecv1, tsa, 'T',  1. )
98      END IF
99      !
100   END SUBROUTINE bdy_tra
101
102
103   SUBROUTINE bdy_rnf( idx, pta, jpa )
104      !!----------------------------------------------------------------------
105      !!                 ***  SUBROUTINE bdy_rnf  ***
106      !!                   
107      !! ** Purpose : Specialized routine to apply TRA runoff values at OBs:
108      !!                  - duplicate the neighbour value for the temperature
109      !!                  - specified to 0.1 PSU for the salinity
110      !!
111      !!----------------------------------------------------------------------
112      TYPE(OBC_INDEX),                     INTENT(in) ::   idx  ! OBC indices
113      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(inout) ::   pta  ! tracer trend
114      INTEGER,                             INTENT(in) ::   jpa  ! TRA index
115      !
116      INTEGER  ::   ib, ii, ij, igrd   ! dummy loop indices
117      INTEGER  ::   ik, ip, jp ! 2D addresses
118      !!----------------------------------------------------------------------
119      !
120      igrd = 1                       ! Everything is at T-points here
121      IF(      jpa == jp_tem )   THEN
122         CALL bdy_nmn( idx, igrd, pta )
123      ELSE IF( jpa == jp_sal )   THEN
124         DO ib = 1, idx%nblenrim(igrd)
125            ii = idx%nbi(ib,igrd)
126            ij = idx%nbj(ib,igrd)
127            pta(ii,ij,1:jpkm1) = 0.1 * tmask(ii,ij,1:jpkm1)
128         END DO
129      END IF
130      !
131   END SUBROUTINE bdy_rnf
132
133
134   SUBROUTINE bdy_tra_dmp( kt )
135      !!----------------------------------------------------------------------
136      !!                 ***  SUBROUTINE bdy_tra_dmp  ***
137      !!                   
138      !! ** Purpose : Apply damping for tracers at open boundaries.
139      !!
140      !!----------------------------------------------------------------------
141      INTEGER, INTENT(in) ::   kt   !
142      !
143      REAL(wp) ::   zwgt           ! boundary weight
144      REAL(wp) ::   zta, zsa, ztime
145      INTEGER  ::   ib, ik, igrd   ! dummy loop indices
146      INTEGER  ::   ii, ij         ! 2D addresses
147      INTEGER  ::   ib_bdy         ! Loop index
148      !!----------------------------------------------------------------------
149      !
150      IF( ln_timing )   CALL timing_start('bdy_tra_dmp')
151      !
152      DO ib_bdy = 1, nb_bdy
153         IF( ln_tra_dmp(ib_bdy) ) THEN
154            igrd = 1                       ! Everything is at T-points here
155            DO ib = 1, idx_bdy(ib_bdy)%nblen(igrd)
156               ii = idx_bdy(ib_bdy)%nbi(ib,igrd)
157               ij = idx_bdy(ib_bdy)%nbj(ib,igrd)
158               zwgt = idx_bdy(ib_bdy)%nbd(ib,igrd)
159               DO ik = 1, jpkm1
160                  zta = zwgt * ( dta_bdy(ib_bdy)%tem(ib,ik) - tsb(ii,ij,ik,jp_tem) ) * tmask(ii,ij,ik)
161                  zsa = zwgt * ( dta_bdy(ib_bdy)%sal(ib,ik) - tsb(ii,ij,ik,jp_sal) ) * tmask(ii,ij,ik)
162                  tsa(ii,ij,ik,jp_tem) = tsa(ii,ij,ik,jp_tem) + zta
163                  tsa(ii,ij,ik,jp_sal) = tsa(ii,ij,ik,jp_sal) + zsa
164               END DO
165            END DO
166         ENDIF
167      END DO
168      !
169      IF( ln_timing )   CALL timing_stop('bdy_tra_dmp')
170      !
171   END SUBROUTINE bdy_tra_dmp
172 
173   !!======================================================================
174END MODULE bdytra
Note: See TracBrowser for help on using the repository browser.