source: NEMO/branches/2019/dev_r10984_HPC-13_IRRMANN_DYN_optimization/src/OCE/nemogcm.F90 @ 11381

Last change on this file since 11381 was 11381, checked in by girrmann, 2 years ago

dev_r10984_HPC-13 : repair faulty commit [11380], see #2308

  • Property svn:keywords set to Id
File size: 35.1 KB
Line 
1MODULE nemogcm
2   !!======================================================================
3   !!                       ***  MODULE nemogcm   ***
4   !! Ocean system   : NEMO GCM (ocean dynamics, on-line tracers, biochemistry and sea-ice)
5   !!======================================================================
6   !! History :  OPA  ! 1990-10  (C. Levy, G. Madec)  Original code
7   !!            7.0  ! 1991-11  (M. Imbard, C. Levy, G. Madec)
8   !!            7.1  ! 1993-03  (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
9   !!                             P. Delecluse, C. Perigaud, G. Caniaux, B. Colot, C. Maes) release 7.1
10   !!             -   ! 1992-06  (L.Terray)  coupling implementation
11   !!             -   ! 1993-11  (M.A. Filiberti) IGLOO sea-ice
12   !!            8.0  ! 1996-03  (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
13   !!                             P. Delecluse, L.Terray, M.A. Filiberti, J. Vialar, A.M. Treguier, M. Levy) release 8.0
14   !!            8.1  ! 1997-06  (M. Imbard, G. Madec)
15   !!            8.2  ! 1999-11  (M. Imbard, H. Goosse)  sea-ice model
16   !!                 ! 1999-12  (V. Thierry, A-M. Treguier, M. Imbard, M-A. Foujols)  OPEN-MP
17   !!                 ! 2000-07  (J-M Molines, M. Imbard)  Open Boundary Conditions  (CLIPPER)
18   !!   NEMO     1.0  ! 2002-08  (G. Madec)  F90: Free form and modules
19   !!             -   ! 2004-06  (R. Redler, NEC CCRLE, Germany) add OASIS[3/4] coupled interfaces
20   !!             -   ! 2004-08  (C. Talandier) New trends organization
21   !!             -   ! 2005-06  (C. Ethe) Add the 1D configuration possibility
22   !!             -   ! 2005-11  (V. Garnier) Surface pressure gradient organization
23   !!             -   ! 2006-03  (L. Debreu, C. Mazauric)  Agrif implementation
24   !!             -   ! 2006-04  (G. Madec, R. Benshila)  Step reorganization
25   !!             -   ! 2007-07  (J. Chanut, A. Sellar) Unstructured open boundaries (BDY)
26   !!            3.2  ! 2009-08  (S. Masson)  open/write in the listing file in mpp
27   !!            3.3  ! 2010-05  (K. Mogensen, A. Weaver, M. Martin, D. Lea) Assimilation interface
28   !!             -   ! 2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase
29   !!            3.3.1! 2011-01  (A. R. Porter, STFC Daresbury) dynamical allocation
30   !!             -   ! 2011-11  (C. Harris) decomposition changes for running with CICE
31   !!            3.6  ! 2012-05  (C. Calone, J. Simeon, G. Madec, C. Ethe) Add grid coarsening
32   !!             -   ! 2014-12  (G. Madec) remove KPP scheme and cross-land advection (cla)
33   !!            4.0  ! 2016-10  (G. Madec, S. Flavoni)  domain configuration / user defined interface
34   !!----------------------------------------------------------------------
35
36   !!----------------------------------------------------------------------
37   !!   nemo_gcm      : solve ocean dynamics, tracer, biogeochemistry and/or sea-ice
38   !!   nemo_init     : initialization of the NEMO system
39   !!   nemo_ctl      : initialisation of the contol print
40   !!   nemo_closefile: close remaining open files
41   !!   nemo_alloc    : dynamical allocation
42   !!----------------------------------------------------------------------
43   USE step_oce       ! module used in the ocean time stepping module (step.F90)
44   USE phycst         ! physical constant                  (par_cst routine)
45   USE domain         ! domain initialization   (dom_init & dom_cfg routines)
46   USE closea         ! treatment of closed seas (for ln_closea)
47   USE usrdef_nam     ! user defined configuration
48   USE tideini        ! tidal components initialization   (tide_ini routine)
49   USE bdy_oce,  ONLY : ln_bdy
50   USE bdyini         ! open boundary cond. setting       (bdy_init routine)
51   USE istate         ! initial state setting          (istate_init routine)
52   USE ldfdyn         ! lateral viscosity setting      (ldfdyn_init routine)
53   USE ldftra         ! lateral diffusivity setting    (ldftra_init routine)
54   USE trdini         ! dyn/tra trends initialization     (trd_init routine)
55   USE asminc         ! assimilation increments     
56   USE asmbkg         ! writing out state trajectory
57   USE diaptr         ! poleward transports           (dia_ptr_init routine)
58   USE diadct         ! sections transports           (dia_dct_init routine)
59   USE diaobs         ! Observation diagnostics       (dia_obs_init routine)
60   USE diacfl         ! CFL diagnostics               (dia_cfl_init routine)
61   USE diaharm        ! tidal harmonics diagnostics  (dia_harm_init routine)
62   USE step           ! NEMO time-stepping                 (stp     routine)
63   USE icbini         ! handle bergs, initialisation
64   USE icbstp         ! handle bergs, calving, themodynamics and transport
65   USE cpl_oasis3     ! OASIS3 coupling
66   USE c1d            ! 1D configuration
67   USE step_c1d       ! Time stepping loop for the 1D configuration
68   USE dyndmp         ! Momentum damping
69   USE stopar         ! Stochastic param.: ???
70   USE stopts         ! Stochastic param.: ???
71   USE diurnal_bulk   ! diurnal bulk SST
72   USE step_diu       ! diurnal bulk SST timestepping (called from here if run offline)
73   USE crsini         ! initialise grid coarsening utility
74   USE diatmb         ! Top,middle,bottom output
75   USE dia25h         ! 25h mean output
76   USE sbc_oce , ONLY : lk_oasis
77   USE wet_dry        ! Wetting and drying setting   (wad_init routine)
78#if defined key_top
79   USE trcini         ! passive tracer initialisation
80#endif
81#if defined key_nemocice_decomp
82   USE ice_domain_size, only: nx_global, ny_global
83#endif
84   !
85   USE lib_mpp        ! distributed memory computing
86   USE mppini         ! shared/distributed memory setting (mpp_init routine)
87   USE lbcnfd  , ONLY : isendto, nsndto, nfsloop, nfeloop   ! Setup of north fold exchanges
88   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined)
89#if defined key_iomput
90   USE xios           ! xIOserver
91#endif
92#if defined key_agrif
93   USE agrif_all_update   ! Master Agrif update
94#endif
95
96   IMPLICIT NONE
97   PRIVATE
98
99   PUBLIC   nemo_gcm    ! called by model.F90
100   PUBLIC   nemo_init   ! needed by AGRIF
101   PUBLIC   nemo_alloc  ! needed by TAM
102
103   CHARACTER(lc) ::   cform_aaa="( /, 'AAAAAAAA', / ) "     ! flag for output listing
104
105#if defined key_mpp_mpi
106   ! need MPI_Wtime
107   INCLUDE 'mpif.h'
108#endif
109
110   !!----------------------------------------------------------------------
111   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
112   !! $Id$
113   !! Software governed by the CeCILL license (see ./LICENSE)
114   !!----------------------------------------------------------------------
115CONTAINS
116
117   SUBROUTINE nemo_gcm
118      !!----------------------------------------------------------------------
119      !!                     ***  ROUTINE nemo_gcm  ***
120      !!
121      !! ** Purpose :   NEMO solves the primitive equations on an orthogonal
122      !!              curvilinear mesh on the sphere.
123      !!
124      !! ** Method  : - model general initialization
125      !!              - launch the time-stepping (stp routine)
126      !!              - finalize the run by closing files and communications
127      !!
128      !! References : Madec, Delecluse, Imbard, and Levy, 1997:  internal report, IPSL.
129      !!              Madec, 2008, internal report, IPSL.
130      !!----------------------------------------------------------------------
131      INTEGER ::   istp   ! time step index
132      !!----------------------------------------------------------------------
133      !
134#if defined key_agrif
135      CALL Agrif_Init_Grids()      ! AGRIF: set the meshes
136#endif
137      !                            !-----------------------!
138      CALL nemo_init               !==  Initialisations  ==!
139      !                            !-----------------------!
140#if defined key_agrif
141      CALL Agrif_Declare_Var_dom   ! AGRIF: set the meshes for DOM
142      CALL Agrif_Declare_Var       !  "      "   "   "      "  DYN/TRA
143# if defined key_top
144      CALL Agrif_Declare_Var_top   !  "      "   "   "      "  TOP
145# endif
146# if defined key_si3
147      CALL Agrif_Declare_Var_ice   !  "      "   "   "      "  Sea ice
148# endif
149#endif
150      ! check that all process are still there... If some process have an error,
151      ! they will never enter in step and other processes will wait until the end of the cpu time!
152      CALL mpp_max( 'nemogcm', nstop )
153
154      IF(lwp) WRITE(numout,cform_aaa)   ! Flag AAAAAAA
155
156      !                            !-----------------------!
157      !                            !==   time stepping   ==!
158      !                            !-----------------------!
159      istp = nit000
160      !
161#if defined key_c1d
162      DO WHILE ( istp <= nitend .AND. nstop == 0 )    !==  C1D time-stepping  ==!
163         CALL stp_c1d( istp )
164         istp = istp + 1
165      END DO
166#else
167      !
168# if defined key_agrif
169      !                                               !==  AGRIF time-stepping  ==!
170      CALL Agrif_Regrid()
171      !
172      ! Recursive update from highest nested level to lowest:
173      CALL Agrif_step_child_adj(Agrif_Update_All)
174      !
175      DO WHILE( istp <= nitend .AND. nstop == 0 )
176         CALL stp
177         istp = istp + 1
178      END DO
179      !
180      IF( .NOT. Agrif_Root() ) THEN
181         CALL Agrif_ParentGrid_To_ChildGrid()
182         IF( ln_diaobs )   CALL dia_obs_wri
183         IF( ln_timing )   CALL timing_finalize
184         CALL Agrif_ChildGrid_To_ParentGrid()
185      ENDIF
186      !
187# else
188      !
189      IF( .NOT.ln_diurnal_only ) THEN                 !==  Standard time-stepping  ==!
190         !
191         DO WHILE( istp <= nitend .AND. nstop == 0 )
192#if defined key_mpp_mpi
193            ncom_stp = istp
194            IF ( istp == ( nit000 + 1 ) ) elapsed_time = MPI_Wtime()
195            IF ( istp ==         nitend ) elapsed_time = MPI_Wtime() - elapsed_time
196#endif
197            CALL stp        ( istp ) 
198            istp = istp + 1
199         END DO
200         !
201      ELSE                                            !==  diurnal SST time-steeping only  ==!
202         !
203         DO WHILE( istp <= nitend .AND. nstop == 0 )
204            CALL stp_diurnal( istp )   ! time step only the diurnal SST
205            istp = istp + 1
206         END DO
207         !
208      ENDIF
209      !
210# endif
211      !
212#endif
213      !
214      IF( ln_diaobs   )   CALL dia_obs_wri
215      !
216      IF( ln_icebergs )   CALL icb_end( nitend )
217
218      !                            !------------------------!
219      !                            !==  finalize the run  ==!
220      !                            !------------------------!
221      IF(lwp) WRITE(numout,cform_aaa)        ! Flag AAAAAAA
222      !
223      IF( nstop /= 0 .AND. lwp ) THEN        ! error print
224         WRITE(ctmp1,*) '   ==>>>   nemo_gcm: a total of ', nstop, ' errors have been found'
225         CALL ctl_stop( ctmp1 )
226      ENDIF
227      !
228      IF( ln_timing )   CALL timing_finalize
229      !
230      CALL nemo_closefile
231      !
232#if defined key_iomput
233                                    CALL xios_finalize  ! end mpp communications with xios
234      IF( lk_oasis     )            CALL cpl_finalize   ! end coupling and mpp communications with OASIS
235#else
236      IF    ( lk_oasis ) THEN   ;   CALL cpl_finalize   ! end coupling and mpp communications with OASIS
237      ELSEIF( lk_mpp   ) THEN   ;   CALL mppstop( ldfinal = .TRUE. )   ! end mpp communications
238      ENDIF
239#endif
240      !
241      IF(lwm) THEN
242         IF( nstop == 0 ) THEN   ;   STOP 0
243         ELSE                    ;   STOP 123
244         ENDIF
245      ENDIF
246      !
247   END SUBROUTINE nemo_gcm
248
249
250   SUBROUTINE nemo_init
251      !!----------------------------------------------------------------------
252      !!                     ***  ROUTINE nemo_init  ***
253      !!
254      !! ** Purpose :   initialization of the NEMO GCM
255      !!----------------------------------------------------------------------
256      INTEGER ::   ios, ilocal_comm   ! local integers
257      !!
258      NAMELIST/namctl/ ln_ctl   , sn_cfctl, nn_print, nn_ictls, nn_ictle,   &
259         &             nn_isplt , nn_jsplt, nn_jctls, nn_jctle,             &
260         &             ln_timing, ln_diacfl
261      NAMELIST/namcfg/ ln_read_cfg, cn_domcfg, ln_closea, ln_write_cfg, cn_domcfg_out, ln_use_jattr
262      !!----------------------------------------------------------------------
263      !
264      cxios_context = 'nemo'
265      !
266      !                             !-------------------------------------------------!
267      !                             !     set communicator & select the local rank    !
268      !                             !  must be done as soon as possible to get narea  !
269      !                             !-------------------------------------------------!
270      !
271#if defined key_iomput
272      IF( Agrif_Root() ) THEN
273         IF( lk_oasis ) THEN
274            CALL cpl_init( "oceanx", ilocal_comm )                               ! nemo local communicator given by oasis
275            CALL xios_initialize( "not used"       , local_comm =ilocal_comm )   ! send nemo communicator to xios
276         ELSE
277            CALL xios_initialize( "for_xios_mpi_id", return_comm=ilocal_comm )   ! nemo local communicator given by xios
278         ENDIF
279      ENDIF
280      CALL mpp_start( ilocal_comm )
281#else
282      IF( lk_oasis ) THEN
283         IF( Agrif_Root() ) THEN
284            CALL cpl_init( "oceanx", ilocal_comm )          ! nemo local communicator given by oasis
285         ENDIF
286         CALL mpp_start( ilocal_comm )
287      ELSE
288         CALL mpp_start( )
289      ENDIF
290#endif
291      !
292      narea = mpprank + 1               ! mpprank: the rank of proc (0 --> mppsize -1 )
293      lwm = (narea == 1)                ! control of output namelists
294      !
295      !                             !---------------------------------------------------------------!
296      !                             ! Open output files, reference and configuration namelist files !
297      !                             !---------------------------------------------------------------!
298      !
299      ! open ocean.output as soon as possible to get all output prints (including errors messages)
300      IF( lwm )   CALL ctl_opn(     numout,        'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. )
301      ! open reference and configuration namelist files
302                  CALL ctl_opn( numnam_ref,        'namelist_ref',     'OLD', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. )
303                  CALL ctl_opn( numnam_cfg,        'namelist_cfg',     'OLD', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. )
304      IF( lwm )   CALL ctl_opn(     numond, 'output.namelist.dyn', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. )
305      ! open /dev/null file to be able to supress output write easily
306                  CALL ctl_opn(     numnul,           '/dev/null', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. )
307      !
308      !                             !--------------------!
309      !                             ! Open listing units !  -> need ln_ctl from namctl to define lwp
310      !                             !--------------------!
311      !
312      REWIND( numnam_ref )              ! Namelist namctl in reference namelist
313      READ  ( numnam_ref, namctl, IOSTAT = ios, ERR = 901 )
314901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namctl in reference namelist' )
315      REWIND( numnam_cfg )              ! Namelist namctl in confguration namelist
316      READ  ( numnam_cfg, namctl, IOSTAT = ios, ERR = 902 )
317902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namctl in configuration namelist' )
318      !
319      lwp = (narea == 1) .OR. ln_ctl    ! control of all listing output print
320      !
321      IF(lwp) THEN                      ! open listing units
322         !
323         IF( .NOT. lwm )   &            ! alreay opened for narea == 1
324            &            CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE., narea )
325         !
326         WRITE(numout,*)
327         WRITE(numout,*) '   CNRS - NERC - Met OFFICE - MERCATOR-ocean - CMCC'
328         WRITE(numout,*) '                       NEMO team'
329         WRITE(numout,*) '            Ocean General Circulation Model'
330         WRITE(numout,*) '                NEMO version 4.0  (2019) '
331         WRITE(numout,*)
332         WRITE(numout,*) "           ._      ._      ._      ._      ._    "
333         WRITE(numout,*) "       _.-._)`\_.-._)`\_.-._)`\_.-._)`\_.-._)`\_ "
334         WRITE(numout,*)
335         WRITE(numout,*) "           o         _,           _,             "
336         WRITE(numout,*) "            o      .' (        .-' /             "
337         WRITE(numout,*) "           o     _/..._'.    .'   /              "
338         WRITE(numout,*) "      (    o .-'`      ` '-./  _.'               "
339         WRITE(numout,*) "       )    ( o)           ;= <_         (       "
340         WRITE(numout,*) "      (      '-.,\\__ __.-;`\   '.        )      "
341         WRITE(numout,*) "       )  )       \) |`\ \)  '.   \      (   (   "
342         WRITE(numout,*) "      (  (           \_/       '-._\      )   )  "
343         WRITE(numout,*) "       )  ) jgs                     `    (   (   "
344         WRITE(numout,*) "     ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^ "
345         WRITE(numout,*)
346         !
347         WRITE(numout,cform_aaa)                                        ! Flag AAAAAAA
348         !
349      ENDIF
350      !
351      ! finalize the definition of namctl variables
352      IF( sn_cfctl%l_config ) THEN
353         ! Activate finer control of report outputs
354         ! optionally switch off output from selected areas (note this only
355         ! applies to output which does not involve global communications)
356         IF( ( narea < sn_cfctl%procmin .OR. narea > sn_cfctl%procmax  ) .OR. &
357           & ( MOD( narea - sn_cfctl%procmin, sn_cfctl%procincr ) /= 0 ) )    &
358           &   CALL nemo_set_cfctl( sn_cfctl, .FALSE., .FALSE. )
359      ELSE
360         ! Use ln_ctl to turn on or off all options.
361         CALL nemo_set_cfctl( sn_cfctl, ln_ctl, .TRUE. )
362      ENDIF
363      !
364      IF(lwm) WRITE( numond, namctl )
365      !
366      !                             !------------------------------------!
367      !                             !  Set global domain size parameters !
368      !                             !------------------------------------!
369      !
370      REWIND( numnam_ref )              ! Namelist namcfg in reference namelist
371      READ  ( numnam_ref, namcfg, IOSTAT = ios, ERR = 903 )
372903   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namcfg in reference namelist' )
373      REWIND( numnam_cfg )              ! Namelist namcfg in confguration namelist
374      READ  ( numnam_cfg, namcfg, IOSTAT = ios, ERR = 904 )
375904   IF( ios >  0 )   CALL ctl_nam ( ios , 'namcfg in configuration namelist' )   
376      !
377      IF( ln_read_cfg ) THEN            ! Read sizes in domain configuration file
378         CALL domain_cfg ( cn_cfg, nn_cfg, jpiglo, jpjglo, jpkglo, jperio )
379      ELSE                              ! user-defined namelist
380         CALL usr_def_nam( cn_cfg, nn_cfg, jpiglo, jpjglo, jpkglo, jperio )
381      ENDIF
382      !
383      IF(lwm)   WRITE( numond, namcfg )
384      !
385      !                             !-----------------------------------------!
386      !                             ! mpp parameters and domain decomposition !
387      !                             !-----------------------------------------!
388      CALL mpp_init
389
390      ! Now we know the dimensions of the grid and numout has been set: we can allocate arrays
391      CALL nemo_alloc()
392
393      !                             !-------------------------------!
394      !                             !  NEMO general initialization  !
395      !                             !-------------------------------!
396
397      CALL nemo_ctl                          ! Control prints
398      !
399      !                                      ! General initialization
400      IF( ln_timing    )   CALL timing_init     ! timing
401      IF( ln_timing    )   CALL timing_start( 'nemo_init')
402      !
403                           CALL     phy_cst         ! Physical constants
404                           CALL     eos_init        ! Equation of state
405      IF( lk_c1d       )   CALL     c1d_init        ! 1D column configuration
406                           CALL     wad_init        ! Wetting and drying options
407                           CALL     dom_init("OPA") ! Domain
408      IF( ln_crs       )   CALL     crs_init        ! coarsened grid: domain initialization
409      IF( ln_ctl       )   CALL prt_ctl_init        ! Print control
410     
411      CALL diurnal_sst_bulk_init                ! diurnal sst
412      IF( ln_diurnal   )   CALL diurnal_sst_coolskin_init   ! cool skin   
413      !                           
414      IF( ln_diurnal_only ) THEN                   ! diurnal only: a subset of the initialisation routines
415         CALL  istate_init                            ! ocean initial state (Dynamics and tracers)
416         CALL     sbc_init                            ! Forcings : surface module
417         CALL tra_qsr_init                            ! penetrative solar radiation qsr
418         IF( ln_diaobs ) THEN                         ! Observation & model comparison
419            CALL dia_obs_init                            ! Initialize observational data
420            CALL dia_obs( nit000 - 1 )                   ! Observation operator for restart
421         ENDIF     
422         IF( lk_asminc )   CALL asm_inc_init          ! Assimilation increments
423         !
424         RETURN                                       ! end of initialization
425      ENDIF
426     
427                           CALL  istate_init    ! ocean initial state (Dynamics and tracers)
428
429      !                                      ! external forcing
430                           CALL    tide_init    ! tidal harmonics
431                           CALL     sbc_init    ! surface boundary conditions (including sea-ice)
432                           CALL     bdy_init    ! Open boundaries initialisation
433
434      !                                      ! Ocean physics
435                           CALL zdf_phy_init    ! Vertical physics
436                                     
437      !                                         ! Lateral physics
438                           CALL ldf_tra_init      ! Lateral ocean tracer physics
439                           CALL ldf_eiv_init      ! eddy induced velocity param.
440                           CALL ldf_dyn_init      ! Lateral ocean momentum physics
441
442      !                                      ! Active tracers
443      IF( ln_traqsr    )   CALL tra_qsr_init      ! penetrative solar radiation qsr
444                           CALL tra_bbc_init      ! bottom heat flux
445                           CALL tra_bbl_init      ! advective (and/or diffusive) bottom boundary layer scheme
446                           CALL tra_dmp_init      ! internal tracer damping
447                           CALL tra_adv_init      ! horizontal & vertical advection
448                           CALL tra_ldf_init      ! lateral mixing
449
450      !                                      ! Dynamics
451      IF( lk_c1d       )   CALL dyn_dmp_init      ! internal momentum damping
452                           CALL dyn_adv_init      ! advection (vector or flux form)
453                           CALL dyn_vor_init      ! vorticity term including Coriolis
454                           CALL dyn_ldf_init      ! lateral mixing
455                           CALL dyn_hpg_init      ! horizontal gradient of Hydrostatic pressure
456                           CALL dyn_spg_init      ! surface pressure gradient
457
458#if defined key_top
459      !                                      ! Passive tracers
460                           CALL     trc_init
461#endif
462      IF( l_ldfslp     )   CALL ldf_slp_init    ! slope of lateral mixing
463
464      !                                      ! Icebergs
465                           CALL icb_init( rdt, nit000)   ! initialise icebergs instance
466
467      !                                      ! Misc. options
468                           CALL sto_par_init    ! Stochastic parametrization
469      IF( ln_sto_eos   )   CALL sto_pts_init    ! RRandom T/S fluctuations
470     
471      !                                      ! Diagnostics
472      IF( lk_floats    )   CALL     flo_init    ! drifting Floats
473      IF( ln_diacfl    )   CALL dia_cfl_init    ! Initialise CFL diagnostics
474                           CALL dia_ptr_init    ! Poleward TRansports initialization
475                           CALL dia_dct_init    ! Sections tranports
476                           CALL dia_hsb_init    ! heat content, salt content and volume budgets
477                           CALL     trd_init    ! Mixed-layer/Vorticity/Integral constraints trends
478                           CALL dia_obs_init    ! Initialize observational data
479                           CALL dia_tmb_init    ! TMB outputs
480                           CALL dia_25h_init    ! 25h mean  outputs
481                           CALL dia_harm_init   ! tidal harmonics outputs
482     IF( ln_diaobs    )    CALL dia_obs( nit000-1 )   ! Observation operator for restart
483
484      !                                      ! Assimilation increments
485      IF( lk_asminc    )   CALL asm_inc_init    ! Initialize assimilation increments
486      !
487      IF(lwp) WRITE(numout,cform_aaa)           ! Flag AAAAAAA
488      !
489      IF( ln_timing    )   CALL timing_stop( 'nemo_init')
490      !
491   END SUBROUTINE nemo_init
492
493
494   SUBROUTINE nemo_ctl
495      !!----------------------------------------------------------------------
496      !!                     ***  ROUTINE nemo_ctl  ***
497      !!
498      !! ** Purpose :   control print setting
499      !!
500      !! ** Method  : - print namctl and namcfg information and check some consistencies
501      !!----------------------------------------------------------------------
502      !
503      IF(lwp) THEN                  ! control print
504         WRITE(numout,*)
505         WRITE(numout,*) 'nemo_ctl: Control prints'
506         WRITE(numout,*) '~~~~~~~~'
507         WRITE(numout,*) '   Namelist namctl'
508         WRITE(numout,*) '      run control (for debugging)     ln_ctl     = ', ln_ctl
509         WRITE(numout,*) '       finer control over o/p sn_cfctl%l_config  = ', sn_cfctl%l_config
510         WRITE(numout,*) '                              sn_cfctl%l_runstat = ', sn_cfctl%l_runstat
511         WRITE(numout,*) '                              sn_cfctl%l_trcstat = ', sn_cfctl%l_trcstat
512         WRITE(numout,*) '                              sn_cfctl%l_oceout  = ', sn_cfctl%l_oceout
513         WRITE(numout,*) '                              sn_cfctl%l_layout  = ', sn_cfctl%l_layout
514         WRITE(numout,*) '                              sn_cfctl%l_mppout  = ', sn_cfctl%l_mppout
515         WRITE(numout,*) '                              sn_cfctl%l_mpptop  = ', sn_cfctl%l_mpptop
516         WRITE(numout,*) '                              sn_cfctl%procmin   = ', sn_cfctl%procmin 
517         WRITE(numout,*) '                              sn_cfctl%procmax   = ', sn_cfctl%procmax 
518         WRITE(numout,*) '                              sn_cfctl%procincr  = ', sn_cfctl%procincr 
519         WRITE(numout,*) '                              sn_cfctl%ptimincr  = ', sn_cfctl%ptimincr 
520         WRITE(numout,*) '      level of print                  nn_print   = ', nn_print
521         WRITE(numout,*) '      Start i indice for SUM control  nn_ictls   = ', nn_ictls
522         WRITE(numout,*) '      End i indice for SUM control    nn_ictle   = ', nn_ictle
523         WRITE(numout,*) '      Start j indice for SUM control  nn_jctls   = ', nn_jctls
524         WRITE(numout,*) '      End j indice for SUM control    nn_jctle   = ', nn_jctle
525         WRITE(numout,*) '      number of proc. following i     nn_isplt   = ', nn_isplt
526         WRITE(numout,*) '      number of proc. following j     nn_jsplt   = ', nn_jsplt
527         WRITE(numout,*) '      timing by routine               ln_timing  = ', ln_timing
528         WRITE(numout,*) '      CFL diagnostics                 ln_diacfl  = ', ln_diacfl
529      ENDIF
530      !
531      nprint    = nn_print          ! convert DOCTOR namelist names into OLD names
532      nictls    = nn_ictls
533      nictle    = nn_ictle
534      njctls    = nn_jctls
535      njctle    = nn_jctle
536      isplt     = nn_isplt
537      jsplt     = nn_jsplt
538
539      IF(lwp) THEN                  ! control print
540         WRITE(numout,*)
541         WRITE(numout,*) '   Namelist namcfg'
542         WRITE(numout,*) '      read domain configuration file                ln_read_cfg      = ', ln_read_cfg
543         WRITE(numout,*) '         filename to be read                           cn_domcfg     = ', TRIM(cn_domcfg)
544         WRITE(numout,*) '         keep closed seas in the domain (if exist)     ln_closea     = ', ln_closea
545         WRITE(numout,*) '      create a configuration definition file        ln_write_cfg     = ', ln_write_cfg
546         WRITE(numout,*) '         filename to be written                        cn_domcfg_out = ', TRIM(cn_domcfg_out)
547         WRITE(numout,*) '      use file attribute if exists as i/p j-start   ln_use_jattr     = ', ln_use_jattr
548      ENDIF
549      IF( .NOT.ln_read_cfg )   ln_closea = .false.   ! dealing possible only with a domcfg file
550      !
551      !                             ! Parameter control
552      !
553      IF( ln_ctl ) THEN                 ! sub-domain area indices for the control prints
554         IF( lk_mpp .AND. jpnij > 1 ) THEN
555            isplt = jpni   ;   jsplt = jpnj   ;   ijsplt = jpni*jpnj   ! the domain is forced to the real split domain
556         ELSE
557            IF( isplt == 1 .AND. jsplt == 1  ) THEN
558               CALL ctl_warn( ' - isplt & jsplt are equal to 1',   &
559                  &           ' - the print control will be done over the whole domain' )
560            ENDIF
561            ijsplt = isplt * jsplt            ! total number of processors ijsplt
562         ENDIF
563         IF(lwp) WRITE(numout,*)'          - The total number of processors over which the'
564         IF(lwp) WRITE(numout,*)'            print control will be done is ijsplt : ', ijsplt
565         !
566         !                              ! indices used for the SUM control
567         IF( nictls+nictle+njctls+njctle == 0 )   THEN    ! print control done over the default area
568            lsp_area = .FALSE.
569         ELSE                                             ! print control done over a specific  area
570            lsp_area = .TRUE.
571            IF( nictls < 1 .OR. nictls > jpiglo )   THEN
572               CALL ctl_warn( '          - nictls must be 1<=nictls>=jpiglo, it is forced to 1' )
573               nictls = 1
574            ENDIF
575            IF( nictle < 1 .OR. nictle > jpiglo )   THEN
576               CALL ctl_warn( '          - nictle must be 1<=nictle>=jpiglo, it is forced to jpiglo' )
577               nictle = jpiglo
578            ENDIF
579            IF( njctls < 1 .OR. njctls > jpjglo )   THEN
580               CALL ctl_warn( '          - njctls must be 1<=njctls>=jpjglo, it is forced to 1' )
581               njctls = 1
582            ENDIF
583            IF( njctle < 1 .OR. njctle > jpjglo )   THEN
584               CALL ctl_warn( '          - njctle must be 1<=njctle>=jpjglo, it is forced to jpjglo' )
585               njctle = jpjglo
586            ENDIF
587         ENDIF
588      ENDIF
589      !
590      IF( 1._wp /= SIGN(1._wp,-0._wp)  )   CALL ctl_stop( 'nemo_ctl: The intrinsec SIGN function follows f2003 standard.',  &
591         &                                                'Compile with key_nosignedzero enabled:',   &
592         &                                                '--> add -Dkey_nosignedzero to the definition of %CPP in your arch file' )
593      !
594#if defined key_agrif
595      IF( ln_timing )   CALL ctl_stop( 'AGRIF not implemented with ln_timing = true')
596#endif
597      !
598   END SUBROUTINE nemo_ctl
599
600
601   SUBROUTINE nemo_closefile
602      !!----------------------------------------------------------------------
603      !!                     ***  ROUTINE nemo_closefile  ***
604      !!
605      !! ** Purpose :   Close the files
606      !!----------------------------------------------------------------------
607      !
608      IF( lk_mpp )   CALL mppsync
609      !
610      CALL iom_close                                 ! close all input/output files managed by iom_*
611      !
612      IF( numstp          /= -1 )   CLOSE( numstp          )   ! time-step file
613      IF( numrun          /= -1 )   CLOSE( numrun          )   ! run statistics file
614      IF( numnam_ref      /= -1 )   CLOSE( numnam_ref      )   ! oce reference namelist
615      IF( numnam_cfg      /= -1 )   CLOSE( numnam_cfg      )   ! oce configuration namelist
616      IF( lwm.AND.numond  /= -1 )   CLOSE( numond          )   ! oce output namelist
617      IF( numnam_ice_ref  /= -1 )   CLOSE( numnam_ice_ref  )   ! ice reference namelist
618      IF( numnam_ice_cfg  /= -1 )   CLOSE( numnam_ice_cfg  )   ! ice configuration namelist
619      IF( lwm.AND.numoni  /= -1 )   CLOSE( numoni          )   ! ice output namelist
620      IF( numevo_ice      /= -1 )   CLOSE( numevo_ice      )   ! ice variables (temp. evolution)
621      IF( numout          /=  6 )   CLOSE( numout          )   ! standard model output file
622      IF( numdct_vol      /= -1 )   CLOSE( numdct_vol      )   ! volume transports
623      IF( numdct_heat     /= -1 )   CLOSE( numdct_heat     )   ! heat transports
624      IF( numdct_salt     /= -1 )   CLOSE( numdct_salt     )   ! salt transports
625      !
626      numout = 6                                     ! redefine numout in case it is used after this point...
627      !
628   END SUBROUTINE nemo_closefile
629
630
631   SUBROUTINE nemo_alloc
632      !!----------------------------------------------------------------------
633      !!                     ***  ROUTINE nemo_alloc  ***
634      !!
635      !! ** Purpose :   Allocate all the dynamic arrays of the OPA modules
636      !!
637      !! ** Method  :
638      !!----------------------------------------------------------------------
639      USE diawri    , ONLY : dia_wri_alloc
640      USE dom_oce   , ONLY : dom_oce_alloc
641      USE trc_oce   , ONLY : trc_oce_alloc
642      USE bdy_oce   , ONLY : bdy_oce_alloc
643      !
644      INTEGER :: ierr
645      !!----------------------------------------------------------------------
646      !
647      ierr =        oce_alloc    ()    ! ocean
648      ierr = ierr + dia_wri_alloc()
649      ierr = ierr + dom_oce_alloc()    ! ocean domain
650      ierr = ierr + zdf_oce_alloc()    ! ocean vertical physics
651      ierr = ierr + trc_oce_alloc()    ! shared TRC / TRA arrays
652      ierr = ierr + bdy_oce_alloc()    ! bdy masks (incl. initialization)
653      !
654      CALL mpp_sum( 'nemogcm', ierr )
655      IF( ierr /= 0 )   CALL ctl_stop( 'STOP', 'nemo_alloc: unable to allocate standard ocean arrays' )
656      !
657   END SUBROUTINE nemo_alloc
658
659   
660   SUBROUTINE nemo_set_cfctl(sn_cfctl, setto, for_all )
661      !!----------------------------------------------------------------------
662      !!                     ***  ROUTINE nemo_set_cfctl  ***
663      !!
664      !! ** Purpose :   Set elements of the output control structure to setto.
665      !!                for_all should be .false. unless all areas are to be
666      !!                treated identically.
667      !!
668      !! ** Method  :   Note this routine can be used to switch on/off some
669      !!                types of output for selected areas but any output types
670      !!                that involve global communications (e.g. mpp_max, glob_sum)
671      !!                should be protected from selective switching by the
672      !!                for_all argument
673      !!----------------------------------------------------------------------
674      LOGICAL :: setto, for_all
675      TYPE(sn_ctl) :: sn_cfctl
676      !!----------------------------------------------------------------------
677      IF( for_all ) THEN
678         sn_cfctl%l_runstat = setto
679         sn_cfctl%l_trcstat = setto
680      ENDIF
681      sn_cfctl%l_oceout  = setto
682      sn_cfctl%l_layout  = setto
683      sn_cfctl%l_mppout  = setto
684      sn_cfctl%l_mpptop  = setto
685   END SUBROUTINE nemo_set_cfctl
686
687   !!======================================================================
688END MODULE nemogcm
689
Note: See TracBrowser for help on using the repository browser.