source: NEMO/branches/2019/dev_r10984_HPC-13_IRRMANN_DYN_optimization/src/ICE/icecor.F90 @ 11381

Last change on this file since 11381 was 11381, checked in by girrmann, 2 years ago

dev_r10984_HPC-13 : repair faulty commit [11380], see #2308

  • Property svn:keywords set to Id
File size: 10.1 KB
Line 
1MODULE icecor
2   !!======================================================================
3   !!                     ***  MODULE  icecor  ***
4   !!   sea-ice: Corrections on sea-ice variables at the end of the time step
5   !!======================================================================
6   !! History :  3.0  !  2006-04  (M. Vancoppenolle) Original code
7   !!            3.5  !  2014-06  (C. Rousset)       Complete rewriting/cleaning
8   !!            4.0  !  2018     (many people)      SI3 [aka Sea Ice cube]
9   !!----------------------------------------------------------------------
10#if defined key_si3
11   !!----------------------------------------------------------------------
12   !!   'key_si3'                                       SI3 sea-ice model
13   !!----------------------------------------------------------------------
14   !!    ice_cor      : corrections on sea-ice variables
15   !!----------------------------------------------------------------------
16   USE dom_oce        ! ocean domain
17   USE phycst         ! physical constants
18   USE ice            ! sea-ice: variable
19   USE ice1D          ! sea-ice: thermodynamic sea-ice variables
20   USE iceitd         ! sea-ice: rebining
21   USE icevar         ! sea-ice: operations
22   USE icectl         ! sea-ice: control prints
23   !
24   USE in_out_manager ! I/O manager
25   USE iom            ! I/O manager library
26   USE lib_mpp        ! MPP library
27   USE lib_fortran    ! fortran utilities (glob_sum + no signed zero)
28   USE lbclnk         ! lateral boundary conditions (or mpp links)
29   USE timing         ! Timing
30
31   IMPLICIT NONE
32   PRIVATE
33
34   PUBLIC   ice_cor   ! called by icestp.F90
35
36   !! * Substitutions
37#  include "vectopt_loop_substitute.h90"
38   !!----------------------------------------------------------------------
39   !! NEMO/ICE 4.0 , NEMO Consortium (2018)
40   !! $Id$
41   !! Software governed by the CeCILL license (see ./LICENSE)
42   !!----------------------------------------------------------------------
43CONTAINS
44
45   SUBROUTINE ice_cor( kt, kn )
46      !!----------------------------------------------------------------------
47      !!               ***  ROUTINE ice_cor  ***
48      !!               
49      !! ** Purpose :   Computes corrections on sea-ice global variables at
50      !!              the end of the dynamics (kn=1) and thermodynamics (kn=2)
51      !!----------------------------------------------------------------------
52      INTEGER, INTENT(in) ::   kt    ! number of iteration
53      INTEGER, INTENT(in) ::   kn    ! 1 = after dyn ; 2 = after thermo
54      !
55      INTEGER  ::   ji, jj, jk, jl   ! dummy loop indices
56      REAL(wp) ::   zsal, zzc
57      REAL(wp), DIMENSION(jpi,jpj) ::   zafx   ! concentration trends diag
58      !!----------------------------------------------------------------------
59      ! controls
60      IF( ln_timing    )   CALL timing_start('icecor')                                                             ! timing
61      IF( ln_icediachk )   CALL ice_cons_hsm(0, 'icecor', rdiag_v, rdiag_s, rdiag_t, rdiag_fv, rdiag_fs, rdiag_ft) ! conservation
62      !
63      IF( kt == nit000 .AND. lwp .AND. kn == 2 ) THEN
64         WRITE(numout,*)
65         WRITE(numout,*) 'ice_cor:  correct sea ice variables if out of bounds ' 
66         WRITE(numout,*) '~~~~~~~'
67      ENDIF
68      !                             !-----------------------------------------------------
69      !                             !  ice thickness must exceed himin (for temp. diff.) !
70      !                             !-----------------------------------------------------
71      WHERE( a_i(:,:,:) >= epsi20 )   ;   h_i(:,:,:) = v_i(:,:,:) / a_i(:,:,:)
72      ELSEWHERE                       ;   h_i(:,:,:) = 0._wp
73      END WHERE
74      WHERE( h_i(:,:,:) < rn_himin )      a_i(:,:,:) = a_i(:,:,:) * h_i(:,:,:) / rn_himin
75      !
76      !                             !-----------------------------------------------------
77      !                             !  ice concentration should not exceed amax          !
78      !                             !-----------------------------------------------------
79      at_i(:,:) = SUM( a_i(:,:,:), dim=3 )
80      DO jl  = 1, jpl
81         WHERE( at_i(:,:) > rn_amax_2d(:,:) )   a_i(:,:,jl) = a_i(:,:,jl) * rn_amax_2d(:,:) / at_i(:,:)
82      END DO
83   
84      !                             !-----------------------------------------------------
85      IF ( nn_icesal == 2 ) THEN    !  salinity must stay in bounds [Simin,Simax]        !
86         !                          !-----------------------------------------------------
87         zzc = rhoi * r1_rdtice
88         DO jl = 1, jpl
89            DO jj = 1, jpj 
90               DO ji = 1, jpi
91                  zsal = sv_i(ji,jj,jl)
92                  sv_i(ji,jj,jl) = MIN(  MAX( rn_simin*v_i(ji,jj,jl) , sv_i(ji,jj,jl) ) , rn_simax*v_i(ji,jj,jl)  )
93                  sfx_res(ji,jj) = sfx_res(ji,jj) - ( sv_i(ji,jj,jl) - zsal ) * zzc   ! associated salt flux
94               END DO
95            END DO
96         END DO
97      ENDIF
98      !                             !-----------------------------------------------------
99      !                             !  Rebin categories with thickness out of bounds     !
100      !                             !-----------------------------------------------------
101      IF ( jpl > 1 )   CALL ice_itd_reb( kt )
102
103      !                             !-----------------------------------------------------
104      CALL ice_var_zapsmall         !  Zap small values                                  !
105      !                             !-----------------------------------------------------
106
107      !                             !-----------------------------------------------------
108      IF( kn == 2 ) THEN            !  Ice drift case: Corrections to avoid wrong values !
109         DO jj = 2, jpjm1           !-----------------------------------------------------
110            DO ji = 2, jpim1
111               IF ( at_i(ji,jj) == 0._wp ) THEN    ! what to do if there is no ice
112                  IF ( at_i(ji+1,jj) == 0._wp )   u_ice(ji  ,jj) = 0._wp   ! right side
113                  IF ( at_i(ji-1,jj) == 0._wp )   u_ice(ji-1,jj) = 0._wp   ! left side
114                  IF ( at_i(ji,jj+1) == 0._wp )   v_ice(ji,jj  ) = 0._wp   ! upper side
115                  IF ( at_i(ji,jj-1) == 0._wp )   v_ice(ji,jj-1) = 0._wp   ! bottom side
116               ENDIF
117            END DO
118         END DO
119         CALL lbc_lnk_multi( 'icecor', u_ice, 'U', -1., v_ice, 'V', -1. )
120      ENDIF
121
122      !                             !-----------------------------------------------------
123      SELECT CASE( kn )             !  Diagnostics                                       !
124      !                             !-----------------------------------------------------
125      CASE( 1 )                        !--- dyn trend diagnostics
126         !
127!!gm   here I think the number of ice cat is too small to use a SUM instruction...
128         DO jj = 1, jpj
129            DO ji = 1, jpi           
130               !                 ! heat content variation (W.m-2)
131               diag_heat(ji,jj) = - (  SUM( e_i(ji,jj,1:nlay_i,:) - e_i_b(ji,jj,1:nlay_i,:) )    & 
132                  &                  + SUM( e_s(ji,jj,1:nlay_s,:) - e_s_b(ji,jj,1:nlay_s,:) )  ) * r1_rdtice
133               !                 ! salt, volume
134               diag_sice(ji,jj) = SUM( sv_i(ji,jj,:) - sv_i_b(ji,jj,:) ) * rhoi * r1_rdtice
135               diag_vice(ji,jj) = SUM( v_i (ji,jj,:) - v_i_b (ji,jj,:) ) * rhoi * r1_rdtice
136               diag_vsnw(ji,jj) = SUM( v_s (ji,jj,:) - v_s_b (ji,jj,:) ) * rhos * r1_rdtice
137            END DO
138         END DO
139         !                       ! concentration tendency (dynamics)
140         IF( iom_use('afxdyn') .OR. iom_use('afxthd') .OR. iom_use('afxtot') ) THEN
141            zafx(:,:) = SUM( a_i(:,:,:) - a_i_b(:,:,:), dim=3 ) * r1_rdtice 
142            CALL iom_put( 'afxdyn' , zafx )
143         ENDIF
144         !
145      CASE( 2 )                        !--- thermo trend diagnostics & ice aging
146         !
147         oa_i(:,:,:) = oa_i(:,:,:) + a_i(:,:,:) * rdt_ice   ! ice natural aging incrementation
148         !
149!!gm   here I think the number of ice cat is too small to use a SUM instruction...
150         DO jj = 1, jpj
151            DO ji = 1, jpi           
152               !                 ! heat content variation (W.m-2)
153               diag_heat(ji,jj) = diag_heat(ji,jj) - (  SUM( e_i(ji,jj,1:nlay_i,:) - e_i_b(ji,jj,1:nlay_i,:) )    & 
154                  &                                   + SUM( e_s(ji,jj,1:nlay_s,:) - e_s_b(ji,jj,1:nlay_s,:) )  ) * r1_rdtice
155               !                 ! salt, volume
156               diag_sice(ji,jj) = diag_sice(ji,jj) + SUM( sv_i(ji,jj,:) - sv_i_b(ji,jj,:) ) * rhoi * r1_rdtice
157               diag_vice(ji,jj) = diag_vice(ji,jj) + SUM( v_i (ji,jj,:) - v_i_b (ji,jj,:) ) * rhoi * r1_rdtice
158               diag_vsnw(ji,jj) = diag_vsnw(ji,jj) + SUM( v_s (ji,jj,:) - v_s_b (ji,jj,:) ) * rhos * r1_rdtice
159            END DO
160         END DO
161         !                       ! concentration tendency (total + thermo)
162         IF( iom_use('afxdyn') .OR. iom_use('afxthd') .OR. iom_use('afxtot') ) THEN
163            zafx(:,:) = zafx(:,:) + SUM( a_i(:,:,:) - a_i_b(:,:,:), dim=3 ) * r1_rdtice
164            CALL iom_put( 'afxthd' , SUM( a_i(:,:,:) - a_i_b(:,:,:), dim=3 ) * r1_rdtice )
165            CALL iom_put( 'afxtot' , zafx )
166         ENDIF
167         !
168      END SELECT
169      !
170      ! controls
171      IF( ln_icediachk   )   CALL ice_cons_hsm(1, 'icecor', rdiag_v, rdiag_s, rdiag_t, rdiag_fv, rdiag_fs, rdiag_ft) ! conservation
172      IF( ln_ctl         )   CALL ice_prt3D   ('icecor')                                                             ! prints
173      IF( ln_icectl .AND. kn == 2 ) &
174         &                   CALL ice_prt     ( kt, iiceprt, jiceprt, 2, ' - Final state - ' )                       ! prints
175      IF( ln_timing      )   CALL timing_stop ('icecor')                                                             ! timing
176      !
177   END SUBROUTINE ice_cor
178
179#else
180   !!----------------------------------------------------------------------
181   !!   Default option           Dummy module         NO SI3 sea-ice model
182   !!----------------------------------------------------------------------
183#endif
184
185   !!======================================================================
186END MODULE icecor
Note: See TracBrowser for help on using the repository browser.