source: NEMO/branches/2020/dev_12905_xios_restart/src/OFF/nemogcm.F90 @ 13000

Last change on this file since 13000 was 13000, checked in by andmirek, 12 months ago

Ticket #2462 restart read/write with XIOS in ORCA2_OFF_PISCES

  • Property svn:keywords set to Id
File size: 29.8 KB
Line 
1MODULE nemogcm
2   !!======================================================================
3   !!                       ***  MODULE nemogcm   ***
4   !! Off-line Ocean   : passive tracer evolution, dynamics read in files
5   !!======================================================================
6   !! History :  3.3  ! 2010-05  (C. Ethe)  Full reorganization of the off-line: phasing with the on-line
7   !!            3.4  ! 2011-01  (C. Ethe, A. R. Porter, STFC Daresbury) dynamical allocation
8   !!            4.0  ! 2016-10  (C. Ethe, G. Madec, S. Flavoni)  domain configuration / user defined interface
9   !!            4.1  ! 2019-08  (A. Coward, D. Storkey) rewrite in preparation for new timestepping scheme
10   !!----------------------------------------------------------------------
11
12   !!----------------------------------------------------------------------
13   !!   nemo_gcm      : off-line: solve ocean tracer only
14   !!   nemo_gcm      : solve ocean dynamics, tracer, biogeochemistry and/or sea-ice
15   !!   nemo_init     : initialization of the NEMO system
16   !!   nemo_ctl      : initialisation of the contol print
17   !!   nemo_closefile: close remaining open files
18   !!   nemo_alloc    : dynamical allocation
19   !!   istate_init   : simple initialization to zero of ocean fields
20   !!   stp_ctl       : reduced step control (no dynamics in off-line)
21   !!----------------------------------------------------------------------
22   USE dom_oce        ! ocean space domain variables
23   USE oce            ! dynamics and tracers variables
24   USE trc_oce        ! Shared ocean/passive tracers variables
25   USE c1d            ! 1D configuration
26   USE domain         ! domain initialization from coordinate & bathymetry (dom_init routine)
27   USE closea         ! treatment of closed seas (for ln_closea)
28   USE usrdef_nam     ! user defined configuration
29   USE eosbn2         ! equation of state            (eos bn2 routine)
30   USE bdy_oce,  ONLY : ln_bdy
31   USE bdyini         ! open boundary cond. setting       (bdy_init routine)
32   !              ! ocean physics
33   USE ldftra         ! lateral diffusivity setting    (ldf_tra_init routine)
34   USE ldfslp         ! slopes of neutral surfaces     (ldf_slp_init routine)
35   USE traqsr         ! solar radiation penetration    (tra_qsr_init routine)
36   USE trabbl         ! bottom boundary layer          (tra_bbl_init routine)
37   USE traldf         ! lateral physics                (tra_ldf_init routine)
38   USE sbcmod         ! surface boundary condition     (sbc_init     routine)
39   USE phycst         ! physical constant                   (par_cst routine)
40   USE dtadyn         ! Lecture and Interpolation of the dynamical fields
41   USE trcini         ! Initilization of the passive tracers
42   USE daymod         ! calendar                            (day     routine)
43   USE trcstp         ! passive tracer time-stepping        (trc_stp routine)
44   USE dtadyn         ! Lecture and interpolation of the dynamical fields
45   !              ! Passive tracers needs
46   USE trc            ! passive tracer : variables
47   USE trcnam         ! passive tracer : namelist
48   USE trcrst         ! passive tracer restart
49   USE diaptr         ! Need to initialise this as some variables are used in if statements later
50   USE sbc_oce , ONLY : ln_rnf
51   USE sbcrnf         ! surface boundary condition : runoffs
52   !              ! I/O & MPP
53   USE iom            ! I/O library
54   USE in_out_manager ! I/O manager
55   USE mppini         ! shared/distributed memory setting (mpp_init routine)
56   USE lib_mpp        ! distributed memory computing
57#if defined key_iomput
58   USE xios           ! xIOserver
59#endif
60   USE prtctl         ! Print control                    (prt_ctl_init routine)
61   USE timing         ! Timing
62   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined)
63   USE lbcnfd  , ONLY : isendto, nsndto, nfsloop, nfeloop   ! Setup of north fold exchanges
64   USE step, ONLY : Nbb, Nnn, Naa, Nrhs   ! time level indices
65
66   IMPLICIT NONE
67   PRIVATE
68   
69   PUBLIC   nemo_gcm   ! called by nemo.F90
70
71   CHARACTER (len=64) ::   cform_aaa="( /, 'AAAAAAAA', / ) "   ! flag for output listing
72
73   !!----------------------------------------------------------------------
74   !! NEMO/OFF 4.0 , NEMO Consortium (2018)
75   !! $Id$
76   !! Software governed by the CeCILL license (see ./LICENSE)
77   !!----------------------------------------------------------------------
78CONTAINS
79
80   SUBROUTINE nemo_gcm
81      !!----------------------------------------------------------------------
82      !!                     ***  ROUTINE nemo_gcm  ***
83      !!
84      !! ** Purpose :   NEMO solves the primitive equations on an orthogonal
85      !!              curvilinear mesh on the sphere.
86      !!
87      !! ** Method  : - model general initialization
88      !!              - launch the time-stepping (dta_dyn and trc_stp)
89      !!              - finalize the run by closing files and communications
90      !!
91      !! References : Madec, Delecluse,Imbard, and Levy, 1997:  internal report, IPSL.
92      !!              Madec, 2008, internal report, IPSL.
93      !!----------------------------------------------------------------------
94      INTEGER :: istp, indic       ! time step index
95      !!----------------------------------------------------------------------
96
97      CALL nemo_init  ! Initializations
98
99      ! check that all process are still there... If some process have an error,
100      ! they will never enter in step and other processes will wait until the end of the cpu time!
101      CALL mpp_max( 'nemogcm', nstop )
102
103      !                            !-----------------------!
104      !                            !==   time stepping   ==!
105      !                            !-----------------------!
106      istp = nit000
107      !
108      IF( ln_rnf )   CALL sbc_rnf(istp)   ! runoffs initialization
109      !
110      CALL iom_init( cxios_context )      ! iom_put initialization (must be done after nemo_init for AGRIF+XIOS+OASIS)
111      !
112      DO WHILE ( istp <= nitend .AND. nstop == 0 )    !==  OFF time-stepping  ==!
113         !
114      IF((istp == nitrst) .AND. lwxios) THEN
115         CALL iom_swap(      cwtxios_context          )
116         CALL iom_init_closedef(cwtxios_context)
117         CALL iom_setkt( istp - nit000 + 1,      cwtxios_context          )
118      ENDIF
119
120         IF( istp /= nit000 )   CALL day        ( istp )         ! Calendar (day was already called at nit000 in day_init)
121                                CALL iom_setkt  ( istp - nit000 + 1, cxios_context )   ! say to iom that we are at time step kstp
122#if defined key_sed_off
123                                CALL dta_dyn_sed( istp,      Nnn      )       ! Interpolation of the dynamical fields
124#else
125                                CALL dta_dyn    ( istp, Nbb, Nnn, Naa )       ! Interpolation of the dynamical fields
126#endif
127                                CALL trc_stp    ( istp, Nbb, Nnn, Nrhs, Naa ) ! time-stepping
128#if ! defined key_sed_off
129         IF( .NOT.ln_linssh )   CALL dta_dyn_atf( istp, Nbb, Nnn, Naa )       ! time filter of sea  surface height and vertical scale factors
130#endif
131         ! Swap time levels
132         Nrhs = Nbb
133         Nbb = Nnn
134         Nnn = Naa
135         Naa = Nrhs
136         !
137#if ! defined key_sed_off
138         IF( .NOT.ln_linssh )   CALL dta_dyn_sf_interp( istp, Nnn )  ! calculate now grid parameters
139#endif
140                                CALL stp_ctl    ( istp, indic )  ! Time loop: control and print
141         istp = istp + 1
142      END DO
143      !
144#if defined key_iomput
145      CALL iom_context_finalize( cxios_context ) ! needed for XIOS+AGRIF
146#endif
147
148      !                            !------------------------!
149      !                            !==  finalize the run  ==!
150      !                            !------------------------!
151      IF(lwp) WRITE(numout,cform_aaa)                 ! Flag AAAAAAA
152
153      IF( nstop /= 0 .AND. lwp ) THEN                 ! error print
154         WRITE(ctmp1,*) '   ==>>>   nemo_gcm: a total of ', nstop, ' errors have been found'
155         CALL ctl_stop( ctmp1 )
156      ENDIF
157      !
158      IF( ln_timing )   CALL timing_finalize
159      !
160      CALL nemo_closefile
161      !
162#if defined key_iomput
163                     CALL xios_finalize   ! end mpp communications with xios
164#else
165      IF( lk_mpp )   CALL mppstop         ! end mpp communications
166#endif
167      !
168      IF(lwm) THEN
169         IF( nstop == 0 ) THEN   ;   STOP 0
170         ELSE                    ;   STOP 123
171         ENDIF
172      ENDIF
173      !
174   END SUBROUTINE nemo_gcm
175
176
177   SUBROUTINE nemo_init
178      !!----------------------------------------------------------------------
179      !!                     ***  ROUTINE nemo_init  ***
180      !!
181      !! ** Purpose :   initialization of the nemo model in off-line mode
182      !!----------------------------------------------------------------------
183      INTEGER ::   ios, ilocal_comm   ! local integers
184      !!
185      NAMELIST/namctl/ sn_cfctl, nn_print, nn_ictls, nn_ictle,              &
186         &             nn_isplt , nn_jsplt, nn_jctls, nn_jctle,             &
187         &             ln_timing, ln_diacfl
188      NAMELIST/namcfg/ ln_read_cfg, cn_domcfg, ln_closea, ln_write_cfg, cn_domcfg_out, ln_use_jattr
189      !!----------------------------------------------------------------------
190      !
191      cxios_context = 'nemo'
192      !
193      !                             !-------------------------------------------------!
194      !                             !     set communicator & select the local rank    !
195      !                             !  must be done as soon as possible to get narea  !
196      !                             !-------------------------------------------------!
197      !
198#if defined key_iomput
199      CALL xios_initialize( "for_xios_mpi_id", return_comm=ilocal_comm )   ! nemo local communicator given by xios
200      CALL mpp_start( ilocal_comm )
201#else
202      CALL mpp_start( )
203#endif
204      !
205      narea = mpprank + 1               ! mpprank: the rank of proc (0 --> mppsize -1 )
206      lwm = (narea == 1)                ! control of output namelists
207      !
208      !                             !---------------------------------------------------------------!
209      !                             ! Open output files, reference and configuration namelist files !
210      !                             !---------------------------------------------------------------!
211      !
212      ! open ocean.output as soon as possible to get all output prints (including errors messages)
213      IF( lwm )   CALL ctl_opn(     numout,        'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. )
214      ! open reference and configuration namelist files
215                  CALL load_nml( numnam_ref,        'namelist_ref',                                           -1, lwm )
216                  CALL load_nml( numnam_cfg,        'namelist_cfg',                                           -1, lwm )
217      IF( lwm )   CALL ctl_opn(     numond, 'output.namelist.dyn', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. )
218      ! open /dev/null file to be able to supress output write easily
219      IF( Agrif_Root() ) THEN
220                  CALL ctl_opn(     numnul,           '/dev/null', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. )
221#ifdef key_agrif
222      ELSE
223                  numnul = Agrif_Parent(numnul)   
224#endif
225      ENDIF
226      !
227      !                             !--------------------!
228      !                             ! Open listing units !  -> need sn_cfctl from namctl to define lwp
229      !                             !--------------------!
230      !
231      READ  ( numnam_ref, namctl, IOSTAT = ios, ERR = 901 )
232901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namctl in reference namelist' )
233      READ  ( numnam_cfg, namctl, IOSTAT = ios, ERR = 902 )
234902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namctl in configuration namelist' )
235      !
236      ! finalize the definition of namctl variables
237      IF( sn_cfctl%l_allon ) THEN
238         ! Turn on all options.
239         CALL nemo_set_cfctl( sn_cfctl, .TRUE., .TRUE. )
240         ! Ensure all processors are active
241         sn_cfctl%procmin = 0 ; sn_cfctl%procmax = 1000000 ; sn_cfctl%procincr = 1
242      ELSEIF( sn_cfctl%l_config ) THEN
243         ! Activate finer control of report outputs
244         ! optionally switch off output from selected areas (note this only
245         ! applies to output which does not involve global communications)
246         IF( ( narea < sn_cfctl%procmin .OR. narea > sn_cfctl%procmax  ) .OR. &
247           & ( MOD( narea - sn_cfctl%procmin, sn_cfctl%procincr ) /= 0 ) )    &
248           &   CALL nemo_set_cfctl( sn_cfctl, .FALSE., .FALSE. )
249      ELSE
250         ! turn off all options.
251         CALL nemo_set_cfctl( sn_cfctl, .FALSE., .TRUE. )
252      ENDIF
253      !
254      lwp = (narea == 1) .OR. sn_cfctl%l_oceout    ! control of all listing output print
255      !
256      IF(lwp) THEN                            ! open listing units
257         !
258         IF( .NOT. lwm )   &           ! alreay opened for narea == 1
259            &     CALL ctl_opn(     numout,        'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE., narea )
260         !
261         WRITE(numout,*)
262         WRITE(numout,*) '   CNRS - NERC - Met OFFICE - MERCATOR-ocean - CMCC'
263         WRITE(numout,*) '                       NEMO team'
264         WRITE(numout,*) '                   Off-line TOP Model'
265         WRITE(numout,*) '                NEMO version 4.0  (2019) '
266         WRITE(numout,*)
267         WRITE(numout,*) "           ._      ._      ._      ._      ._    "
268         WRITE(numout,*) "       _.-._)`\_.-._)`\_.-._)`\_.-._)`\_.-._)`\_ "
269         WRITE(numout,*)
270         WRITE(numout,*) "           o         _,           _,             "
271         WRITE(numout,*) "            o      .' (        .-' /             "
272         WRITE(numout,*) "           o     _/..._'.    .'   /              "
273         WRITE(numout,*) "      (    o .-'`      ` '-./  _.'               "
274         WRITE(numout,*) "       )    ( o)           ;= <_         (       "
275         WRITE(numout,*) "      (      '-.,\\__ __.-;`\   '.        )      "
276         WRITE(numout,*) "       )  )       \) |`\ \)  '.   \      (   (   "
277         WRITE(numout,*) "      (  (           \_/       '-._\      )   )  "
278         WRITE(numout,*) "       )  )                        `     (   (   "
279         WRITE(numout,*) "     ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^ "
280         WRITE(numout,*)
281         !
282         WRITE(numout,cform_aaa)                                        ! Flag AAAAAAA
283         !
284      ENDIF
285      !
286      IF(lwm) WRITE( numond, namctl )
287      !
288      !                             !------------------------------------!
289      !                             !  Set global domain size parameters !
290      !                             !------------------------------------!
291      !     
292      READ  ( numnam_ref, namcfg, IOSTAT = ios, ERR = 903 )
293903   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namcfg in reference namelist' )
294      READ  ( numnam_cfg, namcfg, IOSTAT = ios, ERR = 904 )
295904   IF( ios >  0 )   CALL ctl_nam ( ios , 'namcfg in configuration namelist' )   
296      !
297      IF( ln_read_cfg ) THEN              ! Read sizes in domain configuration file
298         CALL domain_cfg ( cn_cfg, nn_cfg, jpiglo, jpjglo, jpkglo, jperio )
299      ELSE                                ! user-defined namelist
300         CALL usr_def_nam( cn_cfg, nn_cfg, jpiglo, jpjglo, jpkglo, jperio )
301      ENDIF
302      !
303      IF(lwm)   WRITE( numond, namcfg )
304      l_offline = .true.                  ! passive tracers are run offline
305      !
306      !                             !-----------------------------------------!
307      !                             ! mpp parameters and domain decomposition !
308      !                             !-----------------------------------------!
309      !
310      CALL mpp_init
311
312      ! Now we know the dimensions of the grid and numout has been set: we can allocate arrays
313      CALL nemo_alloc()
314
315      ! Initialise time level indices
316      Nbb = 1; Nnn = 2; Naa = 3; Nrhs = Naa
317
318      !                             !-------------------------------!
319      !                             !  NEMO general initialization  !
320      !                             !-------------------------------!
321
322      CALL nemo_ctl                          ! Control prints
323      !
324      !                                      ! General initialization
325      IF( ln_timing    )   CALL timing_init
326      IF( ln_timing    )   CALL timing_start( 'nemo_init')
327      !
328                           CALL     phy_cst         ! Physical constants
329                           CALL     eos_init        ! Equation of state
330      IF( lk_c1d       )   CALL     c1d_init        ! 1D column configuration
331                           CALL     dom_init( Nbb, Nnn, Naa ) ! Domain
332      IF( sn_cfctl%l_prtctl )   &
333         &                 CALL prt_ctl_init        ! Print control
334
335                           CALL  istate_init( Nnn, Naa )    ! ocean initial state (Dynamics and tracers)
336
337                           CALL     sbc_init( Nbb, Nnn, Naa )    ! Forcings : surface module
338                           CALL     bdy_init    ! Open boundaries initialisation   
339
340      !                                      ! Tracer physics
341                           CALL ldf_tra_init    ! Lateral ocean tracer physics
342                           CALL ldf_eiv_init    ! Eddy induced velocity param
343                           CALL tra_ldf_init    ! lateral mixing
344      IF( l_ldfslp     )   CALL ldf_slp_init    ! slope of lateral mixing
345      IF( ln_traqsr    )   CALL tra_qsr_init    ! penetrative solar radiation
346      IF( ln_trabbl    )   CALL tra_bbl_init    ! advective (and/or diffusive) bottom boundary layer scheme
347
348      !                                      ! Passive tracers
349                           CALL trc_nam_run    ! Needed to get restart parameters for passive tracers
350                           CALL trc_rst_cal( nit000, 'READ' )   ! calendar
351#if defined key_sed_off
352                           CALL dta_dyn_sed_init(  Nnn      )        ! Initialization for the dynamics
353#else
354                           CALL dta_dyn_init( Nbb, Nnn, Naa )        ! Initialization for the dynamics
355#endif
356
357                           CALL     trc_init( Nbb, Nnn, Naa )        ! Passive tracers initialization
358                           CALL dia_ptr_init   ! Poleward TRansports initialization
359                           
360      IF(lwp) WRITE(numout,cform_aaa)           ! Flag AAAAAAA
361      !
362      IF( ln_timing    )   CALL timing_stop( 'nemo_init')
363      !
364   END SUBROUTINE nemo_init
365
366
367   SUBROUTINE nemo_ctl
368      !!----------------------------------------------------------------------
369      !!                     ***  ROUTINE nemo_ctl  ***
370      !!
371      !! ** Purpose :   control print setting
372      !!
373      !! ** Method  : - print namctl and namcfg information and check some consistencies
374      !!----------------------------------------------------------------------
375      !
376      IF(lwp) THEN                  ! control print
377         WRITE(numout,*)
378         WRITE(numout,*) 'nemo_ctl: Control prints'
379         WRITE(numout,*) '~~~~~~~~'
380         WRITE(numout,*) '   Namelist namctl'
381         WRITE(numout,*) '                              sn_cfctl%l_glochk  = ', sn_cfctl%l_glochk
382         WRITE(numout,*) '                              sn_cfctl%l_allon   = ', sn_cfctl%l_allon
383         WRITE(numout,*) '       finer control over o/p sn_cfctl%l_config  = ', sn_cfctl%l_config
384         WRITE(numout,*) '                              sn_cfctl%l_runstat = ', sn_cfctl%l_runstat
385         WRITE(numout,*) '                              sn_cfctl%l_trcstat = ', sn_cfctl%l_trcstat
386         WRITE(numout,*) '                              sn_cfctl%l_oceout  = ', sn_cfctl%l_oceout
387         WRITE(numout,*) '                              sn_cfctl%l_layout  = ', sn_cfctl%l_layout
388         WRITE(numout,*) '                              sn_cfctl%l_prtctl  = ', sn_cfctl%l_prtctl
389         WRITE(numout,*) '                              sn_cfctl%l_prttrc  = ', sn_cfctl%l_prttrc
390         WRITE(numout,*) '                              sn_cfctl%l_oasout  = ', sn_cfctl%l_oasout
391         WRITE(numout,*) '                              sn_cfctl%procmin   = ', sn_cfctl%procmin 
392         WRITE(numout,*) '                              sn_cfctl%procmax   = ', sn_cfctl%procmax 
393         WRITE(numout,*) '                              sn_cfctl%procincr  = ', sn_cfctl%procincr 
394         WRITE(numout,*) '                              sn_cfctl%ptimincr  = ', sn_cfctl%ptimincr 
395         WRITE(numout,*) '      level of print                  nn_print   = ', nn_print
396         WRITE(numout,*) '      Start i indice for SUM control  nn_ictls   = ', nn_ictls
397         WRITE(numout,*) '      End i indice for SUM control    nn_ictle   = ', nn_ictle
398         WRITE(numout,*) '      Start j indice for SUM control  nn_jctls   = ', nn_jctls
399         WRITE(numout,*) '      End j indice for SUM control    nn_jctle   = ', nn_jctle
400         WRITE(numout,*) '      number of proc. following i     nn_isplt   = ', nn_isplt
401         WRITE(numout,*) '      number of proc. following j     nn_jsplt   = ', nn_jsplt
402         WRITE(numout,*) '      timing by routine               ln_timing  = ', ln_timing
403         WRITE(numout,*) '      CFL diagnostics                 ln_diacfl  = ', ln_diacfl
404      ENDIF
405      !
406      nprint    = nn_print          ! convert DOCTOR namelist names into OLD names
407      nictls    = nn_ictls
408      nictle    = nn_ictle
409      njctls    = nn_jctls
410      njctle    = nn_jctle
411      isplt     = nn_isplt
412      jsplt     = nn_jsplt
413
414      IF(lwp) THEN                  ! control print
415         WRITE(numout,*)
416         WRITE(numout,*) '   Namelist namcfg'
417         WRITE(numout,*) '      read domain configuration file              ln_read_cfg      = ', ln_read_cfg
418         WRITE(numout,*) '         filename to be read                         cn_domcfg     = ', TRIM(cn_domcfg)
419         WRITE(numout,*) '         keep closed seas in the domain (if exist)   ln_closea     = ', ln_closea
420         WRITE(numout,*) '      create a configuration definition file      ln_write_cfg     = ', ln_write_cfg
421         WRITE(numout,*) '         filename to be written                      cn_domcfg_out = ', TRIM(cn_domcfg_out)
422         WRITE(numout,*) '      use file attribute if exists as i/p j-start ln_use_jattr     = ', ln_use_jattr
423      ENDIF
424      IF( .NOT.ln_read_cfg )   ln_closea = .false.   ! dealing possible only with a domcfg file
425      !
426      !                             ! Parameter control
427      !
428      IF( sn_cfctl%l_prtctl .OR. sn_cfctl%l_prttrc ) THEN              ! sub-domain area indices for the control prints
429         IF( lk_mpp .AND. jpnij > 1 ) THEN
430            isplt = jpni   ;   jsplt = jpnj   ;   ijsplt = jpni*jpnj   ! the domain is forced to the real split domain
431         ELSE
432            IF( isplt == 1 .AND. jsplt == 1  ) THEN
433               CALL ctl_warn( ' - isplt & jsplt are equal to 1',   &
434                  &           ' - the print control will be done over the whole domain' )
435            ENDIF
436            ijsplt = isplt * jsplt            ! total number of processors ijsplt
437         ENDIF
438         IF(lwp) WRITE(numout,*)'          - The total number of processors over which the'
439         IF(lwp) WRITE(numout,*)'            print control will be done is ijsplt : ', ijsplt
440         !
441         !                              ! indices used for the SUM control
442         IF( nictls+nictle+njctls+njctle == 0 )   THEN    ! print control done over the default area
443            lsp_area = .FALSE.
444         ELSE                                             ! print control done over a specific  area
445            lsp_area = .TRUE.
446            IF( nictls < 1 .OR. nictls > jpiglo )   THEN
447               CALL ctl_warn( '          - nictls must be 1<=nictls>=jpiglo, it is forced to 1' )
448               nictls = 1
449            ENDIF
450            IF( nictle < 1 .OR. nictle > jpiglo )   THEN
451               CALL ctl_warn( '          - nictle must be 1<=nictle>=jpiglo, it is forced to jpiglo' )
452               nictle = jpiglo
453            ENDIF
454            IF( njctls < 1 .OR. njctls > jpjglo )   THEN
455               CALL ctl_warn( '          - njctls must be 1<=njctls>=jpjglo, it is forced to 1' )
456               njctls = 1
457            ENDIF
458            IF( njctle < 1 .OR. njctle > jpjglo )   THEN
459               CALL ctl_warn( '          - njctle must be 1<=njctle>=jpjglo, it is forced to jpjglo' )
460               njctle = jpjglo
461            ENDIF
462         ENDIF
463      ENDIF
464      !
465      IF( 1._wp /= SIGN(1._wp,-0._wp)  )   CALL ctl_stop( 'nemo_ctl: The intrinsec SIGN function follows f2003 standard.',  &
466         &                                                'Compile with key_nosignedzero enabled' )
467      !
468   END SUBROUTINE nemo_ctl
469
470
471   SUBROUTINE nemo_closefile
472      !!----------------------------------------------------------------------
473      !!                     ***  ROUTINE nemo_closefile  ***
474      !!
475      !! ** Purpose :   Close the files
476      !!----------------------------------------------------------------------
477      !
478      IF( lk_mpp )   CALL mppsync
479      !
480      CALL iom_close                                 ! close all input/output files managed by iom_*
481      !
482      IF( numstp     /= -1 )   CLOSE( numstp     )   ! time-step file
483      IF( lwm.AND.numond  /= -1 )   CLOSE( numond          )   ! oce output namelist
484      !
485      numout = 6                                     ! redefine numout in case it is used after this point...
486      !
487   END SUBROUTINE nemo_closefile
488
489
490   SUBROUTINE nemo_alloc
491      !!----------------------------------------------------------------------
492      !!                     ***  ROUTINE nemo_alloc  ***
493      !!
494      !! ** Purpose :   Allocate all the dynamic arrays of the OPA modules
495      !!
496      !! ** Method  :
497      !!----------------------------------------------------------------------
498      USE diawri ,   ONLY : dia_wri_alloc
499      USE dom_oce,   ONLY : dom_oce_alloc
500      USE zdf_oce,   ONLY : zdf_oce_alloc
501      USE trc_oce,   ONLY : trc_oce_alloc
502      USE bdy_oce,   ONLY : bdy_oce_alloc
503      !
504      INTEGER :: ierr
505      !!----------------------------------------------------------------------
506      !
507      ierr =        oce_alloc    ()          ! ocean
508      ierr = ierr + dia_wri_alloc()
509      ierr = ierr + dom_oce_alloc()          ! ocean domain
510      ierr = ierr + zdf_oce_alloc()          ! ocean vertical physics
511      ierr = ierr + trc_oce_alloc()          ! shared TRC / TRA arrays
512      ierr = ierr + bdy_oce_alloc()    ! bdy masks (incl. initialization)     
513      !
514      CALL mpp_sum( 'nemogcm', ierr )
515      IF( ierr /= 0 )   CALL ctl_stop( 'STOP', 'nemo_alloc: unable to allocate standard ocean arrays' )
516      !
517   END SUBROUTINE nemo_alloc
518
519   SUBROUTINE nemo_set_cfctl(sn_cfctl, setto, for_all )
520      !!----------------------------------------------------------------------
521      !!                     ***  ROUTINE nemo_set_cfctl  ***
522      !!
523      !! ** Purpose :   Set elements of the output control structure to setto.
524      !!                for_all should be .false. unless all areas are to be
525      !!                treated identically.
526      !!
527      !! ** Method  :   Note this routine can be used to switch on/off some
528      !!                types of output for selected areas but any output types
529      !!                that involve global communications (e.g. mpp_max, glob_sum)
530      !!                should be protected from selective switching by the
531      !!                for_all argument
532      !!----------------------------------------------------------------------
533      LOGICAL :: setto, for_all
534      TYPE(sn_ctl) :: sn_cfctl
535      !!----------------------------------------------------------------------
536      IF( for_all ) THEN
537         sn_cfctl%l_runstat = setto
538         sn_cfctl%l_trcstat = setto
539      ENDIF
540      sn_cfctl%l_oceout  = setto
541      sn_cfctl%l_layout  = setto
542      sn_cfctl%l_prtctl  = setto
543      sn_cfctl%l_prttrc  = setto
544      sn_cfctl%l_oasout  = setto
545   END SUBROUTINE nemo_set_cfctl
546
547   SUBROUTINE istate_init( Kmm, Kaa )
548      !!----------------------------------------------------------------------
549      !!                   ***  ROUTINE istate_init  ***
550      !!
551      !! ** Purpose :   Initialization to zero of the dynamics and tracers.
552      !!----------------------------------------------------------------------
553      INTEGER, INTENT(in) ::   Kmm, Kaa  ! ocean time level indices
554      !
555      !     now fields         !     after fields      !
556      uu   (:,:,:,Kmm)   = 0._wp   ;   uu(:,:,:,Kaa) = 0._wp   !
557      vv   (:,:,:,Kmm)   = 0._wp   ;   vv(:,:,:,Kaa) = 0._wp   !
558      ww   (:,:,:)   = 0._wp   !                       !
559      hdiv (:,:,:)   = 0._wp   !                       !
560      ts  (:,:,:,:,Kmm) = 0._wp   !                       !
561      !
562      rhd  (:,:,:) = 0.e0
563      rhop (:,:,:) = 0.e0
564      rn2  (:,:,:) = 0.e0
565      !
566   END SUBROUTINE istate_init
567
568
569   SUBROUTINE stp_ctl( kt, kindic )
570      !!----------------------------------------------------------------------
571      !!                    ***  ROUTINE stp_ctl  ***
572      !!
573      !! ** Purpose :   Control the run
574      !!
575      !! ** Method  : - Save the time step in numstp
576      !!
577      !! ** Actions :   'time.step' file containing the last ocean time-step
578      !!----------------------------------------------------------------------
579      INTEGER, INTENT(in   ) ::   kt      ! ocean time-step index
580      INTEGER, INTENT(inout) ::   kindic  ! indicator of solver convergence
581      !!----------------------------------------------------------------------
582      !
583      IF( kt == nit000 .AND. lwm ) THEN
584         WRITE(numout,*)
585         WRITE(numout,*) 'stp_ctl : time-stepping control'
586         WRITE(numout,*) '~~~~~~~'
587         ! open time.step file
588         CALL ctl_opn( numstp, 'time.step', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, numout, lwp, narea )
589      ENDIF
590      !
591      IF(lwm) WRITE ( numstp, '(1x, i8)' )   kt      !* save the current time step in numstp
592      IF(lwm) REWIND( numstp )                       ! --------------------------
593      !
594   END SUBROUTINE stp_ctl
595   !!======================================================================
596END MODULE nemogcm
Note: See TracBrowser for help on using the repository browser.