source: NEMO/branches/2019/dev_r11943_MERGE_2019/src/OFF/dtadyn.F90 @ 11960

Last change on this file since 11960 was 11960, checked in by acc, 20 months ago

Branch 2019/dev_r11943_MERGE_2019. Merge in changes from 2019/dev_r11613_ENHANCE-04_namelists_as_internalfiles. (svn merge -r 11614:11954). Resolved tree conflicts and one actual conflict. Sette tested(these changes alter the ext/AGRIF reference; remember to update). See ticket #2341

  • Property svn:keywords set to Id
File size: 41.9 KB
Line 
1MODULE dtadyn
2   !!======================================================================
3   !!                       ***  MODULE  dtadyn  ***
4   !! Off-line : interpolation of the physical fields
5   !!======================================================================
6   !! History :   OPA  ! 1992-01 (M. Imbard) Original code
7   !!             8.0  ! 1998-04 (L.Bopp MA Foujols) slopes for isopyc.
8   !!              -   ! 1998-05 (L. Bopp) read output of coupled run
9   !!             8.2  ! 2001-01 (M. Levy et M. Benjelloul) add netcdf FORMAT
10   !!   NEMO      1.0  ! 2005-03 (O. Aumont and A. El Moussaoui) F90
11   !!              -   ! 2005-12 (C. Ethe) Adapted for DEGINT
12   !!             3.0  ! 2007-06 (C. Ethe) use of iom module
13   !!             3.3  ! 2010-11 (C. Ethe) Full reorganization of the off-line: phasing with the on-line
14   !!             3.4  ! 2011-05 (C. Ethe) Use of fldread
15   !!             4.1  ! 2019-08 (A. Coward, D. Storkey) split dta_dyn_sf_swp -> dta_dyn_sf_atf and dta_dyn_sf_interp
16   !!----------------------------------------------------------------------
17
18   !!----------------------------------------------------------------------
19   !!   dta_dyn_init : initialization, namelist read, and SAVEs control
20   !!   dta_dyn      : Interpolation of the fields
21   !!----------------------------------------------------------------------
22   USE oce             ! ocean dynamics and tracers variables
23   USE c1d             ! 1D configuration: lk_c1d
24   USE dom_oce         ! ocean domain: variables
25   USE domvvl          ! variable volume
26   USE zdf_oce         ! ocean vertical physics: variables
27   USE sbc_oce         ! surface module: variables
28   USE trc_oce         ! share ocean/biogeo variables
29   USE phycst          ! physical constants
30   USE trabbl          ! active tracer: bottom boundary layer
31   USE ldfslp          ! lateral diffusion: iso-neutral slopes
32   USE sbcrnf          ! river runoffs
33   USE ldftra          ! ocean tracer   lateral physics
34   USE zdfmxl          ! vertical physics: mixed layer depth
35   USE eosbn2          ! equation of state - Brunt Vaisala frequency
36   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
37   USE zpshde          ! z-coord. with partial steps: horizontal derivatives
38   USE in_out_manager  ! I/O manager
39   USE iom             ! I/O library
40   USE lib_mpp         ! distributed memory computing library
41   USE prtctl          ! print control
42   USE fldread         ! read input fields
43   USE timing          ! Timing
44   USE trc, ONLY : ln_rsttr, numrtr, numrtw, lrst_trc
45
46   IMPLICIT NONE
47   PRIVATE
48
49   PUBLIC   dta_dyn_init       ! called by nemo_init
50   PUBLIC   dta_dyn            ! called by nemo_gcm
51   PUBLIC   dta_dyn_sed_init   ! called by nemo_init
52   PUBLIC   dta_dyn_sed        ! called by nemo_gcm
53   PUBLIC   dta_dyn_atf        ! called by nemo_gcm
54   PUBLIC   dta_dyn_sf_interp  ! called by nemo_gcm
55
56   CHARACTER(len=100) ::   cn_dir          !: Root directory for location of ssr files
57   LOGICAL            ::   ln_dynrnf       !: read runoff data in file (T) or set to zero (F)
58   LOGICAL            ::   ln_dynrnf_depth       !: read runoff data in file (T) or set to zero (F)
59   REAL(wp)           ::   fwbcorr
60
61
62   INTEGER  , PARAMETER ::   jpfld = 20     ! maximum number of fields to read
63   INTEGER  , SAVE      ::   jf_tem         ! index of temperature
64   INTEGER  , SAVE      ::   jf_sal         ! index of salinity
65   INTEGER  , SAVE      ::   jf_uwd         ! index of u-transport
66   INTEGER  , SAVE      ::   jf_vwd         ! index of v-transport
67   INTEGER  , SAVE      ::   jf_wwd         ! index of v-transport
68   INTEGER  , SAVE      ::   jf_avt         ! index of Kz
69   INTEGER  , SAVE      ::   jf_mld         ! index of mixed layer deptht
70   INTEGER  , SAVE      ::   jf_emp         ! index of water flux
71   INTEGER  , SAVE      ::   jf_empb        ! index of water flux
72   INTEGER  , SAVE      ::   jf_qsr         ! index of solar radiation
73   INTEGER  , SAVE      ::   jf_wnd         ! index of wind speed
74   INTEGER  , SAVE      ::   jf_ice         ! index of sea ice cover
75   INTEGER  , SAVE      ::   jf_rnf         ! index of river runoff
76   INTEGER  , SAVE      ::   jf_fmf         ! index of downward salt flux
77   INTEGER  , SAVE      ::   jf_ubl         ! index of u-bbl coef
78   INTEGER  , SAVE      ::   jf_vbl         ! index of v-bbl coef
79   INTEGER  , SAVE      ::   jf_div         ! index of e3t
80
81
82   TYPE(FLD), ALLOCATABLE, SAVE, DIMENSION(:) :: sf_dyn  ! structure of input fields (file informations, fields read)
83   !                                               !
84   REAL(wp) , ALLOCATABLE, SAVE, DIMENSION(:,:,:,:) :: uslpdta    ! zonal isopycnal slopes
85   REAL(wp) , ALLOCATABLE, SAVE, DIMENSION(:,:,:,:) :: vslpdta    ! meridional isopycnal slopes
86   REAL(wp) , ALLOCATABLE, SAVE, DIMENSION(:,:,:,:) :: wslpidta   ! zonal diapycnal slopes
87   REAL(wp) , ALLOCATABLE, SAVE, DIMENSION(:,:,:,:) :: wslpjdta   ! meridional diapycnal slopes
88
89   INTEGER, SAVE  :: nprevrec, nsecdyn
90
91   !!----------------------------------------------------------------------
92   !! NEMO/OFF 4.0 , NEMO Consortium (2018)
93   !! $Id$
94   !! Software governed by the CeCILL license (see ./LICENSE)
95   !!----------------------------------------------------------------------
96CONTAINS
97
98   SUBROUTINE dta_dyn( kt, Kbb, Kmm, Kaa )
99      !!----------------------------------------------------------------------
100      !!                  ***  ROUTINE dta_dyn  ***
101      !!
102      !! ** Purpose :  Prepares dynamics and physics fields from a NEMO run
103      !!               for an off-line simulation of passive tracers
104      !!
105      !! ** Method : calculates the position of data
106      !!             - computes slopes if needed
107      !!             - interpolates data if needed
108      !!----------------------------------------------------------------------
109      INTEGER, INTENT(in) ::   kt             ! ocean time-step index
110      INTEGER, INTENT(in) ::   Kbb, Kmm, Kaa  ! ocean time level indices
111      !
112      INTEGER             ::   ji, jj, jk
113      REAL(wp), ALLOCATABLE, DIMENSION(:,:)   ::   zemp
114      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) ::   zhdivtr
115      !!----------------------------------------------------------------------
116      !
117      IF( ln_timing )   CALL timing_start( 'dta_dyn')
118      !
119      nsecdyn = nsec_year + nsec1jan000   ! number of seconds between Jan. 1st 00h of nit000 year and the middle of time step
120      !
121      IF( kt == nit000 ) THEN    ;    nprevrec = 0
122      ELSE                       ;    nprevrec = sf_dyn(jf_tem)%nrec_a(2)
123      ENDIF
124      CALL fld_read( kt, 1, sf_dyn )      !=  read data at kt time step   ==!
125      !
126      IF( l_ldfslp .AND. .NOT.lk_c1d )   CALL  dta_dyn_slp( kt, Kbb, Kmm )    ! Computation of slopes
127      !
128      ts(:,:,:,jp_tem,Kmm) = sf_dyn(jf_tem)%fnow(:,:,:)  * tmask(:,:,:)    ! temperature
129      ts(:,:,:,jp_sal,Kmm) = sf_dyn(jf_sal)%fnow(:,:,:)  * tmask(:,:,:)    ! salinity
130      wndm(:,:)         = sf_dyn(jf_wnd)%fnow(:,:,1)  * tmask(:,:,1)    ! wind speed - needed for gas exchange
131      fmmflx(:,:)       = sf_dyn(jf_fmf)%fnow(:,:,1)  * tmask(:,:,1)    ! downward salt flux (v3.5+)
132      fr_i(:,:)         = sf_dyn(jf_ice)%fnow(:,:,1)  * tmask(:,:,1)    ! Sea-ice fraction
133      qsr (:,:)         = sf_dyn(jf_qsr)%fnow(:,:,1)  * tmask(:,:,1)    ! solar radiation
134      emp (:,:)         = sf_dyn(jf_emp)%fnow(:,:,1)  * tmask(:,:,1)    ! E-P
135      IF( ln_dynrnf ) THEN
136         rnf (:,:)      = sf_dyn(jf_rnf)%fnow(:,:,1) * tmask(:,:,1)    ! E-P
137         IF( ln_dynrnf_depth .AND. .NOT. ln_linssh )    CALL  dta_dyn_hrnf(Kmm)
138      ENDIF
139      !
140      uu(:,:,:,Kmm)        = sf_dyn(jf_uwd)%fnow(:,:,:) * umask(:,:,:)    ! effective u-transport
141      vv(:,:,:,Kmm)        = sf_dyn(jf_vwd)%fnow(:,:,:) * vmask(:,:,:)    ! effective v-transport
142      ww(:,:,:)        = sf_dyn(jf_wwd)%fnow(:,:,:) * tmask(:,:,:)    ! effective v-transport
143      !
144      IF( .NOT.ln_linssh ) THEN
145         ALLOCATE( zemp(jpi,jpj) , zhdivtr(jpi,jpj,jpk) )
146         zhdivtr(:,:,:) = sf_dyn(jf_div)%fnow(:,:,:)  * tmask(:,:,:)    ! effective u-transport
147         emp_b  (:,:)   = sf_dyn(jf_empb)%fnow(:,:,1) * tmask(:,:,1)    ! E-P
148         zemp   (:,:)   = ( 0.5_wp * ( emp(:,:) + emp_b(:,:) ) + rnf(:,:) + fwbcorr ) * tmask(:,:,1)
149         CALL dta_dyn_ssh( kt, zhdivtr, ssh(:,:,Kbb), zemp, ssh(:,:,Kaa), e3t(:,:,:,Kaa) )  !=  ssh, vertical scale factor & vertical transport
150         DEALLOCATE( zemp , zhdivtr )
151         !                                           Write in the tracer restart file
152         !                                          *********************************
153         IF( lrst_trc ) THEN
154            IF(lwp) WRITE(numout,*)
155            IF(lwp) WRITE(numout,*) 'dta_dyn_ssh : ssh field written in tracer restart file at it= ', kt,' date= ', ndastp
156            IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
157            CALL iom_rstput( kt, nitrst, numrtw, 'sshn', ssh(:,:,Kaa) )
158            CALL iom_rstput( kt, nitrst, numrtw, 'sshb', ssh(:,:,Kmm) )
159         ENDIF
160      ENDIF
161      !
162      CALL eos    ( ts(:,:,:,:,Kmm), rhd, rhop, gdept_0(:,:,:) ) ! In any case, we need rhop
163      CALL eos_rab( ts(:,:,:,:,Kmm), rab_n, Kmm )       ! now    local thermal/haline expension ratio at T-points
164      CALL bn2    ( ts(:,:,:,:,Kmm), rab_n, rn2, Kmm )  ! before Brunt-Vaisala frequency need for zdfmxl
165
166      rn2b(:,:,:) = rn2(:,:,:)         ! needed for zdfmxl
167      CALL zdf_mxl( kt, Kmm )          ! In any case, we need mxl
168      !
169      hmld(:,:)       = sf_dyn(jf_mld)%fnow(:,:,1) * tmask(:,:,1)    ! mixed layer depht
170      avt(:,:,:)      = sf_dyn(jf_avt)%fnow(:,:,:) * tmask(:,:,:)    ! vertical diffusive coefficient
171      avs(:,:,:)      = avt(:,:,:)
172      !
173      IF( ln_trabbl .AND. .NOT.lk_c1d ) THEN       ! diffusive Bottom boundary layer param
174         ahu_bbl(:,:) = sf_dyn(jf_ubl)%fnow(:,:,1) * umask(:,:,1)    ! bbl diffusive coef
175         ahv_bbl(:,:) = sf_dyn(jf_vbl)%fnow(:,:,1) * vmask(:,:,1)
176      ENDIF
177      !
178      !
179      CALL eos( ts(:,:,:,:,Kmm), rhd, rhop, gdept_0(:,:,:) ) ! In any case, we need rhop
180      !
181      IF(ln_ctl) THEN                  ! print control
182         CALL prt_ctl(tab3d_1=ts(:,:,:,jp_tem,Kmm), clinfo1=' tn      - : ', mask1=tmask,  kdim=jpk   )
183         CALL prt_ctl(tab3d_1=ts(:,:,:,jp_sal,Kmm), clinfo1=' sn      - : ', mask1=tmask,  kdim=jpk   )
184         CALL prt_ctl(tab3d_1=uu(:,:,:,Kmm)               , clinfo1=' uu(:,:,:,Kmm)      - : ', mask1=umask,  kdim=jpk   )
185         CALL prt_ctl(tab3d_1=vv(:,:,:,Kmm)               , clinfo1=' vv(:,:,:,Kmm)      - : ', mask1=vmask,  kdim=jpk   )
186         CALL prt_ctl(tab3d_1=ww               , clinfo1=' ww      - : ', mask1=tmask,  kdim=jpk   )
187         CALL prt_ctl(tab3d_1=avt              , clinfo1=' kz      - : ', mask1=tmask,  kdim=jpk   )
188         CALL prt_ctl(tab3d_1=uslp             , clinfo1=' slp  - u : ', tab3d_2=vslp, clinfo2=' v : ', kdim=jpk)
189         CALL prt_ctl(tab3d_1=wslpi            , clinfo1=' slp  - wi: ', tab3d_2=wslpj, clinfo2=' wj: ', kdim=jpk)
190      ENDIF
191      !
192      IF( ln_timing )   CALL timing_stop( 'dta_dyn')
193      !
194   END SUBROUTINE dta_dyn
195
196
197   SUBROUTINE dta_dyn_init( Kbb, Kmm, Kaa )
198      !!----------------------------------------------------------------------
199      !!                  ***  ROUTINE dta_dyn_init  ***
200      !!
201      !! ** Purpose :   Initialisation of the dynamical data     
202      !! ** Method  : - read the data namdta_dyn namelist
203      !!----------------------------------------------------------------------
204      INTEGER, INTENT(in) ::   Kbb, Kmm, Kaa  ! ocean time level indices
205      !
206      INTEGER  :: ierr, ierr0, ierr1, ierr2, ierr3   ! return error code
207      INTEGER  :: ifpr                               ! dummy loop indice
208      INTEGER  :: jfld                               ! dummy loop arguments
209      INTEGER  :: inum, idv, idimv                   ! local integer
210      INTEGER  :: ios                                ! Local integer output status for namelist read
211      INTEGER  :: ji, jj, jk
212      REAL(wp) :: zcoef
213      INTEGER  :: nkrnf_max
214      REAL(wp) :: hrnf_max
215      !!
216      CHARACTER(len=100)            ::  cn_dir        !   Root directory for location of core files
217      TYPE(FLD_N), DIMENSION(jpfld) ::  slf_d         ! array of namelist informations on the fields to read
218      TYPE(FLD_N) :: sn_uwd, sn_vwd, sn_wwd, sn_empb, sn_emp  ! informations about the fields to be read
219      TYPE(FLD_N) :: sn_tem , sn_sal , sn_avt   !   "                 "
220      TYPE(FLD_N) :: sn_mld, sn_qsr, sn_wnd , sn_ice , sn_fmf   !   "               "
221      TYPE(FLD_N) :: sn_ubl, sn_vbl, sn_rnf    !   "              "
222      TYPE(FLD_N) :: sn_div  ! informations about the fields to be read
223      !!
224      NAMELIST/namdta_dyn/cn_dir, ln_dynrnf, ln_dynrnf_depth,  fwbcorr, &
225         &                sn_uwd, sn_vwd, sn_wwd, sn_emp,               &
226         &                sn_avt, sn_tem, sn_sal, sn_mld , sn_qsr ,     &
227         &                sn_wnd, sn_ice, sn_fmf,                       &
228         &                sn_ubl, sn_vbl, sn_rnf,                       &
229         &                sn_empb, sn_div 
230      !!----------------------------------------------------------------------
231      !
232      READ  ( numnam_ref, namdta_dyn, IOSTAT = ios, ERR = 901)
233901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namdta_dyn in reference namelist' )
234      READ  ( numnam_cfg, namdta_dyn, IOSTAT = ios, ERR = 902 )
235902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namdta_dyn in configuration namelist' )
236      IF(lwm) WRITE ( numond, namdta_dyn )
237      !                                         ! store namelist information in an array
238      !                                         ! Control print
239      IF(lwp) THEN
240         WRITE(numout,*)
241         WRITE(numout,*) 'dta_dyn : offline dynamics '
242         WRITE(numout,*) '~~~~~~~ '
243         WRITE(numout,*) '   Namelist namdta_dyn'
244         WRITE(numout,*) '      runoffs option enabled (T) or not (F)            ln_dynrnf        = ', ln_dynrnf
245         WRITE(numout,*) '      runoffs is spread in vertical                    ln_dynrnf_depth  = ', ln_dynrnf_depth
246         WRITE(numout,*) '      annual global mean of empmr for ssh correction   fwbcorr          = ', fwbcorr
247         WRITE(numout,*)
248      ENDIF
249      !
250      jf_uwd  = 1     ;   jf_vwd  = 2    ;   jf_wwd = 3    ;   jf_emp = 4    ;   jf_avt = 5
251      jf_tem  = 6     ;   jf_sal  = 7    ;   jf_mld = 8    ;   jf_qsr = 9
252      jf_wnd  = 10    ;   jf_ice  = 11   ;   jf_fmf = 12   ;   jfld   = jf_fmf
253      !
254      slf_d(jf_uwd)  = sn_uwd    ;   slf_d(jf_vwd)  = sn_vwd   ;   slf_d(jf_wwd) = sn_wwd
255      slf_d(jf_emp)  = sn_emp    ;   slf_d(jf_avt)  = sn_avt
256      slf_d(jf_tem)  = sn_tem    ;   slf_d(jf_sal)  = sn_sal   ;   slf_d(jf_mld) = sn_mld
257      slf_d(jf_qsr)  = sn_qsr    ;   slf_d(jf_wnd)  = sn_wnd   ;   slf_d(jf_ice) = sn_ice
258      slf_d(jf_fmf)  = sn_fmf
259      !
260      IF( .NOT.ln_linssh ) THEN
261               jf_div  = jfld + 1   ;         jf_empb  = jfld + 2    ;   jfld = jf_empb
262         slf_d(jf_div) = sn_div     ;   slf_d(jf_empb) = sn_empb
263      ENDIF
264      !
265      IF( ln_trabbl ) THEN
266               jf_ubl  = jfld + 1   ;         jf_vbl  = jfld + 2     ;   jfld = jf_vbl
267         slf_d(jf_ubl) = sn_ubl     ;   slf_d(jf_vbl) = sn_vbl
268      ENDIF
269      !
270      IF( ln_dynrnf ) THEN
271               jf_rnf  = jfld + 1   ;     jfld  = jf_rnf
272         slf_d(jf_rnf) = sn_rnf   
273      ELSE
274         rnf(:,:) = 0._wp
275      ENDIF
276
277      ALLOCATE( sf_dyn(jfld), STAT=ierr )         ! set sf structure
278      IF( ierr > 0 )  THEN
279         CALL ctl_stop( 'dta_dyn: unable to allocate sf structure' )   ;   RETURN
280      ENDIF
281      !                                         ! fill sf with slf_i and control print
282      CALL fld_fill( sf_dyn, slf_d, cn_dir, 'dta_dyn_init', 'Data in file', 'namdta_dyn' )
283      !
284      ! Open file for each variable to get his number of dimension
285      DO ifpr = 1, jfld
286         CALL fld_clopn( sf_dyn(ifpr), nyear, nmonth, nday )
287         idv   = iom_varid( sf_dyn(ifpr)%num , slf_d(ifpr)%clvar )        ! id of the variable sdjf%clvar
288         idimv = iom_file ( sf_dyn(ifpr)%num )%ndims(idv)                 ! number of dimension for variable sdjf%clvar
289         IF( sf_dyn(ifpr)%num /= 0 )   CALL iom_close( sf_dyn(ifpr)%num ) ! close file if already open
290         ierr1=0
291         IF( idimv == 3 ) THEN    ! 2D variable
292                                      ALLOCATE( sf_dyn(ifpr)%fnow(jpi,jpj,1)    , STAT=ierr0 )
293            IF( slf_d(ifpr)%ln_tint ) ALLOCATE( sf_dyn(ifpr)%fdta(jpi,jpj,1,2)  , STAT=ierr1 )
294         ELSE                     ! 3D variable
295                                      ALLOCATE( sf_dyn(ifpr)%fnow(jpi,jpj,jpk)  , STAT=ierr0 )
296            IF( slf_d(ifpr)%ln_tint ) ALLOCATE( sf_dyn(ifpr)%fdta(jpi,jpj,jpk,2), STAT=ierr1 )
297         ENDIF
298         IF( ierr0 + ierr1 > 0 ) THEN
299            CALL ctl_stop( 'dta_dyn_init : unable to allocate sf_dyn array structure' )   ;   RETURN
300         ENDIF
301      END DO
302      !
303      IF( l_ldfslp .AND. .NOT.lk_c1d ) THEN                  ! slopes
304         IF( sf_dyn(jf_tem)%ln_tint ) THEN      ! time interpolation
305            ALLOCATE( uslpdta (jpi,jpj,jpk,2), vslpdta (jpi,jpj,jpk,2),    &
306            &         wslpidta(jpi,jpj,jpk,2), wslpjdta(jpi,jpj,jpk,2), STAT=ierr2 )
307            !
308            IF( ierr2 > 0 )  THEN
309               CALL ctl_stop( 'dta_dyn_init : unable to allocate slope arrays' )   ;   RETURN
310            ENDIF
311         ENDIF
312      ENDIF
313      !
314      IF( .NOT.ln_linssh ) THEN
315        IF( .NOT. sf_dyn(jf_uwd)%ln_clim .AND. ln_rsttr .AND.    &                     ! Restart: read in restart file
316           iom_varid( numrtr, 'sshn', ldstop = .FALSE. ) > 0 ) THEN
317           IF(lwp) WRITE(numout,*) ' ssh(:,:,Kmm) forcing fields read in the restart file for initialisation'
318           CALL iom_get( numrtr, jpdom_autoglo, 'sshn', ssh(:,:,Kmm)   )
319           CALL iom_get( numrtr, jpdom_autoglo, 'sshb', ssh(:,:,Kbb)   )
320        ELSE
321           IF(lwp) WRITE(numout,*) ' ssh(:,:,Kmm) forcing fields read in the restart file for initialisation'
322           CALL iom_open( 'restart', inum )
323           CALL iom_get( inum, jpdom_autoglo, 'sshn', ssh(:,:,Kmm)   )
324           CALL iom_get( inum, jpdom_autoglo, 'sshb', ssh(:,:,Kbb)   )
325           CALL iom_close( inum )                                        ! close file
326        ENDIF
327        !
328        DO jk = 1, jpkm1
329           e3t(:,:,jk,Kmm) = e3t_0(:,:,jk) * ( 1._wp + ssh(:,:,Kmm) * tmask(:,:,1) / ( ht_0(:,:) + 1.0 - tmask(:,:,1) ) )
330        ENDDO
331        e3t(:,:,jpk,Kaa) = e3t_0(:,:,jpk)
332
333        ! Horizontal scale factor interpolations
334        ! --------------------------------------
335        CALL dom_vvl_interpol( e3t(:,:,:,Kmm), e3u(:,:,:,Kmm), 'U' )
336        CALL dom_vvl_interpol( e3t(:,:,:,Kmm), e3v(:,:,:,Kmm), 'V' )
337
338        ! Vertical scale factor interpolations
339        ! ------------------------------------
340        CALL dom_vvl_interpol( e3t(:,:,:,Kmm), e3w(:,:,:,Kmm), 'W' )
341 
342        e3t(:,:,:,Kbb)  = e3t(:,:,:,Kmm)
343        e3u(:,:,:,Kbb)  = e3u(:,:,:,Kmm)
344        e3v(:,:,:,Kbb)  = e3v(:,:,:,Kmm)
345
346        ! t- and w- points depth
347        ! ----------------------
348        gdept(:,:,1,Kmm) = 0.5_wp * e3w(:,:,1,Kmm)
349        gdepw(:,:,1,Kmm) = 0.0_wp
350
351        DO jk = 2, jpk
352           DO jj = 1,jpj
353              DO ji = 1,jpi
354                !    zcoef = (tmask(ji,jj,jk) - wmask(ji,jj,jk))   ! 0 everywhere
355                !    tmask = wmask, ie everywhere expect at jk = mikt
356                                                                   ! 1 for jk =
357                                                                   ! mikt
358                 zcoef = (tmask(ji,jj,jk) - wmask(ji,jj,jk))
359                 gdepw(ji,jj,jk,Kmm) = gdepw(ji,jj,jk-1,Kmm) + e3t(ji,jj,jk-1,Kmm)
360                 gdept(ji,jj,jk,Kmm) =      zcoef  * ( gdepw(ji,jj,jk  ,Kmm) + 0.5 * e3w(ji,jj,jk,Kmm))  &
361                     &                + (1-zcoef) * ( gdept(ji,jj,jk-1,Kmm) + e3w(ji,jj,jk,Kmm))
362              END DO
363           END DO
364        END DO
365
366        gdept(:,:,:,Kbb) = gdept(:,:,:,Kmm)
367        gdepw(:,:,:,Kbb) = gdepw(:,:,:,Kmm)
368        !
369      ENDIF
370      !
371      IF( ln_dynrnf .AND. ln_dynrnf_depth ) THEN       ! read depht over which runoffs are distributed
372         IF(lwp) WRITE(numout,*) 
373         IF(lwp) WRITE(numout,*) ' read in the file depht over which runoffs are distributed'
374         CALL iom_open ( "runoffs", inum )                           ! open file
375         CALL iom_get  ( inum, jpdom_data, 'rodepth', h_rnf )   ! read the river mouth array
376         CALL iom_close( inum )                                        ! close file
377         !
378         nk_rnf(:,:) = 0                               ! set the number of level over which river runoffs are applied
379         DO jj = 1, jpj
380            DO ji = 1, jpi
381               IF( h_rnf(ji,jj) > 0._wp ) THEN
382                  jk = 2
383                  DO WHILE ( jk /= mbkt(ji,jj) .AND. gdept_0(ji,jj,jk) < h_rnf(ji,jj) ) ;  jk = jk + 1
384                  END DO
385                  nk_rnf(ji,jj) = jk
386               ELSEIF( h_rnf(ji,jj) == -1._wp   ) THEN   ;  nk_rnf(ji,jj) = 1
387               ELSEIF( h_rnf(ji,jj) == -999._wp ) THEN   ;  nk_rnf(ji,jj) = mbkt(ji,jj)
388               ELSE
389                  CALL ctl_stop( 'sbc_rnf_init: runoff depth not positive, and not -999 or -1, rnf value in file fort.999'  )
390                  WRITE(999,*) 'ji, jj, h_rnf(ji,jj) :', ji, jj, h_rnf(ji,jj)
391               ENDIF
392            END DO
393         END DO
394         DO jj = 1, jpj                                ! set the associated depth
395            DO ji = 1, jpi
396               h_rnf(ji,jj) = 0._wp
397               DO jk = 1, nk_rnf(ji,jj)
398                  h_rnf(ji,jj) = h_rnf(ji,jj) + e3t(ji,jj,jk,Kmm)
399               END DO
400            END DO
401         END DO
402      ELSE                                       ! runoffs applied at the surface
403         nk_rnf(:,:) = 1
404         h_rnf (:,:) = e3t(:,:,1,Kmm)
405      ENDIF
406      nkrnf_max = MAXVAL( nk_rnf(:,:) )
407      hrnf_max = MAXVAL( h_rnf(:,:) )
408      IF( lk_mpp )  THEN
409         CALL mpp_max( 'dtadyn', nkrnf_max )                 ! max over the  global domain
410         CALL mpp_max( 'dtadyn', hrnf_max )                 ! max over the  global domain
411      ENDIF
412      IF(lwp) WRITE(numout,*) ' '
413      IF(lwp) WRITE(numout,*) ' max depht of runoff : ', hrnf_max,'    max level  : ', nkrnf_max
414      IF(lwp) WRITE(numout,*) ' '
415      !
416      CALL dta_dyn( nit000, Kbb, Kmm, Kaa )
417      !
418   END SUBROUTINE dta_dyn_init
419
420   SUBROUTINE dta_dyn_sed( kt, Kmm )
421      !!----------------------------------------------------------------------
422      !!                  ***  ROUTINE dta_dyn  ***
423      !!
424      !! ** Purpose :  Prepares dynamics and physics fields from a NEMO run
425      !!               for an off-line simulation of passive tracers
426      !!
427      !! ** Method : calculates the position of data
428      !!             - computes slopes if needed
429      !!             - interpolates data if needed
430      !!----------------------------------------------------------------------
431      INTEGER, INTENT(in) ::   kt   ! ocean time-step index
432      INTEGER, INTENT(in) ::   Kmm  ! ocean time level index
433      !
434      !!----------------------------------------------------------------------
435      !
436      IF( ln_timing )   CALL timing_start( 'dta_dyn_sed')
437      !
438      nsecdyn = nsec_year + nsec1jan000   ! number of seconds between Jan. 1st 00h of nit000 year and the middle of time step
439      !
440      IF( kt == nit000 ) THEN    ;    nprevrec = 0
441      ELSE                       ;    nprevrec = sf_dyn(jf_tem)%nrec_a(2)
442      ENDIF
443      CALL fld_read( kt, 1, sf_dyn )      !=  read data at kt time step   ==!
444      !
445      ts(:,:,:,jp_tem,Kmm) = sf_dyn(jf_tem)%fnow(:,:,:)  * tmask(:,:,:)    ! temperature
446      ts(:,:,:,jp_sal,Kmm) = sf_dyn(jf_sal)%fnow(:,:,:)  * tmask(:,:,:)    ! salinity
447      !
448      CALL eos    ( ts(:,:,:,:,Kmm), rhd, rhop, gdept_0(:,:,:) ) ! In any case, we need rhop
449
450      IF(ln_ctl) THEN                  ! print control
451         CALL prt_ctl(tab3d_1=ts(:,:,:,jp_tem,Kmm), clinfo1=' tn      - : ', mask1=tmask,  kdim=jpk   )
452         CALL prt_ctl(tab3d_1=ts(:,:,:,jp_sal,Kmm), clinfo1=' sn      - : ', mask1=tmask,  kdim=jpk   )
453      ENDIF
454      !
455      IF( ln_timing )   CALL timing_stop( 'dta_dyn_sed')
456      !
457   END SUBROUTINE dta_dyn_sed
458
459
460   SUBROUTINE dta_dyn_sed_init( Kmm )
461      !!----------------------------------------------------------------------
462      !!                  ***  ROUTINE dta_dyn_init  ***
463      !!
464      !! ** Purpose :   Initialisation of the dynamical data
465      !! ** Method  : - read the data namdta_dyn namelist
466      !!----------------------------------------------------------------------
467      INTEGER, INTENT( in ) :: Kmm                   ! ocean time level index
468      !
469      INTEGER  :: ierr, ierr0, ierr1, ierr2, ierr3   ! return error code
470      INTEGER  :: ifpr                               ! dummy loop indice
471      INTEGER  :: jfld                               ! dummy loop arguments
472      INTEGER  :: inum, idv, idimv                   ! local integer
473      INTEGER  :: ios                                ! Local integer output status for namelist read
474      !!
475      CHARACTER(len=100)            ::  cn_dir        !   Root directory for location of core files
476      TYPE(FLD_N), DIMENSION(2) ::  slf_d         ! array of namelist informations on the fields to read
477      TYPE(FLD_N) :: sn_tem , sn_sal   !   "                 "
478      !!
479      NAMELIST/namdta_dyn/cn_dir, ln_dynrnf, ln_dynrnf_depth,  fwbcorr, &
480         &                sn_tem, sn_sal
481      !!----------------------------------------------------------------------
482      !
483      READ  ( numnam_ref, namdta_dyn, IOSTAT = ios, ERR = 901)
484901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namdta_dyn in reference namelist' )
485      READ  ( numnam_cfg, namdta_dyn, IOSTAT = ios, ERR = 902 )
486902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namdta_dyn in configuration namelist' )
487      IF(lwm) WRITE ( numond, namdta_dyn )
488      !                                         ! store namelist information in an array
489      !                                         ! Control print
490      IF(lwp) THEN
491         WRITE(numout,*)
492         WRITE(numout,*) 'dta_dyn : offline dynamics '
493         WRITE(numout,*) '~~~~~~~ '
494         WRITE(numout,*) '   Namelist namdta_dyn'
495         WRITE(numout,*) '      runoffs option enabled (T) or not (F)            ln_dynrnf        = ', ln_dynrnf
496         WRITE(numout,*) '      runoffs is spread in vertical                    ln_dynrnf_depth  = ', ln_dynrnf_depth
497         WRITE(numout,*) '      annual global mean of empmr for ssh correction   fwbcorr          = ', fwbcorr
498         WRITE(numout,*)
499      ENDIF
500      !
501      jf_tem  = 1     ;   jf_sal  = 2    ;   jfld   = jf_sal
502      !
503      slf_d(jf_tem)  = sn_tem    ;   slf_d(jf_sal)  = sn_sal
504      !
505      ALLOCATE( sf_dyn(jfld), STAT=ierr )         ! set sf structure
506      IF( ierr > 0 )  THEN
507         CALL ctl_stop( 'dta_dyn: unable to allocate sf structure' )   ;   RETURN
508      ENDIF
509      !                                         ! fill sf with slf_i and control print
510      CALL fld_fill( sf_dyn, slf_d, cn_dir, 'dta_dyn_init', 'Data in file', 'namdta_dyn' )
511      !
512      ! Open file for each variable to get his number of dimension
513      DO ifpr = 1, jfld
514         CALL fld_clopn( sf_dyn(ifpr), nyear, nmonth, nday )
515         idv   = iom_varid( sf_dyn(ifpr)%num , slf_d(ifpr)%clvar )        ! id of the variable sdjf%clvar
516         idimv = iom_file ( sf_dyn(ifpr)%num )%ndims(idv)                 ! number of dimension for variable sdjf%clvar
517         IF( sf_dyn(ifpr)%num /= 0 )   CALL iom_close( sf_dyn(ifpr)%num ) ! close file if already open
518         ierr1=0
519         IF( idimv == 3 ) THEN    ! 2D variable
520                                      ALLOCATE( sf_dyn(ifpr)%fnow(jpi,jpj,1)    , STAT=ierr0 )
521            IF( slf_d(ifpr)%ln_tint ) ALLOCATE( sf_dyn(ifpr)%fdta(jpi,jpj,1,2)  , STAT=ierr1 )
522         ELSE                     ! 3D variable
523                                      ALLOCATE( sf_dyn(ifpr)%fnow(jpi,jpj,jpk)  , STAT=ierr0 )
524            IF( slf_d(ifpr)%ln_tint ) ALLOCATE( sf_dyn(ifpr)%fdta(jpi,jpj,jpk,2), STAT=ierr1 )
525         ENDIF
526         IF( ierr0 + ierr1 > 0 ) THEN
527            CALL ctl_stop( 'dta_dyn_init : unable to allocate sf_dyn array structure' )   ;   RETURN
528         ENDIF
529      END DO
530      !
531      CALL dta_dyn_sed( nit000, Kmm )
532      !
533   END SUBROUTINE dta_dyn_sed_init
534
535   SUBROUTINE dta_dyn_atf( kt, Kbb, Kmm, Kaa )
536     !!---------------------------------------------------------------------
537      !!                    ***  ROUTINE dta_dyn_swp  ***
538      !!
539      !! ** Purpose :   Asselin time filter of now SSH
540      !!---------------------------------------------------------------------
541      INTEGER, INTENT(in) :: kt             ! time step
542      INTEGER, INTENT(in) :: Kbb, Kmm, Kaa  ! ocean time level indices
543      !
544      !!---------------------------------------------------------------------
545
546      IF( kt == nit000 ) THEN
547         IF(lwp) WRITE(numout,*)
548         IF(lwp) WRITE(numout,*) 'dta_dyn_atf : Asselin time filter of sea surface height'
549         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ '
550      ENDIF
551
552      ssh(:,:,Kmm) = ssh(:,:,Kmm) + atfp * ( ssh(:,:,Kbb) - 2 * ssh(:,:,Kmm) + ssh(:,:,Kaa)) 
553
554      !! Do we also need to time filter e3t??
555      !
556   END SUBROUTINE dta_dyn_atf
557   
558   SUBROUTINE dta_dyn_sf_interp( kt, Kmm )
559      !!---------------------------------------------------------------------
560      !!                    ***  ROUTINE dta_dyn_sf_interp  ***
561      !!
562      !! ** Purpose :   Calculate scale factors at U/V/W points and depths
563      !!                given the after e3t field
564      !!---------------------------------------------------------------------
565      INTEGER, INTENT(in) :: kt   ! time step
566      INTEGER, INTENT(in) :: Kmm  ! ocean time level indices
567      !
568      INTEGER             :: ji, jj, jk
569      REAL(wp)            :: zcoef
570      !!---------------------------------------------------------------------
571
572      ! Horizontal scale factor interpolations
573      ! --------------------------------------
574      CALL dom_vvl_interpol( e3t(:,:,:,Kmm), e3u(:,:,:,Kmm), 'U' )
575      CALL dom_vvl_interpol( e3t(:,:,:,Kmm), e3v(:,:,:,Kmm), 'V' )
576
577      ! Vertical scale factor interpolations
578      ! ------------------------------------
579      CALL dom_vvl_interpol( e3t(:,:,:,Kmm), e3w (:,:,:,Kmm), 'W' )
580
581      ! t- and w- points depth
582      ! ----------------------
583      gdept(:,:,1,Kmm) = 0.5_wp * e3w(:,:,1,Kmm)
584      gdepw(:,:,1,Kmm) = 0.0_wp
585      !
586      DO jk = 2, jpk
587         DO jj = 1,jpj
588            DO ji = 1,jpi
589               zcoef = (tmask(ji,jj,jk) - wmask(ji,jj,jk))
590               gdepw(ji,jj,jk,Kmm) = gdepw(ji,jj,jk-1,Kmm) + e3t(ji,jj,jk-1,Kmm)
591               gdept(ji,jj,jk,Kmm) =      zcoef  * ( gdepw(ji,jj,jk  ,Kmm) + 0.5 * e3w(ji,jj,jk,Kmm))  &
592                  &                + (1-zcoef) * ( gdept(ji,jj,jk-1,Kmm) + e3w(ji,jj,jk,Kmm))
593            END DO
594         END DO
595      END DO
596      !
597   END SUBROUTINE dta_dyn_sf_interp
598
599   SUBROUTINE dta_dyn_ssh( kt, phdivtr, psshb,  pemp, pssha, pe3ta )
600      !!----------------------------------------------------------------------
601      !!                ***  ROUTINE dta_dyn_wzv  ***
602      !!                   
603      !! ** Purpose :   compute the after ssh (ssh(:,:,Kaa)) and the now vertical velocity
604      !!
605      !! ** Method  : Using the incompressibility hypothesis,
606      !!        - the ssh increment is computed by integrating the horizontal divergence
607      !!          and multiply by the time step.
608      !!
609      !!        - compute the after scale factor : repartition of ssh INCREMENT proportionnaly
610      !!                                           to the level thickness ( z-star case )
611      !!
612      !!        - the vertical velocity is computed by integrating the horizontal divergence 
613      !!          from the bottom to the surface minus the scale factor evolution.
614      !!          The boundary conditions are w=0 at the bottom (no flux)
615      !!
616      !! ** action  :   ssh(:,:,Kaa) / e3t(:,:,:,Kaa) / ww
617      !!
618      !! Reference  : Leclair, M., and G. Madec, 2009, Ocean Modelling.
619      !!----------------------------------------------------------------------
620      INTEGER,                                   INTENT(in )    :: kt        !  time-step
621      REAL(wp), DIMENSION(jpi,jpj,jpk)          , INTENT(in )   :: phdivtr   ! horizontal divergence transport
622      REAL(wp), DIMENSION(jpi,jpj)    , OPTIONAL, INTENT(in )   :: psshb     ! now ssh
623      REAL(wp), DIMENSION(jpi,jpj)    , OPTIONAL, INTENT(in )   :: pemp      ! evaporation minus precipitation
624      REAL(wp), DIMENSION(jpi,jpj)    , OPTIONAL, INTENT(inout) :: pssha     ! after ssh
625      REAL(wp), DIMENSION(jpi,jpj,jpk), OPTIONAL, INTENT(out)   :: pe3ta     ! after vertical scale factor
626      !
627      INTEGER                       :: jk
628      REAL(wp), DIMENSION(jpi,jpj)  :: zhdiv 
629      REAL(wp)  :: z2dt 
630      !!----------------------------------------------------------------------
631      !
632      z2dt = 2._wp * rdt
633      !
634      zhdiv(:,:) = 0._wp
635      DO jk = 1, jpkm1
636         zhdiv(:,:) = zhdiv(:,:) +  phdivtr(:,:,jk) * tmask(:,:,jk)
637      END DO
638      !                                                ! Sea surface  elevation time-stepping
639      pssha(:,:) = ( psshb(:,:) - z2dt * ( r1_rau0 * pemp(:,:)  + zhdiv(:,:) ) ) * ssmask(:,:)
640      !                                                 !
641      !                                                 ! After acale factors at t-points ( z_star coordinate )
642      DO jk = 1, jpkm1
643        pe3ta(:,:,jk) = e3t_0(:,:,jk) * ( 1._wp + pssha(:,:) * tmask(:,:,1) / ( ht_0(:,:) + 1.0 - tmask(:,:,1) ) )
644      END DO
645      !
646   END SUBROUTINE dta_dyn_ssh
647
648
649   SUBROUTINE dta_dyn_hrnf( Kmm )
650      !!----------------------------------------------------------------------
651      !!                  ***  ROUTINE sbc_rnf  ***
652      !!
653      !! ** Purpose :   update the horizontal divergence with the runoff inflow
654      !!
655      !! ** Method  :
656      !!                CAUTION : rnf is positive (inflow) decreasing the
657      !!                          divergence and expressed in m/s
658      !!
659      !! ** Action  :   phdivn   decreased by the runoff inflow
660      !!----------------------------------------------------------------------
661      !!
662      INTEGER, INTENT(in) :: Kmm  ! ocean time level index
663      !
664      INTEGER  ::   ji, jj, jk    ! dummy loop indices
665      !!----------------------------------------------------------------------
666      !
667      DO jj = 1, jpj                   ! update the depth over which runoffs are distributed
668         DO ji = 1, jpi
669            h_rnf(ji,jj) = 0._wp
670            DO jk = 1, nk_rnf(ji,jj)                           ! recalculates h_rnf to be the depth in metres
671                h_rnf(ji,jj) = h_rnf(ji,jj) + e3t(ji,jj,jk,Kmm)   ! to the bottom of the relevant grid box
672            END DO
673        END DO
674      END DO
675      !
676   END SUBROUTINE dta_dyn_hrnf
677
678
679
680   SUBROUTINE dta_dyn_slp( kt, Kbb, Kmm )
681      !!---------------------------------------------------------------------
682      !!                    ***  ROUTINE dta_dyn_slp  ***
683      !!
684      !! ** Purpose : Computation of slope
685      !!
686      !!---------------------------------------------------------------------
687      INTEGER,  INTENT(in) :: kt       ! time step
688      INTEGER,  INTENT(in) :: Kbb, Kmm ! ocean time level indices
689      !
690      INTEGER  ::   ji, jj     ! dummy loop indices
691      REAL(wp) ::   ztinta     ! ratio applied to after  records when doing time interpolation
692      REAL(wp) ::   ztintb     ! ratio applied to before records when doing time interpolation
693      INTEGER  ::   iswap 
694      REAL(wp), DIMENSION(jpi,jpj,jpk)      ::   zuslp, zvslp, zwslpi, zwslpj
695      REAL(wp), DIMENSION(jpi,jpj,jpk,jpts) ::   zts
696      !!---------------------------------------------------------------------
697      !
698      IF( sf_dyn(jf_tem)%ln_tint ) THEN    ! Computes slopes (here avt is used as workspace)                       
699         IF( kt == nit000 ) THEN
700            IF(lwp) WRITE(numout,*) ' Compute new slopes at kt = ', kt
701            zts(:,:,:,jp_tem) = sf_dyn(jf_tem)%fdta(:,:,:,1) * tmask(:,:,:)   ! temperature
702            zts(:,:,:,jp_sal) = sf_dyn(jf_sal)%fdta(:,:,:,1) * tmask(:,:,:)   ! salinity
703            avt(:,:,:)        = sf_dyn(jf_avt)%fdta(:,:,:,1) * tmask(:,:,:)   ! vertical diffusive coef.
704            CALL compute_slopes( kt, zts, zuslp, zvslp, zwslpi, zwslpj, Kbb, Kmm )
705            uslpdta (:,:,:,1) = zuslp (:,:,:) 
706            vslpdta (:,:,:,1) = zvslp (:,:,:) 
707            wslpidta(:,:,:,1) = zwslpi(:,:,:) 
708            wslpjdta(:,:,:,1) = zwslpj(:,:,:) 
709            !
710            zts(:,:,:,jp_tem) = sf_dyn(jf_tem)%fdta(:,:,:,2) * tmask(:,:,:)   ! temperature
711            zts(:,:,:,jp_sal) = sf_dyn(jf_sal)%fdta(:,:,:,2) * tmask(:,:,:)   ! salinity
712            avt(:,:,:)        = sf_dyn(jf_avt)%fdta(:,:,:,2) * tmask(:,:,:)   ! vertical diffusive coef.
713            CALL compute_slopes( kt, zts, zuslp, zvslp, zwslpi, zwslpj, Kbb, Kmm )
714            uslpdta (:,:,:,2) = zuslp (:,:,:) 
715            vslpdta (:,:,:,2) = zvslp (:,:,:) 
716            wslpidta(:,:,:,2) = zwslpi(:,:,:) 
717            wslpjdta(:,:,:,2) = zwslpj(:,:,:) 
718         ELSE
719           !
720           iswap = 0
721           IF( sf_dyn(jf_tem)%nrec_a(2) - nprevrec /= 0 )  iswap = 1
722           IF( nsecdyn > sf_dyn(jf_tem)%nrec_b(2) .AND. iswap == 1 )  THEN    ! read/update the after data
723              IF(lwp) WRITE(numout,*) ' Compute new slopes at kt = ', kt
724              uslpdta (:,:,:,1) =  uslpdta (:,:,:,2)         ! swap the data
725              vslpdta (:,:,:,1) =  vslpdta (:,:,:,2) 
726              wslpidta(:,:,:,1) =  wslpidta(:,:,:,2) 
727              wslpjdta(:,:,:,1) =  wslpjdta(:,:,:,2) 
728              !
729              zts(:,:,:,jp_tem) = sf_dyn(jf_tem)%fdta(:,:,:,2) * tmask(:,:,:)   ! temperature
730              zts(:,:,:,jp_sal) = sf_dyn(jf_sal)%fdta(:,:,:,2) * tmask(:,:,:)   ! salinity
731              avt(:,:,:)        = sf_dyn(jf_avt)%fdta(:,:,:,2) * tmask(:,:,:)   ! vertical diffusive coef.
732              CALL compute_slopes( kt, zts, zuslp, zvslp, zwslpi, zwslpj, Kbb, Kmm )
733              !
734              uslpdta (:,:,:,2) = zuslp (:,:,:) 
735              vslpdta (:,:,:,2) = zvslp (:,:,:) 
736              wslpidta(:,:,:,2) = zwslpi(:,:,:) 
737              wslpjdta(:,:,:,2) = zwslpj(:,:,:) 
738            ENDIF
739         ENDIF
740      ENDIF
741      !
742      IF( sf_dyn(jf_tem)%ln_tint )  THEN
743         ztinta =  REAL( nsecdyn - sf_dyn(jf_tem)%nrec_b(2), wp )  &
744            &    / REAL( sf_dyn(jf_tem)%nrec_a(2) - sf_dyn(jf_tem)%nrec_b(2), wp )
745         ztintb =  1. - ztinta
746         IF( l_ldfslp .AND. .NOT.lk_c1d ) THEN    ! Computes slopes (here avt is used as workspace)
747            uslp (:,:,:) = ztintb * uslpdta (:,:,:,1)  + ztinta * uslpdta (:,:,:,2) 
748            vslp (:,:,:) = ztintb * vslpdta (:,:,:,1)  + ztinta * vslpdta (:,:,:,2) 
749            wslpi(:,:,:) = ztintb * wslpidta(:,:,:,1)  + ztinta * wslpidta(:,:,:,2) 
750            wslpj(:,:,:) = ztintb * wslpjdta(:,:,:,1)  + ztinta * wslpjdta(:,:,:,2) 
751         ENDIF
752      ELSE
753         zts(:,:,:,jp_tem) = sf_dyn(jf_tem)%fnow(:,:,:) * tmask(:,:,:)   ! temperature
754         zts(:,:,:,jp_sal) = sf_dyn(jf_sal)%fnow(:,:,:) * tmask(:,:,:)   ! salinity
755         avt(:,:,:)        = sf_dyn(jf_avt)%fnow(:,:,:) * tmask(:,:,:)   ! vertical diffusive coef.
756         CALL compute_slopes( kt, zts, zuslp, zvslp, zwslpi, zwslpj, Kbb, Kmm )
757         !
758         IF( l_ldfslp .AND. .NOT.lk_c1d ) THEN    ! Computes slopes (here avt is used as workspace)
759            uslp (:,:,:) = zuslp (:,:,:)
760            vslp (:,:,:) = zvslp (:,:,:)
761            wslpi(:,:,:) = zwslpi(:,:,:)
762            wslpj(:,:,:) = zwslpj(:,:,:)
763         ENDIF
764      ENDIF
765      !
766   END SUBROUTINE dta_dyn_slp
767
768
769   SUBROUTINE compute_slopes( kt, pts, puslp, pvslp, pwslpi, pwslpj, Kbb, Kmm )
770      !!---------------------------------------------------------------------
771      !!                    ***  ROUTINE dta_dyn_slp  ***
772      !!
773      !! ** Purpose :   Computation of slope
774      !!---------------------------------------------------------------------
775      INTEGER ,                              INTENT(in ) :: kt       ! time step
776      REAL(wp), DIMENSION(jpi,jpj,jpk,jpts), INTENT(in ) :: pts      ! temperature/salinity
777      REAL(wp), DIMENSION(jpi,jpj,jpk)     , INTENT(out) :: puslp    ! zonal isopycnal slopes
778      REAL(wp), DIMENSION(jpi,jpj,jpk)     , INTENT(out) :: pvslp    ! meridional isopycnal slopes
779      REAL(wp), DIMENSION(jpi,jpj,jpk)     , INTENT(out) :: pwslpi   ! zonal diapycnal slopes
780      REAL(wp), DIMENSION(jpi,jpj,jpk)     , INTENT(out) :: pwslpj   ! meridional diapycnal slopes
781      INTEGER ,                              INTENT(in ) :: Kbb, Kmm ! ocean time level indices
782      !!---------------------------------------------------------------------
783      !
784      IF( l_ldfslp .AND. .NOT.lk_c1d ) THEN    ! Computes slopes (here avt is used as workspace)
785         CALL eos    ( pts, rhd, rhop, gdept_0(:,:,:) )
786         CALL eos_rab( pts, rab_n, Kmm )       ! now local thermal/haline expension ratio at T-points
787         CALL bn2    ( pts, rab_n, rn2, Kmm  ) ! now    Brunt-Vaisala
788
789      ! Partial steps: before Horizontal DErivative
790      IF( ln_zps  .AND. .NOT. ln_isfcav)                            &
791         &            CALL zps_hde    ( kt, Kmm, jpts, pts, gtsu, gtsv,  &  ! Partial steps: before horizontal gradient
792         &                                        rhd, gru , grv    )  ! of t, s, rd at the last ocean level
793      IF( ln_zps .AND.        ln_isfcav)                            &
794         &            CALL zps_hde_isf( kt, Kmm, jpts, pts, gtsu, gtsv, gtui, gtvi, &  ! Partial steps for top cell (ISF)
795         &                                        rhd, gru , grv , grui, grvi )  ! of t, s, rd at the first ocean level
796
797         rn2b(:,:,:) = rn2(:,:,:)                ! needed for zdfmxl
798         CALL zdf_mxl( kt, Kmm )                 ! mixed layer depth
799         CALL ldf_slp( kt, rhd, rn2, Kbb, Kmm )  ! slopes
800         puslp (:,:,:) = uslp (:,:,:)
801         pvslp (:,:,:) = vslp (:,:,:)
802         pwslpi(:,:,:) = wslpi(:,:,:)
803         pwslpj(:,:,:) = wslpj(:,:,:)
804     ELSE
805         puslp (:,:,:) = 0.            ! to avoid warning when compiling
806         pvslp (:,:,:) = 0.
807         pwslpi(:,:,:) = 0.
808         pwslpj(:,:,:) = 0.
809     ENDIF
810      !
811   END SUBROUTINE compute_slopes
812
813   !!======================================================================
814END MODULE dtadyn
Note: See TracBrowser for help on using the repository browser.