source: NEMO/branches/2019/dev_r11756_SI3restart_XIOS/src/ICE/icerst.F90 @ 11840

Last change on this file since 11840 was 11840, checked in by andmirek, 2 years ago

Ticket #2323 write SI3 restart with XIOS

  • Property svn:keywords set to Id
File size: 15.5 KB
Line 
1MODULE icerst
2   !!======================================================================
3   !!                     ***  MODULE  icerst  ***
4   !!   sea-ice :  write/read the ice restart file
5   !!======================================================================
6   !! History:   4.0  !  2018     (many people)      SI3 [aka Sea Ice cube]
7   !!----------------------------------------------------------------------
8#if defined key_si3
9   !!----------------------------------------------------------------------
10   !!   'key_si3'                                       SI3 sea-ice model
11   !!----------------------------------------------------------------------
12   !!   ice_rst_opn   : open  restart file
13   !!   ice_rst_write : write restart file
14   !!   ice_rst_read  : read  restart file
15   !!----------------------------------------------------------------------
16   USE ice            ! sea-ice: variables
17   USE dom_oce        ! ocean domain
18   USE phycst  , ONLY : rt0
19   USE sbc_oce , ONLY : nn_fsbc, ln_cpl
20   USE iceistate      ! sea-ice: initial state
21   USE icectl         ! sea-ice: control
22   !
23   USE in_out_manager ! I/O manager
24   USE iom            ! I/O manager library
25   USE lib_mpp        ! MPP library
26   USE lib_fortran    ! fortran utilities (glob_sum + no signed zero)
27
28   IMPLICIT NONE
29   PRIVATE
30
31   PUBLIC   ice_rst_opn     ! called by icestp
32   PUBLIC   ice_rst_write   ! called by icestp
33   PUBLIC   ice_rst_read    ! called by ice_init
34
35   !!----------------------------------------------------------------------
36   !! NEMO/ICE 4.0 , NEMO Consortium (2018)
37   !! $Id$
38   !! Software governed by the CeCILL license (see ./LICENSE)
39   !!----------------------------------------------------------------------
40CONTAINS
41
42   SUBROUTINE ice_rst_opn( kt )
43      !!----------------------------------------------------------------------
44      !!                    ***  ice_rst_opn  ***
45      !!
46      !! ** purpose  :   open restart file
47      !!----------------------------------------------------------------------
48      INTEGER, INTENT(in) ::   kt       ! number of iteration
49      !
50      CHARACTER(len=20)   ::   clkt     ! ocean time-step define as a character
51      CHARACTER(len=50)   ::   clname   ! ice output restart file name
52      CHARACTER(len=256)  ::   clpath   ! full path to ice output restart file
53      CHARACTER(LEN=52)   ::   clpname   ! ocean output restart file name including prefix for AGRIF
54      !!----------------------------------------------------------------------
55      !
56      IF( kt == nit000 )   lrst_ice = .FALSE.   ! default definition
57
58      IF( ln_rst_list .OR. nn_stock /= -1 ) THEN
59      ! in order to get better performances with NetCDF format, we open and define the ice restart file
60      ! one ice time step before writing the data (-> at nitrst - 2*nn_fsbc + 1), except if we write ice
61      ! restart files every ice time step or if an ice restart file was writen at nitend - 2*nn_fsbc + 1
62      IF( kt == nitrst - 2*nn_fsbc + 1 .OR. nn_stock == nn_fsbc    &
63         &                             .OR. ( kt == nitend - nn_fsbc + 1 .AND. .NOT. lrst_ice ) ) THEN
64         IF( nitrst <= nitend .AND. nitrst > 0 ) THEN
65            ! beware of the format used to write kt (default is i8.8, that should be large enough...)
66            IF( nitrst > 99999999 ) THEN   ;   WRITE(clkt, *       ) nitrst
67            ELSE                           ;   WRITE(clkt, '(i8.8)') nitrst
68            ENDIF
69            ! create the file
70            clname = TRIM(cexper)//"_"//TRIM(ADJUSTL(clkt))//"_"//TRIM(cn_icerst_out)
71            clpath = TRIM(cn_icerst_outdir) 
72            IF( clpath(LEN_TRIM(clpath):) /= '/' ) clpath = TRIM(clpath)//'/'
73            IF(lwp) THEN
74               WRITE(numout,*)
75               WRITE(numout,*) '             open ice restart NetCDF file: ',TRIM(clpath)//clname
76               IF( kt == nitrst - 2*nn_fsbc + 1 ) THEN
77                  WRITE(numout,*) '             kt = nitrst - 2*nn_fsbc + 1 = ', kt,' date= ', ndastp
78               ELSE
79                  WRITE(numout,*) '             kt = '                         , kt,' date= ', ndastp
80               ENDIF
81            ENDIF
82            !
83            IF(.NOT.lwxios) THEN
84               CALL iom_open( TRIM(clpath)//TRIM(clname), numriw, ldwrt = .TRUE., kdlev = jpl )
85            ELSE
86#if defined key_iomput
87               cwixios_context = "si3_rstw_"//TRIM(ADJUSTL(clkt))
88               IF( TRIM(Agrif_CFixed()) == '0' ) THEN
89                  clpname = clname
90               ELSE
91                  clpname = TRIM(Agrif_CFixed())//"_"//clname
92               ENDIF
93               CALL iom_init( cwixios_context, TRIM(clpath)//TRIM(clpname), .false. )
94               CALL xios_update_calendar(nitrst)
95               CALL iom_swap(      cxios_context          )
96#else
97               clinfo = 'Can not use XIOS in rst_opn'
98               CALL ctl_stop(TRIM(clinfo))
99#endif
100            ENDIF
101            lrst_ice = .TRUE.
102         ENDIF
103      ENDIF
104      ENDIF
105      !
106      IF( ln_icectl )   CALL ice_prt( kt, iiceprt, jiceprt, 1, ' - Beginning the time step - ' )   ! control print
107      !
108   END SUBROUTINE ice_rst_opn
109
110
111   SUBROUTINE ice_rst_write( kt )
112      !!----------------------------------------------------------------------
113      !!                    ***  ice_rst_write  ***
114      !!
115      !! ** purpose  :   write restart file
116      !!----------------------------------------------------------------------
117      INTEGER, INTENT(in) ::   kt     ! number of iteration
118      !!
119      INTEGER ::   jk    ! dummy loop indices
120      INTEGER ::   iter
121      CHARACTER(len=25) ::   znam
122      CHARACTER(len=2)  ::   zchar, zchar1
123      REAL(wp), DIMENSION(jpi,jpj,jpl) ::   z3d   ! 3D workspace
124      !!----------------------------------------------------------------------
125
126      iter = kt + nn_fsbc - 1   ! ice restarts are written at kt == nitrst - nn_fsbc + 1
127
128      IF( iter == nitrst ) THEN
129         IF(lwp) WRITE(numout,*)
130         IF(lwp) WRITE(numout,*) 'ice_rst_write : write ice restart file  kt =', kt
131         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~~~'         
132      ENDIF
133
134      ! Write in numriw (if iter == nitrst)
135      ! ------------------
136      !                                                                        ! calendar control
137      IF(lwxios) CALL iom_swap(      cwixios_context          )
138      CALL iom_rstput( iter, nitrst, numriw, 'nn_fsbc', REAL( nn_fsbc, wp ), ldxios = lwxios )      ! time-step
139      CALL iom_rstput( iter, nitrst, numriw, 'kt_ice' , REAL( iter   , wp ), ldxios = lwxios )      ! date
140      CALL iom_delay_rst( 'WRITE', 'ICE', numriw )   ! save only ice delayed global communication variables
141
142      ! Prognostic variables
143      CALL iom_rstput( iter, nitrst, numriw, 'v_i'  , v_i, ldxios = lwxios   )
144      CALL iom_rstput( iter, nitrst, numriw, 'v_s'  , v_s, ldxios = lwxios   )
145      CALL iom_rstput( iter, nitrst, numriw, 'sv_i' , sv_i, ldxios = lwxios  )
146      CALL iom_rstput( iter, nitrst, numriw, 'a_i'  , a_i, ldxios = lwxios   )
147      CALL iom_rstput( iter, nitrst, numriw, 't_su' , t_su, ldxios = lwxios  )
148      CALL iom_rstput( iter, nitrst, numriw, 'u_ice', u_ice, ldxios = lwxios )
149      CALL iom_rstput( iter, nitrst, numriw, 'v_ice', v_ice, ldxios = lwxios )
150      CALL iom_rstput( iter, nitrst, numriw, 'oa_i' , oa_i, ldxios = lwxios  )
151      CALL iom_rstput( iter, nitrst, numriw, 'a_ip' , a_ip, ldxios = lwxios  )
152      CALL iom_rstput( iter, nitrst, numriw, 'v_ip' , v_ip, ldxios = lwxios  )
153      ! Snow enthalpy
154      DO jk = 1, nlay_s 
155         WRITE(zchar1,'(I2.2)') jk
156         znam = 'e_s'//'_l'//zchar1
157         z3d(:,:,:) = e_s(:,:,jk,:)
158         CALL iom_rstput( iter, nitrst, numriw, znam , z3d, ldxios = lwxios )
159      END DO
160      ! Ice enthalpy
161      DO jk = 1, nlay_i 
162         WRITE(zchar1,'(I2.2)') jk
163         znam = 'e_i'//'_l'//zchar1
164         z3d(:,:,:) = e_i(:,:,jk,:)
165         CALL iom_rstput( iter, nitrst, numriw, znam , z3d, ldxios = lwxios )
166      END DO
167      ! fields needed for Met Office (Jules) coupling
168      IF( ln_cpl ) THEN
169         CALL iom_rstput( iter, nitrst, numriw, 'cnd_ice', cnd_ice, ldxios = lwxios )
170         CALL iom_rstput( iter, nitrst, numriw, 't1_ice' , t1_ice, ldxios = lwxios  )
171      ENDIF
172      IF(lwxios) CALL iom_swap(      cxios_context          )
173      !
174
175      ! close restart file
176      ! ------------------
177      IF( iter == nitrst ) THEN
178         IF(lwxios) THEN
179            CALL iom_context_finalize(      cwixios_context          )
180         ELSE
181            CALL iom_close( numriw )
182         ENDIF
183         lrst_ice = .FALSE.
184      ENDIF
185      !
186   END SUBROUTINE ice_rst_write
187
188
189   SUBROUTINE ice_rst_read
190      !!----------------------------------------------------------------------
191      !!                    ***  ice_rst_read  ***
192      !!
193      !! ** purpose  :   read restart file
194      !!----------------------------------------------------------------------
195      INTEGER           ::   jk
196      LOGICAL           ::   llok
197      INTEGER           ::   id0, id1, id2, id3, id4   ! local integer
198      CHARACTER(len=25) ::   znam
199      CHARACTER(len=2)  ::   zchar, zchar1
200      REAL(wp)          ::   zfice, ziter
201      REAL(wp), DIMENSION(jpi,jpj,jpl) ::   z3d   ! 3D workspace
202      !!----------------------------------------------------------------------
203
204      IF(lwp) THEN
205         WRITE(numout,*)
206         WRITE(numout,*) 'ice_rst_read: read ice NetCDF restart file'
207         WRITE(numout,*) '~~~~~~~~~~~~'
208      ENDIF
209
210      lxios_sini = .FALSE.
211      CALL iom_open ( TRIM(cn_icerst_indir)//'/'//cn_icerst_in, numrir, kdlev = jpl )
212
213      ! test if v_i exists
214      id0 = iom_varid( numrir, 'v_i' , ldstop = .FALSE. )
215
216      !                    ! ------------------------------ !
217      IF( id0 > 0 ) THEN   ! == case of a normal restart == !
218         !                 ! ------------------------------ !
219         IF(.NOT.lxios_set) THEN
220            lrxios = lrxios.AND.lxios_sini
221         ELSE
222            IF(.NOT.lxios_sini) THEN
223               WRITE(ctmp1,*) 'E R R O R : XIOS can not be used to read SI3 restart from multiple files'
224               CALL ctl_stop( 'ice_rst_read:', ctmp1 )
225            ENDIF
226         ENDIF
227
228         lrsi3_nemo = .TRUE.                       ! SI3 restart written by NEMO
229
230         IF(lrxios) THEN
231           crixios_context = 'si3_rst'
232           CALL iom_init( crixios_context, TRIM(cn_icerst_indir)//'/'//cn_icerst_in, ld_tmppatch = .false. )
233           lxios_set = .TRUE.
234         ENDIF
235
236         ! Time info
237         CALL iom_get( numrir, 'nn_fsbc', zfice, ldxios = lrxios )
238         CALL iom_get( numrir, 'kt_ice' , ziter, ldxios = lrxios )   
239         IF(lwp) WRITE(numout,*) '   read ice restart file at time step    : ', ziter
240         IF(lwp) WRITE(numout,*) '   in any case we force it to nit000 - 1 : ', nit000 - 1
241
242         ! Control of date
243         IF( ( nit000 - NINT(ziter) ) /= 1 .AND. ABS( nrstdt ) == 1 )   &
244            &     CALL ctl_stop( 'ice_rst_read ===>>>> : problem with nit000 in ice restart',  &
245            &                   '   verify the file or rerun with the value 0 for the',        &
246            &                   '   control of time parameter  nrstdt' )
247         IF( NINT(zfice) /= nn_fsbc          .AND. ABS( nrstdt ) == 1 )   &
248            &     CALL ctl_stop( 'ice_rst_read ===>>>> : problem with nn_fsbc in ice restart',  &
249            &                   '   verify the file or rerun with the value 0 for the',         &
250            &                   '   control of time parameter  nrstdt' )
251
252         ! --- mandatory fields --- !
253         CALL iom_get( numrir, jpdom_autoglo, 'v_i'  , v_i, ldxios = lrxios   )
254         CALL iom_get( numrir, jpdom_autoglo, 'v_s'  , v_s, ldxios = lrxios   )
255         CALL iom_get( numrir, jpdom_autoglo, 'sv_i' , sv_i, ldxios = lrxios  )
256         CALL iom_get( numrir, jpdom_autoglo, 'a_i'  , a_i, ldxios = lrxios   )
257         CALL iom_get( numrir, jpdom_autoglo, 't_su' , t_su, ldxios = lrxios  )
258         CALL iom_get( numrir, jpdom_autoglo, 'u_ice', u_ice, ldxios = lrxios )
259         CALL iom_get( numrir, jpdom_autoglo, 'v_ice', v_ice, ldxios = lrxios )
260         ! Snow enthalpy
261         IF(lrsi3_nemo) THEN
262!NEMO read inerface
263            DO jk = 1, nlay_s
264               WRITE(zchar1,'(I2.2)') jk
265               znam = 'e_s'//'_l'//zchar1
266               CALL iom_get( numrir, jpdom_autoglo, znam , z3d, ldxios = lrxios  )
267               e_s(:,:,jk,:) = z3d(:,:,:)
268            END DO
269            ! Ice enthalpy
270            DO jk = 1, nlay_i
271               WRITE(zchar1,'(I2.2)') jk
272               znam = 'e_i'//'_l'//zchar1
273               CALL iom_get( numrir, jpdom_autoglo, znam , z3d, ldxios = lrxios  )
274               e_i(:,:,jk,:) = z3d(:,:,:)
275            END DO
276         ELSE
277!XIOS read interface
278            CALL iom_get( numrir, jpdom_autoglo, "e_s" , e_s, ldxios = lrxios  )
279            CALL iom_get( numrir, jpdom_autoglo, "e_i" , e_i, ldxios = lrxios  ) 
280         ENDIF
281         ! -- optional fields -- !
282         ! ice age
283         id1 = iom_varid( numrir, 'oa_i' , ldstop = .FALSE. )
284         IF( id1 > 0 ) THEN                       ! fields exist
285            CALL iom_get( numrir, jpdom_autoglo, 'oa_i', oa_i, ldxios = lrxios )
286         ELSE                                     ! start from rest
287            IF(lwp) WRITE(numout,*) '   ==>>   previous run without ice age output then set it to zero'
288            oa_i(:,:,:) = 0._wp
289         ENDIF
290         ! melt ponds
291         id2 = iom_varid( numrir, 'a_ip' , ldstop = .FALSE. )
292         IF( id2 > 0 ) THEN                       ! fields exist
293            CALL iom_get( numrir, jpdom_autoglo, 'a_ip' , a_ip, ldxios = lrxios )
294            CALL iom_get( numrir, jpdom_autoglo, 'v_ip' , v_ip, ldxios = lrxios )
295         ELSE                                     ! start from rest
296            IF(lwp) WRITE(numout,*) '   ==>>   previous run without melt ponds output then set it to zero'
297            a_ip(:,:,:) = 0._wp
298            v_ip(:,:,:) = 0._wp
299         ENDIF
300         ! fields needed for Met Office (Jules) coupling
301         IF( ln_cpl ) THEN
302            id3 = iom_varid( numrir, 'cnd_ice' , ldstop = .FALSE. )
303            id4 = iom_varid( numrir, 't1_ice'  , ldstop = .FALSE. )
304            IF( id3 > 0 .AND. id4 > 0 ) THEN         ! fields exist
305               CALL iom_get( numrir, jpdom_autoglo, 'cnd_ice', cnd_ice, ldxios = lrxios )
306               CALL iom_get( numrir, jpdom_autoglo, 't1_ice' , t1_ice, ldxios = lrxios  )
307            ELSE                                     ! start from rest
308               IF(lwp) WRITE(numout,*) '   ==>>   previous run without conductivity output then set it to zero'
309               cnd_ice(:,:,:) = 0._wp
310               t1_ice (:,:,:) = rt0
311            ENDIF
312         ENDIF
313         IF(lrxios) CALL iom_swap( TRIM(cxios_context) )
314         CALL iom_delay_rst( 'READ', 'ICE', numrir )   ! read only ice delayed global communication variables
315
316         !                 ! ---------------------------------- !
317      ELSE                 ! == case of a simplified restart == !
318         !                 ! ---------------------------------- !
319         CALL ctl_warn('ice_rst_read: you are using a simplified ice restart')
320         !
321         CALL ice_istate_init
322         CALL ice_istate( nit000 )
323         !
324         IF( .NOT.ln_iceini .OR. .NOT.ln_iceini_file ) &
325            &   CALL ctl_stop('STOP', 'ice_rst_read: you need ln_ice_ini=T and ln_iceini_file=T')
326         !
327      ENDIF
328
329   END SUBROUTINE ice_rst_read
330
331#else
332   !!----------------------------------------------------------------------
333   !!   Default option :       Empty module           NO SI3 sea-ice model
334   !!----------------------------------------------------------------------
335#endif
336
337   !!======================================================================
338END MODULE icerst
Note: See TracBrowser for help on using the repository browser.