source: NEMO/branches/2019/dev_r11265_ASINTER-01_Guillaume_ABL1D/src/ABL/sbcabl.F90 @ 11305

Last change on this file since 11305 was 11305, checked in by smasson, 21 months ago

dev_r11265_ABL : first implementation of ABL, see #2131

File size: 17.9 KB
Line 
1MODULE sbcabl
2   !!======================================================================
3   !!                       ***  MODULE  sbcabl  ***
4   !! Ocean forcing:  momentum, heat and freshwater flux formulation
5   !!                 derived from an ABL model
6   !!=====================================================================
7   !! History :  4.0  !  2019-03  (F. Lemarié & G. Samson)  Original code
8   !!----------------------------------------------------------------------
9
10   !!----------------------------------------------------------------------
11   !!   sbc_abl_init  : Initialization of ABL model based on namelist options
12   !!   sbc_abl       : driver for the computation of momentum, heat and freshwater
13   !!                   fluxes over ocean via the ABL model
14   !!----------------------------------------------------------------------
15   USE abl            ! ABL
16   USE par_abl        ! abl parameters
17   USE ablmod
18
19   USE phycst         ! physical constants
20   USE fldread        ! read input fields
21   USE sbc_oce        ! Surface boundary condition: ocean fields
22   USE sbcblk         ! Surface boundary condition: bulk formulae
23   USE dom_oce, ONLY  : tmask
24   !
25   USE iom            ! I/O manager library
26   USE in_out_manager ! I/O manager
27   USE lib_mpp        ! distribued memory computing library
28   USE lib_fortran    ! to use key_nosignedzero
29   USE timing         ! Timing
30   USE lbclnk         ! ocean lateral boundary conditions (or mpp link)
31   USE prtctl         ! Print control
32
33   IMPLICIT NONE
34   PRIVATE
35
36   PUBLIC   sbc_abl_init       ! routine called in sbcmod module
37   PUBLIC   sbc_abl            ! routine called in sbcmod module
38
39   !! * Substitutions
40#  include "vectopt_loop_substitute.h90"
41   !!----------------------------------------------------------------------
42   !! NEMO/OPA 3.7 , NEMO-consortium (2014)
43   !! $Id: sbcabl.F90 6416 2016-04-01 12:22:17Z clem $
44   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
45   !!----------------------------------------------------------------------
46CONTAINS
47
48   SUBROUTINE sbc_abl_init
49      !!---------------------------------------------------------------------
50      !!                    ***  ROUTINE sbc_abl_init  ***
51      !!
52      !! ** Purposes :   - read namelist section namsbc_abl
53      !!                 - initialize and check parameter values
54      !!                 - initialize variables of ABL model
55      !!
56      !!----------------------------------------------------------------------
57      INTEGER            ::   ji, jj, jk, jbak, jbak_dta       ! dummy loop indices
58      INTEGER            ::   ios, ierror, ioptio              ! Local integer
59      INTEGER            ::   inum, indims, idimsz(4), id
60      CHARACTER(len=100) ::   cn_dir, cn_dom                   ! Atmospheric grid directory
61      REAL(wp)           ::   zcff,zcff1
62      LOGICAL            ::   lluldl
63      NAMELIST/namsbc_abl/ cn_dir , cn_dom, ln_hpgls_frc, ln_geos_winds,          &
64         &                 nn_dyn_restore,                                        &
65         &                 rn_ldyn_min , rn_ldyn_max, rn_ltra_min, rn_ltra_max,   &
66         &                 nn_amxl, rn_cm, rn_ct, rn_ce, rn_ceps, rn_Rod, rn_Ric 
67      !!---------------------------------------------------------------------
68
69      REWIND( numnam_ref )              ! Namelist namsbc_abl in reference namelist : ABL parameters
70      READ  ( numnam_ref, namsbc_abl, IOSTAT = ios, ERR = 901 )
71901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc_abl in reference namelist', lwp )
72      !
73      REWIND( numnam_cfg )              ! Namelist namsbc_abl in configuration namelist : ABL parameters
74      READ  ( numnam_cfg, namsbc_abl, IOSTAT = ios, ERR = 902 )
75902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc_abl in configuration namelist', lwp )
76      !
77      IF(lwm) WRITE( numond, namsbc_abl )
78      !
79      ! Check ABL mixing length option     
80      IF( nn_amxl  < 0   .OR.  nn_amxl  > 2 )   &
81         &                 CALL ctl_stop( 'abl_init : bad flag, nn_amxl must be  0, 1 or 2 ' )         
82      !
83      ! Check ABL dyn restore option         
84      IF( nn_dyn_restore  < 0   .OR.  nn_dyn_restore  > 2 )   &
85         &                 CALL ctl_stop( 'abl_init : bad flag, nn_dyn_restore must be  0, 1 or 2 ' )           
86      !
87      !!---------------------------------------------------------------------
88      !! Control prints
89      !!---------------------------------------------------------------------
90      IF(lwp) THEN                              ! Control print (other namelist variable)
91         WRITE(numout,*)
92         WRITE(numout,*) '      ABL -- cn_dir         = ', cn_dir
93         WRITE(numout,*) '      ABL -- cn_dom         = ', cn_dom
94         IF( ln_hpgls_frc ) THEN
95            WRITE(numout,*) '      ABL -- winds forced by large-scale pressure gradient'
96            IF(ln_geos_winds) THEN
97               ln_geos_winds = .FALSE.
98               WRITE(numout,*) '      ABL -- geostrophic guide disabled (not compatible with ln_hpgls_frc = .T.)'                 
99            END IF
100         ELSE IF( ln_geos_winds ) THEN
101            WRITE(numout,*) '      ABL -- winds forced by geostrophic winds'               
102         ELSE
103            WRITE(numout,*) '      ABL -- Geostrophic winds and large-scale pressure gradient are ignored'               
104         END IF
105         !
106         SELECT CASE ( nn_dyn_restore )
107         CASE ( 0 )   
108            WRITE(numout,*) '      ABL -- No restoring for ABL winds'   
109         CASE ( 1 )
110            WRITE(numout,*) '      ABL -- Restoring of ABL winds only in the equatorial region '             
111         CASE ( 2 )
112            WRITE(numout,*) '      ABL -- Restoring of ABL winds activated everywhere '             
113         END SELECT
114         !
115      ENDIF
116
117      !!---------------------------------------------------------------------
118      !! Convert nudging coefficient from hours to 1/sec
119      !!---------------------------------------------------------------------         
120      zcff        = 1._wp / 3600._wp
121      rn_ldyn_min = zcff / rn_ldyn_min
122      rn_ldyn_max = zcff / rn_ldyn_max     
123      rn_ltra_min = zcff / rn_ltra_min
124      rn_ltra_max = zcff / rn_ltra_max   
125
126      !!---------------------------------------------------------------------
127      !! ABL grid initialization
128      !!---------------------------------------------------------------------     
129      CALL iom_open( TRIM(cn_dir)//TRIM(cn_dom), inum ) 
130      id     = iom_varid( inum, 'e3t_abl', kdimsz=idimsz, kndims=indims, lduld=lluldl )
131      jpka   = idimsz(indims - COUNT( (/lluldl/) ) ) 
132      jpkam1 = jpka - 1
133
134      IF( abl_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'abl_init : unable to allocate arrays' )
135      CALL iom_get( inum, jpdom_unknown, 'e3t_abl', e3t_abl(:) )
136      CALL iom_get( inum, jpdom_unknown, 'e3w_abl', e3w_abl(:) )
137      CALL iom_get( inum, jpdom_unknown, 'ght_abl', ght_abl(:) )
138      CALL iom_get( inum, jpdom_unknown, 'ghw_abl', ghw_abl(:) )
139      CALL iom_close( inum )
140
141      IF(lwp) THEN
142         WRITE(numout,*)
143         WRITE(numout,*) '    sbc_abl_init   : ABL Reference vertical grid'
144         WRITE(numout,*) '    ~~~~~~~'     
145         WRITE(numout, "(9x,'  level ght_abl   ghw_abl   e3t_abl   e3w_abl  ')" )
146         WRITE(numout, "(10x, i4, 4f9.2)" ) ( jk, ght_abl(jk), ghw_abl(jk), e3t_abl(jk), e3w_abl(jk), jk = 1, jpka )
147      END IF
148
149      !!---------------------------------------------------------------------
150      !! Check TKE closure parameters
151      !!---------------------------------------------------------------------
152      rn_Sch  = rn_ce / rn_cm
153      mxl_min = (avm_bak / rn_cm) / sqrt( tke_min )
154
155      IF(lwp) THEN
156         WRITE(numout,*)
157         WRITE(numout,*) '    abl_zdf_tke   : ABL TKE turbulent closure'
158         WRITE(numout,*) '    ~~~~~~~~~~~'     
159         IF(nn_amxl==0) WRITE(numout,*) 'Deardorff 80 length-scale '
160         IF(nn_amxl==1) WRITE(numout,*) 'length-scale based on the distance to the PBL height '
161         WRITE(numout,*) ' Minimum value of atmospheric TKE           = ',tke_min,' m^2 s^-2'
162         WRITE(numout,*) ' Minimum value of atmospheric mixing length = ',mxl_min,' m'
163         WRITE(numout,*) ' Constant for turbulent viscosity           = ',rn_Cm         
164         WRITE(numout,*) ' Constant for turbulent diffusivity         = ',rn_Ct         
165         WRITE(numout,*) ' Constant for Schmidt number                = ',rn_Sch           
166         WRITE(numout,*) ' Constant for TKE dissipation               = ',rn_Ceps                       
167      END IF
168
169      !!-------------------------------------------------------------------------------------------
170      !! Compute parameters to build the vertical profile for the nudging term (used in abl_stp())
171      !!-------------------------------------------------------------------------------------------       
172      zcff1       = 1._wp / ( jp_bmax - jp_bmin )**3
173      ! for active tracers
174      jp_alp3_tra = -2._wp * zcff1                       * ( rn_ltra_max - rn_ltra_min )
175      jp_alp2_tra =  3._wp * zcff1 * (jp_bmax + jp_bmin) * ( rn_ltra_max - rn_ltra_min )
176      jp_alp1_tra = -6._wp * zcff1 *  jp_bmax * jp_bmin  * ( rn_ltra_max - rn_ltra_min )
177      jp_alp0_tra = zcff1 * (  rn_ltra_max * jp_bmin*jp_bmin * (3._wp*jp_bmax - jp_bmin)      &
178         &                   - rn_ltra_min * jp_bmax*jp_bmax * (3._wp*jp_bmin - jp_bmax) ) 
179      ! for dynamics
180      jp_alp3_dyn = -2._wp * zcff1                       * ( rn_ldyn_max - rn_ldyn_min )
181      jp_alp2_dyn =  3._wp * zcff1 * (jp_bmax + jp_bmin) * ( rn_ldyn_max - rn_ldyn_min )
182      jp_alp1_dyn = -6._wp * zcff1 *  jp_bmax * jp_bmin  * ( rn_ldyn_max - rn_ldyn_min )
183      jp_alp0_dyn = zcff1 * (  rn_ldyn_max * jp_bmin*jp_bmin * (3._wp*jp_bmax - jp_bmin)      &
184         &                   - rn_ldyn_min * jp_bmax*jp_bmax * (3._wp*jp_bmin - jp_bmax) )       
185
186      jp_pblh_min = ghw_abl(     4) / jp_bmin  !<-- at least 3 grid points at the bottom have value rn_ltra_min
187      jp_pblh_max = ghw_abl(jpka-3) / jp_bmax  !<-- at least 3 grid points at the top    have value rn_ltra_max
188
189      ! Check parameters for dynamics
190      zcff  = jp_alp3_dyn * jp_bmin**3 + jp_alp2_dyn * jp_bmin**2   &
191         &  + jp_alp1_dyn * jp_bmin    + jp_alp0_dyn 
192      zcff1 = jp_alp3_dyn * jp_bmax**3 + jp_alp2_dyn * jp_bmax**2   &
193         &  + jp_alp1_dyn * jp_bmax    + jp_alp0_dyn     
194      IF(lwp) THEN
195         IF(nn_dyn_restore > 0) THEN
196            WRITE(numout,*) ' ABL Minimum value for dynamics restoring = ',zcff  * rdt
197            WRITE(numout,*) ' ABL Maximum value for dynamics restoring = ',zcff1 * rdt
198            ! Check that restoring coefficients are between 0 and 1
199            IF( zcff1 * rdt > 1._wp .OR. zcff1 * rdt < 0._wp )   &
200               &                   CALL ctl_stop( 'abl_init : wrong value for rn_ldyn_max' )
201            IF( zcff  * rdt > 1._wp .OR. zcff  * rdt < 0._wp )   &
202               &                   CALL ctl_stop( 'abl_init : wrong value for rn_ldyn_min' )
203            IF( zcff  * rdt > zcff1 * rdt ) &
204               &                   CALL ctl_stop( 'abl_init : rn_ldyn_max should be smaller than rn_ldyn_min' )
205         END IF
206      END IF
207
208      ! Check parameters for active tracers
209      zcff  = jp_alp3_tra * jp_bmin**3 + jp_alp2_tra * jp_bmin**2   &
210         &  + jp_alp1_tra * jp_bmin    + jp_alp0_tra 
211      zcff1 = jp_alp3_tra * jp_bmax**3 + jp_alp2_tra * jp_bmax**2   &
212         &  + jp_alp1_tra * jp_bmax    + jp_alp0_tra 
213      IF(lwp) THEN
214         WRITE(numout,*) ' ABL Minimum value for tracers restoring = ',zcff  * rdt
215         WRITE(numout,*) ' ABL Maximum value for tracers restoring = ',zcff1 * rdt
216         ! Check that restoring coefficients are between 0 and 1
217         IF( zcff1 * rdt > 1._wp .OR. zcff1 * rdt < 0._wp )   &
218            &                   CALL ctl_stop( 'abl_init : wrong value for rn_ltra_max' )
219         IF( zcff  * rdt > 1._wp .OR. zcff  * rdt < 0._wp )   &
220            &                   CALL ctl_stop( 'abl_init : wrong value for rn_ltra_min' )
221         IF( zcff  * rdt > zcff1  * rdt ) &
222            &                   CALL ctl_stop( 'abl_init : rn_ltra_max should be smaller than rn_ltra_min' )
223      END IF
224
225      !!-------------------------------------------------------------------------------------------
226      !! Initialize Coriolis frequency, equatorial restoring and land/sea mask
227      !!------------------------------------------------------------------------------------------- 
228      fft_abl(:,:) = 2._wp * omega * SIN( rad * gphit(:,:) )
229
230      ! Equatorial restoring
231      IF( nn_dyn_restore == 1 ) THEN
232         zcff         = 2._wp * omega * SIN( rad * 90._wp )   !++ fmax
233         rest_eq(:,:) = SIN( 0.5_wp*rpi*( (fft_abl(:,:) - zcff)/zcff ) )**8
234      ELSE
235         rest_eq(:,:) = 1._wp
236      END IF
237      ! T-mask
238      msk_abl(:,:) = tmask(:,:,1)
239
240      !!-------------------------------------------------------------------------------------------
241
242      ! initialize 2D bulk fields AND 3D abl data
243      CALL sbc_blk_init
244
245      ! initialize ABL from data or restart
246      !!GS  disabled for now
247      !IF( ln_rstart ) THEN
248      !  CALL ctl_stop( 'STOP', 'sbc_abl_init: restart mode not supported yet' )
249      !ELSE
250
251      CALL fld_read( nit000, nn_fsbc, sf ) ! input fields provided at the first time-step
252
253      ! Initialize the time index for now time (nt_n) and after time (nt_a)
254      nt_n = 1 + MOD( nit000  , 2)
255      nt_a = 1 + MOD( nit000+1, 2)
256
257       u_abl(:,:,:,nt_n      ) = sf(jp_wndi)%fnow(:,:,:)
258       v_abl(:,:,:,nt_n      ) = sf(jp_wndj)%fnow(:,:,:)
259      tq_abl(:,:,:,nt_n,jp_ta) = sf(jp_tair)%fnow(:,:,:)
260      tq_abl(:,:,:,nt_n,jp_qa) = sf(jp_humi)%fnow(:,:,:)
261
262      tke_abl(:,:,:,nt_n     ) = tke_min
263      avm_abl(:,:,:          ) = avm_bak
264      avt_abl(:,:,:          ) = avt_bak
265      mxl_abl(:,:,:          ) = mxl_min 
266      pblh   (:,:            ) = ghw_abl( 3 )  !<-- assume that the pbl contains 3 grid points
267      u_abl  (:,:,:,nt_a     ) = 0._wp
268      v_abl  (:,:,:,nt_a     ) = 0._wp
269      tq_abl (:,:,:,nt_a,:   ) = 0._wp
270      tke_abl(:,:,:,nt_a     ) = 0._wp
271      !ENDIF
272      !!GS restart case not supported
273
274   END SUBROUTINE sbc_abl_init
275
276 
277
278   SUBROUTINE sbc_abl( kt )
279      !!---------------------------------------------------------------------
280      !!                     ***  ROUTINE sbc_abl  ***
281      !!
282      !! ** Purpose :   provide the momentum, heat and freshwater fluxes at
283      !!      the ocean surface from an ABL calculation at each oceanic time step 
284      !!
285      !! ** Method  :
286      !!              - Pre-compute part of turbulent fluxes in blk_oce_1
287      !!              - Perform 1 time-step of the ABL model   
288      !!              - Finalize flux computation in blk_oce_2
289      !!
290      !! ** Outputs : - utau    : i-component of the stress at U-point  (N/m2)
291      !!              - vtau    : j-component of the stress at V-point  (N/m2)
292      !!              - taum    : Wind stress module at T-point         (N/m2)
293      !!              - wndm    : Wind speed module at T-point          (m/s)
294      !!              - qsr     : Solar heat flux over the ocean        (W/m2)
295      !!              - qns     : Non Solar heat flux over the ocean    (W/m2)
296      !!              - emp     : evaporation minus precipitation       (kg/m2/s)
297      !!
298      !!---------------------------------------------------------------------
299      INTEGER ,         INTENT(in) ::   kt   ! ocean time step
300      !!
301      REAL(wp), DIMENSION(jpi,jpj) ::   zssq, zcd_du, zsen, zevp
302      INTEGER                      ::   jbak, jbak_dta, ji, jj
303      !!---------------------------------------------------------------------
304      !
305      !!-------------------------------------------------------------------------------------------
306      !! 1 - Read Atmospheric 3D data for large-scale forcing
307      !!-------------------------------------------------------------------------------------------
308     
309      CALL fld_read( kt, nn_fsbc, sf )             ! input fields provided at the current time-step
310     
311      !!-------------------------------------------------------------------------------------------
312      !! 2 - Compute Cd x ||U||, Ch x ||U||, Ce x ||U||, and SSQ using now fields
313      !!------------------------------------------------------------------------------------------- 
314         
315      CALL blk_oce_1( kt, u_abl(:,:,2,nt_n), v_abl(:,:,2,nt_n), tq_abl(:,:,2,nt_n,jp_ta), tq_abl(:,:,2,nt_n,jp_qa),             &
316              &           sf(jp_slp )%fnow(:,:,1), sst_m, ssu_m, ssv_m, &
317              &              zssq, zcd_du, zsen, zevp )
318 
319      !!-------------------------------------------------------------------------------------------
320      !! 3 - Advance ABL variables from now (n) to after (n+1)
321      !!-------------------------------------------------------------------------------------------   
322 
323      CALL abl_stp( kt, sst_m, ssu_m, ssv_m, zssq, &                            ! in
324              &         sf(jp_wndi)%fnow(:,:,:), sf(jp_wndj)%fnow(:,:,:),   &
325              &         sf(jp_tair)%fnow(:,:,:), sf(jp_humi)%fnow(:,:,:), sf(jp_slp)%fnow(:,:,1),  &
326              &         sf(jp_hpgi)%fnow(:,:,:), sf(jp_hpgj)%fnow(:,:,:),                          &
327              &         zcd_du, zsen, zevp,    &                                ! in/out
328              &         wndm, utau, vtau, taum )                                ! out
329
330      !!-------------------------------------------------------------------------------------------
331      !! 4 - Finalize flux computation using ABL variables at (n+1), nt_n corresponds to (n+1) since
332      !!                                                                time swap is done in abl_stp
333      !!-------------------------------------------------------------------------------------------   
334
335      CALL blk_oce_2( kt, tq_abl(:,:,2,nt_n,jp_ta), sf(jp_qsr )%fnow(:,:,1), sf(jp_qlw )%fnow(:,:,1),     &
336              &           sf(jp_prec)%fnow(:,:,1),  sf(jp_snow)%fnow(:,:,1),   &
337              &           sst_m , zsen, zevp )
338
339   END SUBROUTINE sbc_abl
340
341
342   !!======================================================================
343END MODULE sbcabl
Note: See TracBrowser for help on using the repository browser.