source: NEMO/branches/2019/dev_r11943_MERGE_2019/src/NST/agrif_oce_sponge.F90 @ 12229

Last change on this file since 12229 was 12229, checked in by acc, 20 months ago

2019/dev_r11943_MERGE_2019: Merge in dev_AGRIF-01-05_merged. Fully SETTE tested

  • Property svn:keywords set to Id
File size: 32.5 KB
Line 
1#define SPONGE && define SPONGE_TOP
2
3MODULE agrif_oce_sponge
4   !!======================================================================
5   !!                   ***  MODULE  agrif_oce_interp  ***
6   !! AGRIF: sponge package for the ocean dynamics (OPA)
7   !!======================================================================
8   !! History :  2.0  !  2002-06  (XXX)  Original cade
9   !!             -   !  2005-11  (XXX)
10   !!            3.2  !  2009-04  (R. Benshila)
11   !!            3.6  !  2014-09  (R. Benshila)
12   !!----------------------------------------------------------------------
13#if defined key_agrif
14   !!----------------------------------------------------------------------
15   !!   'key_agrif'                                              AGRIF zoom
16   !!----------------------------------------------------------------------
17   USE par_oce
18   USE oce
19   USE dom_oce
20   !
21   USE in_out_manager
22   USE agrif_oce
23   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
24   USE iom
25   USE vremap
26
27   IMPLICIT NONE
28   PRIVATE
29
30   PUBLIC Agrif_Sponge, Agrif_Sponge_Tra, Agrif_Sponge_Dyn
31   PUBLIC interptsn_sponge, interpun_sponge, interpvn_sponge
32
33   !!----------------------------------------------------------------------
34   !! NEMO/NST 4.0 , NEMO Consortium (2018)
35   !! $Id$
36   !! Software governed by the CeCILL license (see ./LICENSE)
37   !!----------------------------------------------------------------------
38CONTAINS
39
40   SUBROUTINE Agrif_Sponge_Tra
41      !!----------------------------------------------------------------------
42      !!                 *** ROUTINE Agrif_Sponge_Tra ***
43      !!----------------------------------------------------------------------
44      REAL(wp) ::   zcoef   ! local scalar
45     
46      !!----------------------------------------------------------------------
47      !
48#if defined SPONGE
49      !! Assume persistence:
50      zcoef = REAL(Agrif_rhot()-1,wp)/REAL(Agrif_rhot())
51
52      CALL Agrif_Sponge
53      Agrif_SpecialValue    = 0._wp
54      Agrif_UseSpecialValue = .TRUE.
55      tabspongedone_tsn     = .FALSE.
56      !
57      CALL Agrif_Bc_Variable( tsn_sponge_id, calledweight=zcoef, procname=interptsn_sponge )
58      !
59      Agrif_UseSpecialValue = .FALSE.
60#endif
61      !
62      CALL iom_put( 'agrif_spu', fspu(:,:))
63      CALL iom_put( 'agrif_spv', fspv(:,:))
64      !
65   END SUBROUTINE Agrif_Sponge_Tra
66
67
68   SUBROUTINE Agrif_Sponge_dyn
69      !!----------------------------------------------------------------------
70      !!                 *** ROUTINE Agrif_Sponge_dyn ***
71      !!----------------------------------------------------------------------
72      REAL(wp) ::   zcoef   ! local scalar
73      !!----------------------------------------------------------------------
74      !
75#if defined SPONGE
76      zcoef = REAL(Agrif_rhot()-1,wp)/REAL(Agrif_rhot())
77
78      Agrif_SpecialValue=0.
79      Agrif_UseSpecialValue = ln_spc_dyn
80      !
81      tabspongedone_u = .FALSE.
82      tabspongedone_v = .FALSE.         
83      CALL Agrif_Bc_Variable( un_sponge_id, calledweight=zcoef, procname=interpun_sponge )
84      !
85      tabspongedone_u = .FALSE.
86      tabspongedone_v = .FALSE.
87      CALL Agrif_Bc_Variable( vn_sponge_id, calledweight=zcoef, procname=interpvn_sponge )
88      !
89      Agrif_UseSpecialValue = .FALSE.
90#endif
91      !
92      CALL iom_put( 'agrif_spt', fspt(:,:))
93      CALL iom_put( 'agrif_spf', fspf(:,:))
94      !
95   END SUBROUTINE Agrif_Sponge_dyn
96
97
98   SUBROUTINE Agrif_Sponge
99      !!----------------------------------------------------------------------
100      !!                 *** ROUTINE  Agrif_Sponge ***
101      !!----------------------------------------------------------------------
102      INTEGER  ::   ji, jj, ind1, ind2
103      INTEGER  ::   ispongearea, jspongearea
104      REAL(wp) ::   z1_ispongearea, z1_jspongearea
105      REAL(wp), DIMENSION(jpi,jpj) :: ztabramp
106      REAL(wp), DIMENSION(jpjmax)  :: zmskwest,  zmskeast
107      REAL(wp), DIMENSION(jpimax)  :: zmsknorth, zmsksouth
108      !!----------------------------------------------------------------------
109      !
110      ! Sponge 1d example with:
111      !      iraf = 3 ; nbghost = 3 ; nn_sponge_len = 2
112      !                       
113      !coarse :     U     T     U     T     U     T     U
114      !|            |           |           |           |
115      !fine :     t u t u t u t u t u t u t u t u t u t u t
116      !sponge val:0   0   0   1  5/6 4/6 3/6 2/6 1/6  0   0
117      !           |   ghost     | <-- sponge area  -- > |
118      !           |   points    |                       |
119      !                         |--> dynamical interface
120
121#if defined SPONGE || defined SPONGE_TOP
122      IF (( .NOT. spongedoneT ).OR.( .NOT. spongedoneU )) THEN
123         !
124         ! Retrieve masks at open boundaries:
125
126         ! --- West --- !
127         ztabramp(:,:) = 0._wp
128         ind1 = 1+nbghostcells
129         DO ji = mi0(ind1), mi1(ind1)               
130            ztabramp(ji,:) = ssumask(ji,:)
131         END DO
132         !
133         zmskwest(:) = 0._wp
134         zmskwest(1:jpj) = MAXVAL(ztabramp(:,:), dim=1)
135
136         ! --- East --- !
137         ztabramp(:,:) = 0._wp
138         ind1 = jpiglo - nbghostcells - 1
139         DO ji = mi0(ind1), mi1(ind1)                 
140            ztabramp(ji,:) = ssumask(ji,:)
141         END DO
142         !
143         zmskeast(:) = 0._wp
144         zmskeast(1:jpj) = MAXVAL(ztabramp(:,:), dim=1)
145
146         ! --- South --- !
147         ztabramp(:,:) = 0._wp
148         ind1 = 1+nbghostcells
149         DO jj = mj0(ind1), mj1(ind1)                 
150            ztabramp(:,jj) = ssvmask(:,jj)
151         END DO
152         !
153         zmsksouth(:) = 0._wp
154         zmsksouth(1:jpi) = MAXVAL(ztabramp(:,:), dim=2)
155
156         ! --- North --- !
157         ztabramp(:,:) = 0._wp
158         ind1 = jpjglo - nbghostcells - 1
159         DO jj = mj0(ind1), mj1(ind1)                 
160            ztabramp(:,jj) = ssvmask(:,jj)
161         END DO
162         !
163         zmsknorth(:) = 0._wp
164         zmsknorth(1:jpi) = MAXVAL(ztabramp(:,:), dim=2)
165         ! JC: SPONGE MASKING TO BE SORTED OUT:
166         zmskwest(:)  = 1._wp
167         zmskeast(:)  = 1._wp
168         zmsknorth(:) = 1._wp
169         zmsksouth(:) = 1._wp
170#if defined key_mpp_mpi
171!         CALL mpp_max( 'AGRIF_sponge', zmskwest(:) , jpjmax )
172!         CALL mpp_max( 'AGRIF_Sponge', zmskeast(:) , jpjmax )
173!         CALL mpp_max( 'AGRIF_Sponge', zmsksouth(:), jpimax )
174!         CALL mpp_max( 'AGRIF_Sponge', zmsknorth(:), jpimax )
175#endif
176
177         ! Define ramp from boundaries towards domain interior at T-points
178         ! Store it in ztabramp
179
180         ispongearea  = nn_sponge_len * Agrif_irhox()
181         z1_ispongearea = 1._wp / REAL( ispongearea )
182         jspongearea  = nn_sponge_len * Agrif_irhoy()
183         z1_jspongearea = 1._wp / REAL( jspongearea )
184         
185         ztabramp(:,:) = 0._wp
186
187         ! Trick to remove sponge in 2DV domains:
188         IF ( nbcellsx <= 3 ) ispongearea = -1
189         IF ( nbcellsy <= 3 ) jspongearea = -1
190
191         ! --- West --- !
192         ind1 = 1+nbghostcells
193         ind2 = 1+nbghostcells + ispongearea 
194         DO ji = mi0(ind1), mi1(ind2)   
195            DO jj = 1, jpj               
196               ztabramp(ji,jj) = REAL( ind2 - mig(ji) ) * z1_ispongearea * zmskwest(jj)
197            END DO
198         END DO
199
200         ! ghost cells:
201         ind1 = 1
202         ind2 = nbghostcells + 1
203         DO ji = mi0(ind1), mi1(ind2)   
204            DO jj = 1, jpj               
205               ztabramp(ji,jj) = zmskwest(jj)
206            END DO
207         END DO
208
209         ! --- East --- !
210         ind1 = jpiglo - nbghostcells - ispongearea
211         ind2 = jpiglo - nbghostcells
212         DO ji = mi0(ind1), mi1(ind2)
213            DO jj = 1, jpj
214               ztabramp(ji,jj) = MAX( ztabramp(ji,jj), REAL( mig(ji) - ind1 ) * z1_ispongearea) * zmskeast(jj)
215            ENDDO
216         END DO
217
218         ! ghost cells:
219         ind1 = jpiglo - nbghostcells
220         ind2 = jpiglo
221         DO ji = mi0(ind1), mi1(ind2)
222            DO jj = 1, jpj
223               ztabramp(ji,jj) = zmskeast(jj)
224            ENDDO
225         END DO
226
227         ! --- South --- !
228         ind1 = 1+nbghostcells
229         ind2 = 1+nbghostcells + jspongearea
230         DO jj = mj0(ind1), mj1(ind2) 
231            DO ji = 1, jpi
232               ztabramp(ji,jj) = MAX( ztabramp(ji,jj), REAL( ind2 - mjg(jj) ) * z1_jspongearea) * zmsksouth(ji)
233            END DO
234         END DO
235
236         ! ghost cells:
237         ind1 = 1
238         ind2 = nbghostcells + 1
239         DO jj = mj0(ind1), mj1(ind2) 
240            DO ji = 1, jpi
241               ztabramp(ji,jj) = zmsksouth(ji)
242            END DO
243         END DO
244
245         ! --- North --- !
246         ind1 = jpjglo - nbghostcells - jspongearea
247         ind2 = jpjglo - nbghostcells
248         DO jj = mj0(ind1), mj1(ind2)
249            DO ji = 1, jpi
250               ztabramp(ji,jj) = MAX( ztabramp(ji,jj), REAL( mjg(jj) - ind1 ) * z1_jspongearea) * zmsknorth(ji)
251            END DO
252         END DO
253
254         ! ghost cells:
255         ind1 = jpjglo - nbghostcells
256         ind2 = jpjglo
257         DO jj = mj0(ind1), mj1(ind2)
258            DO ji = 1, jpi
259               ztabramp(ji,jj) = zmsknorth(ji)
260            END DO
261         END DO
262
263      ENDIF
264
265      ! Tracers
266      IF( .NOT. spongedoneT ) THEN
267         fspu(:,:) = 0._wp
268         fspv(:,:) = 0._wp
269         DO jj = 2, jpjm1
270            DO ji = 2, jpim1   ! vector opt.
271               fspu(ji,jj) = 0.5_wp * ( ztabramp(ji,jj) + ztabramp(ji+1,jj  ) ) * ssumask(ji,jj)
272               fspv(ji,jj) = 0.5_wp * ( ztabramp(ji,jj) + ztabramp(ji  ,jj+1) ) * ssvmask(ji,jj)
273            END DO
274         END DO
275         CALL lbc_lnk( 'agrif_Sponge', fspu, 'U', 1. )   ! Lateral boundary conditions
276         CALL lbc_lnk( 'agrif_Sponge', fspv, 'V', 1. )
277
278         spongedoneT = .TRUE.
279      ENDIF
280
281      ! Dynamics
282      IF( .NOT. spongedoneU ) THEN
283         fspt(:,:) = 0._wp
284         fspf(:,:) = 0._wp
285         DO jj = 2, jpjm1
286            DO ji = 2, jpim1   ! vector opt.
287               fspt(ji,jj) = ztabramp(ji,jj) * ssmask(ji,jj)
288               fspf(ji,jj) = 0.25_wp * ( ztabramp(ji  ,jj  ) + ztabramp(ji  ,jj+1)   &
289                                     &  +ztabramp(ji+1,jj+1) + ztabramp(ji+1,jj  ) ) &
290                                     &  * ssvmask(ji,jj) * ssvmask(ji,jj+1)
291            END DO
292         END DO
293         CALL lbc_lnk( 'agrif_Sponge', fspt, 'T', 1. )   ! Lateral boundary conditions
294         CALL lbc_lnk( 'agrif_Sponge', fspf, 'F', 1. )
295         
296         spongedoneU = .TRUE.
297      ENDIF
298
299#if defined key_vertical
300      ! Remove vertical interpolation where not needed:
301      DO jj = 2, jpjm1
302         DO ji = 2, jpim1
303            IF ((fspu(ji-1,jj)==0._wp).AND.(fspu(ji,jj)==0._wp).AND. &
304            &   (fspv(ji,jj-1)==0._wp).AND.(fspv(ji,jj)==0._wp)) mbkt_parent(ji,jj) = 0
305!
306            IF ((fspt(ji+1,jj)==0._wp).AND.(fspt(ji,jj)==0._wp).AND. &
307            &   (fspf(ji,jj-1)==0._wp).AND.(fspf(ji,jj)==0._wp)) mbku_parent(ji,jj) = 0
308!
309            IF ((fspt(ji,jj+1)==0._wp).AND.(fspt(ji,jj)==0._wp).AND. &
310            &   (fspf(ji-1,jj)==0._wp).AND.(fspf(ji,jj)==0._wp)) mbkv_parent(ji,jj) = 0
311!
312            IF ( ssmask(ji,jj) == 0._wp) mbkt_parent(ji,jj) = 0
313            IF (ssumask(ji,jj) == 0._wp) mbku_parent(ji,jj) = 0
314            IF (ssvmask(ji,jj) == 0._wp) mbkv_parent(ji,jj) = 0
315         END DO
316      END DO
317      !
318      ztabramp(:,:) = REAL( mbkt_parent(:,:), wp )   ;   CALL lbc_lnk( 'Agrif_Sponge', ztabramp, 'T', 1. )
319      mbkt_parent(:,:) = NINT( ztabramp(:,:) )
320      ztabramp(:,:) = REAL( mbku_parent(:,:), wp )   ;   CALL lbc_lnk( 'Agrif_Sponge', ztabramp, 'U', 1. )
321      mbku_parent(:,:) = NINT( ztabramp(:,:) )
322      ztabramp(:,:) = REAL( mbkv_parent(:,:), wp )   ;   CALL lbc_lnk( 'Agrif_Sponge', ztabramp, 'V', 1. )
323      mbkv_parent(:,:) = NINT( ztabramp(:,:) )
324#endif
325      !
326#endif
327      !
328   END SUBROUTINE Agrif_Sponge
329
330   SUBROUTINE interptsn_sponge( tabres, i1, i2, j1, j2, k1, k2, n1, n2, before )
331      !!----------------------------------------------------------------------
332      !!                 *** ROUTINE interptsn_sponge ***
333      !!----------------------------------------------------------------------
334      INTEGER                                     , INTENT(in   ) ::   i1, i2, j1, j2, k1, k2, n1, n2
335      REAL(wp), DIMENSION(i1:i2,j1:j2,k1:k2,n1:n2), INTENT(inout) ::   tabres
336      LOGICAL                                     , INTENT(in   ) ::   before
337      !
338      INTEGER  ::   ji, jj, jk, jn   ! dummy loop indices
339      INTEGER  ::   iku, ikv
340      REAL(wp) :: ztsa, zabe1, zabe2, zbtr, zhtot, ztrelax
341      REAL(wp), DIMENSION(i1:i2,j1:j2,jpk) :: ztu, ztv
342      REAL(wp), DIMENSION(i1:i2,j1:j2,jpk,n1:n2) ::tsbdiff
343      ! vertical interpolation:
344      REAL(wp), DIMENSION(i1:i2,j1:j2,jpk,n1:n2) ::tabres_child
345      REAL(wp), DIMENSION(k1:k2,n1:n2-1) :: tabin
346      REAL(wp), DIMENSION(k1:k2) :: h_in
347      REAL(wp), DIMENSION(1:jpk) :: h_out
348      INTEGER :: N_in, N_out
349      !!----------------------------------------------------------------------
350      !
351      IF( before ) THEN
352         DO jn = 1, jpts
353            DO jk=k1,k2
354               DO jj=j1,j2
355                  DO ji=i1,i2
356                     tabres(ji,jj,jk,jn) = ts(ji,jj,jk,jn,Kbb_a)
357                  END DO
358               END DO
359            END DO
360         END DO
361
362# if defined key_vertical
363        ! Interpolate thicknesses
364        ! Warning: these are masked, hence extrapolated prior interpolation.
365        DO jk=k1,k2
366           DO jj=j1,j2
367              DO ji=i1,i2
368                  tabres(ji,jj,jk,jpts+1) = tmask(ji,jj,jk) * e3t(ji,jj,jk,Kbb_a)
369              END DO
370           END DO
371        END DO
372
373        ! Extrapolate thicknesses in partial bottom cells:
374        ! Set them to Agrif_SpecialValue (0.). Correct bottom thicknesses are retrieved later on
375        IF (ln_zps) THEN
376           DO jj=j1,j2
377              DO ji=i1,i2
378                  jk = mbkt(ji,jj)
379                  tabres(ji,jj,jk,jpts+1) = 0._wp
380              END DO
381           END DO           
382        END IF
383     
384        ! Save ssh at last level:
385        IF (.NOT.ln_linssh) THEN
386           tabres(i1:i2,j1:j2,k2,jpts+1) = ssh(i1:i2,j1:j2,Kbb_a)*tmask(i1:i2,j1:j2,1) 
387        ELSE
388           tabres(i1:i2,j1:j2,k2,jpts+1) = 0._wp
389        END IF     
390# endif
391
392      ELSE   
393         !
394# if defined key_vertical
395
396         IF (ln_linssh) tabres(i1:i2,j1:j2,k2,n2) = 0._wp
397
398         DO jj=j1,j2
399            DO ji=i1,i2
400               tabres_child(ji,jj,:,:) = 0._wp 
401               N_in = mbkt_parent(ji,jj)
402               zhtot = 0._wp
403               DO jk=1,N_in !k2 = jpk of parent grid
404                  IF (jk==N_in) THEN
405                     h_in(jk) = ht0_parent(ji,jj) + tabres(ji,jj,k2,n2) - zhtot
406                  ELSE
407                     h_in(jk) = tabres(ji,jj,jk,n2)
408                  ENDIF
409                  zhtot = zhtot + h_in(jk)
410                  tabin(jk,:) = tabres(ji,jj,jk,n1:n2-1)
411               END DO
412               N_out = 0
413               DO jk=1,jpk ! jpk of child grid
414                  IF (tmask(ji,jj,jk) == 0) EXIT
415                  N_out = N_out + 1
416                  h_out(jk) = e3t(ji,jj,jk,Kbb_a) !Child grid scale factors. Could multiply by e1e2t here instead of division above
417               ENDDO
418
419               ! Account for small differences in free-surface
420               IF ( sum(h_out(1:N_out)) > sum(h_in(1:N_in) )) THEN
421                  h_out(1) = h_out(1) - ( sum(h_out(1:N_out))-sum(h_in(1:N_in)) )
422               ELSE
423                  h_in(1)   = h_in(1)   - (sum(h_in(1:N_in))-sum(h_out(1:N_out)) )
424               ENDIF
425               IF (N_in*N_out > 0) THEN
426                  CALL reconstructandremap(tabin(1:N_in,1:jpts),h_in(1:N_in),tabres_child(ji,jj,1:N_out,1:jpts),h_out(1:N_out),N_in,N_out,jpts)
427               ENDIF
428            ENDDO
429         ENDDO
430# endif
431
432         DO jj=j1,j2
433            DO ji=i1,i2
434               DO jk=1,jpkm1
435# if defined key_vertical
436                  tsbdiff(ji,jj,jk,1:jpts) = (ts(ji,jj,jk,1:jpts,Kbb_a) - tabres_child(ji,jj,jk,1:jpts)) * tmask(ji,jj,jk)
437# else
438                  tsbdiff(ji,jj,jk,1:jpts) = (ts(ji,jj,jk,1:jpts,Kbb_a) - tabres(ji,jj,jk,1:jpts))*tmask(ji,jj,jk)
439# endif
440               ENDDO
441            ENDDO
442         ENDDO
443
444         !* set relaxation time scale
445         IF( neuler == 0 .AND. lk_agrif_fstep ) THEN   ;   ztrelax =   rn_trelax_tra  / (        rdt )
446         ELSE                                          ;   ztrelax =   rn_trelax_tra  / (2._wp * rdt )
447         ENDIF
448
449         DO jn = 1, jpts           
450            DO jk = 1, jpkm1
451               ztu(i1:i2,j1:j2,jk) = 0._wp
452               DO jj = j1,j2
453                  DO ji = i1,i2-1
454                     zabe1 = rn_sponge_tra * fspu(ji,jj) * umask(ji,jj,jk) * e2_e1u(ji,jj) * e3u(ji,jj,jk,Kmm_a)
455                     ztu(ji,jj,jk) = zabe1 * ( tsbdiff(ji+1,jj  ,jk,jn) - tsbdiff(ji,jj,jk,jn) ) 
456                  END DO
457               END DO
458               ztv(i1:i2,j1:j2,jk) = 0._wp
459               DO ji = i1,i2
460                  DO jj = j1,j2-1
461                     zabe2 = rn_sponge_tra * fspv(ji,jj) * vmask(ji,jj,jk) * e1_e2v(ji,jj) * e3v(ji,jj,jk,Kmm_a)
462                     ztv(ji,jj,jk) = zabe2 * ( tsbdiff(ji  ,jj+1,jk,jn) - tsbdiff(ji,jj,jk,jn) )
463                  END DO
464               END DO
465               !
466               IF( ln_zps ) THEN      ! set gradient at partial step level
467                  DO jj = j1,j2
468                     DO ji = i1,i2
469                        ! last level
470                        iku = mbku(ji,jj)
471                        ikv = mbkv(ji,jj)
472                        IF( iku == jk )   ztu(ji,jj,jk) = 0._wp
473                        IF( ikv == jk )   ztv(ji,jj,jk) = 0._wp
474                     END DO
475                  END DO
476               ENDIF
477            END DO
478            !
479            DO jk = 1, jpkm1
480               DO jj = j1+1,j2-1
481                  DO ji = i1+1,i2-1
482                     IF (.NOT. tabspongedone_tsn(ji,jj)) THEN
483                        zbtr = r1_e1e2t(ji,jj) / e3t(ji,jj,jk,Kmm_a)
484                        ! horizontal diffusive trends
485                        ztsa = zbtr * (  ztu(ji,jj,jk) - ztu(ji-1,jj,jk) + ztv(ji,jj,jk) - ztv(ji,jj-1,jk)  ) &
486                             &  - ztrelax * fspt(ji,jj) * tsbdiff(ji,jj,jk,jn) 
487                        ! add it to the general tracer trends
488                        ts(ji,jj,jk,jn,Krhs_a) = ts(ji,jj,jk,jn,Krhs_a) + ztsa
489                     ENDIF
490                  END DO
491               END DO
492            END DO
493            !
494         END DO
495         !
496         tabspongedone_tsn(i1+1:i2-1,j1+1:j2-1) = .TRUE.
497         !
498      ENDIF
499      !
500   END SUBROUTINE interptsn_sponge
501
502   SUBROUTINE interpun_sponge(tabres,i1,i2,j1,j2,k1,k2,m1,m2, before)
503      !!---------------------------------------------
504      !!   *** ROUTINE interpun_sponge ***
505      !!---------------------------------------------   
506      INTEGER, INTENT(in) :: i1,i2,j1,j2,k1,k2,m1,m2
507      REAL(wp), DIMENSION(i1:i2,j1:j2,k1:k2,m1:m2), INTENT(inout) :: tabres
508      LOGICAL, INTENT(in) :: before
509
510      INTEGER :: ji,jj,jk,jmax
511
512      ! sponge parameters
513      REAL(wp) :: ze2u, ze1v, zua, zva, zbtr, zhtot, ztrelax
514      REAL(wp), DIMENSION(i1:i2,j1:j2,1:jpk) :: ubdiff
515      REAL(wp), DIMENSION(i1:i2,j1:j2,1:jpk) :: rotdiff, hdivdiff
516      ! vertical interpolation:
517      REAL(wp), DIMENSION(i1:i2,j1:j2,1:jpk) :: tabres_child
518      REAL(wp), DIMENSION(k1:k2) :: tabin, h_in
519      REAL(wp), DIMENSION(1:jpk) :: h_out
520      INTEGER ::N_in, N_out
521      !!---------------------------------------------   
522      !
523      IF( before ) THEN
524         DO jk=k1,k2
525            DO jj=j1,j2
526               DO ji=i1,i2
527                  tabres(ji,jj,jk,m1) = uu(ji,jj,jk,Kbb_a)
528# if defined key_vertical
529                  tabres(ji,jj,jk,m2) = e3u(ji,jj,jk,Kbb_a)*umask(ji,jj,jk)
530# endif
531               END DO
532            END DO
533         END DO
534
535# if defined key_vertical
536         ! Extrapolate thicknesses in partial bottom cells:
537         ! Set them to Agrif_SpecialValue (0.). Correct bottom thicknesses are retrieved later on
538         IF (ln_zps) THEN
539            DO jj=j1,j2
540               DO ji=i1,i2
541                  jk = mbku(ji,jj)
542                  tabres(ji,jj,jk,m2) = 0._wp
543               END DO
544            END DO           
545         END IF
546        ! Save ssh at last level:
547        tabres(i1:i2,j1:j2,k2,m2) = 0._wp
548        IF (.NOT.ln_linssh) THEN
549           ! This vertical sum below should be replaced by the sea-level at U-points (optimization):
550           DO jk=1,jpk
551              tabres(i1:i2,j1:j2,k2,m2) = tabres(i1:i2,j1:j2,k2,m2) + e3u(i1:i2,j1:j2,jk,Kbb_a) * umask(i1:i2,j1:j2,jk)
552           END DO
553           tabres(i1:i2,j1:j2,k2,m2) = tabres(i1:i2,j1:j2,k2,m2) - hu_0(i1:i2,j1:j2)
554        END IF 
555# endif
556
557      ELSE
558
559# if defined key_vertical
560         IF (ln_linssh) tabres(i1:i2,j1:j2,k2,m2) = 0._wp
561
562         DO jj=j1,j2
563            DO ji=i1,i2
564               tabres_child(ji,jj,:) = 0._wp
565               N_in = mbku_parent(ji,jj)
566               zhtot = 0._wp
567               DO jk=1,N_in
568                  IF (jk==N_in) THEN
569                     h_in(jk) = hu0_parent(ji,jj) + tabres(ji,jj,k2,m2) - zhtot
570                  ELSE
571                     h_in(jk) = tabres(ji,jj,jk,m2)
572                  ENDIF
573                  zhtot = zhtot + h_in(jk)
574                  tabin(jk) = tabres(ji,jj,jk,m1)
575               ENDDO
576               !         
577               N_out = 0
578               DO jk=1,jpk
579                  IF (umask(ji,jj,jk) == 0) EXIT
580                  N_out = N_out + 1
581                  h_out(N_out) = e3u(ji,jj,jk,Kbb_a)
582               ENDDO
583
584               ! Account for small differences in free-surface
585               IF ( sum(h_out(1:N_out)) > sum(h_in(1:N_in) )) THEN
586                  h_out(1) = h_out(1) - ( sum(h_out(1:N_out))-sum(h_in(1:N_in)) )
587               ELSE
588                  h_in(1)   = h_in(1)   - (sum(h_in(1:N_in))-sum(h_out(1:N_out)) )
589               ENDIF
590                 
591               IF (N_in * N_out > 0) THEN
592                  CALL reconstructandremap(tabin(1:N_in),h_in(1:N_in),tabres_child(ji,jj,1:N_out),h_out(1:N_out),N_in,N_out,1)
593               ENDIF
594            ENDDO
595         ENDDO
596
597         ubdiff(i1:i2,j1:j2,:) = (uu(i1:i2,j1:j2,:,Kbb_a) - tabres_child(i1:i2,j1:j2,:))*umask(i1:i2,j1:j2,:)
598#else
599         ubdiff(i1:i2,j1:j2,:) = (uu(i1:i2,j1:j2,:,Kbb_a) - tabres(i1:i2,j1:j2,:,1))*umask(i1:i2,j1:j2,:)
600#endif
601         !* set relaxation time scale
602         IF( neuler == 0 .AND. lk_agrif_fstep ) THEN   ;   ztrelax =   rn_trelax_dyn  / (        rdt )
603         ELSE                                          ;   ztrelax =   rn_trelax_dyn  / (2._wp * rdt )
604         ENDIF
605         !
606         DO jk = 1, jpkm1                                 ! Horizontal slab
607            !                                             ! ===============
608
609            !                                             ! --------
610            ! Horizontal divergence                       !   div
611            !                                             ! --------
612            DO jj = j1,j2
613               DO ji = i1+1,i2   ! vector opt.
614                  zbtr = r1_e1e2t(ji,jj) / e3t(ji,jj,jk,Kbb_a) * rn_sponge_dyn * fspt(ji,jj)
615                  hdivdiff(ji,jj,jk) = (  e2u(ji  ,jj)*e3u(ji  ,jj,jk,Kbb_a) * ubdiff(ji  ,jj,jk) &
616                                     &   -e2u(ji-1,jj)*e3u(ji-1,jj,jk,Kbb_a) * ubdiff(ji-1,jj,jk) ) * zbtr
617               END DO
618            END DO
619
620            DO jj = j1,j2-1
621               DO ji = i1,i2   ! vector opt.
622                  zbtr = r1_e1e2f(ji,jj) * e3f(ji,jj,jk) * rn_sponge_dyn * fspf(ji,jj)
623                  rotdiff(ji,jj,jk) = ( -e1u(ji,jj+1) * ubdiff(ji,jj+1,jk)   &
624                                    &   +e1u(ji,jj  ) * ubdiff(ji,jj  ,jk) ) * fmask(ji,jj,jk) * zbtr 
625               END DO
626            END DO
627         END DO
628         !
629         DO jj = j1+1, j2-1
630            DO ji = i1+1, i2-1   ! vector opt.
631
632               IF (.NOT. tabspongedone_u(ji,jj)) THEN
633                  DO jk = 1, jpkm1                                 ! Horizontal slab
634                     ze2u = rotdiff (ji,jj,jk)
635                     ze1v = hdivdiff(ji,jj,jk)
636                     ! horizontal diffusive trends
637                     zua = - ( ze2u - rotdiff (ji,jj-1,jk) ) / ( e2u(ji,jj) * e3u(ji,jj,jk,Kmm_a) )   &
638                         & + ( hdivdiff(ji+1,jj,jk) - ze1v ) * r1_e1u(ji,jj) & 
639                         & - ztrelax  * fspu(ji,jj) * ubdiff(ji,jj,jk)
640
641                     ! add it to the general momentum trends
642                     uu(ji,jj,jk,Krhs_a) = uu(ji,jj,jk,Krhs_a) + zua                                 
643                  END DO
644               ENDIF
645
646            END DO
647         END DO
648
649         tabspongedone_u(i1+1:i2-1,j1+1:j2-1) = .TRUE.
650
651         jmax = j2-1
652         IF ((nbondj == 1).OR.(nbondj == 2)) jmax = MIN(jmax,nlcj-nbghostcells-2)   ! North
653
654         DO jj = j1+1, jmax
655            DO ji = i1+1, i2   ! vector opt.
656
657               IF (.NOT. tabspongedone_v(ji,jj)) THEN
658                  DO jk = 1, jpkm1                                 ! Horizontal slab
659                     ze2u = rotdiff (ji,jj,jk)
660                     ze1v = hdivdiff(ji,jj,jk)
661
662                     ! horizontal diffusive trends
663                     zva = + ( ze2u - rotdiff (ji-1,jj,jk) ) / ( e1v(ji,jj) * e3v(ji,jj,jk,Kmm_a) )   &
664                           + ( hdivdiff(ji,jj+1,jk) - ze1v ) * r1_e2v(ji,jj)
665
666                     ! add it to the general momentum trends
667                     vv(ji,jj,jk,Krhs_a) = vv(ji,jj,jk,Krhs_a) + zva
668                  END DO
669               ENDIF
670               !
671            END DO
672         END DO
673         !
674         tabspongedone_v(i1+1:i2,j1+1:jmax) = .TRUE.
675         !
676      ENDIF
677      !
678   END SUBROUTINE interpun_sponge
679
680   SUBROUTINE interpvn_sponge(tabres,i1,i2,j1,j2,k1,k2,m1,m2, before,nb,ndir)
681      !!---------------------------------------------
682      !!   *** ROUTINE interpvn_sponge ***
683      !!---------------------------------------------
684      INTEGER, INTENT(in) :: i1,i2,j1,j2,k1,k2,m1,m2
685      REAL(wp), DIMENSION(i1:i2,j1:j2,k1:k2,m1:m2), INTENT(inout) :: tabres
686      LOGICAL, INTENT(in) :: before
687      INTEGER, INTENT(in) :: nb , ndir
688      !
689      INTEGER  ::   ji, jj, jk, imax
690      REAL(wp) ::   ze2u, ze1v, zua, zva, zbtr, zhtot, ztrelax
691      REAL(wp), DIMENSION(i1:i2,j1:j2,1:jpk) :: vbdiff
692      REAL(wp), DIMENSION(i1:i2,j1:j2,1:jpk) :: rotdiff, hdivdiff
693      ! vertical interpolation:
694      REAL(wp), DIMENSION(i1:i2,j1:j2,1:jpk) :: tabres_child
695      REAL(wp), DIMENSION(k1:k2) :: tabin, h_in
696      REAL(wp), DIMENSION(1:jpk) :: h_out
697      INTEGER :: N_in, N_out
698      !!---------------------------------------------
699     
700      IF( before ) THEN
701         DO jk=k1,k2
702            DO jj=j1,j2
703               DO ji=i1,i2
704                  tabres(ji,jj,jk,m1) = vv(ji,jj,jk,Kbb_a)
705# if defined key_vertical
706                  tabres(ji,jj,jk,m2) = vmask(ji,jj,jk) * e3v(ji,jj,jk,Kbb_a)
707# endif
708               END DO
709            END DO
710         END DO
711
712# if defined key_vertical
713         ! Extrapolate thicknesses in partial bottom cells:
714         ! Set them to Agrif_SpecialValue (0.). Correct bottom thicknesses are retrieved later on
715         IF (ln_zps) THEN
716            DO jj=j1,j2
717               DO ji=i1,i2
718                  jk = mbkv(ji,jj)
719                  tabres(ji,jj,jk,m2) = 0._wp
720               END DO
721            END DO           
722         END IF
723        ! Save ssh at last level:
724        tabres(i1:i2,j1:j2,k2,m2) = 0._wp
725        IF (.NOT.ln_linssh) THEN
726           ! This vertical sum below should be replaced by the sea-level at V-points (optimization):
727           DO jk=1,jpk
728              tabres(i1:i2,j1:j2,k2,m2) = tabres(i1:i2,j1:j2,k2,m2) + e3v(i1:i2,j1:j2,jk,Kbb_a) * vmask(i1:i2,j1:j2,jk)
729           END DO
730           tabres(i1:i2,j1:j2,k2,m2) = tabres(i1:i2,j1:j2,k2,m2) - hv_0(i1:i2,j1:j2)
731        END IF 
732# endif
733
734      ELSE
735
736# if defined key_vertical
737         IF (ln_linssh) tabres(i1:i2,j1:j2,k2,m2) = 0._wp
738         DO jj=j1,j2
739            DO ji=i1,i2
740               tabres_child(ji,jj,:) = 0._wp
741               N_in = mbkv_parent(ji,jj)
742               zhtot = 0._wp
743               DO jk=1,N_in
744                  IF (jk==N_in) THEN
745                     h_in(jk) = hv0_parent(ji,jj) + tabres(ji,jj,k2,m2) - zhtot
746                  ELSE
747                     h_in(jk) = tabres(ji,jj,jk,m2)
748                  ENDIF
749                  zhtot = zhtot + h_in(jk)
750                  tabin(jk) = tabres(ji,jj,jk,m1)
751               ENDDO
752               !         
753               N_out = 0
754               DO jk=1,jpk
755                  IF (vmask(ji,jj,jk) == 0) EXIT
756                  N_out = N_out + 1
757                  h_out(N_out) = e3v(ji,jj,jk,Kbb_a)
758               ENDDO
759
760               ! Account for small differences in free-surface
761               IF ( sum(h_out(1:N_out)) > sum(h_in(1:N_in) )) THEN
762                  h_out(1) = h_out(1) - ( sum(h_out(1:N_out))-sum(h_in(1:N_in)) )
763               ELSE
764                  h_in(1)   = h_in(1) - (  sum(h_in(1:N_in))-sum(h_out(1:N_out)) )
765               ENDIF
766         
767               IF (N_in * N_out > 0) THEN
768                  CALL reconstructandremap(tabin(1:N_in),h_in(1:N_in),tabres_child(ji,jj,1:N_out),h_out(1:N_out),N_in,N_out,1)
769               ENDIF
770            ENDDO
771         ENDDO
772
773         vbdiff(i1:i2,j1:j2,:) = (vv(i1:i2,j1:j2,:,Kbb_a) - tabres_child(i1:i2,j1:j2,:))*vmask(i1:i2,j1:j2,:) 
774# else
775         vbdiff(i1:i2,j1:j2,:) = (vv(i1:i2,j1:j2,:,Kbb_a) - tabres(i1:i2,j1:j2,:,1))*vmask(i1:i2,j1:j2,:)
776# endif
777         !* set relaxation time scale
778         IF( neuler == 0 .AND. lk_agrif_fstep ) THEN   ;   ztrelax =   rn_trelax_dyn  / (        rdt )
779         ELSE                                          ;   ztrelax =   rn_trelax_dyn  / (2._wp * rdt )
780         ENDIF
781         !
782         DO jk = 1, jpkm1                                 ! Horizontal slab
783            !                                             ! ===============
784
785            !                                             ! --------
786            ! Horizontal divergence                       !   div
787            !                                             ! --------
788            DO jj = j1+1,j2
789               DO ji = i1,i2   ! vector opt.
790                  zbtr = r1_e1e2t(ji,jj) / e3t(ji,jj,jk,Kbb_a) * rn_sponge_dyn * fspt(ji,jj)
791                  hdivdiff(ji,jj,jk) = ( e1v(ji,jj  ) * e3v(ji,jj  ,jk,Kbb_a) * vbdiff(ji,jj  ,jk)  &
792                                     &  -e1v(ji,jj-1) * e3v(ji,jj-1,jk,Kbb_a) * vbdiff(ji,jj-1,jk)  ) * zbtr
793               END DO
794            END DO
795            DO jj = j1,j2
796               DO ji = i1,i2-1   ! vector opt.
797                  zbtr = r1_e1e2f(ji,jj) * e3f(ji,jj,jk) * rn_sponge_dyn * fspf(ji,jj)
798                  rotdiff(ji,jj,jk) = ( e2v(ji+1,jj) * vbdiff(ji+1,jj,jk) & 
799                                    &  -e2v(ji  ,jj) * vbdiff(ji  ,jj,jk)  ) * fmask(ji,jj,jk) * zbtr
800               END DO
801            END DO
802         END DO
803
804         !                                                ! ===============
805         !                                               
806
807         imax = i2 - 1
808         IF ((nbondi == 1).OR.(nbondi == 2))   imax = MIN(imax,nlci-nbghostcells-2)   ! East
809
810         DO jj = j1+1, j2
811            DO ji = i1+1, imax   ! vector opt.
812               IF( .NOT. tabspongedone_u(ji,jj) ) THEN
813                  DO jk = 1, jpkm1
814                     uu(ji,jj,jk,Krhs_a) = uu(ji,jj,jk,Krhs_a)                                                               &
815                        & - ( rotdiff (ji  ,jj,jk) - rotdiff (ji,jj-1,jk)) / ( e2u(ji,jj) * e3u(ji,jj,jk,Kmm_a) )  &
816                        & + ( hdivdiff(ji+1,jj,jk) - hdivdiff(ji,jj  ,jk)) * r1_e1u(ji,jj)
817                  END DO
818               ENDIF
819            END DO
820         END DO
821         !
822         tabspongedone_u(i1+1:imax,j1+1:j2) = .TRUE.
823         !
824         DO jj = j1+1, j2-1
825            DO ji = i1+1, i2-1   ! vector opt.
826               IF( .NOT. tabspongedone_v(ji,jj) ) THEN
827                  DO jk = 1, jpkm1
828                     vv(ji,jj,jk,Krhs_a) = vv(ji,jj,jk,Krhs_a)                                                                  &
829                        &  + ( rotdiff (ji,jj  ,jk) - rotdiff (ji-1,jj,jk) ) / ( e1v(ji,jj) * e3v(ji,jj,jk,Kmm_a) )   &
830                        &  + ( hdivdiff(ji,jj+1,jk) - hdivdiff(ji  ,jj,jk) ) * r1_e2v(ji,jj)                      &
831                        &  - ztrelax * fspv(ji,jj) * vbdiff(ji,jj,jk)
832                  END DO
833               ENDIF
834            END DO
835         END DO
836         tabspongedone_v(i1+1:i2-1,j1+1:j2-1) = .TRUE.
837      ENDIF
838      !
839   END SUBROUTINE interpvn_sponge
840
841#else
842   !!----------------------------------------------------------------------
843   !!   Empty module                                          no AGRIF zoom
844   !!----------------------------------------------------------------------
845CONTAINS
846   SUBROUTINE agrif_oce_sponge_empty
847      WRITE(*,*)  'agrif_oce_sponge : You should not have seen this print! error?'
848   END SUBROUTINE agrif_oce_sponge_empty
849#endif
850
851   !!======================================================================
852END MODULE agrif_oce_sponge
Note: See TracBrowser for help on using the repository browser.