source: NEMO/branches/2020/dev_12905_xios_restart/src/OCE/IOM/iom.F90 @ 12957

Last change on this file since 12957 was 12957, checked in by andmirek, 17 months ago

Ticket #2462: write/read SI3 restart with XIOS (has debug print statements)

  • Property svn:keywords set to Id
File size: 125.0 KB
Line 
1MODULE iom
2   !!======================================================================
3   !!                    ***  MODULE  iom ***
4   !! Input/Output manager :  Library to read input files
5   !!======================================================================
6   !! History :  2.0  ! 2005-12  (J. Belier) Original code
7   !!            2.0  ! 2006-02  (S. Masson) Adaptation to NEMO
8   !!            3.0  ! 2007-07  (D. Storkey) Changes to iom_gettime
9   !!            3.4  ! 2012-12  (R. Bourdalle-Badie and G. Reffray)  add C1D case 
10   !!            3.6  ! 2014-15  DIMG format removed
11   !!            3.6  ! 2015-15  (J. Harle) Added procedure to read REAL attributes
12   !!            4.0  ! 2017-11  (M. Andrejczuk) Extend IOM interface to write any 3D fields
13   !!----------------------------------------------------------------------
14
15   !!----------------------------------------------------------------------
16   !!   iom_open       : open a file read only
17   !!   iom_close      : close a file or all files opened by iom
18   !!   iom_get        : read a field (interfaced to several routines)
19   !!   iom_varid      : get the id of a variable in a file
20   !!   iom_rstput     : write a field in a restart file (interfaced to several routines)
21   !!----------------------------------------------------------------------
22   USE dom_oce         ! ocean space and time domain
23   USE c1d             ! 1D vertical configuration
24   USE flo_oce         ! floats module declarations
25   USE lbclnk          ! lateal boundary condition / mpp exchanges
26   USE iom_def         ! iom variables definitions
27   USE iom_nf90        ! NetCDF format with native NetCDF library
28   USE in_out_manager  ! I/O manager
29   USE lib_mpp           ! MPP library
30#if defined key_iomput
31   USE sbc_oce  , ONLY :   nn_fsbc, ght_abl, ghw_abl, e3t_abl, e3w_abl, jpka, jpkam1
32   USE icb_oce  , ONLY :   nclasses, class_num       !  !: iceberg classes
33#if defined key_si3
34   USE ice      , ONLY :   jpl
35#endif
36   USE domngb          ! ocean space and time domain
37   USE phycst          ! physical constants
38   USE dianam          ! build name of file
39   USE xios
40# endif
41   USE ioipsl, ONLY :  ju2ymds    ! for calendar
42   USE crs             ! Grid coarsening
43#if defined key_top
44   USE trc, ONLY    :  profsed
45#endif
46   USE lib_fortran 
47   USE diu_bulk, ONLY : ln_diurnal_only, ln_diurnal
48   USE iom_nf90
49   USE netcdf
50
51   IMPLICIT NONE
52   PUBLIC   !   must be public to be able to access iom_def through iom
53   
54#if defined key_iomput
55   LOGICAL, PUBLIC, PARAMETER ::   lk_iomput = .TRUE.        !: iom_put flag
56#else
57   LOGICAL, PUBLIC, PARAMETER ::   lk_iomput = .FALSE.       !: iom_put flag
58#endif
59   PUBLIC iom_init, iom_init_closedef, iom_swap, iom_open, iom_close, iom_setkt, iom_varid, iom_get, iom_get_var
60   PUBLIC iom_chkatt, iom_getatt, iom_putatt, iom_getszuld, iom_rstput, iom_delay_rst, iom_put
61   PUBLIC iom_use, iom_context_finalize, iom_update_file_name, iom_miss_val
62
63   PRIVATE iom_rp0d, iom_rp1d, iom_rp2d, iom_rp3d
64   PRIVATE iom_g0d, iom_g1d, iom_g2d, iom_g3d, iom_get_123d
65   PRIVATE iom_p1d, iom_p2d, iom_p3d, iom_p4d
66#if defined key_iomput
67   PRIVATE iom_set_domain_attr, iom_set_axis_attr, iom_set_field_attr, iom_set_file_attr, iom_get_file_attr, iom_set_grid_attr
68   PRIVATE set_grid, set_grid_bounds, set_scalar, set_xmlatt, set_mooring, iom_sdate
69   PRIVATE iom_set_rst_context, iom_set_rstr_active
70# endif
71   PRIVATE iom_set_rstw_active
72
73   INTERFACE iom_get
74      MODULE PROCEDURE iom_g0d, iom_g1d, iom_g2d, iom_g3d
75   END INTERFACE
76   INTERFACE iom_getatt
77      MODULE PROCEDURE iom_g0d_iatt, iom_g1d_iatt, iom_g0d_ratt, iom_g1d_ratt, iom_g0d_catt
78   END INTERFACE
79   INTERFACE iom_putatt
80      MODULE PROCEDURE iom_p0d_iatt, iom_p1d_iatt, iom_p0d_ratt, iom_p1d_ratt, iom_p0d_catt
81   END INTERFACE
82   INTERFACE iom_rstput
83      MODULE PROCEDURE iom_rp0d, iom_rp1d, iom_rp2d, iom_rp3d
84   END INTERFACE
85   INTERFACE iom_put
86      MODULE PROCEDURE iom_p0d, iom_p1d, iom_p2d, iom_p3d, iom_p4d
87   END INTERFACE iom_put
88 
89   !! * Substitutions
90#  include "do_loop_substitute.h90"
91   !!----------------------------------------------------------------------
92   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
93   !! $Id$
94   !! Software governed by the CeCILL license (see ./LICENSE)
95   !!----------------------------------------------------------------------
96CONTAINS
97
98   SUBROUTINE iom_init( cdname, fname, ld_tmppatch, ld_closedef ) 
99      !!----------------------------------------------------------------------
100      !!                     ***  ROUTINE   ***
101      !!
102      !! ** Purpose :   
103      !!
104      !!----------------------------------------------------------------------
105      CHARACTER(len=*),           INTENT(in)  :: cdname
106      CHARACTER(len=*), OPTIONAL, INTENT(in)  :: fname
107      LOGICAL         , OPTIONAL, INTENT(in)  :: ld_tmppatch
108      LOGICAL         , OPTIONAL, INTENT(in)  :: ld_closedef
109#if defined key_iomput
110      !
111      TYPE(xios_duration) :: dtime    = xios_duration(0, 0, 0, 0, 0, 0)
112      TYPE(xios_date)     :: start_date
113      CHARACTER(len=lc) :: clname
114      INTEGER             :: irefyear, irefmonth, irefday
115      INTEGER           :: ji
116      LOGICAL           :: llrst_context              ! is context related to restart
117      INTEGER           :: inum
118      !
119      REAL(wp), ALLOCATABLE, DIMENSION(:,:) :: zt_bnds, zw_bnds
120      REAL(wp), DIMENSION(2,jpkam1)         :: za_bnds   ! ABL vertical boundaries
121      LOGICAL ::   ll_tmppatch = .TRUE.    !: seb: patch before we remove periodicity
122      INTEGER ::   nldi_save, nlei_save    !:      and close boundaries in output files
123      INTEGER ::   nldj_save, nlej_save    !:
124      LOGICAL ::   ll_closedef
125      !!----------------------------------------------------------------------
126      !
127      ! seb: patch before we remove periodicity and close boundaries in output files
128      IF( PRESENT(ld_tmppatch) ) THEN   ;   ll_tmppatch = ld_tmppatch
129      ELSE                              ;   ll_tmppatch = .TRUE.
130      ENDIF
131      IF ( ll_tmppatch ) THEN
132         nldi_save = nldi   ;   nlei_save = nlei
133         nldj_save = nldj   ;   nlej_save = nlej
134         IF( nimpp           ==      1 ) nldi = 1
135         IF( nimpp + jpi - 1 == jpiglo ) nlei = jpi
136         IF( njmpp           ==      1 ) nldj = 1
137         IF( njmpp + jpj - 1 == jpjglo ) nlej = jpj
138      ENDIF
139      !
140      ll_closedef = .TRUE.
141      IF ( PRESENT(ld_closedef) ) ll_closedef = ld_closedef
142      !
143      ALLOCATE( zt_bnds(2,jpk), zw_bnds(2,jpk) )
144      !
145      IF(lwp) write(numout, *) 'TEST IOM_INIT: ', TRIM(cdname),' File: ', TRIM(fname)
146      IF(lwp) CALL FLUSH(numout)
147      clname = cdname
148      IF( TRIM(Agrif_CFixed()) /= '0' )   clname = TRIM(Agrif_CFixed())//"_"//TRIM(cdname)
149      CALL xios_context_initialize(TRIM(clname), mpi_comm_oce)
150      CALL iom_swap( cdname )
151      llrst_context = (TRIM(cdname) == TRIM(crxios_context)) .OR. (TRIM(cdname) == TRIM(cwxios_context))
152      llrst_context = llrst_context .OR. (TRIM(cdname) == TRIM(crixios_context)) .OR. (TRIM(cdname) == TRIM(cwixios_context))
153
154      ! Calendar type is now defined in xml file
155      IF (.NOT.(xios_getvar('ref_year' ,irefyear ))) irefyear  = 1900
156      IF (.NOT.(xios_getvar('ref_month',irefmonth))) irefmonth = 01
157      IF (.NOT.(xios_getvar('ref_day'  ,irefday  ))) irefday   = 01
158
159      SELECT CASE ( nleapy )        ! Choose calendar for IOIPSL
160      CASE ( 1)   ; CALL xios_define_calendar( TYPE = "Gregorian", time_origin = xios_date(irefyear,irefmonth,irefday,00,00,00), &
161          &                                    start_date = xios_date(nyear,nmonth,nday,0,0,0) )
162      CASE ( 0)   ; CALL xios_define_calendar( TYPE = "NoLeap"   , time_origin = xios_date(irefyear,irefmonth,irefday,00,00,00), &
163          &                                    start_date = xios_date(nyear,nmonth,nday,0,0,0) )
164      CASE (30)   ; CALL xios_define_calendar( TYPE = "D360"     , time_origin = xios_date(irefyear,irefmonth,irefday,00,00,00), &
165          &                                    start_date = xios_date(nyear,nmonth,nday,0,0,0) )
166      END SELECT
167
168      ! horizontal grid definition
169      IF(.NOT.llrst_context) CALL set_scalar
170      !
171      IF( TRIM(cdname) == TRIM(cxios_context) ) THEN 
172         CALL set_grid( "T", glamt, gphit, .FALSE., .FALSE. ) 
173         CALL set_grid( "U", glamu, gphiu, .FALSE., .FALSE. )
174         CALL set_grid( "V", glamv, gphiv, .FALSE., .FALSE. )
175         CALL set_grid( "W", glamt, gphit, .FALSE., .FALSE. )
176         CALL set_grid_znl( gphit )
177         !
178         IF( ln_cfmeta ) THEN   ! Add additional grid metadata
179            CALL iom_set_domain_attr("grid_T", area = e1e2t(nldi:nlei, nldj:nlej))
180            CALL iom_set_domain_attr("grid_U", area = e1e2u(nldi:nlei, nldj:nlej))
181            CALL iom_set_domain_attr("grid_V", area = e1e2v(nldi:nlei, nldj:nlej))
182            CALL iom_set_domain_attr("grid_W", area = e1e2t(nldi:nlei, nldj:nlej))
183            CALL set_grid_bounds( "T", glamf, gphif, glamt, gphit )
184            CALL set_grid_bounds( "U", glamv, gphiv, glamu, gphiu )
185            CALL set_grid_bounds( "V", glamu, gphiu, glamv, gphiv )
186            CALL set_grid_bounds( "W", glamf, gphif, glamt, gphit )
187         ENDIF
188      ENDIF
189      !
190      IF( TRIM(cdname) == TRIM(cxios_context)//"_crs" ) THEN 
191         CALL dom_grid_crs   ! Save the parent grid information  & Switch to coarse grid domain
192         !
193         CALL set_grid( "T", glamt_crs, gphit_crs, .FALSE., .FALSE. ) 
194         CALL set_grid( "U", glamu_crs, gphiu_crs, .FALSE., .FALSE. ) 
195         CALL set_grid( "V", glamv_crs, gphiv_crs, .FALSE., .FALSE. ) 
196         CALL set_grid( "W", glamt_crs, gphit_crs, .FALSE., .FALSE. ) 
197         CALL set_grid_znl( gphit_crs )
198          !
199         CALL dom_grid_glo   ! Return to parent grid domain
200         !
201         IF( ln_cfmeta .AND. .NOT. llrst_context) THEN   ! Add additional grid metadata
202            CALL iom_set_domain_attr("grid_T", area = e1e2t_crs(nldi:nlei, nldj:nlej))
203            CALL iom_set_domain_attr("grid_U", area = e1u_crs(nldi:nlei, nldj:nlej) * e2u_crs(nldi:nlei, nldj:nlej))
204            CALL iom_set_domain_attr("grid_V", area = e1v_crs(nldi:nlei, nldj:nlej) * e2v_crs(nldi:nlei, nldj:nlej))
205            CALL iom_set_domain_attr("grid_W", area = e1e2t_crs(nldi:nlei, nldj:nlej))
206            CALL set_grid_bounds( "T", glamf_crs, gphif_crs, glamt_crs, gphit_crs )
207            CALL set_grid_bounds( "U", glamv_crs, gphiv_crs, glamu_crs, gphiu_crs )
208            CALL set_grid_bounds( "V", glamu_crs, gphiu_crs, glamv_crs, gphiv_crs )
209            CALL set_grid_bounds( "W", glamf_crs, gphif_crs, glamt_crs, gphit_crs )
210         ENDIF
211      ENDIF
212      !
213      ! vertical grid definition
214      IF(.NOT.llrst_context) THEN
215          CALL iom_set_axis_attr(  "deptht", paxis = gdept_1d )
216          CALL iom_set_axis_attr(  "depthu", paxis = gdept_1d )
217          CALL iom_set_axis_attr(  "depthv", paxis = gdept_1d )
218          CALL iom_set_axis_attr(  "depthw", paxis = gdepw_1d )
219
220          ! ABL
221          IF( .NOT. ALLOCATED(ght_abl) ) THEN   ! force definition for xml files (xios)
222             ALLOCATE( ght_abl(jpka), ghw_abl(jpka), e3t_abl(jpka), e3w_abl(jpka) )   ! default allocation needed by iom
223             ght_abl(:) = -1._wp   ;   ghw_abl(:) = -1._wp
224             e3t_abl(:) = -1._wp   ;   e3w_abl(:) = -1._wp
225          ENDIF
226          CALL iom_set_axis_attr( "ght_abl", ght_abl(2:jpka) )
227          CALL iom_set_axis_attr( "ghw_abl", ghw_abl(2:jpka) )
228         
229          ! Add vertical grid bounds
230          zt_bnds(2,:      ) = gdept_1d(:)
231          zt_bnds(1,2:jpk  ) = gdept_1d(1:jpkm1)
232          zt_bnds(1,1      ) = gdept_1d(1) - e3w_1d(1)
233          zw_bnds(1,:      ) = gdepw_1d(:)
234          zw_bnds(2,1:jpkm1) = gdepw_1d(2:jpk)
235          zw_bnds(2,jpk:   ) = gdepw_1d(jpk) + e3t_1d(jpk)
236          CALL iom_set_axis_attr(  "deptht", bounds=zw_bnds )
237          CALL iom_set_axis_attr(  "depthu", bounds=zw_bnds )
238          CALL iom_set_axis_attr(  "depthv", bounds=zw_bnds )
239          CALL iom_set_axis_attr(  "depthw", bounds=zt_bnds )
240
241          ! ABL
242          za_bnds(1,:) = ghw_abl(1:jpkam1)
243          za_bnds(2,:) = ghw_abl(2:jpka  )
244          CALL iom_set_axis_attr( "ght_abl", bounds=za_bnds )
245          za_bnds(1,:) = ght_abl(2:jpka  )
246          za_bnds(2,:) = ght_abl(2:jpka  ) + e3w_abl(2:jpka)
247          CALL iom_set_axis_attr( "ghw_abl", bounds=za_bnds )
248
249          CALL iom_set_axis_attr( "nfloat", (/ (REAL(ji,wp), ji=1,jpnfl) /) )
250# if defined key_si3
251          CALL iom_set_axis_attr( "ncatice", (/ (REAL(ji,wp), ji=1,jpl) /) )
252          ! SIMIP diagnostics (4 main arctic straits)
253          CALL iom_set_axis_attr( "nstrait", (/ (REAL(ji,wp), ji=1,4) /) )
254# endif
255#if defined key_top
256          IF( ALLOCATED(profsed) ) CALL iom_set_axis_attr( "profsed", paxis = profsed )
257#endif
258          CALL iom_set_axis_attr( "icbcla", class_num )
259          CALL iom_set_axis_attr( "iax_20C", (/ REAL(20,wp) /) )   ! strange syntaxe and idea...
260          CALL iom_set_axis_attr( "iax_26C", (/ REAL(26,wp) /) )   ! strange syntaxe and idea...
261          CALL iom_set_axis_attr( "iax_28C", (/ REAL(28,wp) /) )   ! strange syntaxe and idea...
262          CALL iom_set_axis_attr( "basin"  , (/ (REAL(ji,wp), ji=1,5) /) )
263      ENDIF
264      !
265      ! automatic definitions of some of the xml attributs
266      IF(lwp) write(numout, *) 'TEST IOM_INIT: ', TRIM(cdname), TRIM(cdname) == TRIM(crixios_context)
267      IF(lwp) CALL FLUSH(numout)
268      IF( TRIM(cdname) == TRIM(crxios_context) .OR. TRIM(cdname) == TRIM(crixios_context)) THEN
269          IF(TRIM(cdname) == TRIM(crxios_context) ) THEN
270             inum = numror
271          ELSEIF(TRIM(cdname) == TRIM(crixios_context)) THEN
272             inum = numrir 
273          ELSE
274             CALL ctl_stop( 'iom_init:', 'restart read with XIOS: Unknown restart context' )
275          ENDIF
276          CALL iom_set_rst_context(.TRUE.)
277!set which fields will be read from restart file
278          CALL iom_set_rstr_active(fname, inum)
279      ELSE IF( (TRIM(cdname) == TRIM(cwxios_context)) .OR. (TRIM(cdname) == TRIM(cwixios_context))) THEN
280          CALL iom_set_rstw_file(fname)
281      ELSE
282          CALL set_xmlatt
283      ENDIF
284      !
285      ! set time step length
286      dtime%second = rn_Dt
287      CALL xios_set_timestep( dtime )
288      !
289      ! conditional closure of context definition
290      IF ( ll_closedef ) CALL iom_init_closedef
291      !
292      DEALLOCATE( zt_bnds, zw_bnds )
293      !
294      IF ( ll_tmppatch ) THEN
295         nldi = nldi_save   ;   nlei = nlei_save
296         nldj = nldj_save   ;   nlej = nlej_save
297      ENDIF
298#endif
299      !
300   END SUBROUTINE iom_init
301
302   SUBROUTINE iom_init_closedef(cdname)
303      !!----------------------------------------------------------------------
304      !!            ***  SUBROUTINE iom_init_closedef  ***
305      !!----------------------------------------------------------------------
306      !!
307      !! ** Purpose : Closure of context definition
308      !!
309      !!----------------------------------------------------------------------
310   CHARACTER(len=*), OPTIONAL, INTENT(IN) :: cdname
311#if defined key_iomput
312   LOGICAL :: llrstw
313
314      IF(lwp) write(numout, *) 'XIOS CLOSE definitions for: ', TRIM(cdname)
315      llrstw = .FALSE.
316     IF(PRESENT(cdname)) THEN
317         IF((TRIM(cdname) == TRIM(cwxios_context)) .OR. (TRIM(cdname) == TRIM(cwixios_context))) THEN
318           llrstw = .TRUE.
319         ENDIF
320      ENDIF
321
322      IF( llrstw ) THEN
323!set names of the fields in restart file IF using XIOS to write data
324          CALL iom_set_rst_context(.FALSE.)
325      ENDIF
326
327      CALL xios_close_context_definition()
328
329      IF(.NOT. llrstw)  CALL xios_update_calendar( 0 )
330
331#else
332      IF( .FALSE. )   WRITE(numout,*) 'iom_init_closedef: should not see this'   ! useless statement to avoid compilation warnings
333#endif
334
335   END SUBROUTINE iom_init_closedef
336
337   SUBROUTINE iom_set_rstr_active(cdfname, idnum)
338      !!---------------------------------------------------------------------
339      !!                   ***  SUBROUTINE  iom_set_rstr_active  ***
340      !!
341      !! ** Purpose :  define file name in XIOS context for reading restart file,
342      !!               enable variables present in restart file for reading with XIOS
343      !!---------------------------------------------------------------------
344
345!sets enabled = .TRUE. for each field in restart file
346   CHARACTER(len=*), INTENT(IN) :: cdfname
347   INTEGER         , INTENT(IN) :: idnum 
348#if defined key_iomput
349   INTEGER                                    :: ndims, nvars, natts, unlimitedDimId, dimlen, xtype,mdims
350   TYPE(xios_field)                           :: field_hdl
351   TYPE(xios_file)                            :: file_hdl
352   TYPE(xios_filegroup)                       :: filegroup_hdl
353   INTEGER                                    :: dimids(4), jv,i, idim
354   CHARACTER(LEN=256)                         :: clinfo               ! info character
355   INTEGER, ALLOCATABLE                       :: indimlens(:)
356   CHARACTER(LEN=nf90_max_name), ALLOCATABLE  :: indimnames(:)
357   CHARACTER(LEN=nf90_max_name)               :: dimname, varname
358   LOGICAL                                    :: lmeta
359
360!failed to build with AGRIF
361!      meta(1:NMETA) = ["nav_lat",        &
362!            "nav_lon", "nav_lev", "time_instant",                  &
363!            "time_instant_bounds", "time_counter",                 &
364!            "time_counter_bounds", "x", "y", "numcat"]
365
366        meta(1) = "nav_lat"
367        meta(2) = "nav_lon"
368        meta(3) = "nav_lev"
369        meta(4) = "time_instant"
370        meta(5) = "time_instant_bounds"
371        meta(6) = "time_counter"
372        meta(7) = "time_counter_bounds"
373        meta(8) = "x"
374        meta(9) = "y"
375        meta(10) = "numcat"
376
377        clinfo = '          iom_set_rstr_active, file: '//TRIM(cdfname)
378
379        IF(lwp) write(numout, *) TRIM(clinfo)
380        IF(lwp) CALL FLUSH(numout)
381!set name of the restart file and enable available fields
382        CALL xios_get_handle("file_definition", filegroup_hdl )
383        CALL xios_add_child(filegroup_hdl, file_hdl, 'rrestart')
384        CALL xios_set_file_attr( "rrestart", name=trim(cdfname), type="one_file", &
385             par_access="collective", enabled=.TRUE., mode="read",                 &
386             output_freq=xios_timestep)
387
388        CALL iom_nf90_check( nf90_inquire( iom_file(idnum)%nfid, ndims, nvars, natts ), clinfo )
389        ALLOCATE(indimlens(ndims), indimnames(ndims))
390        CALL iom_nf90_check( nf90_inquire( iom_file(idnum)%nfid, unlimitedDimId = unlimitedDimId ), clinfo )
391
392        DO idim = 1, ndims
393           CALL iom_nf90_check( nf90_inquire_dimension( iom_file(idnum)%nfid, idim, dimname, dimlen ), clinfo )
394           indimlens(idim) = dimlen
395           indimnames(idim) = dimname
396        ENDDO
397
398        DO jv =1, nvars
399            lmeta = .FALSE.
400            CALL iom_nf90_check( nf90_inquire_variable( iom_file(idnum)%nfid, jv, varname, xtype, ndims, dimids, natts ), clinfo )
401            DO i = 1, NMETA
402               IF(TRIM(varname) == TRIM(meta(i))) THEN
403                  lmeta = .TRUE.
404               ENDIF
405            ENDDO
406            IF(.NOT.lmeta) THEN
407               CALL xios_add_child(file_hdl, field_hdl, TRIM(varname))
408               if(lwp) write(numout, *) 'ADD field: ', TRIM(varname)
409               IF(lwp) CALL FLUSH(numout)
410               mdims = ndims
411
412               IF(ANY(dimids(1:ndims) == unlimitedDimId)) THEN
413                mdims = mdims - 1
414               ENDIF
415
416               IF(mdims == 3) THEN
417                      if(lwp) write(numout, *) '3D', indimlens(ndims)
418                      IF(lwp) CALL FLUSH(numout)
419
420                      CALL xios_set_attr (field_hdl, enabled = .TRUE., name = TRIM(varname),   &
421                                   domain_ref="grid_N", axis_ref=TRIM(iom_axis(indimlens(ndims))), &
422                                   prec = 8, operation = "instant")
423               ELSEIF(mdims == 2) THEN
424                      if(lwp) write(numout, *) '2D'
425                      IF(lwp) CALL FLUSH(numout)
426
427                      CALL xios_set_attr (field_hdl, enabled = .TRUE., name = TRIM(varname), &
428                                          domain_ref="grid_N", prec = 8, operation = "instant") 
429               ELSEIF(mdims == 1) THEN
430                      if(lwp) write(numout, *) '1D', indimlens(ndims)
431                      IF(lwp) CALL FLUSH(numout)
432
433                      CALL xios_set_attr (field_hdl, enabled = .TRUE., name = TRIM(varname), &
434                                          axis_ref=TRIM(iom_axis(indimlens(ndims))), prec = 8, operation = "instant")
435               ELSEIF(mdims == 0) THEN
436                      if(lwp) write(numout, *) '0D'
437                      IF(lwp) CALL FLUSH(numout)
438
439                      CALL xios_set_attr (field_hdl, enabled = .TRUE., name = TRIM(varname), &
440                                                scalar_ref = "grid_scalar", prec = 8, operation = "instant")
441               ELSE
442                      if(lwp) write(numout, *) 'WAHT?'
443                      IF(lwp) CALL FLUSH(numout)
444
445                      WRITE(ctmp1,*) 'iom_set_rstr_active: variable ', TRIM(varname) ,' incorrect number of dimensions' 
446                      CALL ctl_stop( 'iom_set_rstr_active:', ctmp1 )
447               ENDIF
448            ENDIF
449        ENDDO
450        DEALLOCATE(indimlens, indimnames)
451#endif
452   END SUBROUTINE iom_set_rstr_active
453
454   SUBROUTINE iom_set_rstw_file(cdrst_file)
455      !!---------------------------------------------------------------------
456      !!                   ***  SUBROUTINE iom_set_rstw_file   ***
457      !!
458      !! ** Purpose :  define file name in XIOS context for writing restart
459      !!---------------------------------------------------------------------
460   CHARACTER(len=*) :: cdrst_file
461#if defined key_iomput
462   TYPE(xios_file) :: file_hdl
463   TYPE(xios_filegroup) :: filegroup_hdl
464   INTEGER :: i
465   CHARACTER(lc)  ::   clpath
466
467!set name of the restart file and enable available fields
468        IF(lwp) WRITE(numout,*) 'Setting restart filename (for XIOS write) to: ',cdrst_file
469        IF(lwp) CALL FLUSH(numout)
470        CALL xios_get_handle("file_definition", filegroup_hdl )
471        CALL xios_add_child(filegroup_hdl, file_hdl, 'wrestart')
472        IF(nxioso.eq.1) THEN
473           CALL xios_set_file_attr( "wrestart", type="one_file", enabled=.TRUE.,& 
474                                    mode="write", output_freq=xios_timestep) 
475           if(lwp) write(numout,*) 'OPEN ', trim(cdrst_file), ' in one_file mode' 
476        ELSE 
477           CALL xios_set_file_attr( "wrestart", type="multiple_file", enabled=.TRUE.,& 
478                                    mode="write", output_freq=xios_timestep) 
479           if(lwp) write(numout,*) 'OPEN ', trim(cdrst_file), ' in multiple_file mode' 
480        ENDIF
481        CALL xios_set_file_attr( "wrestart", name=trim(cdrst_file))
482#endif
483   END SUBROUTINE iom_set_rstw_file
484
485
486   SUBROUTINE iom_set_rstw_active(sdfield, rd0, rd1, rd2, rd3)
487      !!---------------------------------------------------------------------
488      !!                   ***  SUBROUTINE iom_set_rstw_active   ***
489      !!
490      !! ** Purpose :  define file name in XIOS context for writing restart
491      !!               enable variables present in restart file for writing
492      !!---------------------------------------------------------------------
493!sets enabled = .TRUE. for each field in restart file
494   CHARACTER(len = *), INTENT(IN)                     :: sdfield
495   REAL(wp), OPTIONAL, INTENT(IN)                     :: rd0
496   REAL(wp), OPTIONAL, INTENT(IN), DIMENSION(:)       :: rd1
497   REAL(wp), OPTIONAL, INTENT(IN), DIMENSION(:, :)    :: rd2
498   REAL(wp), OPTIONAL, INTENT(IN), DIMENSION(:, :, :) :: rd3 
499#if defined key_iomput
500   TYPE(xios_field) :: field_hdl
501   TYPE(xios_file) :: file_hdl
502   INTEGER :: i
503   CHARACTER(lc)  ::   clpath
504   CHARACTER(len=1024) :: fname
505   CHARACTER(len=lc)   :: axis_ref
506
507        CALL xios_get_handle("wrestart", file_hdl)
508!define fields for restart context
509        CALL xios_add_child(file_hdl, field_hdl, TRIM(sdfield))
510
511        IF(PRESENT(rd3)) THEN
512               CALL xios_set_attr (field_hdl, enabled = .TRUE., name = TRIM(sdfield),   &
513                            domain_ref="grid_N", axis_ref=TRIM(iom_axis(size(rd3, 3))), &
514                            prec = 8, operation = "instant")
515        ENDIF
516
517        IF(PRESENT(rd2)) THEN
518               CALL xios_set_attr (field_hdl, enabled = .TRUE., name = TRIM(sdfield), &
519                                   domain_ref="grid_N", prec = 8, operation = "instant") 
520        ENDIF
521
522        IF(PRESENT(rd1)) THEN
523               CALL xios_set_attr (field_hdl, enabled = .TRUE., name = TRIM(sdfield), &
524                                   axis_ref=TRIM(iom_axis(size(rd1, 1))), prec = 8, operation = "instant")
525        ENDIF
526
527        IF(PRESENT(rd0)) THEN
528               CALL xios_set_attr (field_hdl, enabled = .TRUE., name = TRIM(sdfield), &
529                                         scalar_ref = "grid_scalar", prec = 8, operation = "instant")
530        ENDIF
531#endif
532   END SUBROUTINE iom_set_rstw_active
533
534   FUNCTION iom_axis(idlev) result(axis_ref)
535     !!---------------------------------------------------------------------
536      !!                   ***  FUNCTION  iom_axis  ***
537      !!
538      !! ** Purpose : Used for grid definition when XIOS is used to read/write
539      !!              restart. Returns axis corresponding to the number of levels
540      !!              given as an input variable. Axes are defined in routine
541      !!              iom_set_rst_context
542      !!---------------------------------------------------------------------
543    INTEGER, INTENT(IN) :: idlev
544    CHARACTER(len=lc)   :: axis_ref
545    CHARACTER(len=12)   :: str
546       IF(idlev == jpk) THEN
547         axis_ref="nav_lev"
548#if defined key_si3
549       ELSEIF(idlev == jpl) THEN
550         axis_ref="numcat"
551#endif         
552       ELSE
553         write(str, *) idlev
554         CALL ctl_stop( 'iom_axis', 'Definition for axis with '//TRIM(ADJUSTL(str))//' levels missing')
555       ENDIF
556   END FUNCTION iom_axis
557
558   SUBROUTINE iom_set_rst_context(ld_rstr) 
559     !!---------------------------------------------------------------------
560      !!                   ***  SUBROUTINE  iom_set_rst_context  ***
561      !!
562      !! ** Purpose : Define domain, axis and grid for restart (read/write)
563      !!              context
564      !!               
565      !!---------------------------------------------------------------------
566   LOGICAL, INTENT(IN)               :: ld_rstr
567   INTEGER :: ji
568#if defined key_iomput
569   TYPE(xios_domaingroup)            :: domaingroup_hdl 
570   TYPE(xios_domain)                 :: domain_hdl 
571   TYPE(xios_axisgroup)              :: axisgroup_hdl 
572   TYPE(xios_axis)                   :: axis_hdl 
573   TYPE(xios_scalar)                 :: scalar_hdl 
574   TYPE(xios_scalargroup)            :: scalargroup_hdl 
575
576     CALL xios_get_handle("domain_definition",domaingroup_hdl) 
577     CALL xios_add_child(domaingroup_hdl, domain_hdl, "grid_N") 
578     CALL set_grid("N", glamt, gphit, .TRUE., ld_rstr) 
579 
580     CALL xios_get_handle("axis_definition",axisgroup_hdl) 
581     CALL xios_add_child(axisgroup_hdl, axis_hdl, "nav_lev") 
582!AGRIF fails to compile when unit= is in call to xios_set_axis_attr
583!    CALL xios_set_axis_attr( "nav_lev", long_name="Vertical levels",  unit="m", positive="down")
584     CALL xios_set_axis_attr( "nav_lev", long_name="Vertical levels in meters", positive="down")
585     CALL iom_set_axis_attr( "nav_lev", paxis = gdept_1d ) 
586#if defined key_si3
587     CALL xios_add_child(axisgroup_hdl, axis_hdl, "numcat")
588     CALL iom_set_axis_attr( "numcat", (/ (REAL(ji,wp), ji=1,jpl) /) )
589#endif
590
591     CALL xios_get_handle("scalar_definition", scalargroup_hdl) 
592     CALL xios_add_child(scalargroup_hdl, scalar_hdl, "grid_scalar") 
593#endif
594   END SUBROUTINE iom_set_rst_context
595
596   SUBROUTINE iom_swap( cdname )
597      !!---------------------------------------------------------------------
598      !!                   ***  SUBROUTINE  iom_swap  ***
599      !!
600      !! ** Purpose :  swap context between different agrif grid for xmlio_server
601      !!---------------------------------------------------------------------
602      CHARACTER(len=*), INTENT(in) :: cdname
603#if defined key_iomput
604      TYPE(xios_context) :: nemo_hdl
605
606      IF( TRIM(Agrif_CFixed()) == '0' ) THEN
607        CALL xios_get_handle(TRIM(cdname),nemo_hdl)
608      ELSE
609        CALL xios_get_handle(TRIM(Agrif_CFixed())//"_"//TRIM(cdname),nemo_hdl)
610      ENDIF
611      !
612      CALL xios_set_current_context(nemo_hdl)
613#endif
614      !
615   END SUBROUTINE iom_swap
616
617
618   SUBROUTINE iom_open( cdname, kiomid, ldwrt, kdom, ldstop, ldiof, kdlev, cdcomp )
619      !!---------------------------------------------------------------------
620      !!                   ***  SUBROUTINE  iom_open  ***
621      !!
622      !! ** Purpose :  open an input file (return 0 if not found)
623      !!---------------------------------------------------------------------
624      CHARACTER(len=*), INTENT(in   )           ::   cdname   ! File name
625      INTEGER         , INTENT(  out)           ::   kiomid   ! iom identifier of the opened file
626      LOGICAL         , INTENT(in   ), OPTIONAL ::   ldwrt    ! open in write modeb          (default = .FALSE.)
627      INTEGER         , INTENT(in   ), OPTIONAL ::   kdom     ! Type of domain to be written (default = jpdom_local_noovlap)
628      LOGICAL         , INTENT(in   ), OPTIONAL ::   ldstop   ! stop if open to read a non-existing file (default = .TRUE.)
629      LOGICAL         , INTENT(in   ), OPTIONAL ::   ldiof    ! Interp On the Fly, needed for AGRIF (default = .FALSE.)
630      INTEGER         , INTENT(in   ), OPTIONAL ::   kdlev    ! number of vertical levels
631      CHARACTER(len=3), INTENT(in   ), OPTIONAL ::   cdcomp   ! name of component calling iom_nf90_open
632      !
633      CHARACTER(LEN=256)    ::   clname    ! the name of the file based on cdname [[+clcpu]+clcpu]
634      CHARACTER(LEN=256)    ::   cltmpn    ! tempory name to store clname (in writting mode)
635      CHARACTER(LEN=10)     ::   clsuffix  ! ".nc"
636      CHARACTER(LEN=15)     ::   clcpu     ! the cpu number (max jpmax_digits digits)
637      CHARACTER(LEN=256)    ::   clinfo    ! info character
638      LOGICAL               ::   llok      ! check the existence
639      LOGICAL               ::   llwrt     ! local definition of ldwrt
640      LOGICAL               ::   llnoov    ! local definition to read overlap
641      LOGICAL               ::   llstop    ! local definition of ldstop
642      LOGICAL               ::   lliof     ! local definition of ldiof
643      INTEGER               ::   icnt      ! counter for digits in clcpu (max = jpmax_digits)
644      INTEGER               ::   iln, ils  ! lengths of character
645      INTEGER               ::   idom      ! type of domain
646      INTEGER               ::   istop     !
647      INTEGER, DIMENSION(2,5) ::   idompar ! domain parameters:
648      ! local number of points for x,y dimensions
649      ! position of first local point for x,y dimensions
650      ! position of last local point for x,y dimensions
651      ! start halo size for x,y dimensions
652      ! end halo size for x,y dimensions
653      !---------------------------------------------------------------------
654      ! Initializations and control
655      ! =============
656      kiomid = -1
657      clinfo = '                    iom_open ~~~  '
658      istop = nstop
659      ! if iom_open is called for the first time: initialize iom_file(:)%nfid to 0
660      ! (could be done when defining iom_file in f95 but not in f90)
661      IF( Agrif_Root() ) THEN
662         IF( iom_open_init == 0 ) THEN
663            iom_file(:)%nfid = 0
664            iom_open_init = 1
665         ENDIF
666      ENDIF
667      ! do we read or write the file?
668      IF( PRESENT(ldwrt) ) THEN   ;   llwrt = ldwrt
669      ELSE                        ;   llwrt = .FALSE.
670      ENDIF
671      ! do we call ctl_stop if we try to open a non-existing file in read mode?
672      IF( PRESENT(ldstop) ) THEN   ;   llstop = ldstop
673      ELSE                         ;   llstop = .TRUE.
674      ENDIF
675      ! are we using interpolation on the fly?
676      IF( PRESENT(ldiof) ) THEN   ;   lliof = ldiof
677      ELSE                        ;   lliof = .FALSE.
678      ENDIF
679      ! do we read the overlap
680      ! ugly patch SM+JMM+RB to overwrite global definition in some cases
681      llnoov = (jpni * jpnj ) == jpnij .AND. .NOT. lk_agrif
682      ! create the file name by added, if needed, TRIM(Agrif_CFixed()) and TRIM(clsuffix)
683      ! =============
684      clname   = trim(cdname)
685      IF ( .NOT. Agrif_Root() .AND. .NOT. lliof ) THEN
686         iln    = INDEX(clname,'/') 
687         cltmpn = clname(1:iln)
688         clname = clname(iln+1:LEN_TRIM(clname))
689         clname=TRIM(cltmpn)//TRIM(Agrif_CFixed())//'_'//TRIM(clname)
690      ENDIF
691      ! which suffix should we use?
692      clsuffix = '.nc'
693      ! Add the suffix if needed
694      iln = LEN_TRIM(clname)
695      ils = LEN_TRIM(clsuffix)
696      IF( iln <= ils .OR. INDEX( TRIM(clname), TRIM(clsuffix), back = .TRUE. ) /= iln - ils + 1 )   &
697         &   clname = TRIM(clname)//TRIM(clsuffix)
698      cltmpn = clname   ! store this name
699      ! try to find if the file to be opened already exist
700      ! =============
701      INQUIRE( FILE = clname, EXIST = llok )
702      IF( .NOT.llok ) THEN
703         ! we try to add the cpu number to the name
704         WRITE(clcpu,*) narea-1
705
706         clcpu  = TRIM(ADJUSTL(clcpu))
707         iln = INDEX(clname,TRIM(clsuffix), back = .TRUE.)
708         clname = clname(1:iln-1)//'_'//TRIM(clcpu)//TRIM(clsuffix)
709         icnt = 0
710         INQUIRE( FILE = clname, EXIST = llok ) 
711         ! we try different formats for the cpu number by adding 0
712         DO WHILE( .NOT.llok .AND. icnt < jpmax_digits )
713            clcpu  = "0"//trim(clcpu)
714            clname = clname(1:iln-1)//'_'//TRIM(clcpu)//TRIM(clsuffix)
715            INQUIRE( FILE = clname, EXIST = llok )
716            icnt = icnt + 1
717         END DO
718      ELSE
719         lxios_sini = .TRUE.
720      ENDIF
721      IF( llwrt ) THEN
722         ! check the domain definition
723! JMM + SM: ugly patch before getting the new version of lib_mpp)
724!         idom = jpdom_local_noovlap   ! default definition
725         IF( llnoov ) THEN   ;   idom = jpdom_local_noovlap   ! default definition
726         ELSE                ;   idom = jpdom_local_full      ! default definition
727         ENDIF
728         IF( PRESENT(kdom) )   idom = kdom
729         ! create the domain informations
730         ! =============
731         SELECT CASE (idom)
732         CASE (jpdom_local_full)
733            idompar(:,1) = (/ jpi             , jpj              /)
734            idompar(:,2) = (/ nimpp           , njmpp            /)
735            idompar(:,3) = (/ nimpp + jpi - 1 , njmpp + jpj - 1  /)
736            idompar(:,4) = (/ nldi - 1        , nldj - 1         /)
737            idompar(:,5) = (/ jpi - nlei      , jpj - nlej       /)
738         CASE (jpdom_local_noextra)
739            idompar(:,1) = (/ nlci            , nlcj             /)
740            idompar(:,2) = (/ nimpp           , njmpp            /)
741            idompar(:,3) = (/ nimpp + nlci - 1, njmpp + nlcj - 1 /)
742            idompar(:,4) = (/ nldi - 1        , nldj - 1         /)
743            idompar(:,5) = (/ nlci - nlei     , nlcj - nlej      /)
744         CASE (jpdom_local_noovlap)
745            idompar(:,1) = (/ nlei  - nldi + 1, nlej  - nldj + 1 /)
746            idompar(:,2) = (/ nimpp + nldi - 1, njmpp + nldj - 1 /)
747            idompar(:,3) = (/ nimpp + nlei - 1, njmpp + nlej - 1 /)
748            idompar(:,4) = (/ 0               , 0                /)
749            idompar(:,5) = (/ 0               , 0                /)
750         CASE DEFAULT
751            CALL ctl_stop( TRIM(clinfo), 'wrong value of kdom, only jpdom_local* cases are accepted' )
752         END SELECT
753      ENDIF
754      ! Open the NetCDF file
755      ! =============
756      ! do we have some free file identifier?
757      IF( MINVAL(iom_file(:)%nfid) /= 0 )   &
758         &   CALL ctl_stop( TRIM(clinfo), 'No more free file identifier', 'increase jpmax_files in iom_def' )
759      ! if no file was found...
760      IF( .NOT. llok ) THEN
761         IF( .NOT. llwrt ) THEN   ! we are in read mode
762            IF( llstop ) THEN   ;   CALL ctl_stop( TRIM(clinfo), 'File '//TRIM(cltmpn)//'* not found' )
763            ELSE                ;   istop = nstop + 1   ! make sure that istop /= nstop so we don't open the file
764            ENDIF
765         ELSE                     ! we are in write mode so we
766            clname = cltmpn       ! get back the file name without the cpu number
767         ENDIF
768      ELSE
769         IF( llwrt .AND. .NOT. ln_clobber ) THEN   ! we stop as we want to write in a new file
770            CALL ctl_stop( TRIM(clinfo), 'We want to write in a new file but '//TRIM(clname)//' already exists...' )
771            istop = nstop + 1                      ! make sure that istop /= nstop so we don't open the file
772         ELSEIF( llwrt ) THEN     ! the file exists and we are in write mode with permission to
773            clname = cltmpn       ! overwrite so get back the file name without the cpu number
774         ENDIF
775      ENDIF
776      IF( istop == nstop ) THEN   ! no error within this routine
777         CALL iom_nf90_open( clname, kiomid, llwrt, llok, idompar, kdlev = kdlev, cdcomp = cdcomp )
778      ENDIF
779      !
780   END SUBROUTINE iom_open
781
782
783   SUBROUTINE iom_close( kiomid )
784      !!--------------------------------------------------------------------
785      !!                   ***  SUBROUTINE  iom_close  ***
786      !!
787      !! ** Purpose : close an input file, or all files opened by iom
788      !!--------------------------------------------------------------------
789      INTEGER, INTENT(inout), OPTIONAL ::   kiomid   ! iom identifier of the file to be closed
790      !                                              ! return 0 when file is properly closed
791      !                                              ! No argument: all files opened by iom are closed
792
793      INTEGER ::   jf         ! dummy loop indices
794      INTEGER ::   i_s, i_e   ! temporary integer
795      CHARACTER(LEN=100)    ::   clinfo    ! info character
796      !---------------------------------------------------------------------
797      !
798      IF( iom_open_init == 0 )   RETURN   ! avoid to use iom_file(jf)%nfid that us not yet initialized
799      !
800      clinfo = '                    iom_close ~~~  '
801      IF( PRESENT(kiomid) ) THEN
802         i_s = kiomid
803         i_e = kiomid
804      ELSE
805         i_s = 1
806         i_e = jpmax_files
807      ENDIF
808
809      IF( i_s > 0 ) THEN
810         DO jf = i_s, i_e
811            IF( iom_file(jf)%nfid > 0 ) THEN
812               CALL iom_nf90_close( jf )
813               iom_file(jf)%nfid       = 0          ! free the id
814               IF( PRESENT(kiomid) )   kiomid = 0   ! return 0 as id to specify that the file was closed
815               IF(lwp) WRITE(numout,*) TRIM(clinfo)//' close file: '//TRIM(iom_file(jf)%name)//' ok'
816            ELSEIF( PRESENT(kiomid) ) THEN
817               WRITE(ctmp1,*) '--->',  kiomid
818               CALL ctl_stop( TRIM(clinfo)//' Invalid file identifier', ctmp1 )
819            ENDIF
820         END DO
821      ENDIF
822      !   
823   END SUBROUTINE iom_close
824
825
826   FUNCTION iom_varid ( kiomid, cdvar, kdimsz, kndims, lduld, ldstop ) 
827      !!-----------------------------------------------------------------------
828      !!                  ***  FUNCTION  iom_varid  ***
829      !!
830      !! ** Purpose : get the id of a variable in a file (return 0 if not found)
831      !!-----------------------------------------------------------------------
832      INTEGER              , INTENT(in   )           ::   kiomid   ! file Identifier
833      CHARACTER(len=*)     , INTENT(in   )           ::   cdvar    ! name of the variable
834      INTEGER, DIMENSION(:), INTENT(  out), OPTIONAL ::   kdimsz   ! size of each dimension
835      INTEGER              , INTENT(  out), OPTIONAL ::   kndims   ! number of dimensions
836      LOGICAL              , INTENT(  out), OPTIONAL ::   lduld    ! true if the last dimension is unlimited (time)
837      LOGICAL              , INTENT(in   ), OPTIONAL ::   ldstop   ! stop if looking for non-existing variable (default = .TRUE.)
838      !
839      INTEGER                        ::   iom_varid, iiv, i_nvd
840      LOGICAL                        ::   ll_fnd
841      CHARACTER(LEN=100)             ::   clinfo                   ! info character
842      LOGICAL                        ::   llstop                   ! local definition of ldstop
843      !!-----------------------------------------------------------------------
844      iom_varid = 0                         ! default definition
845      ! do we call ctl_stop if we look for non-existing variable?
846      IF( PRESENT(ldstop) ) THEN   ;   llstop = ldstop
847      ELSE                         ;   llstop = .TRUE.
848      ENDIF
849      !
850      IF( kiomid > 0 ) THEN
851         clinfo = 'iom_varid, file: '//trim(iom_file(kiomid)%name)//', var: '//trim(cdvar)
852         IF( iom_file(kiomid)%nfid == 0 ) THEN
853            CALL ctl_stop( trim(clinfo), 'the file is not open' )
854         ELSE
855            ll_fnd  = .FALSE.
856            iiv = 0
857            !
858            DO WHILE ( .NOT.ll_fnd .AND. iiv < iom_file(kiomid)%nvars )
859               iiv = iiv + 1
860               ll_fnd  = ( TRIM(cdvar) == TRIM(iom_file(kiomid)%cn_var(iiv)) )
861            END DO
862            !
863            IF( .NOT.ll_fnd ) THEN
864               iiv = iiv + 1
865               IF( iiv <= jpmax_vars ) THEN
866                  iom_varid = iom_nf90_varid( kiomid, cdvar, iiv, kdimsz, kndims, lduld )
867               ELSE
868                  CALL ctl_stop( trim(clinfo), 'Too many variables in the file '//iom_file(kiomid)%name,   &
869                        &                      'increase the parameter jpmax_vars')
870               ENDIF
871               IF( llstop .AND. iom_varid == -1 )   CALL ctl_stop( TRIM(clinfo)//' not found' ) 
872            ELSE
873               iom_varid = iiv
874               IF( PRESENT(kdimsz) ) THEN
875                  i_nvd = iom_file(kiomid)%ndims(iiv)
876                  IF( i_nvd <= size(kdimsz) ) THEN
877                     kdimsz(1:i_nvd) = iom_file(kiomid)%dimsz(1:i_nvd,iiv)
878                  ELSE
879                     WRITE(ctmp1,*) i_nvd, size(kdimsz)
880                     CALL ctl_stop( trim(clinfo), 'error in kdimsz size'//trim(ctmp1) )
881                  ENDIF
882               ENDIF
883               IF( PRESENT(kndims) )  kndims = iom_file(kiomid)%ndims(iiv)
884               IF( PRESENT( lduld) )  lduld  = iom_file(kiomid)%luld( iiv)
885            ENDIF
886         ENDIF
887      ENDIF
888      !
889   END FUNCTION iom_varid
890
891
892   !!----------------------------------------------------------------------
893   !!                   INTERFACE iom_get
894   !!----------------------------------------------------------------------
895   SUBROUTINE iom_g0d( kiomid, cdvar, pvar, ktime, ldxios )
896      INTEGER         , INTENT(in   )                 ::   kiomid    ! Identifier of the file
897      CHARACTER(len=*), INTENT(in   )                 ::   cdvar     ! Name of the variable
898      REAL(wp)        , INTENT(  out)                 ::   pvar      ! read field
899      INTEGER         , INTENT(in   ),     OPTIONAL   ::   ktime     ! record number
900      LOGICAL         , INTENT(in   ),     OPTIONAL   ::   ldxios    ! use xios to read restart
901      !
902      INTEGER                                         ::   idvar     ! variable id
903      INTEGER                                         ::   idmspc    ! number of spatial dimensions
904      INTEGER         , DIMENSION(1)                  ::   itime     ! record number
905      CHARACTER(LEN=100)                              ::   clinfo    ! info character
906      CHARACTER(LEN=100)                              ::   clname    ! file name
907      CHARACTER(LEN=1)                                ::   cldmspc   !
908      LOGICAL                                         ::   llxios
909      !
910      llxios = .FALSE.
911      IF( PRESENT(ldxios) ) llxios = ldxios
912
913      IF(.NOT.llxios) THEN  ! read data using default library
914         itime = 1
915         IF( PRESENT(ktime) ) itime = ktime
916         !
917         clname = iom_file(kiomid)%name
918         clinfo = '          iom_g0d, file: '//trim(clname)//', var: '//trim(cdvar)
919         !
920         IF( kiomid > 0 ) THEN
921            idvar = iom_varid( kiomid, cdvar )
922            IF( iom_file(kiomid)%nfid > 0 .AND. idvar > 0 ) THEN
923               idmspc = iom_file ( kiomid )%ndims( idvar )
924               IF( iom_file(kiomid)%luld(idvar) )  idmspc = idmspc - 1
925               WRITE(cldmspc , fmt='(i1)') idmspc
926               IF( idmspc > 0 )  CALL ctl_stop( TRIM(clinfo), 'When reading to a 0D array, we do not accept data', &
927                                    &                         'with 1 or more spatial dimensions: '//cldmspc//' were found.' , &
928                                    &                         'Use ncwa -a to suppress the unnecessary dimensions' )
929               CALL iom_nf90_get( kiomid, idvar, pvar, itime )
930            ENDIF
931         ENDIF
932      ELSE
933#if defined key_iomput
934         IF(lwp) WRITE(numout,*) 'XIOS RST READ (0D): ', trim(cdvar)
935         CALL xios_recv_field( trim(cdvar), pvar)
936#else
937         WRITE(ctmp1,*) 'Can not use XIOS in iom_g0d, file: '//trim(clname)//', var:'//trim(cdvar)
938         CALL ctl_stop( 'iom_g0d', ctmp1 )
939#endif
940      ENDIF
941   END SUBROUTINE iom_g0d
942
943   SUBROUTINE iom_g1d( kiomid, kdom, cdvar, pvar, ktime, kstart, kcount, ldxios )
944      INTEGER         , INTENT(in   )                         ::   kiomid    ! Identifier of the file
945      INTEGER         , INTENT(in   )                         ::   kdom      ! Type of domain to be read
946      CHARACTER(len=*), INTENT(in   )                         ::   cdvar     ! Name of the variable
947      REAL(wp)        , INTENT(  out), DIMENSION(:)           ::   pvar      ! read field
948      INTEGER         , INTENT(in   )              , OPTIONAL ::   ktime     ! record number
949      INTEGER         , INTENT(in   ), DIMENSION(1), OPTIONAL ::   kstart    ! start axis position of the reading
950      INTEGER         , INTENT(in   ), DIMENSION(1), OPTIONAL ::   kcount    ! number of points in each axis
951      LOGICAL         , INTENT(in   ),               OPTIONAL ::   ldxios    ! read data using XIOS
952      !
953      IF( kiomid > 0 ) THEN
954         IF( iom_file(kiomid)%nfid > 0 ) CALL iom_get_123d( kiomid, kdom       , cdvar        , pv_r1d=pvar,   &
955              &                                                     ktime=ktime, kstart=kstart, kcount=kcount, &
956              &                                                     ldxios=ldxios )
957      ENDIF
958   END SUBROUTINE iom_g1d
959
960   SUBROUTINE iom_g2d( kiomid, kdom, cdvar, pvar, ktime, kstart, kcount, lrowattr, ldxios)
961      INTEGER         , INTENT(in   )                           ::   kiomid    ! Identifier of the file
962      INTEGER         , INTENT(in   )                           ::   kdom      ! Type of domain to be read
963      CHARACTER(len=*), INTENT(in   )                           ::   cdvar     ! Name of the variable
964      REAL(wp)        , INTENT(  out), DIMENSION(:,:)           ::   pvar      ! read field
965      INTEGER         , INTENT(in   )                , OPTIONAL ::   ktime     ! record number
966      INTEGER         , INTENT(in   ), DIMENSION(2)  , OPTIONAL ::   kstart    ! start axis position of the reading
967      INTEGER         , INTENT(in   ), DIMENSION(2)  , OPTIONAL ::   kcount    ! number of points in each axis
968      LOGICAL         , INTENT(in   )                , OPTIONAL ::   lrowattr  ! logical flag telling iom_get to
969                                                                               ! look for and use a file attribute
970                                                                               ! called open_ocean_jstart to set the start
971                                                                               ! value for the 2nd dimension (netcdf only)
972      LOGICAL         , INTENT(in   ),               OPTIONAL ::   ldxios      ! read data using XIOS
973      !
974      IF( kiomid > 0 ) THEN
975         IF( iom_file(kiomid)%nfid > 0 ) CALL iom_get_123d( kiomid, kdom       , cdvar        , pv_r2d=pvar,   &
976              &                                                     ktime=ktime, kstart=kstart, kcount=kcount, &
977              &                                                     lrowattr=lrowattr,  ldxios=ldxios)
978      ENDIF
979   END SUBROUTINE iom_g2d
980
981   SUBROUTINE iom_g3d( kiomid, kdom, cdvar, pvar, ktime, kstart, kcount, lrowattr, ldxios )
982      INTEGER         , INTENT(in   )                             ::   kiomid    ! Identifier of the file
983      INTEGER         , INTENT(in   )                             ::   kdom      ! Type of domain to be read
984      CHARACTER(len=*), INTENT(in   )                             ::   cdvar     ! Name of the variable
985      REAL(wp)        , INTENT(  out), DIMENSION(:,:,:)           ::   pvar      ! read field
986      INTEGER         , INTENT(in   )                  , OPTIONAL ::   ktime     ! record number
987      INTEGER         , INTENT(in   ), DIMENSION(3)    , OPTIONAL ::   kstart    ! start axis position of the reading
988      INTEGER         , INTENT(in   ), DIMENSION(3)    , OPTIONAL ::   kcount    ! number of points in each axis
989      LOGICAL         , INTENT(in   )                  , OPTIONAL ::   lrowattr  ! logical flag telling iom_get to
990                                                                                 ! look for and use a file attribute
991                                                                                 ! called open_ocean_jstart to set the start
992                                                                                 ! value for the 2nd dimension (netcdf only)
993      LOGICAL         , INTENT(in   ),               OPTIONAL ::   ldxios        ! read data using XIOS
994      !
995      IF( kiomid > 0 ) THEN
996         IF( iom_file(kiomid)%nfid > 0 ) CALL iom_get_123d( kiomid, kdom       , cdvar        , pv_r3d=pvar,   &
997              &                                                     ktime=ktime, kstart=kstart, kcount=kcount, &
998              &                                                     lrowattr=lrowattr, ldxios=ldxios )
999      ENDIF
1000   END SUBROUTINE iom_g3d
1001   !!----------------------------------------------------------------------
1002
1003   SUBROUTINE iom_get_123d( kiomid, kdom  , cdvar ,   &
1004         &                  pv_r1d, pv_r2d, pv_r3d,   &
1005         &                  ktime , kstart, kcount,   &
1006         &                  lrowattr, ldxios        )
1007      !!-----------------------------------------------------------------------
1008      !!                  ***  ROUTINE  iom_get_123d  ***
1009      !!
1010      !! ** Purpose : read a 1D/2D/3D variable
1011      !!
1012      !! ** Method : read ONE record at each CALL
1013      !!-----------------------------------------------------------------------
1014      INTEGER                    , INTENT(in   )           ::   kiomid     ! Identifier of the file
1015      INTEGER                    , INTENT(in   )           ::   kdom       ! Type of domain to be read
1016      CHARACTER(len=*)           , INTENT(in   )           ::   cdvar      ! Name of the variable
1017      REAL(wp), DIMENSION(:)     , INTENT(  out), OPTIONAL ::   pv_r1d     ! read field (1D case)
1018      REAL(wp), DIMENSION(:,:)   , INTENT(  out), OPTIONAL ::   pv_r2d     ! read field (2D case)
1019      REAL(wp), DIMENSION(:,:,:) , INTENT(  out), OPTIONAL ::   pv_r3d     ! read field (3D case)
1020      INTEGER                    , INTENT(in   ), OPTIONAL ::   ktime      ! record number
1021      INTEGER , DIMENSION(:)     , INTENT(in   ), OPTIONAL ::   kstart     ! start position of the reading in each axis
1022      INTEGER , DIMENSION(:)     , INTENT(in   ), OPTIONAL ::   kcount     ! number of points to be read in each axis
1023      LOGICAL                    , INTENT(in   ), OPTIONAL ::   lrowattr   ! logical flag telling iom_get to
1024                                                                           ! look for and use a file attribute
1025                                                                           ! called open_ocean_jstart to set the start
1026                                                                           ! value for the 2nd dimension (netcdf only)
1027      LOGICAL                    , INTENT(in   ), OPTIONAL ::   ldxios     ! use XIOS to read restart
1028      !
1029      LOGICAL                        ::   llxios       ! local definition for XIOS read
1030      LOGICAL                        ::   llnoov      ! local definition to read overlap
1031      LOGICAL                        ::   luse_jattr  ! local definition to read open_ocean_jstart file attribute
1032      INTEGER                        ::   jstartrow   ! start point for 2nd dimension optionally set by file attribute
1033      INTEGER                        ::   jl          ! loop on number of dimension
1034      INTEGER                        ::   idom        ! type of domain
1035      INTEGER                        ::   idvar       ! id of the variable
1036      INTEGER                        ::   inbdim      ! number of dimensions of the variable
1037      INTEGER                        ::   idmspc      ! number of spatial dimensions
1038      INTEGER                        ::   itime       ! record number
1039      INTEGER                        ::   istop       ! temporary value of nstop
1040      INTEGER                        ::   ix1, ix2, iy1, iy2   ! subdomain indexes
1041      INTEGER                        ::   ji, jj      ! loop counters
1042      INTEGER                        ::   irankpv     !
1043      INTEGER                        ::   ind1, ind2  ! substring index
1044      INTEGER, DIMENSION(jpmax_dims) ::   istart      ! starting point to read for each axis
1045      INTEGER, DIMENSION(jpmax_dims) ::   icnt        ! number of value to read along each axis
1046      INTEGER, DIMENSION(jpmax_dims) ::   idimsz      ! size of the dimensions of the variable
1047      INTEGER, DIMENSION(jpmax_dims) ::   ishape      ! size of the dimensions of the variable
1048      REAL(wp)                       ::   zscf, zofs  ! sacle_factor and add_offset
1049      INTEGER                        ::   itmp        ! temporary integer
1050      CHARACTER(LEN=256)             ::   clinfo      ! info character
1051      CHARACTER(LEN=256)             ::   clname      ! file name
1052      CHARACTER(LEN=1)               ::   clrankpv, cldmspc      !
1053      LOGICAL                        ::   ll_depth_spec ! T => if kstart, kcount present then *only* use values for 3rd spatial dimension.
1054      INTEGER                        ::   inlev       ! number of levels for 3D data
1055      REAL(wp)                       ::   gma, gmi
1056      !---------------------------------------------------------------------
1057      !
1058      inlev = -1
1059      IF( PRESENT(pv_r3d) )   inlev = SIZE(pv_r3d, 3)
1060      !
1061      llxios = .FALSE.
1062      if(PRESENT(ldxios)) llxios = ldxios
1063      idvar = iom_varid( kiomid, cdvar ) 
1064      idom = kdom
1065      !
1066      IF(.NOT.llxios) THEN
1067         clname = iom_file(kiomid)%name   !   esier to read
1068         clinfo = '          iom_get_123d, file: '//trim(clname)//', var: '//trim(cdvar)
1069         ! local definition of the domain ?
1070         ! do we read the overlap
1071         ! ugly patch SM+JMM+RB to overwrite global definition in some cases
1072         llnoov = (jpni * jpnj ) == jpnij .AND. .NOT. lk_agrif 
1073         ! check kcount and kstart optionals parameters...
1074         IF( PRESENT(kcount) .AND. (.NOT. PRESENT(kstart)) ) CALL ctl_stop(trim(clinfo), 'kcount present needs kstart present')
1075         IF( PRESENT(kstart) .AND. (.NOT. PRESENT(kcount)) ) CALL ctl_stop(trim(clinfo), 'kstart present needs kcount present')
1076         IF( PRESENT(kstart) .AND. idom /= jpdom_unknown .AND.  idom /= jpdom_autoglo_xy  ) &
1077     &          CALL ctl_stop(trim(clinfo), 'kstart present needs kdom = jpdom_unknown or kdom = jpdom_autoglo_xy')
1078
1079         luse_jattr = .false.
1080         IF( PRESENT(lrowattr) ) THEN
1081            IF( lrowattr .AND. idom /= jpdom_data   ) CALL ctl_stop(trim(clinfo), 'lrowattr present and true needs kdom = jpdom_data')
1082            IF( lrowattr .AND. idom == jpdom_data   ) luse_jattr = .true.
1083         ENDIF
1084
1085         ! Search for the variable in the data base (eventually actualize data)
1086         istop = nstop
1087         !
1088         IF( idvar > 0 ) THEN
1089            ! to write iom_file(kiomid)%dimsz in a shorter way !
1090            idimsz(:) = iom_file(kiomid)%dimsz(:, idvar) 
1091            inbdim = iom_file(kiomid)%ndims(idvar)            ! number of dimensions in the file
1092            idmspc = inbdim                                   ! number of spatial dimensions in the file
1093            IF( iom_file(kiomid)%luld(idvar) )   idmspc = inbdim - 1
1094            IF( idmspc > 3 )   CALL ctl_stop(trim(clinfo), 'the file has more than 3 spatial dimensions this case is not coded...') 
1095            !
1096            ! update idom definition...
1097            ! Identify the domain in case of jpdom_auto(glo/dta) definition
1098            IF( idom == jpdom_autoglo_xy ) THEN
1099               ll_depth_spec = .TRUE.
1100               idom = jpdom_autoglo
1101            ELSE
1102               ll_depth_spec = .FALSE.
1103            ENDIF
1104            IF( idom == jpdom_autoglo .OR. idom == jpdom_autodta ) THEN           
1105               IF( idom == jpdom_autoglo ) THEN   ;   idom = jpdom_global 
1106               ELSE                               ;   idom = jpdom_data
1107               ENDIF
1108               ind1 = INDEX( clname, '_', back = .TRUE. ) + 1
1109               ind2 = INDEX( clname, '.', back = .TRUE. ) - 1
1110               IF( ind2 > ind1 ) THEN   ;   IF( VERIFY( clname(ind1:ind2), '0123456789' ) == 0 )   idom = jpdom_local   ;   ENDIF
1111            ENDIF
1112            ! Identify the domain in case of jpdom_local definition
1113            IF( idom == jpdom_local ) THEN
1114               IF(     idimsz(1) == jpi               .AND. idimsz(2) == jpj               ) THEN   ;   idom = jpdom_local_full
1115               ELSEIF( idimsz(1) == nlci              .AND. idimsz(2) == nlcj              ) THEN   ;   idom = jpdom_local_noextra
1116               ELSEIF( idimsz(1) == (nlei - nldi + 1) .AND. idimsz(2) == (nlej - nldj + 1) ) THEN   ;   idom = jpdom_local_noovlap
1117               ELSE   ;   CALL ctl_stop( trim(clinfo), 'impossible to identify the local domain' )
1118               ENDIF
1119            ENDIF
1120            !
1121            ! check the consistency between input array and data rank in the file
1122            !
1123            ! initializations
1124            itime = 1
1125            IF( PRESENT(ktime) ) itime = ktime
1126            !
1127            irankpv = 1 * COUNT( (/PRESENT(pv_r1d)/) ) + 2 * COUNT( (/PRESENT(pv_r2d)/) ) + 3 * COUNT( (/PRESENT(pv_r3d)/) )
1128            WRITE(clrankpv, fmt='(i1)') irankpv
1129            WRITE(cldmspc , fmt='(i1)') idmspc
1130            !
1131            !!GS: we consider 2D data as 3D data with vertical dim size = 1
1132            !IF(     idmspc <  irankpv ) THEN
1133            !   CALL ctl_stop( TRIM(clinfo), 'The file has only '//cldmspc//' spatial dimension',   &
1134            !      &                         'it is impossible to read a '//clrankpv//'D array from this file...' )
1135            !ELSEIF( idmspc == irankpv ) THEN
1136            IF( idmspc == irankpv ) THEN
1137               IF( PRESENT(pv_r1d) .AND. idom /= jpdom_unknown )   &
1138                  &   CALL ctl_stop( TRIM(clinfo), 'case not coded...You must use jpdom_unknown' )
1139            ELSEIF( idmspc >  irankpv ) THEN
1140                  IF( PRESENT(pv_r2d) .AND. itime == 1 .AND. idimsz(3) == 1 .AND. idmspc == 3 ) THEN
1141                     CALL ctl_warn( trim(clinfo), '2D array but 3 spatial dimensions for the data...'              ,   &
1142                           &         'As the size of the z dimension is 1 and as we try to read the first record, ',   &
1143                           &         'we accept this case, even if there is a possible mix-up between z and time dimension' )   
1144                     idmspc = idmspc - 1
1145                  ELSE
1146                     CALL ctl_stop( TRIM(clinfo), 'To keep iom lisibility, when reading a '//clrankpv//'D array,'         ,   &
1147                        &                         'we do not accept data with '//cldmspc//' spatial dimensions',   &
1148                        &                         'Use ncwa -a to suppress the unnecessary dimensions' )
1149                  ENDIF
1150            ENDIF
1151            !
1152            ! definition of istart and icnt
1153            !
1154            icnt  (:) = 1
1155            istart(:) = 1
1156            istart(idmspc+1) = itime
1157   
1158            IF( PRESENT(kstart) .AND. .NOT. ll_depth_spec ) THEN
1159               istart(1:idmspc) = kstart(1:idmspc) 
1160               icnt  (1:idmspc) = kcount(1:idmspc)
1161            ELSE
1162               IF(idom == jpdom_unknown ) THEN
1163                  icnt(1:idmspc) = idimsz(1:idmspc)
1164               ELSE
1165                  IF( .NOT. PRESENT(pv_r1d) ) THEN   !   not a 1D array
1166                     IF(     idom == jpdom_data    ) THEN
1167                        jstartrow = 1
1168                        IF( luse_jattr ) THEN
1169                           CALL iom_getatt(kiomid, 'open_ocean_jstart', jstartrow ) ! -999 is returned if the attribute is not found
1170                           jstartrow = MAX(1,jstartrow)
1171                        ENDIF
1172                        istart(1:2) = (/ mig(1), mjg(1) + jstartrow - 1 /)  ! icnt(1:2) done below
1173                     ELSEIF( idom == jpdom_global  ) THEN ; istart(1:2) = (/ nimpp , njmpp  /)  ! icnt(1:2) done below
1174                     ENDIF
1175                     ! we do not read the overlap                     -> we start to read at nldi, nldj
1176! JMM + SM: ugly patch before getting the new version of lib_mpp)
1177!                  IF( idom /= jpdom_local_noovlap )   istart(1:2) = istart(1:2) + (/ nldi - 1, nldj - 1 /)
1178                     IF( llnoov .AND. idom /= jpdom_local_noovlap ) istart(1:2) = istart(1:2) + (/ nldi - 1, nldj - 1 /)
1179                  ! we do not read the overlap and the extra-halos -> from nldi to nlei and from nldj to nlej
1180! JMM + SM: ugly patch before getting the new version of lib_mpp)
1181!                  icnt(1:2) = (/ nlei - nldi + 1, nlej - nldj + 1 /)
1182                     IF( llnoov ) THEN   ;   icnt(1:2) = (/ nlei - nldi + 1, nlej - nldj + 1 /)
1183                     ELSE                ;   icnt(1:2) = (/ nlci           , nlcj            /)
1184                     ENDIF
1185                     IF( PRESENT(pv_r3d) ) THEN
1186                        IF( idom == jpdom_data ) THEN                        ;                               icnt(3) = inlev
1187                        ELSEIF( ll_depth_spec .AND. PRESENT(kstart) ) THEN   ;   istart(3) = kstart(3)   ;   icnt(3) = kcount(3)
1188                        ELSE                                                 ;                               icnt(3) = inlev
1189                        ENDIF
1190                     ENDIF
1191                  ENDIF
1192               ENDIF
1193            ENDIF
1194
1195            ! check that istart and icnt can be used with this file
1196            !-
1197            DO jl = 1, jpmax_dims
1198               itmp = istart(jl)+icnt(jl)-1
1199               IF( itmp > idimsz(jl) .AND. idimsz(jl) /= 0 ) THEN
1200                  WRITE( ctmp1, FMT="('(istart(', i1, ') + icnt(', i1, ') - 1) = ', i5)" ) jl, jl, itmp
1201                  WRITE( ctmp2, FMT="(' is larger than idimsz(', i1,') = ', i5)"         ) jl, idimsz(jl)
1202                  CALL ctl_stop( trim(clinfo), 'start and count too big regarding to the size of the data, ', ctmp1, ctmp2 )     
1203               ENDIF
1204            END DO
1205
1206            ! check that icnt matches the input array
1207            !-     
1208            IF( idom == jpdom_unknown ) THEN
1209               IF( irankpv == 1 )        ishape(1:1) = SHAPE(pv_r1d)
1210               IF( irankpv == 2 )        ishape(1:2) = SHAPE(pv_r2d)
1211               IF( irankpv == 3 )        ishape(1:3) = SHAPE(pv_r3d)
1212               ctmp1 = 'd'
1213            ELSE
1214               IF( irankpv == 2 ) THEN
1215! JMM + SM: ugly patch before getting the new version of lib_mpp)
1216!               ishape(1:2) = SHAPE(pv_r2d(nldi:nlei,nldj:nlej  ))   ;   ctmp1 = 'd(nldi:nlei,nldj:nlej)'
1217                  IF( llnoov ) THEN ; ishape(1:2)=SHAPE(pv_r2d(nldi:nlei,nldj:nlej  )) ; ctmp1='d(nldi:nlei,nldj:nlej)'
1218                  ELSE              ; ishape(1:2)=SHAPE(pv_r2d(1   :nlci,1   :nlcj  )) ; ctmp1='d(1:nlci,1:nlcj)'
1219                  ENDIF
1220               ENDIF
1221               IF( irankpv == 3 ) THEN 
1222! JMM + SM: ugly patch before getting the new version of lib_mpp)
1223!               ishape(1:3) = SHAPE(pv_r3d(nldi:nlei,nldj:nlej,:))   ;   ctmp1 = 'd(nldi:nlei,nldj:nlej,:)'
1224                  IF( llnoov ) THEN ; ishape(1:3)=SHAPE(pv_r3d(nldi:nlei,nldj:nlej,:)) ; ctmp1='d(nldi:nlei,nldj:nlej,:)'
1225                  ELSE              ; ishape(1:3)=SHAPE(pv_r3d(1   :nlci,1   :nlcj,:)) ; ctmp1='d(1:nlci,1:nlcj,:)'
1226                  ENDIF
1227               ENDIF
1228            ENDIF
1229         
1230            DO jl = 1, irankpv
1231               WRITE( ctmp2, FMT="(', ', i1,'): ', i5,' /= icnt(', i1,'):', i5)" ) jl, ishape(jl), jl, icnt(jl)
1232               IF( ishape(jl) /= icnt(jl) )   CALL ctl_stop( TRIM(clinfo), 'size(pv_r'//clrankpv//TRIM(ctmp1)//TRIM(ctmp2) )
1233            END DO
1234
1235         ENDIF
1236
1237         ! read the data
1238         !-     
1239         IF( idvar > 0 .AND. istop == nstop ) THEN   ! no additional errors until this point...
1240            !
1241         ! find the right index of the array to be read
1242! JMM + SM: ugly patch before getting the new version of lib_mpp)
1243!         IF( idom /= jpdom_unknown ) THEN   ;   ix1 = nldi   ;   ix2 = nlei      ;   iy1 = nldj   ;   iy2 = nlej
1244!         ELSE                               ;   ix1 = 1      ;   ix2 = icnt(1)   ;   iy1 = 1      ;   iy2 = icnt(2)
1245!         ENDIF
1246            IF( llnoov ) THEN
1247               IF( idom /= jpdom_unknown ) THEN   ;   ix1 = nldi   ;   ix2 = nlei      ;   iy1 = nldj   ;   iy2 = nlej
1248               ELSE                               ;   ix1 = 1      ;   ix2 = icnt(1)   ;   iy1 = 1      ;   iy2 = icnt(2)
1249               ENDIF
1250            ELSE
1251               IF( idom /= jpdom_unknown ) THEN   ;   ix1 = 1      ;   ix2 = nlci      ;   iy1 = 1      ;   iy2 = nlcj
1252               ELSE                               ;   ix1 = 1      ;   ix2 = icnt(1)   ;   iy1 = 1      ;   iy2 = icnt(2)
1253               ENDIF
1254            ENDIF
1255     
1256            CALL iom_nf90_get( kiomid, idvar, inbdim, istart, icnt, ix1, ix2, iy1, iy2, pv_r1d, pv_r2d, pv_r3d )
1257
1258            IF( istop == nstop ) THEN   ! no additional errors until this point...
1259               IF(lwp) WRITE(numout,"(10x,' read ',a,' (rec: ',i6,') in ',a,' ok')") TRIM(cdvar), itime, TRIM(iom_file(kiomid)%name)
1260             
1261               !--- overlap areas and extra hallows (mpp)
1262               IF(     PRESENT(pv_r2d) .AND. idom /= jpdom_unknown ) THEN
1263                  CALL lbc_lnk( 'iom', pv_r2d,'Z', -999., kfillmode = jpfillnothing )
1264               ELSEIF( PRESENT(pv_r3d) .AND. idom /= jpdom_unknown ) THEN
1265                  ! this if could be simplified with the new lbc_lnk that works with any size of the 3rd dimension
1266                  IF( icnt(3) == inlev ) THEN
1267                     CALL lbc_lnk( 'iom', pv_r3d,'Z', -999., kfillmode = jpfillnothing )
1268                  ELSE   ! put some arbitrary value (a call to lbc_lnk will be done later...)
1269                     DO jj = nlcj+1, jpj   ;   pv_r3d(1:nlci, jj, :) = pv_r3d(1:nlci, nlej, :)   ;   END DO
1270                     DO ji = nlci+1, jpi   ;   pv_r3d(ji    , : , :) = pv_r3d(nlei  , :   , :)   ;   END DO
1271                  ENDIF
1272               ENDIF
1273               !
1274            ELSE
1275               ! return if istop == nstop is false
1276               RETURN
1277            ENDIF
1278         ELSE
1279            ! return if statment idvar > 0 .AND. istop == nstop is false
1280            RETURN
1281         ENDIF
1282         !
1283      ELSE        ! read using XIOS. Only if KEY_IOMPUT is defined
1284#if defined key_iomput
1285!would be good to be able to check which context is active and swap only if current is not restart
1286         IF( PRESENT(pv_r3d) ) THEN
1287            pv_r3d(:, :, :) = 0.
1288            if(lwp) write(numout,*) 'XIOS RST READ (3D): ',trim(cdvar)
1289            CALL xios_recv_field( trim(cdvar), pv_r3d)
1290            IF(idom /= jpdom_unknown ) then
1291                CALL lbc_lnk( 'iom', pv_r3d,'Z', -999., kfillmode = jpfillnothing)
1292            ENDIF
1293         ELSEIF( PRESENT(pv_r2d) ) THEN
1294            pv_r2d(:, :) = 0.
1295            if(lwp) write(numout,*) 'XIOS RST READ (2D): ', trim(cdvar)
1296            CALL xios_recv_field( trim(cdvar), pv_r2d)
1297            IF(idom /= jpdom_unknown ) THEN
1298                CALL lbc_lnk('iom', pv_r2d,'Z',-999., kfillmode = jpfillnothing)
1299            ENDIF
1300         ELSEIF( PRESENT(pv_r1d) ) THEN
1301            pv_r1d(:) = 0.
1302            if(lwp) write(numout,*) 'XIOS RST READ (1D): ', trim(cdvar)
1303            CALL xios_recv_field( trim(cdvar), pv_r1d)
1304         ENDIF
1305#else
1306         istop = istop + 1 
1307         clinfo = 'Can not use XIOS in iom_get_123d, file: '//trim(clname)//', var:'//trim(cdvar)
1308#endif
1309      ENDIF
1310!some final adjustments
1311      ! C1D case : always call lbc_lnk to replicate the central value over the whole 3X3 domain
1312      IF( lk_c1d .AND. PRESENT(pv_r2d) )   CALL lbc_lnk( 'iom', pv_r2d,'Z',1. )
1313      IF( lk_c1d .AND. PRESENT(pv_r3d) )   CALL lbc_lnk( 'iom', pv_r3d,'Z',1. )
1314
1315      !--- Apply scale_factor and offset
1316      zscf = iom_file(kiomid)%scf(idvar)      ! scale factor
1317      zofs = iom_file(kiomid)%ofs(idvar)      ! offset
1318      IF(     PRESENT(pv_r1d) ) THEN
1319         IF( zscf /= 1. )   pv_r1d(:) = pv_r1d(:) * zscf 
1320         IF( zofs /= 0. )   pv_r1d(:) = pv_r1d(:) + zofs
1321      ELSEIF( PRESENT(pv_r2d) ) THEN
1322         IF( zscf /= 1.)   pv_r2d(:,:) = pv_r2d(:,:) * zscf
1323         IF( zofs /= 0.)   pv_r2d(:,:) = pv_r2d(:,:) + zofs
1324      ELSEIF( PRESENT(pv_r3d) ) THEN
1325         IF( zscf /= 1.)   pv_r3d(:,:,:) = pv_r3d(:,:,:) * zscf
1326         IF( zofs /= 0.)   pv_r3d(:,:,:) = pv_r3d(:,:,:) + zofs
1327      ENDIF
1328      !
1329   END SUBROUTINE iom_get_123d
1330
1331   SUBROUTINE iom_get_var( cdname, z2d)
1332      CHARACTER(LEN=*), INTENT(in ) ::   cdname
1333      REAL(wp), DIMENSION(jpi,jpj) ::   z2d 
1334#if defined key_iomput
1335      IF( xios_field_is_active( cdname, at_current_timestep_arg = .TRUE. ) ) THEN
1336         z2d(:,:) = 0._wp
1337         CALL xios_recv_field( cdname, z2d)
1338      ENDIF
1339#else
1340      IF( .FALSE. )   WRITE(numout,*) cdname, z2d ! useless test to avoid compilation warnings
1341#endif
1342   END SUBROUTINE iom_get_var
1343
1344
1345   FUNCTION iom_getszuld ( kiomid ) 
1346      !!-----------------------------------------------------------------------
1347      !!                  ***  FUNCTION  iom_getszuld  ***
1348      !!
1349      !! ** Purpose : get the size of the unlimited dimension in a file
1350      !!              (return -1 if not found)
1351      !!-----------------------------------------------------------------------
1352      INTEGER, INTENT(in   ) ::   kiomid   ! file Identifier
1353      !
1354      INTEGER                ::   iom_getszuld
1355      !!-----------------------------------------------------------------------
1356      iom_getszuld = -1
1357      IF( kiomid > 0 ) THEN
1358         IF( iom_file(kiomid)%iduld > 0 )   iom_getszuld = iom_file(kiomid)%lenuld
1359      ENDIF
1360   END FUNCTION iom_getszuld
1361   
1362
1363   !!----------------------------------------------------------------------
1364   !!                   INTERFACE iom_chkatt
1365   !!----------------------------------------------------------------------
1366   SUBROUTINE iom_chkatt( kiomid, cdatt, llok, ksize, cdvar )
1367      INTEGER         , INTENT(in   )                 ::   kiomid    ! Identifier of the file
1368      CHARACTER(len=*), INTENT(in   )                 ::   cdatt     ! Name of the attribute
1369      LOGICAL         , INTENT(  out)                 ::   llok      ! Error code
1370      INTEGER         , INTENT(  out), OPTIONAL       ::   ksize     ! Size of the attribute array
1371      CHARACTER(len=*), INTENT(in   ), OPTIONAL       ::   cdvar     ! Name of the variable
1372      !
1373      IF( kiomid > 0 ) THEN
1374         IF( iom_file(kiomid)%nfid > 0 )   CALL iom_nf90_chkatt( kiomid, cdatt, llok, ksize=ksize, cdvar=cdvar )
1375      ENDIF
1376      !
1377   END SUBROUTINE iom_chkatt
1378
1379   !!----------------------------------------------------------------------
1380   !!                   INTERFACE iom_getatt
1381   !!----------------------------------------------------------------------
1382   SUBROUTINE iom_g0d_iatt( kiomid, cdatt, katt0d, cdvar )
1383      INTEGER               , INTENT(in   )           ::   kiomid    ! Identifier of the file
1384      CHARACTER(len=*)      , INTENT(in   )           ::   cdatt     ! Name of the attribute
1385      INTEGER               , INTENT(  out)           ::   katt0d    ! read field
1386      CHARACTER(len=*)      , INTENT(in   ), OPTIONAL ::   cdvar     ! Name of the variable
1387      !
1388      IF( kiomid > 0 ) THEN
1389         IF( iom_file(kiomid)%nfid > 0 )   CALL iom_nf90_getatt( kiomid, cdatt,  katt0d =  katt0d, cdvar=cdvar )
1390      ENDIF
1391   END SUBROUTINE iom_g0d_iatt
1392
1393   SUBROUTINE iom_g1d_iatt( kiomid, cdatt, katt1d, cdvar )
1394      INTEGER               , INTENT(in   )           ::   kiomid    ! Identifier of the file
1395      CHARACTER(len=*)      , INTENT(in   )           ::   cdatt     ! Name of the attribute
1396      INTEGER, DIMENSION(:) , INTENT(  out)           ::   katt1d    ! read field
1397      CHARACTER(len=*)      , INTENT(in   ), OPTIONAL ::   cdvar     ! Name of the variable
1398      !
1399      IF( kiomid > 0 ) THEN
1400         IF( iom_file(kiomid)%nfid > 0 )   CALL iom_nf90_getatt( kiomid, cdatt,  katt1d =  katt1d, cdvar=cdvar )
1401      ENDIF
1402   END SUBROUTINE iom_g1d_iatt
1403
1404   SUBROUTINE iom_g0d_ratt( kiomid, cdatt, patt0d, cdvar )
1405      INTEGER               , INTENT(in   )           ::   kiomid    ! Identifier of the file
1406      CHARACTER(len=*)      , INTENT(in   )           ::   cdatt     ! Name of the attribute
1407      REAL(wp)              , INTENT(  out)           ::   patt0d    ! read field
1408      CHARACTER(len=*)      , INTENT(in   ), OPTIONAL ::   cdvar     ! Name of the variable
1409      !
1410      IF( kiomid > 0 ) THEN
1411         IF( iom_file(kiomid)%nfid > 0 )   CALL iom_nf90_getatt( kiomid, cdatt,  patt0d =  patt0d, cdvar=cdvar )
1412      ENDIF
1413   END SUBROUTINE iom_g0d_ratt
1414
1415   SUBROUTINE iom_g1d_ratt( kiomid, cdatt, patt1d, cdvar )
1416      INTEGER               , INTENT(in   )           ::   kiomid    ! Identifier of the file
1417      CHARACTER(len=*)      , INTENT(in   )           ::   cdatt     ! Name of the attribute
1418      REAL(wp), DIMENSION(:), INTENT(  out)           ::   patt1d    ! read field
1419      CHARACTER(len=*)      , INTENT(in   ), OPTIONAL ::   cdvar     ! Name of the variable
1420      !
1421      IF( kiomid > 0 ) THEN
1422         IF( iom_file(kiomid)%nfid > 0 )   CALL iom_nf90_getatt( kiomid, cdatt,  patt1d =  patt1d, cdvar=cdvar )
1423      ENDIF
1424   END SUBROUTINE iom_g1d_ratt
1425   
1426   SUBROUTINE iom_g0d_catt( kiomid, cdatt, cdatt0d, cdvar )
1427      INTEGER               , INTENT(in   )           ::   kiomid    ! Identifier of the file
1428      CHARACTER(len=*)      , INTENT(in   )           ::   cdatt     ! Name of the attribute
1429      CHARACTER(len=*)      , INTENT(  out)           ::   cdatt0d   ! read field
1430      CHARACTER(len=*)      , INTENT(in   ), OPTIONAL ::   cdvar     ! Name of the variable
1431      !
1432      IF( kiomid > 0 ) THEN
1433         IF( iom_file(kiomid)%nfid > 0 )   CALL iom_nf90_getatt( kiomid, cdatt, cdatt0d = cdatt0d, cdvar=cdvar )
1434      ENDIF
1435   END SUBROUTINE iom_g0d_catt
1436
1437
1438   !!----------------------------------------------------------------------
1439   !!                   INTERFACE iom_putatt
1440   !!----------------------------------------------------------------------
1441   SUBROUTINE iom_p0d_iatt( kiomid, cdatt, katt0d, cdvar )
1442      INTEGER               , INTENT(in   )           ::   kiomid    ! Identifier of the file
1443      CHARACTER(len=*)      , INTENT(in   )           ::   cdatt     ! Name of the attribute
1444      INTEGER               , INTENT(in   )           ::   katt0d    ! written field
1445      CHARACTER(len=*)      , INTENT(in   ), OPTIONAL ::   cdvar     ! Name of the variable
1446      !
1447      IF( kiomid > 0 ) THEN
1448         IF( iom_file(kiomid)%nfid > 0 )   CALL iom_nf90_putatt( kiomid, cdatt,  katt0d =  katt0d, cdvar=cdvar )
1449      ENDIF
1450   END SUBROUTINE iom_p0d_iatt
1451
1452   SUBROUTINE iom_p1d_iatt( kiomid, cdatt, katt1d, cdvar )
1453      INTEGER               , INTENT(in   )           ::   kiomid    ! Identifier of the file
1454      CHARACTER(len=*)      , INTENT(in   )           ::   cdatt     ! Name of the attribute
1455      INTEGER, DIMENSION(:) , INTENT(in   )           ::   katt1d    ! written field
1456      CHARACTER(len=*)      , INTENT(in   ), OPTIONAL ::   cdvar     ! Name of the variable
1457      !
1458      IF( kiomid > 0 ) THEN
1459         IF( iom_file(kiomid)%nfid > 0 )   CALL iom_nf90_putatt( kiomid, cdatt,  katt1d =  katt1d, cdvar=cdvar )
1460      ENDIF
1461   END SUBROUTINE iom_p1d_iatt
1462
1463   SUBROUTINE iom_p0d_ratt( kiomid, cdatt, patt0d, cdvar )
1464      INTEGER               , INTENT(in   )           ::   kiomid    ! Identifier of the file
1465      CHARACTER(len=*)      , INTENT(in   )           ::   cdatt     ! Name of the attribute
1466      REAL(wp)              , INTENT(in   )           ::   patt0d    ! written field
1467      CHARACTER(len=*)      , INTENT(in   ), OPTIONAL ::   cdvar     ! Name of the variable
1468      !
1469      IF( kiomid > 0 ) THEN
1470         IF( iom_file(kiomid)%nfid > 0 )   CALL iom_nf90_putatt( kiomid, cdatt,  patt0d =  patt0d, cdvar=cdvar )
1471      ENDIF
1472   END SUBROUTINE iom_p0d_ratt
1473
1474   SUBROUTINE iom_p1d_ratt( kiomid, cdatt, patt1d, cdvar )
1475      INTEGER               , INTENT(in   )           ::   kiomid    ! Identifier of the file
1476      CHARACTER(len=*)      , INTENT(in   )           ::   cdatt     ! Name of the attribute
1477      REAL(wp), DIMENSION(:), INTENT(in   )           ::   patt1d    ! written field
1478      CHARACTER(len=*)      , INTENT(in   ), OPTIONAL ::   cdvar     ! Name of the variable
1479      !
1480      IF( kiomid > 0 ) THEN
1481         IF( iom_file(kiomid)%nfid > 0 )   CALL iom_nf90_putatt( kiomid, cdatt,  patt1d =  patt1d, cdvar=cdvar )
1482      ENDIF
1483   END SUBROUTINE iom_p1d_ratt
1484   
1485   SUBROUTINE iom_p0d_catt( kiomid, cdatt, cdatt0d, cdvar )
1486      INTEGER               , INTENT(in   )           ::   kiomid    ! Identifier of the file
1487      CHARACTER(len=*)      , INTENT(in   )           ::   cdatt     ! Name of the attribute
1488      CHARACTER(len=*)      , INTENT(in   )           ::   cdatt0d   ! written field
1489      CHARACTER(len=*)      , INTENT(in   ), OPTIONAL ::   cdvar     ! Name of the variable
1490      !
1491      IF( kiomid > 0 ) THEN
1492         IF( iom_file(kiomid)%nfid > 0 )   CALL iom_nf90_putatt( kiomid, cdatt, cdatt0d = cdatt0d, cdvar=cdvar )
1493      ENDIF
1494   END SUBROUTINE iom_p0d_catt
1495
1496
1497   !!----------------------------------------------------------------------
1498   !!                   INTERFACE iom_rstput
1499   !!----------------------------------------------------------------------
1500   SUBROUTINE iom_rp0d( kt, kwrite, kiomid, cdvar, pvar, ktype, ldxios )
1501      INTEGER         , INTENT(in)                         ::   kt       ! ocean time-step
1502      INTEGER         , INTENT(in)                         ::   kwrite   ! writing time-step
1503      INTEGER         , INTENT(in)                         ::   kiomid   ! Identifier of the file
1504      CHARACTER(len=*), INTENT(in)                         ::   cdvar    ! time axis name
1505      REAL(wp)        , INTENT(in)                         ::   pvar     ! written field
1506      INTEGER         , INTENT(in), OPTIONAL               ::   ktype    ! variable external type
1507      LOGICAL, OPTIONAL :: ldxios   ! xios write flag
1508      LOGICAL :: llx                ! local xios write flag
1509      INTEGER :: ivid   ! variable id
1510
1511      llx = .FALSE.
1512      IF(PRESENT(ldxios)) llx = ldxios
1513      IF( llx ) THEN
1514#ifdef key_iomput
1515      IF( kt == kwrite ) THEN
1516          IF(lwp) write(numout,*) 'RESTART: write (XIOS 0D) ',trim(cdvar)
1517          CALL xios_send_field(trim(cdvar), pvar)
1518      ELSE
1519          IF(lwp) write(numout,*) 'RESTART: define (XIOS 0D) ',trim(cdvar)
1520          CALL iom_set_rstw_active( trim(cdvar), rd0 = pvar ) 
1521      ENDIF
1522#endif
1523      ELSE
1524         IF( kiomid > 0 ) THEN
1525            IF( iom_file(kiomid)%nfid > 0 ) THEN
1526               ivid = iom_varid( kiomid, cdvar, ldstop = .FALSE. )
1527               CALL iom_nf90_rstput( kt, kwrite, kiomid, cdvar, ivid, ktype, pv_r0d = pvar )
1528            ENDIF
1529         ENDIF
1530      ENDIF
1531   END SUBROUTINE iom_rp0d
1532
1533   SUBROUTINE iom_rp1d( kt, kwrite, kiomid, cdvar, pvar, ktype, ldxios )
1534      INTEGER         , INTENT(in)                         ::   kt       ! ocean time-step
1535      INTEGER         , INTENT(in)                         ::   kwrite   ! writing time-step
1536      INTEGER         , INTENT(in)                         ::   kiomid   ! Identifier of the file
1537      CHARACTER(len=*), INTENT(in)                         ::   cdvar    ! time axis name
1538      REAL(wp)        , INTENT(in), DIMENSION(          :) ::   pvar     ! written field
1539      INTEGER         , INTENT(in), OPTIONAL               ::   ktype    ! variable external type
1540      LOGICAL, OPTIONAL                                    ::   ldxios   ! xios write flag
1541      LOGICAL :: llx                ! local xios write flag
1542      INTEGER :: ivid   ! variable id
1543
1544      llx = .FALSE.
1545      IF(PRESENT(ldxios)) llx = ldxios
1546      IF( llx ) THEN
1547#ifdef key_iomput
1548      IF( kt == kwrite ) THEN
1549         IF(lwp) write(numout,*) 'RESTART: write (XIOS 1D) ',trim(cdvar)
1550         CALL xios_send_field(trim(cdvar), pvar)
1551      ELSE
1552         IF(lwp) write(numout,*) 'RESTART: define (XIOS 1D) ',trim(cdvar)
1553         CALL iom_set_rstw_active( trim(cdvar), rd1 = pvar ) 
1554      ENDIF
1555#endif
1556      ELSE
1557         IF( kiomid > 0 ) THEN
1558            IF( iom_file(kiomid)%nfid > 0 ) THEN
1559               ivid = iom_varid( kiomid, cdvar, ldstop = .FALSE. )
1560               CALL iom_nf90_rstput( kt, kwrite, kiomid, cdvar, ivid, ktype, pv_r1d = pvar )
1561            ENDIF
1562         ENDIF
1563      ENDIF
1564   END SUBROUTINE iom_rp1d
1565
1566   SUBROUTINE iom_rp2d( kt, kwrite, kiomid, cdvar, pvar, ktype, ldxios )
1567      INTEGER         , INTENT(in)                         ::   kt       ! ocean time-step
1568      INTEGER         , INTENT(in)                         ::   kwrite   ! writing time-step
1569      INTEGER         , INTENT(in)                         ::   kiomid   ! Identifier of the file
1570      CHARACTER(len=*), INTENT(in)                         ::   cdvar    ! time axis name
1571      REAL(wp)        , INTENT(in), DIMENSION(:,    :    ) ::   pvar     ! written field
1572      INTEGER         , INTENT(in), OPTIONAL               ::   ktype    ! variable external type
1573      LOGICAL, OPTIONAL :: ldxios   ! xios write flag
1574      LOGICAL :: llx
1575      INTEGER :: ivid   ! variable id
1576
1577      llx = .FALSE.
1578      IF(PRESENT(ldxios)) llx = ldxios
1579      IF( llx ) THEN
1580#ifdef key_iomput
1581      IF( kt == kwrite ) THEN
1582         IF(lwp) write(numout,*) 'RESTART: write (XIOS 2D) ',trim(cdvar)
1583         CALL xios_send_field(trim(cdvar), pvar)
1584      ELSE
1585         IF(lwp) write(numout,*) 'RESTART: define (XIOS 2D) ',trim(cdvar)
1586         CALL iom_set_rstw_active( trim(cdvar), rd2 = pvar ) 
1587      ENDIF
1588#endif
1589      ELSE
1590         IF( kiomid > 0 ) THEN
1591            IF( iom_file(kiomid)%nfid > 0 ) THEN
1592               ivid = iom_varid( kiomid, cdvar, ldstop = .FALSE. )
1593               CALL iom_nf90_rstput( kt, kwrite, kiomid, cdvar, ivid, ktype, pv_r2d = pvar )
1594            ENDIF
1595         ENDIF
1596      ENDIF
1597   END SUBROUTINE iom_rp2d
1598
1599   SUBROUTINE iom_rp3d( kt, kwrite, kiomid, cdvar, pvar, ktype, ldxios )
1600      INTEGER         , INTENT(in)                         ::   kt       ! ocean time-step
1601      INTEGER         , INTENT(in)                         ::   kwrite   ! writing time-step
1602      INTEGER         , INTENT(in)                         ::   kiomid   ! Identifier of the file
1603      CHARACTER(len=*), INTENT(in)                         ::   cdvar    ! time axis name
1604      REAL(wp)        , INTENT(in),       DIMENSION(:,:,:) ::   pvar     ! written field
1605      INTEGER         , INTENT(in), OPTIONAL               ::   ktype    ! variable external type
1606      LOGICAL, OPTIONAL :: ldxios   ! xios write flag
1607      LOGICAL :: llx                 ! local xios write flag
1608      INTEGER :: ivid   ! variable id
1609
1610      llx = .FALSE.
1611      IF(PRESENT(ldxios)) llx = ldxios
1612      IF( llx ) THEN
1613#ifdef key_iomput
1614      IF( kt == kwrite ) THEN
1615         IF(lwp) write(numout,*) 'RESTART: write (XIOS 3D) ',trim(cdvar)
1616         CALL xios_send_field(trim(cdvar), pvar)
1617      ELSE
1618         IF(lwp) write(numout,*) 'RESTART: define (XIOS 3D) ',trim(cdvar)
1619         CALL iom_set_rstw_active( trim(cdvar), rd3 = pvar )
1620      ENDIF
1621#endif
1622      ELSE
1623         IF( kiomid > 0 ) THEN
1624            IF( iom_file(kiomid)%nfid > 0 ) THEN
1625               ivid = iom_varid( kiomid, cdvar, ldstop = .FALSE. )
1626               CALL iom_nf90_rstput( kt, kwrite, kiomid, cdvar, ivid, ktype, pv_r3d = pvar )
1627            ENDIF
1628         ENDIF
1629      ENDIF
1630   END SUBROUTINE iom_rp3d
1631
1632
1633  SUBROUTINE iom_delay_rst( cdaction, cdcpnt, kncid )
1634      !!---------------------------------------------------------------------
1635      !!   Routine iom_delay_rst: used read/write restart related to mpp_delay
1636      !!
1637      !!---------------------------------------------------------------------
1638      CHARACTER(len=*), INTENT(in   ) ::   cdaction        !
1639      CHARACTER(len=*), INTENT(in   ) ::   cdcpnt
1640      INTEGER         , INTENT(in   ) ::   kncid
1641      !
1642      INTEGER  :: ji
1643      INTEGER  :: indim
1644      LOGICAL  :: llattexist
1645      REAL(wp), ALLOCATABLE, DIMENSION(:) ::   zreal1d
1646      !!---------------------------------------------------------------------
1647      !
1648      !                                      ===================================
1649      IF( TRIM(cdaction) == 'READ' ) THEN   ! read restart related to mpp_delay !
1650         !                                   ===================================
1651         DO ji = 1, nbdelay
1652            IF ( c_delaycpnt(ji) == cdcpnt ) THEN
1653               CALL iom_chkatt( kncid, 'DELAY_'//c_delaylist(ji), llattexist, indim )
1654               IF( llattexist )  THEN
1655                  ALLOCATE( todelay(ji)%z1d(indim) )
1656                  CALL iom_getatt( kncid, 'DELAY_'//c_delaylist(ji), todelay(ji)%z1d(:) )
1657                  ndelayid(ji) = 0   ! set to 0 to specify that the value was read in the restart
1658               ENDIF
1659           ENDIF
1660         END DO
1661         !                                   ====================================
1662      ELSE                                  ! write restart related to mpp_delay !
1663         !                                   ====================================
1664         DO ji = 1, nbdelay   ! save only ocean delayed global communication variables
1665            IF ( c_delaycpnt(ji) == cdcpnt ) THEN
1666               IF( ASSOCIATED(todelay(ji)%z1d) ) THEN
1667                  CALL mpp_delay_rcv(ji)   ! make sure %z1d is received
1668                  CALL iom_putatt( kncid, 'DELAY_'//c_delaylist(ji), todelay(ji)%z1d(:) )
1669               ENDIF
1670            ENDIF
1671         END DO
1672         !
1673      ENDIF
1674     
1675   END SUBROUTINE iom_delay_rst
1676 
1677   
1678
1679   !!----------------------------------------------------------------------
1680   !!                   INTERFACE iom_put
1681   !!----------------------------------------------------------------------
1682   SUBROUTINE iom_p0d( cdname, pfield0d )
1683      CHARACTER(LEN=*), INTENT(in) ::   cdname
1684      REAL(wp)        , INTENT(in) ::   pfield0d
1685!!      REAL(wp)        , DIMENSION(jpi,jpj) ::   zz     ! masson
1686#if defined key_iomput
1687!!clem      zz(:,:)=pfield0d
1688!!clem      CALL xios_send_field(cdname, zz)
1689      CALL xios_send_field(cdname, (/pfield0d/)) 
1690#else
1691      IF( .FALSE. )   WRITE(numout,*) cdname, pfield0d   ! useless test to avoid compilation warnings
1692#endif
1693   END SUBROUTINE iom_p0d
1694
1695   SUBROUTINE iom_p1d( cdname, pfield1d )
1696      CHARACTER(LEN=*)          , INTENT(in) ::   cdname
1697      REAL(wp),     DIMENSION(:), INTENT(in) ::   pfield1d
1698#if defined key_iomput
1699      CALL xios_send_field( cdname, RESHAPE( (/pfield1d/), (/1,1,SIZE(pfield1d)/) ) )
1700#else
1701      IF( .FALSE. )   WRITE(numout,*) cdname, pfield1d   ! useless test to avoid compilation warnings
1702#endif
1703   END SUBROUTINE iom_p1d
1704
1705   SUBROUTINE iom_p2d( cdname, pfield2d )
1706      CHARACTER(LEN=*)            , INTENT(in) ::   cdname
1707      REAL(wp),     DIMENSION(:,:), INTENT(in) ::   pfield2d
1708#if defined key_iomput
1709      CALL xios_send_field(cdname, pfield2d)
1710#else
1711      IF( .FALSE. )   WRITE(numout,*) cdname, pfield2d   ! useless test to avoid compilation warnings
1712#endif
1713   END SUBROUTINE iom_p2d
1714
1715   SUBROUTINE iom_p3d( cdname, pfield3d )
1716      CHARACTER(LEN=*)                , INTENT(in) ::   cdname
1717      REAL(wp),       DIMENSION(:,:,:), INTENT(in) ::   pfield3d
1718#if defined key_iomput
1719      CALL xios_send_field( cdname, pfield3d )
1720#else
1721      IF( .FALSE. )   WRITE(numout,*) cdname, pfield3d   ! useless test to avoid compilation warnings
1722#endif
1723   END SUBROUTINE iom_p3d
1724
1725   SUBROUTINE iom_p4d( cdname, pfield4d )
1726      CHARACTER(LEN=*)                , INTENT(in) ::   cdname
1727      REAL(wp),       DIMENSION(:,:,:,:), INTENT(in) ::   pfield4d
1728#if defined key_iomput
1729      CALL xios_send_field(cdname, pfield4d)
1730#else
1731      IF( .FALSE. )   WRITE(numout,*) cdname, pfield4d   ! useless test to avoid compilation warnings
1732#endif
1733   END SUBROUTINE iom_p4d
1734
1735
1736#if defined key_iomput
1737   !!----------------------------------------------------------------------
1738   !!   'key_iomput'                                         XIOS interface
1739   !!----------------------------------------------------------------------
1740
1741   SUBROUTINE iom_set_domain_attr( cdid, ni_glo, nj_glo, ibegin, jbegin, ni, nj,                                               &
1742      &                                    data_dim, data_ibegin, data_ni, data_jbegin, data_nj, lonvalue, latvalue, mask,     &
1743      &                                    nvertex, bounds_lon, bounds_lat, area )
1744      !!----------------------------------------------------------------------
1745      !!----------------------------------------------------------------------
1746      CHARACTER(LEN=*)                  , INTENT(in) ::   cdid
1747      INTEGER                 , OPTIONAL, INTENT(in) ::   ni_glo, nj_glo, ibegin, jbegin, ni, nj
1748      INTEGER                 , OPTIONAL, INTENT(in) ::   data_dim, data_ibegin, data_ni, data_jbegin, data_nj
1749      INTEGER                 , OPTIONAL, INTENT(in) ::   nvertex
1750      REAL(wp), DIMENSION(:)  , OPTIONAL, INTENT(in) ::   lonvalue, latvalue
1751      REAL(wp), DIMENSION(:,:), OPTIONAL, INTENT(in) ::   bounds_lon, bounds_lat, area
1752      LOGICAL , DIMENSION(:)  , OPTIONAL, INTENT(in) ::   mask
1753      !!----------------------------------------------------------------------
1754      !
1755      IF( xios_is_valid_domain     (cdid) ) THEN
1756         CALL xios_set_domain_attr     ( cdid, ni_glo=ni_glo, nj_glo=nj_glo, ibegin=ibegin, jbegin=jbegin, ni=ni, nj=nj,   &
1757            &    data_dim=data_dim, data_ibegin=data_ibegin, data_ni=data_ni, data_jbegin=data_jbegin, data_nj=data_nj ,   &
1758            &    lonvalue_1D=lonvalue, latvalue_1D=latvalue, mask_1D=mask, nvertex=nvertex, bounds_lon_1D=bounds_lon,      &
1759            &    bounds_lat_1D=bounds_lat, area=area, type='curvilinear')
1760      ENDIF
1761      IF( xios_is_valid_domaingroup(cdid) ) THEN
1762         CALL xios_set_domaingroup_attr( cdid, ni_glo=ni_glo, nj_glo=nj_glo, ibegin=ibegin, jbegin=jbegin, ni=ni, nj=nj,   &
1763            &    data_dim=data_dim, data_ibegin=data_ibegin, data_ni=data_ni, data_jbegin=data_jbegin, data_nj=data_nj ,   &
1764            &    lonvalue_1D=lonvalue, latvalue_1D=latvalue, mask_1D=mask, nvertex=nvertex, bounds_lon_1D=bounds_lon,      &
1765            &    bounds_lat_1D=bounds_lat, area=area, type='curvilinear' )
1766      ENDIF
1767      !
1768      CALL xios_solve_inheritance()
1769      !
1770   END SUBROUTINE iom_set_domain_attr
1771
1772
1773   SUBROUTINE iom_set_zoom_domain_attr( cdid, ibegin, jbegin, ni, nj )
1774      !!----------------------------------------------------------------------
1775      !!----------------------------------------------------------------------
1776      CHARACTER(LEN=*), INTENT(in) ::   cdid
1777      INTEGER         , INTENT(in) ::   ibegin, jbegin, ni, nj
1778      !
1779      TYPE(xios_gridgroup) :: gridgroup_hdl
1780      TYPE(xios_grid)      :: grid_hdl
1781      TYPE(xios_domain)    :: domain_hdl 
1782      TYPE(xios_axis)      :: axis_hdl 
1783      CHARACTER(LEN=64)    :: cldomrefid   ! domain_ref name
1784      CHARACTER(len=1)     :: cl1          ! last character of this name
1785      !!----------------------------------------------------------------------
1786      !
1787      IF( xios_is_valid_zoom_domain(cdid) ) THEN
1788         ! define the zoom_domain attributs
1789         CALL xios_set_zoom_domain_attr( cdid, ibegin=ibegin, jbegin=jbegin, ni=ni, nj=nj )
1790         ! define a new 2D grid with this new domain
1791         CALL xios_get_handle("grid_definition", gridgroup_hdl )
1792         CALL xios_add_child(gridgroup_hdl, grid_hdl, TRIM(cdid)//'_2D' )   ! add a new 2D grid to grid_definition
1793         CALL xios_add_child(grid_hdl, domain_hdl, TRIM(cdid) )             ! add its domain
1794         ! define a new 3D grid with this new domain
1795         CALL xios_add_child(gridgroup_hdl, grid_hdl, TRIM(cdid)//'_3D' )   ! add a new 3D grid to grid_definition
1796         CALL xios_add_child(grid_hdl, domain_hdl, TRIM(cdid) )             ! add its domain
1797         ! vertical axis
1798         cl1 = cdid(LEN_TRIM(cdid):)                                        ! last letter of cdid
1799         cl1 = CHAR(ICHAR(cl1)+32)                                          ! from upper to lower case
1800         CALL xios_add_child(grid_hdl, axis_hdl, 'depth'//cl1)              ! add its axis
1801      ENDIF
1802      !     
1803   END SUBROUTINE iom_set_zoom_domain_attr
1804
1805
1806   SUBROUTINE iom_set_axis_attr( cdid, paxis, bounds )
1807      !!----------------------------------------------------------------------
1808      !!----------------------------------------------------------------------
1809      CHARACTER(LEN=*)      , INTENT(in) ::   cdid
1810      REAL(wp), DIMENSION(:)  , OPTIONAL, INTENT(in) ::   paxis
1811      REAL(wp), DIMENSION(:,:), OPTIONAL, INTENT(in) ::   bounds
1812      !!----------------------------------------------------------------------
1813      IF( PRESENT(paxis) ) THEN
1814         IF( xios_is_valid_axis     (cdid) )   CALL xios_set_axis_attr     ( cdid, n_glo=SIZE(paxis), value=paxis )
1815         IF( xios_is_valid_axisgroup(cdid) )   CALL xios_set_axisgroup_attr( cdid, n_glo=SIZE(paxis), value=paxis )
1816      ENDIF
1817      IF( xios_is_valid_axis     (cdid) )   CALL xios_set_axis_attr     ( cdid, bounds=bounds )
1818      IF( xios_is_valid_axisgroup(cdid) )   CALL xios_set_axisgroup_attr( cdid, bounds=bounds )
1819      CALL xios_solve_inheritance()
1820   END SUBROUTINE iom_set_axis_attr
1821
1822
1823   SUBROUTINE iom_set_field_attr( cdid, freq_op, freq_offset )
1824      !!----------------------------------------------------------------------
1825      !!----------------------------------------------------------------------
1826      CHARACTER(LEN=*)             , INTENT(in) ::   cdid
1827      TYPE(xios_duration), OPTIONAL, INTENT(in) ::   freq_op
1828      TYPE(xios_duration), OPTIONAL, INTENT(in) ::   freq_offset
1829      !!----------------------------------------------------------------------
1830      IF( xios_is_valid_field     (cdid) )   CALL xios_set_field_attr     ( cdid, freq_op=freq_op, freq_offset=freq_offset )
1831      IF( xios_is_valid_fieldgroup(cdid) )   CALL xios_set_fieldgroup_attr( cdid, freq_op=freq_op, freq_offset=freq_offset )
1832      CALL xios_solve_inheritance()
1833   END SUBROUTINE iom_set_field_attr
1834
1835
1836   SUBROUTINE iom_set_file_attr( cdid, name, name_suffix )
1837      !!----------------------------------------------------------------------
1838      !!----------------------------------------------------------------------
1839      CHARACTER(LEN=*)          , INTENT(in) ::   cdid
1840      CHARACTER(LEN=*),OPTIONAL , INTENT(in) ::   name, name_suffix
1841      !!----------------------------------------------------------------------
1842      IF( xios_is_valid_file     (cdid) )   CALL xios_set_file_attr     ( cdid, name=name, name_suffix=name_suffix )
1843      IF( xios_is_valid_filegroup(cdid) )   CALL xios_set_filegroup_attr( cdid, name=name, name_suffix=name_suffix )
1844      CALL xios_solve_inheritance()
1845   END SUBROUTINE iom_set_file_attr
1846
1847
1848   SUBROUTINE iom_get_file_attr( cdid, name, name_suffix, output_freq )
1849      !!----------------------------------------------------------------------
1850      !!----------------------------------------------------------------------
1851      CHARACTER(LEN=*)          , INTENT(in ) ::   cdid
1852      CHARACTER(LEN=*),OPTIONAL , INTENT(out) ::   name, name_suffix
1853      TYPE(xios_duration), OPTIONAL , INTENT(out) :: output_freq
1854      LOGICAL                                 ::   llexist1,llexist2,llexist3
1855      !---------------------------------------------------------------------
1856      IF( PRESENT( name        ) )   name = ''          ! default values
1857      IF( PRESENT( name_suffix ) )   name_suffix = ''
1858      IF( PRESENT( output_freq ) )   output_freq = xios_duration(0,0,0,0,0,0)
1859      IF( xios_is_valid_file     (cdid) ) THEN
1860         CALL xios_solve_inheritance()
1861         CALL xios_is_defined_file_attr     ( cdid, name = llexist1, name_suffix = llexist2, output_freq = llexist3)
1862         IF(llexist1)   CALL xios_get_file_attr     ( cdid, name = name )
1863         IF(llexist2)   CALL xios_get_file_attr     ( cdid, name_suffix = name_suffix )
1864         IF(llexist3)   CALL xios_get_file_attr     ( cdid, output_freq = output_freq )
1865      ENDIF
1866      IF( xios_is_valid_filegroup(cdid) ) THEN
1867         CALL xios_solve_inheritance()
1868         CALL xios_is_defined_filegroup_attr( cdid, name = llexist1, name_suffix = llexist2, output_freq = llexist3)
1869         IF(llexist1)   CALL xios_get_filegroup_attr( cdid, name = name )
1870         IF(llexist2)   CALL xios_get_filegroup_attr( cdid, name_suffix = name_suffix )
1871         IF(llexist3)   CALL xios_get_filegroup_attr( cdid, output_freq = output_freq )
1872      ENDIF
1873   END SUBROUTINE iom_get_file_attr
1874
1875
1876   SUBROUTINE iom_set_grid_attr( cdid, mask )
1877      !!----------------------------------------------------------------------
1878      !!----------------------------------------------------------------------
1879      CHARACTER(LEN=*)                   , INTENT(in) ::   cdid
1880      LOGICAL, DIMENSION(:,:,:), OPTIONAL, INTENT(in) ::   mask
1881      !!----------------------------------------------------------------------
1882      IF( xios_is_valid_grid     (cdid) )   CALL xios_set_grid_attr     ( cdid, mask_3D=mask )
1883      IF( xios_is_valid_gridgroup(cdid) )   CALL xios_set_gridgroup_attr( cdid, mask_3D=mask )
1884      CALL xios_solve_inheritance()
1885   END SUBROUTINE iom_set_grid_attr
1886
1887   SUBROUTINE iom_setkt( kt, cdname )
1888      !!----------------------------------------------------------------------
1889      !!----------------------------------------------------------------------
1890      INTEGER         , INTENT(in) ::   kt 
1891      CHARACTER(LEN=*), INTENT(in) ::   cdname
1892      !!----------------------------------------------------------------------
1893      CALL iom_swap( cdname )   ! swap to cdname context
1894      CALL xios_update_calendar(kt)
1895      IF( cdname /= TRIM(cxios_context) )   CALL iom_swap( TRIM(cxios_context) )   ! return back to nemo context
1896   END SUBROUTINE iom_setkt
1897
1898   SUBROUTINE iom_context_finalize( cdname )
1899      !!----------------------------------------------------------------------
1900      !!----------------------------------------------------------------------
1901      CHARACTER(LEN=*), INTENT(in) :: cdname
1902      CHARACTER(LEN=120)           :: clname
1903      !!----------------------------------------------------------------------
1904      clname = cdname
1905      IF(lwp) write(numout, *) 'Finalize: ', TRIM(cdname)
1906      IF( TRIM(Agrif_CFixed()) .NE. '0' ) clname = TRIM(Agrif_CFixed())//"_"//clname 
1907      IF( xios_is_valid_context(clname) ) THEN
1908         CALL iom_swap( cdname )   ! swap to cdname context
1909         CALL xios_context_finalize() ! finalize the context
1910         IF( cdname /= TRIM(cxios_context) ) CALL iom_swap( TRIM(cxios_context) )   ! return back to nemo context
1911      ENDIF
1912      !
1913   END SUBROUTINE iom_context_finalize
1914
1915
1916   SUBROUTINE set_grid( cdgrd, plon, plat, ldxios, ldrxios )
1917      !!----------------------------------------------------------------------
1918      !!                     ***  ROUTINE set_grid  ***
1919      !!
1920      !! ** Purpose :   define horizontal grids
1921      !!----------------------------------------------------------------------
1922      CHARACTER(LEN=1)            , INTENT(in) ::   cdgrd
1923      REAL(wp), DIMENSION(jpi,jpj), INTENT(in) ::   plon
1924      REAL(wp), DIMENSION(jpi,jpj), INTENT(in) ::   plat
1925      !
1926      INTEGER  :: ni, nj
1927      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zmask
1928      LOGICAL, INTENT(IN) :: ldxios, ldrxios
1929      !!----------------------------------------------------------------------
1930      !
1931      ni = nlei-nldi+1
1932      nj = nlej-nldj+1
1933      !
1934      CALL iom_set_domain_attr("grid_"//cdgrd, ni_glo=jpiglo, nj_glo=jpjglo, ibegin=nimpp+nldi-2, jbegin=njmpp+nldj-2, ni=ni, nj=nj)
1935      CALL iom_set_domain_attr("grid_"//cdgrd, data_dim=2, data_ibegin = 1-nldi, data_ni = jpi, data_jbegin = 1-nldj, data_nj = jpj)
1936!don't define lon and lat for restart reading context.
1937      IF ( .NOT.ldrxios ) &
1938         CALL iom_set_domain_attr("grid_"//cdgrd, lonvalue = RESHAPE(plon(nldi:nlei, nldj:nlej),(/ ni*nj /)),   &
1939         &                                     latvalue = RESHAPE(plat(nldi:nlei, nldj:nlej),(/ ni*nj /))) 
1940      !
1941      IF ( ln_mskland .AND. (.NOT.ldxios) ) THEN
1942         ! mask land points, keep values on coast line -> specific mask for U, V and W points
1943         SELECT CASE ( cdgrd )
1944         CASE('T')   ;   zmask(:,:,:)       = tmask(:,:,:)
1945         CASE('U')   ;   zmask(2:jpim1,:,:) = tmask(2:jpim1,:,:) + tmask(3:jpi,:,:)   ;   CALL lbc_lnk( 'iom', zmask, 'U', 1. )
1946         CASE('V')   ;   zmask(:,2:jpjm1,:) = tmask(:,2:jpjm1,:) + tmask(:,3:jpj,:)   ;   CALL lbc_lnk( 'iom', zmask, 'V', 1. )
1947         CASE('W')   ;   zmask(:,:,2:jpk  ) = tmask(:,:,1:jpkm1) + tmask(:,:,2:jpk)   ;   zmask(:,:,1) = tmask(:,:,1)
1948         END SELECT
1949         !
1950         CALL iom_set_domain_attr( "grid_"//cdgrd       , mask = RESHAPE(zmask(nldi:nlei,nldj:nlej,1),(/ni*nj    /)) /= 0. )
1951         CALL iom_set_grid_attr  ( "grid_"//cdgrd//"_3D", mask = RESHAPE(zmask(nldi:nlei,nldj:nlej,:),(/ni,nj,jpk/)) /= 0. )
1952      ENDIF
1953      !
1954   END SUBROUTINE set_grid
1955
1956
1957   SUBROUTINE set_grid_bounds( cdgrd, plon_cnr, plat_cnr, plon_pnt, plat_pnt )
1958      !!----------------------------------------------------------------------
1959      !!                   ***  ROUTINE set_grid_bounds  ***
1960      !!
1961      !! ** Purpose :   define horizontal grid corners
1962      !!
1963      !!----------------------------------------------------------------------
1964      CHARACTER(LEN=1)                      , INTENT(in) :: cdgrd
1965      REAL(wp), DIMENSION(jpi,jpj)          , INTENT(in) :: plon_cnr, plat_cnr  ! Lat/lon coord. of a contiguous vertex of cell (i,j)
1966      REAL(wp), DIMENSION(jpi,jpj), OPTIONAL, INTENT(in) :: plon_pnt, plat_pnt  ! Lat/lon coord. of the point of cell (i,j)
1967      !
1968      INTEGER :: ji, jj, jn, ni, nj
1969      INTEGER :: icnr, jcnr                             ! Offset such that the vertex coordinate (i+icnr,j+jcnr)
1970      !                                                 ! represents the bottom-left corner of cell (i,j)
1971      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:,:) :: z_bnds      ! Lat/lon coordinates of the vertices of cell (i,j)
1972      REAL(wp), ALLOCATABLE, DIMENSION(:,:)     :: z_fld       ! Working array to determine where to rotate cells
1973      REAL(wp), ALLOCATABLE, DIMENSION(:,:)     :: z_rot       ! Lat/lon working array for rotation of cells
1974      !!----------------------------------------------------------------------
1975      !
1976      ALLOCATE( z_bnds(4,jpi,jpj,2), z_fld(jpi,jpj), z_rot(4,2)  )
1977      !
1978      ! Offset of coordinate representing bottom-left corner
1979      SELECT CASE ( TRIM(cdgrd) )
1980      CASE ('T', 'W')   ;   icnr = -1   ;   jcnr = -1
1981      CASE ('U')        ;   icnr =  0   ;   jcnr = -1
1982      CASE ('V')        ;   icnr = -1   ;   jcnr =  0
1983      END SELECT
1984      !
1985      ni = nlei-nldi+1   ! Dimensions of subdomain interior
1986      nj = nlej-nldj+1
1987      !
1988      z_fld(:,:) = 1._wp
1989      CALL lbc_lnk( 'iom', z_fld, cdgrd, -1. )    ! Working array for location of northfold
1990      !
1991      ! Cell vertices that can be defined
1992      DO jj = 2, jpjm1
1993         DO ji = 2, jpim1
1994            z_bnds(1,ji,jj,1) = plat_cnr(ji+icnr,  jj+jcnr  ) ! Bottom-left
1995            z_bnds(2,ji,jj,1) = plat_cnr(ji+icnr+1,jj+jcnr  ) ! Bottom-right
1996            z_bnds(3,ji,jj,1) = plat_cnr(ji+icnr+1,jj+jcnr+1) ! Top-right
1997            z_bnds(4,ji,jj,1) = plat_cnr(ji+icnr,  jj+jcnr+1) ! Top-left
1998            z_bnds(1,ji,jj,2) = plon_cnr(ji+icnr,  jj+jcnr  ) ! Bottom-left
1999            z_bnds(2,ji,jj,2) = plon_cnr(ji+icnr+1,jj+jcnr  ) ! Bottom-right
2000            z_bnds(3,ji,jj,2) = plon_cnr(ji+icnr+1,jj+jcnr+1) ! Top-right
2001            z_bnds(4,ji,jj,2) = plon_cnr(ji+icnr,  jj+jcnr+1) ! Top-left
2002         END DO
2003      END DO
2004      !
2005      ! Cell vertices on boundries
2006      DO jn = 1, 4
2007         CALL lbc_lnk( 'iom', z_bnds(jn,:,:,1), cdgrd, 1., pfillval=999._wp )
2008         CALL lbc_lnk( 'iom', z_bnds(jn,:,:,2), cdgrd, 1., pfillval=999._wp )
2009      END DO
2010      !
2011      ! Zero-size cells at closed boundaries if cell points provided,
2012      ! otherwise they are closed cells with unrealistic bounds
2013      IF( PRESENT(plon_pnt) .AND. PRESENT(plat_pnt) ) THEN
2014         IF( (nbondi == -1 .OR. nbondi == 2) .AND. .NOT. (jperio == 1 .OR. jperio == 4 .OR. jperio == 6) ) THEN
2015            DO jn = 1, 4        ! (West or jpni = 1), closed E-W
2016               z_bnds(jn,1,:,1) = plat_pnt(1,:)  ;  z_bnds(jn,1,:,2) = plon_pnt(1,:)
2017            END DO
2018         ENDIF
2019         IF( (nbondi == 1 .OR. nbondi == 2) .AND. .NOT. (jperio == 1 .OR. jperio == 4 .OR. jperio == 6) ) THEN
2020            DO jn = 1, 4        ! (East or jpni = 1), closed E-W
2021               z_bnds(jn,nlci,:,1) = plat_pnt(nlci,:)  ;  z_bnds(jn,nlci,:,2) = plon_pnt(nlci,:)
2022            END DO
2023         ENDIF
2024         IF( nbondj == -1 .OR. (nbondj == 2 .AND. jperio /= 2) ) THEN
2025            DO jn = 1, 4        ! South or (jpnj = 1, not symmetric)
2026               z_bnds(jn,:,1,1) = plat_pnt(:,1)  ;  z_bnds(jn,:,1,2) = plon_pnt(:,1)
2027            END DO
2028         ENDIF
2029         IF( (nbondj == 1 .OR. nbondj == 2) .AND. jperio  < 3 ) THEN
2030            DO jn = 1, 4        ! (North or jpnj = 1), no north fold
2031               z_bnds(jn,:,nlcj,1) = plat_pnt(:,nlcj)  ;  z_bnds(jn,:,nlcj,2) = plon_pnt(:,nlcj)
2032            END DO
2033         ENDIF
2034      ENDIF
2035      !
2036      IF( (nbondj == 1 .OR. nbondj == 2) .AND. jperio >= 3 ) THEN    ! Rotate cells at the north fold
2037         DO jj = 1, jpj
2038            DO ji = 1, jpi
2039               IF( z_fld(ji,jj) == -1. ) THEN
2040                  z_rot(1,:) = z_bnds(3,ji,jj,:) ; z_rot(2,:) = z_bnds(4,ji,jj,:)
2041                  z_rot(3,:) = z_bnds(1,ji,jj,:) ; z_rot(4,:) = z_bnds(2,ji,jj,:)
2042                  z_bnds(:,ji,jj,:) = z_rot(:,:)
2043               ENDIF
2044            END DO
2045         END DO
2046      ELSE IF( nbondj == 2 .AND. jperio == 2 ) THEN                  ! Invert cells at the symmetric equator
2047         DO ji = 1, jpi
2048            z_rot(1:2,:) = z_bnds(3:4,ji,1,:)
2049            z_rot(3:4,:) = z_bnds(1:2,ji,1,:)
2050            z_bnds(:,ji,1,:) = z_rot(:,:)
2051         END DO
2052      ENDIF
2053      !
2054      CALL iom_set_domain_attr("grid_"//cdgrd, bounds_lat = RESHAPE(z_bnds(:,nldi:nlei,nldj:nlej,1),(/ 4,ni*nj /)),           &
2055          &                                    bounds_lon = RESHAPE(z_bnds(:,nldi:nlei,nldj:nlej,2),(/ 4,ni*nj /)), nvertex=4 )
2056      !
2057      DEALLOCATE( z_bnds, z_fld, z_rot ) 
2058      !
2059   END SUBROUTINE set_grid_bounds
2060
2061
2062   SUBROUTINE set_grid_znl( plat )
2063      !!----------------------------------------------------------------------
2064      !!                     ***  ROUTINE set_grid_znl  ***
2065      !!
2066      !! ** Purpose :   define grids for zonal mean
2067      !!
2068      !!----------------------------------------------------------------------
2069      REAL(wp), DIMENSION(jpi,jpj), INTENT(in) ::   plat
2070      !
2071      INTEGER  :: ni, nj, ix, iy
2072      REAL(wp), DIMENSION(:), ALLOCATABLE  ::   zlon
2073      !!----------------------------------------------------------------------
2074      !
2075      ni=nlei-nldi+1       ! define zonal mean domain (jpj*jpk)
2076      nj=nlej-nldj+1
2077      ALLOCATE( zlon(ni*nj) )       ;       zlon(:) = 0._wp
2078      !
2079!      CALL dom_ngb( -168.53, 65.03, ix, iy, 'T' ) !  i-line that passes through Bering Strait: Reference latitude (used in plots)
2080      CALL dom_ngb( 180., 90., ix, iy, 'T' ) !  i-line that passes near the North Pole : Reference latitude (used in plots)
2081      CALL iom_set_domain_attr("gznl", ni_glo=jpiglo, nj_glo=jpjglo, ibegin=nimpp+nldi-2, jbegin=njmpp+nldj-2, ni=ni, nj=nj)
2082      CALL iom_set_domain_attr("gznl", data_dim=2, data_ibegin = 1-nldi, data_ni = jpi, data_jbegin = 1-nldj, data_nj = jpj)
2083      CALL iom_set_domain_attr("gznl", lonvalue = zlon,   &
2084         &                             latvalue = RESHAPE(plat(nldi:nlei, nldj:nlej),(/ ni*nj /))) 
2085      CALL iom_set_zoom_domain_attr("ptr", ibegin=ix-1, jbegin=0, ni=1, nj=jpjglo)
2086      !
2087      CALL iom_update_file_name('ptr')
2088      !
2089   END SUBROUTINE set_grid_znl
2090
2091
2092   SUBROUTINE set_scalar
2093      !!----------------------------------------------------------------------
2094      !!                     ***  ROUTINE set_scalar  ***
2095      !!
2096      !! ** Purpose :   define fake grids for scalar point
2097      !!
2098      !!----------------------------------------------------------------------
2099      REAL(wp), DIMENSION(1)   ::   zz = 1.
2100      !!----------------------------------------------------------------------
2101      !
2102      CALL iom_set_domain_attr('scalarpoint', ni_glo=jpnij, nj_glo=1, ibegin=narea-1, jbegin=0, ni=1, nj=1)
2103      CALL iom_set_domain_attr('scalarpoint', data_dim=2, data_ibegin = 1, data_ni = 1, data_jbegin = 1, data_nj = 1)
2104      !
2105      zz = REAL( narea, wp )
2106      CALL iom_set_domain_attr('scalarpoint', lonvalue=zz, latvalue=zz)
2107      !
2108   END SUBROUTINE set_scalar
2109
2110
2111   SUBROUTINE set_xmlatt
2112      !!----------------------------------------------------------------------
2113      !!                     ***  ROUTINE set_xmlatt  ***
2114      !!
2115      !! ** Purpose :   automatic definitions of some of the xml attributs...
2116      !!
2117      !!----------------------------------------------------------------------
2118      CHARACTER(len=1),DIMENSION( 3) ::   clgrd                    ! suffix name
2119      CHARACTER(len=256)             ::   clsuff                   ! suffix name
2120      CHARACTER(len=1)               ::   cl1                      ! 1 character
2121      CHARACTER(len=2)               ::   cl2                      ! 2 characters
2122      CHARACTER(len=3)               ::   cl3                      ! 3 characters
2123      INTEGER                        ::   ji, jg                   ! loop counters
2124      INTEGER                        ::   ix, iy                   ! i-,j- index
2125      REAL(wp)        ,DIMENSION(11) ::   zlontao                  ! longitudes of tao    moorings
2126      REAL(wp)        ,DIMENSION( 7) ::   zlattao                  ! latitudes  of tao    moorings
2127      REAL(wp)        ,DIMENSION( 4) ::   zlonrama                 ! longitudes of rama   moorings
2128      REAL(wp)        ,DIMENSION(11) ::   zlatrama                 ! latitudes  of rama   moorings
2129      REAL(wp)        ,DIMENSION( 3) ::   zlonpira                 ! longitudes of pirata moorings
2130      REAL(wp)        ,DIMENSION( 9) ::   zlatpira                 ! latitudes  of pirata moorings
2131      TYPE(xios_duration)            ::   f_op, f_of
2132      !!----------------------------------------------------------------------
2133      !
2134      ! frequency of the call of iom_put (attribut: freq_op)
2135      f_op%timestep = 1        ;  f_of%timestep =  0  ; CALL iom_set_field_attr('field_definition', freq_op=f_op, freq_offset=f_of)
2136      f_op%timestep = 2        ;  f_of%timestep =  0  ; CALL iom_set_field_attr('trendT_even'     , freq_op=f_op, freq_offset=f_of)
2137      f_op%timestep = 2        ;  f_of%timestep = -1  ; CALL iom_set_field_attr('trendT_odd'      , freq_op=f_op, freq_offset=f_of)
2138      f_op%timestep = nn_fsbc  ;  f_of%timestep =  0  ; CALL iom_set_field_attr('SBC'             , freq_op=f_op, freq_offset=f_of)
2139      f_op%timestep = nn_fsbc  ;  f_of%timestep =  0  ; CALL iom_set_field_attr('SBC_scalar'      , freq_op=f_op, freq_offset=f_of)
2140      f_op%timestep = nn_fsbc  ;  f_of%timestep =  0  ; CALL iom_set_field_attr('ABL'             , freq_op=f_op, freq_offset=f_of)
2141
2142      ! output file names (attribut: name)
2143      DO ji = 1, 9
2144         WRITE(cl1,'(i1)') ji 
2145         CALL iom_update_file_name('file'//cl1)
2146      END DO
2147      DO ji = 1, 99
2148         WRITE(cl2,'(i2.2)') ji 
2149         CALL iom_update_file_name('file'//cl2)
2150      END DO
2151      DO ji = 1, 999
2152         WRITE(cl3,'(i3.3)') ji 
2153         CALL iom_update_file_name('file'//cl3)
2154      END DO
2155
2156      ! Zooms...
2157      clgrd = (/ 'T', 'U', 'W' /) 
2158      DO jg = 1, SIZE(clgrd)                                                                   ! grid type
2159         cl1 = clgrd(jg)
2160         ! Equatorial section (attributs: jbegin, ni, name_suffix)
2161         CALL dom_ngb( 0., 0., ix, iy, cl1 )
2162         CALL iom_set_zoom_domain_attr('Eq'//cl1, ibegin=0, jbegin=iy-1, ni=jpiglo, nj=1 )
2163         CALL iom_get_file_attr   ('Eq'//cl1, name_suffix = clsuff             )
2164         CALL iom_set_file_attr   ('Eq'//cl1, name_suffix = TRIM(clsuff)//'_Eq')
2165         CALL iom_update_file_name('Eq'//cl1)
2166      END DO
2167      ! TAO moorings (attributs: ibegin, jbegin, name_suffix)
2168      zlontao = (/ 137.0, 147.0, 156.0, 165.0, -180.0, -170.0, -155.0, -140.0, -125.0, -110.0, -95.0 /)
2169      zlattao = (/  -8.0,  -5.0,  -2.0,   0.0,    2.0,    5.0,    8.0 /)
2170      CALL set_mooring( zlontao, zlattao )
2171      ! RAMA moorings (attributs: ibegin, jbegin, name_suffix)
2172      zlonrama = (/  55.0,  67.0, 80.5, 90.0 /)
2173      zlatrama = (/ -16.0, -12.0, -8.0, -4.0, -1.5, 0.0, 1.5, 4.0, 8.0, 12.0, 15.0 /)
2174      CALL set_mooring( zlonrama, zlatrama )
2175      ! PIRATA moorings (attributs: ibegin, jbegin, name_suffix)
2176      zlonpira = (/ -38.0, -23.0, -10.0 /)
2177      zlatpira = (/ -19.0, -14.0,  -8.0, 0.0, 4.0, 8.0, 12.0, 15.0, 20.0 /)
2178      CALL set_mooring( zlonpira, zlatpira )
2179      !
2180   END SUBROUTINE set_xmlatt
2181
2182
2183   SUBROUTINE set_mooring( plon, plat )
2184      !!----------------------------------------------------------------------
2185      !!                     ***  ROUTINE set_mooring  ***
2186      !!
2187      !! ** Purpose :   automatic definitions of moorings xml attributs...
2188      !!
2189      !!----------------------------------------------------------------------
2190      REAL(wp), DIMENSION(:), INTENT(in) ::   plon, plat   ! longitudes/latitudes oft the mooring
2191      !
2192!!$      CHARACTER(len=1),DIMENSION(4) ::   clgrd = (/ 'T', 'U', 'V', 'W' /)   ! suffix name
2193      CHARACTER(len=1),DIMENSION(1) ::   clgrd = (/ 'T' /)        ! suffix name
2194      CHARACTER(len=256)            ::   clname                   ! file name
2195      CHARACTER(len=256)            ::   clsuff                   ! suffix name
2196      CHARACTER(len=1)              ::   cl1                      ! 1 character
2197      CHARACTER(len=6)              ::   clon,clat                ! name of longitude, latitude
2198      INTEGER                       ::   ji, jj, jg               ! loop counters
2199      INTEGER                       ::   ix, iy                   ! i-,j- index
2200      REAL(wp)                      ::   zlon, zlat
2201      !!----------------------------------------------------------------------
2202      DO jg = 1, SIZE(clgrd)
2203         cl1 = clgrd(jg)
2204         DO ji = 1, SIZE(plon)
2205            DO jj = 1, SIZE(plat)
2206               zlon = plon(ji)
2207               zlat = plat(jj)
2208               ! modifications for RAMA moorings
2209               IF( zlon ==  67. .AND. zlat ==  15. )   zlon =  65.
2210               IF( zlon ==  90. .AND. zlat <=  -4. )   zlon =  95.
2211               IF( zlon ==  95. .AND. zlat ==  -4. )   zlat =  -5.
2212               ! modifications for PIRATA moorings
2213               IF( zlon == -38. .AND. zlat == -19. )   zlon = -34.
2214               IF( zlon == -38. .AND. zlat == -14. )   zlon = -32.
2215               IF( zlon == -38. .AND. zlat ==  -8. )   zlon = -30.
2216               IF( zlon == -38. .AND. zlat ==   0. )   zlon = -35.
2217               IF( zlon == -23. .AND. zlat ==  20. )   zlat =  21.
2218               IF( zlon == -10. .AND. zlat == -14. )   zlat = -10.
2219               IF( zlon == -10. .AND. zlat ==  -8. )   zlat =  -6.
2220               IF( zlon == -10. .AND. zlat ==   4. ) THEN   ;   zlon = 0.   ;   zlat = 0.   ;   ENDIF
2221               CALL dom_ngb( zlon, zlat, ix, iy, cl1 )
2222               IF( zlon >= 0. ) THEN 
2223                  IF( zlon == REAL(NINT(zlon), wp) ) THEN   ;   WRITE(clon, '(i3,  a)') NINT( zlon), 'e'
2224                  ELSE                                      ;   WRITE(clon, '(f5.1,a)')       zlon , 'e'
2225                  ENDIF
2226               ELSE             
2227                  IF( zlon == REAL(NINT(zlon), wp) ) THEN   ;   WRITE(clon, '(i3,  a)') NINT(-zlon), 'w'
2228                  ELSE                                      ;   WRITE(clon, '(f5.1,a)')      -zlon , 'w'
2229                  ENDIF
2230               ENDIF
2231               IF( zlat >= 0. ) THEN 
2232                  IF( zlat == REAL(NINT(zlat), wp) ) THEN   ;   WRITE(clat, '(i2,  a)') NINT( zlat), 'n'
2233                  ELSE                                      ;   WRITE(clat, '(f4.1,a)')       zlat , 'n'
2234                  ENDIF
2235               ELSE             
2236                  IF( zlat == REAL(NINT(zlat), wp) ) THEN   ;   WRITE(clat, '(i2,  a)') NINT(-zlat), 's'
2237                  ELSE                                      ;   WRITE(clat, '(f4.1,a)')      -zlat , 's'
2238                  ENDIF
2239               ENDIF
2240               clname = TRIM(ADJUSTL(clat))//TRIM(ADJUSTL(clon))
2241               CALL iom_set_zoom_domain_attr(TRIM(clname)//cl1, ibegin= ix-1, jbegin= iy-1, ni=1, nj=1)
2242
2243               CALL iom_get_file_attr   (TRIM(clname)//cl1, name_suffix = clsuff                         )
2244               CALL iom_set_file_attr   (TRIM(clname)//cl1, name_suffix = TRIM(clsuff)//'_'//TRIM(clname))
2245               CALL iom_update_file_name(TRIM(clname)//cl1)
2246            END DO
2247         END DO
2248      END DO
2249     
2250   END SUBROUTINE set_mooring
2251
2252   
2253   SUBROUTINE iom_update_file_name( cdid )
2254      !!----------------------------------------------------------------------
2255      !!                     ***  ROUTINE iom_update_file_name  ***
2256      !!
2257      !! ** Purpose :   
2258      !!
2259      !!----------------------------------------------------------------------
2260      CHARACTER(LEN=*)          , INTENT(in) ::   cdid
2261      !
2262      CHARACTER(LEN=256) ::   clname
2263      CHARACTER(LEN=20)  ::   clfreq
2264      CHARACTER(LEN=20)  ::   cldate
2265      INTEGER            ::   idx
2266      INTEGER            ::   jn
2267      INTEGER            ::   itrlen
2268      INTEGER            ::   iyear, imonth, iday, isec
2269      REAL(wp)           ::   zsec
2270      LOGICAL            ::   llexist
2271      TYPE(xios_duration)   ::   output_freq 
2272      !!----------------------------------------------------------------------
2273      !
2274      DO jn = 1, 2
2275         !
2276         output_freq = xios_duration(0,0,0,0,0,0)
2277         IF( jn == 1 )   CALL iom_get_file_attr( cdid, name        = clname, output_freq = output_freq )
2278         IF( jn == 2 )   CALL iom_get_file_attr( cdid, name_suffix = clname )
2279         !
2280         IF ( TRIM(clname) /= '' ) THEN 
2281            !
2282            idx = INDEX(clname,'@expname@') + INDEX(clname,'@EXPNAME@')
2283            DO WHILE ( idx /= 0 ) 
2284               clname = clname(1:idx-1)//TRIM(cexper)//clname(idx+9:LEN_TRIM(clname))
2285               idx = INDEX(clname,'@expname@') + INDEX(clname,'@EXPNAME@')
2286            END DO
2287            !
2288            idx = INDEX(clname,'@freq@') + INDEX(clname,'@FREQ@')
2289            DO WHILE ( idx /= 0 ) 
2290              IF ( output_freq%timestep /= 0) THEN
2291                  WRITE(clfreq,'(I18,A2)')INT(output_freq%timestep),'ts' 
2292                  itrlen = LEN_TRIM(ADJUSTL(clfreq))
2293              ELSE IF ( output_freq%second /= 0 ) THEN
2294                  WRITE(clfreq,'(I19,A1)')INT(output_freq%second),'s' 
2295                  itrlen = LEN_TRIM(ADJUSTL(clfreq))
2296              ELSE IF ( output_freq%minute /= 0 ) THEN
2297                  WRITE(clfreq,'(I18,A2)')INT(output_freq%minute),'mi' 
2298                  itrlen = LEN_TRIM(ADJUSTL(clfreq))
2299              ELSE IF ( output_freq%hour /= 0 ) THEN
2300                  WRITE(clfreq,'(I19,A1)')INT(output_freq%hour),'h' 
2301                  itrlen = LEN_TRIM(ADJUSTL(clfreq))
2302              ELSE IF ( output_freq%day /= 0 ) THEN
2303                  WRITE(clfreq,'(I19,A1)')INT(output_freq%day),'d' 
2304                  itrlen = LEN_TRIM(ADJUSTL(clfreq))
2305              ELSE IF ( output_freq%month /= 0 ) THEN   
2306                  WRITE(clfreq,'(I19,A1)')INT(output_freq%month),'m' 
2307                  itrlen = LEN_TRIM(ADJUSTL(clfreq))
2308              ELSE IF ( output_freq%year /= 0 ) THEN   
2309                  WRITE(clfreq,'(I19,A1)')INT(output_freq%year),'y' 
2310                  itrlen = LEN_TRIM(ADJUSTL(clfreq))
2311              ELSE
2312                  CALL ctl_stop('error in the name of file id '//TRIM(cdid),   &
2313                     & ' attribute output_freq is undefined -> cannot replace @freq@ in '//TRIM(clname) )
2314              ENDIF
2315              clname = clname(1:idx-1)//TRIM(ADJUSTL(clfreq))//clname(idx+6:LEN_TRIM(clname))
2316              idx = INDEX(clname,'@freq@') + INDEX(clname,'@FREQ@')
2317            END DO
2318            !
2319            idx = INDEX(clname,'@startdate@') + INDEX(clname,'@STARTDATE@')
2320            DO WHILE ( idx /= 0 ) 
2321               cldate = iom_sdate( fjulday - rn_Dt / rday )
2322               clname = clname(1:idx-1)//TRIM(cldate)//clname(idx+11:LEN_TRIM(clname))
2323               idx = INDEX(clname,'@startdate@') + INDEX(clname,'@STARTDATE@')
2324            END DO
2325            !
2326            idx = INDEX(clname,'@startdatefull@') + INDEX(clname,'@STARTDATEFULL@')
2327            DO WHILE ( idx /= 0 ) 
2328               cldate = iom_sdate( fjulday - rn_Dt / rday, ldfull = .TRUE. )
2329               clname = clname(1:idx-1)//TRIM(cldate)//clname(idx+15:LEN_TRIM(clname))
2330               idx = INDEX(clname,'@startdatefull@') + INDEX(clname,'@STARTDATEFULL@')
2331            END DO
2332            !
2333            idx = INDEX(clname,'@enddate@') + INDEX(clname,'@ENDDATE@')
2334            DO WHILE ( idx /= 0 ) 
2335               cldate = iom_sdate( fjulday + rn_Dt / rday * REAL( nitend - nit000, wp ), ld24 = .TRUE. )
2336               clname = clname(1:idx-1)//TRIM(cldate)//clname(idx+9:LEN_TRIM(clname))
2337               idx = INDEX(clname,'@enddate@') + INDEX(clname,'@ENDDATE@')
2338            END DO
2339            !
2340            idx = INDEX(clname,'@enddatefull@') + INDEX(clname,'@ENDDATEFULL@')
2341            DO WHILE ( idx /= 0 ) 
2342               cldate = iom_sdate( fjulday + rn_Dt / rday * REAL( nitend - nit000, wp ), ld24 = .TRUE., ldfull = .TRUE. )
2343               clname = clname(1:idx-1)//TRIM(cldate)//clname(idx+13:LEN_TRIM(clname))
2344               idx = INDEX(clname,'@enddatefull@') + INDEX(clname,'@ENDDATEFULL@')
2345            END DO
2346            !
2347            IF( jn == 1 .AND. TRIM(Agrif_CFixed()) /= '0' )   clname = TRIM(Agrif_CFixed())//"_"//TRIM(clname)
2348            IF( jn == 1 )   CALL iom_set_file_attr( cdid, name        = clname )
2349            IF( jn == 2 )   CALL iom_set_file_attr( cdid, name_suffix = clname )
2350            !
2351         ENDIF
2352         !
2353      END DO
2354      !
2355   END SUBROUTINE iom_update_file_name
2356
2357
2358   FUNCTION iom_sdate( pjday, ld24, ldfull )
2359      !!----------------------------------------------------------------------
2360      !!                     ***  ROUTINE iom_sdate  ***
2361      !!
2362      !! ** Purpose :   send back the date corresponding to the given julian day
2363      !!----------------------------------------------------------------------
2364      REAL(wp), INTENT(in   )           ::   pjday    ! julian day
2365      LOGICAL , INTENT(in   ), OPTIONAL ::   ld24     ! true to force 24:00 instead of 00:00
2366      LOGICAL , INTENT(in   ), OPTIONAL ::   ldfull   ! true to get the compleate date: yyyymmdd_hh:mm:ss
2367      !
2368      CHARACTER(LEN=20) ::   iom_sdate
2369      CHARACTER(LEN=50) ::   clfmt                         !  format used to write the date
2370      INTEGER           ::   iyear, imonth, iday, ihour, iminute, isec
2371      REAL(wp)          ::   zsec
2372      LOGICAL           ::   ll24, llfull
2373      !!----------------------------------------------------------------------
2374      !
2375      IF( PRESENT(ld24) ) THEN   ;   ll24 = ld24
2376      ELSE                       ;   ll24 = .FALSE.
2377      ENDIF
2378      !
2379      IF( PRESENT(ldfull) ) THEN   ;   llfull = ldfull
2380      ELSE                         ;   llfull = .FALSE.
2381      ENDIF
2382      !
2383      CALL ju2ymds( pjday, iyear, imonth, iday, zsec )
2384      isec = NINT(zsec)
2385      !
2386      IF ( ll24 .AND. isec == 0 ) THEN   ! 00:00 of the next day -> move to 24:00 of the current day
2387         CALL ju2ymds( pjday - 1., iyear, imonth, iday, zsec )
2388         isec = 86400
2389      ENDIF
2390      !
2391      IF( iyear < 10000 ) THEN   ;   clfmt = "i4.4,2i2.2"                ! format used to write the date
2392      ELSE                       ;   WRITE(clfmt, "('i',i1,',2i2.2')") INT(LOG10(REAL(iyear,wp))) + 1
2393      ENDIF
2394      !
2395!$AGRIF_DO_NOT_TREAT     
2396      ! needed in the conv
2397      IF( llfull ) THEN
2398         clfmt = TRIM(clfmt)//",'_',i2.2,':',i2.2,':',i2.2"
2399         ihour   = isec / 3600
2400         isec    = MOD(isec, 3600)
2401         iminute = isec / 60
2402         isec    = MOD(isec, 60)
2403         WRITE(iom_sdate, '('//TRIM(clfmt)//')') iyear, imonth, iday, ihour, iminute, isec    ! date of the end of run
2404      ELSE
2405         WRITE(iom_sdate, '('//TRIM(clfmt)//')') iyear, imonth, iday                          ! date of the end of run
2406      ENDIF
2407!$AGRIF_END_DO_NOT_TREAT     
2408      !
2409   END FUNCTION iom_sdate
2410
2411#else
2412   !!----------------------------------------------------------------------
2413   !!   NOT 'key_iomput'                               a few dummy routines
2414   !!----------------------------------------------------------------------
2415   SUBROUTINE iom_setkt( kt, cdname )
2416      INTEGER         , INTENT(in)::   kt 
2417      CHARACTER(LEN=*), INTENT(in) ::   cdname
2418      IF( .FALSE. )   WRITE(numout,*) kt, cdname   ! useless test to avoid compilation warnings
2419   END SUBROUTINE iom_setkt
2420
2421   SUBROUTINE iom_context_finalize( cdname )
2422      CHARACTER(LEN=*), INTENT(in) ::   cdname
2423      IF( .FALSE. )   WRITE(numout,*)  cdname   ! useless test to avoid compilation warnings
2424   END SUBROUTINE iom_context_finalize
2425
2426   SUBROUTINE iom_update_file_name( cdid )
2427      CHARACTER(LEN=*), INTENT(in) ::   cdid
2428      IF( .FALSE. )   WRITE(numout,*)  cdid   ! useless test to avoid compilation warnings
2429   END SUBROUTINE iom_update_file_name
2430
2431#endif
2432
2433   LOGICAL FUNCTION iom_use( cdname )
2434      CHARACTER(LEN=*), INTENT(in) ::   cdname
2435#if defined key_iomput
2436      iom_use = xios_field_is_active( cdname )
2437#else
2438      iom_use = .FALSE.
2439#endif
2440   END FUNCTION iom_use
2441
2442   SUBROUTINE iom_miss_val( cdname, pmiss_val )
2443      CHARACTER(LEN=*), INTENT(in ) ::   cdname
2444      REAL(wp)        , INTENT(out) ::   pmiss_val   
2445#if defined key_iomput
2446      ! get missing value
2447      CALL xios_get_field_attr( cdname, default_value = pmiss_val )
2448#else
2449      IF( .FALSE. )   WRITE(numout,*) cdname, pmiss_val   ! useless test to avoid compilation warnings
2450      IF( .FALSE. )   pmiss_val = 0._wp                   ! useless assignment to avoid compilation warnings
2451#endif
2452   END SUBROUTINE iom_miss_val
2453 
2454   !!======================================================================
2455END MODULE iom
Note: See TracBrowser for help on using the repository browser.