source: NEMO/branches/2020/dev_r12377_KERNEL-06_techene_e3/src/OCE/BDY/bdydta.F90 @ 12680

Last change on this file since 12680 was 12680, checked in by techene, 8 months ago

dynatfQCO.F90, stepLF.F90 : fixed (remove pe3. from dyn_atf_qco input arguments), all : remove e3. tables and include gurvan's feedbacks

  • Property svn:keywords set to Id
File size: 39.9 KB
Line 
1MODULE bdydta
2   !!======================================================================
3   !!                       ***  MODULE bdydta  ***
4   !! Open boundary data : read the data for the unstructured open boundaries.
5   !!======================================================================
6   !! History :  1.0  !  2005-01  (J. Chanut, A. Sellar)  Original code
7   !!             -   !  2007-01  (D. Storkey) Update to use IOM module
8   !!             -   !  2007-07  (D. Storkey) add bdy_dta_fla
9   !!            3.0  !  2008-04  (NEMO team)  add in the reference version
10   !!            3.3  !  2010-09  (E.O'Dea) modifications for Shelf configurations
11   !!            3.3  !  2010-09  (D.Storkey) add ice boundary conditions
12   !!            3.4  !  2011     (D. Storkey) rewrite in preparation for OBC-BDY merge
13   !!            3.6  !  2012-01  (C. Rousset) add ice boundary conditions for sea ice
14   !!            4.0  !  2018     (C. Rousset) SI3 compatibility
15   !!----------------------------------------------------------------------
16
17   !!----------------------------------------------------------------------
18   !!    bdy_dta      : read external data along open boundaries from file
19   !!    bdy_dta_init : initialise arrays etc for reading of external data
20   !!----------------------------------------------------------------------
21   USE oce            ! ocean dynamics and tracers
22   USE dom_oce        ! ocean space and time domain
23   USE phycst         ! physical constants
24   USE sbcapr         ! atmospheric pressure forcing
25   USE tide_mod, ONLY: ln_tide ! tidal forcing
26   USE bdy_oce        ! ocean open boundary conditions 
27   USE bdytides       ! tidal forcing at boundaries
28#if defined key_si3
29   USE ice            ! sea-ice variables
30   USE icevar         ! redistribute ice input into categories
31#endif
32   !
33   USE lib_mpp, ONLY: ctl_stop, ctl_nam
34   USE fldread        ! read input fields
35   USE iom            ! IOM library
36   USE in_out_manager ! I/O logical units
37   USE timing         ! Timing
38
39   IMPLICIT NONE
40   PRIVATE
41
42   PUBLIC   bdy_dta          ! routine called by step.F90 and dynspg_ts.F90
43   PUBLIC   bdy_dta_init     ! routine called by nemogcm.F90
44
45   INTEGER , PARAMETER ::   jpbdyfld  = 16    ! maximum number of files to read
46   INTEGER , PARAMETER ::   jp_bdyssh = 1     !
47   INTEGER , PARAMETER ::   jp_bdyu2d = 2     !
48   INTEGER , PARAMETER ::   jp_bdyv2d = 3     !
49   INTEGER , PARAMETER ::   jp_bdyu3d = 4     !
50   INTEGER , PARAMETER ::   jp_bdyv3d = 5     !
51   INTEGER , PARAMETER ::   jp_bdytem = 6     !
52   INTEGER , PARAMETER ::   jp_bdysal = 7     !
53   INTEGER , PARAMETER ::   jp_bdya_i = 8     !
54   INTEGER , PARAMETER ::   jp_bdyh_i = 9     !
55   INTEGER , PARAMETER ::   jp_bdyh_s = 10    !
56   INTEGER , PARAMETER ::   jp_bdyt_i = 11    !
57   INTEGER , PARAMETER ::   jp_bdyt_s = 12    !
58   INTEGER , PARAMETER ::   jp_bdytsu = 13    !
59   INTEGER , PARAMETER ::   jp_bdys_i = 14    !
60   INTEGER , PARAMETER ::   jp_bdyaip = 15    !
61   INTEGER , PARAMETER ::   jp_bdyhip = 16    !
62#if ! defined key_si3
63   INTEGER , PARAMETER ::   jpl = 1
64#endif
65
66!$AGRIF_DO_NOT_TREAT
67   TYPE(FLD), PUBLIC, ALLOCATABLE, DIMENSION(:,:), TARGET ::   bf   ! structure of input fields (file informations, fields read)
68!$AGRIF_END_DO_NOT_TREAT
69
70   !! * Substitutions
71#  include "do_loop_substitute.h90"
72#  include "domzgr_substitute.h90"
73   !!----------------------------------------------------------------------
74   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
75   !! $Id$
76   !! Software governed by the CeCILL license (see ./LICENSE)
77   !!----------------------------------------------------------------------
78CONTAINS
79
80   SUBROUTINE bdy_dta( kt, Kmm )
81      !!----------------------------------------------------------------------
82      !!                   ***  SUBROUTINE bdy_dta  ***
83      !!                   
84      !! ** Purpose :   Update external data for open boundary conditions
85      !!
86      !! ** Method  :   Use fldread.F90
87      !!               
88      !!----------------------------------------------------------------------
89      INTEGER, INTENT(in)           ::   kt           ! ocean time-step index
90      INTEGER, INTENT(in)           ::   Kmm          ! ocean time level index
91      !
92      INTEGER ::  jbdy, jfld, jstart, jend, ib, jl    ! dummy loop indices
93      INTEGER ::  ii, ij, ik, igrd, ipl               ! local integers
94      INTEGER,   DIMENSION(jpbgrd)     ::   ilen1 
95      INTEGER,   DIMENSION(:), POINTER ::   nblen, nblenrim  ! short cuts
96      TYPE(OBC_DATA)         , POINTER ::   dta_alias        ! short cut
97      TYPE(FLD), DIMENSION(:), POINTER ::   bf_alias
98      !!---------------------------------------------------------------------------
99      !
100      IF( ln_timing )   CALL timing_start('bdy_dta')
101      !
102      ! Initialise data arrays once for all from initial conditions where required
103      !---------------------------------------------------------------------------
104      IF( kt == nit000 ) THEN
105
106         ! Calculate depth-mean currents
107         !-----------------------------
108
109         DO jbdy = 1, nb_bdy
110            !
111            nblen    => idx_bdy(jbdy)%nblen
112            nblenrim => idx_bdy(jbdy)%nblenrim
113            !
114            IF( nn_dyn2d_dta(jbdy) == 0 ) THEN
115               ilen1(:) = nblen(:)
116               IF( dta_bdy(jbdy)%lneed_ssh ) THEN
117                  igrd = 1
118                  DO ib = 1, ilen1(igrd)
119                     ii = idx_bdy(jbdy)%nbi(ib,igrd)
120                     ij = idx_bdy(jbdy)%nbj(ib,igrd)
121                     dta_bdy(jbdy)%ssh(ib) = ssh(ii,ij,Kmm) * tmask(ii,ij,1)         
122                  END DO
123               ENDIF
124               IF( dta_bdy(jbdy)%lneed_dyn2d) THEN
125                  igrd = 2
126                  DO ib = 1, ilen1(igrd)
127                     ii = idx_bdy(jbdy)%nbi(ib,igrd)
128                     ij = idx_bdy(jbdy)%nbj(ib,igrd)
129                     dta_bdy(jbdy)%u2d(ib) = uu_b(ii,ij,Kmm) * umask(ii,ij,1)         
130                  END DO
131                  igrd = 3
132                  DO ib = 1, ilen1(igrd)
133                     ii = idx_bdy(jbdy)%nbi(ib,igrd)
134                     ij = idx_bdy(jbdy)%nbj(ib,igrd)
135                     dta_bdy(jbdy)%v2d(ib) = vv_b(ii,ij,Kmm) * vmask(ii,ij,1)         
136                  END DO
137               ENDIF
138            ENDIF
139            !
140            IF( nn_dyn3d_dta(jbdy) == 0 ) THEN
141               ilen1(:) = nblen(:)
142               IF( dta_bdy(jbdy)%lneed_dyn3d ) THEN
143                  igrd = 2 
144                  DO ib = 1, ilen1(igrd)
145                     DO ik = 1, jpkm1
146                        ii = idx_bdy(jbdy)%nbi(ib,igrd)
147                        ij = idx_bdy(jbdy)%nbj(ib,igrd)
148                        dta_bdy(jbdy)%u3d(ib,ik) =  ( uu(ii,ij,ik,Kmm) - uu_b(ii,ij,Kmm) ) * umask(ii,ij,ik)         
149                     END DO
150                  END DO
151                  igrd = 3 
152                  DO ib = 1, ilen1(igrd)
153                     DO ik = 1, jpkm1
154                        ii = idx_bdy(jbdy)%nbi(ib,igrd)
155                        ij = idx_bdy(jbdy)%nbj(ib,igrd)
156                        dta_bdy(jbdy)%v3d(ib,ik) =  ( vv(ii,ij,ik,Kmm) - vv_b(ii,ij,Kmm) ) * vmask(ii,ij,ik)         
157                     END DO
158                  END DO
159               ENDIF
160            ENDIF
161
162            IF( nn_tra_dta(jbdy) == 0 ) THEN
163               ilen1(:) = nblen(:)
164               IF( dta_bdy(jbdy)%lneed_tra ) THEN
165                  igrd = 1 
166                  DO ib = 1, ilen1(igrd)
167                     DO ik = 1, jpkm1
168                        ii = idx_bdy(jbdy)%nbi(ib,igrd)
169                        ij = idx_bdy(jbdy)%nbj(ib,igrd)
170                        dta_bdy(jbdy)%tem(ib,ik) = ts(ii,ij,ik,jp_tem,Kmm) * tmask(ii,ij,ik)         
171                        dta_bdy(jbdy)%sal(ib,ik) = ts(ii,ij,ik,jp_sal,Kmm) * tmask(ii,ij,ik)         
172                     END DO
173                  END DO
174               ENDIF
175            ENDIF
176
177#if defined key_si3
178            IF( nn_ice_dta(jbdy) == 0 ) THEN    ! set ice to initial values
179               ilen1(:) = nblen(:)
180               IF( dta_bdy(jbdy)%lneed_ice ) THEN
181                  igrd = 1   
182                  DO jl = 1, jpl
183                     DO ib = 1, ilen1(igrd)
184                        ii = idx_bdy(jbdy)%nbi(ib,igrd)
185                        ij = idx_bdy(jbdy)%nbj(ib,igrd)
186                        dta_bdy(jbdy)%a_i(ib,jl) =  a_i (ii,ij,jl) * tmask(ii,ij,1) 
187                        dta_bdy(jbdy)%h_i(ib,jl) =  h_i (ii,ij,jl) * tmask(ii,ij,1) 
188                        dta_bdy(jbdy)%h_s(ib,jl) =  h_s (ii,ij,jl) * tmask(ii,ij,1) 
189                        dta_bdy(jbdy)%t_i(ib,jl) =  SUM(t_i (ii,ij,:,jl)) * r1_nlay_i * tmask(ii,ij,1) 
190                        dta_bdy(jbdy)%t_s(ib,jl) =  SUM(t_s (ii,ij,:,jl)) * r1_nlay_s * tmask(ii,ij,1)
191                        dta_bdy(jbdy)%tsu(ib,jl) =  t_su(ii,ij,jl) * tmask(ii,ij,1) 
192                        dta_bdy(jbdy)%s_i(ib,jl) =  s_i (ii,ij,jl) * tmask(ii,ij,1)
193                        ! melt ponds
194                        dta_bdy(jbdy)%aip(ib,jl) =  a_ip(ii,ij,jl) * tmask(ii,ij,1) 
195                        dta_bdy(jbdy)%hip(ib,jl) =  h_ip(ii,ij,jl) * tmask(ii,ij,1) 
196                     END DO
197                  END DO
198               ENDIF
199            ENDIF
200#endif
201         END DO ! jbdy
202         !
203      ENDIF ! kt == nit000
204
205      ! update external data from files
206      !--------------------------------
207
208      DO jbdy = 1, nb_bdy
209
210         dta_alias => dta_bdy(jbdy)
211         bf_alias  => bf(:,jbdy)
212
213         ! read/update all bdy data
214         ! ------------------------
215         ! BDY: use pt_offset=0.5 as applied at the end of the step and fldread is referenced at the middle of the step
216         CALL fld_read( kt, 1, bf_alias, pt_offset = 0.5_wp, Kmm = Kmm )
217         ! apply some corrections in some specific cases...
218         ! --------------------------------------------------
219         !
220         ! if runoff condition: change river flow we read (in m3/s) into barotropic velocity (m/s)
221         IF( cn_tra(jbdy) == 'runoff' .AND. TRIM(bf_alias(jp_bdyu2d)%clrootname) /= 'NOT USED' ) THEN   ! runoff and we read u/v2d
222            !
223            igrd = 2                      ! zonal flow (m3/s) to barotropic zonal velocity (m/s)
224            DO ib = 1, idx_bdy(jbdy)%nblen(igrd)
225               ii   = idx_bdy(jbdy)%nbi(ib,igrd)
226               ij   = idx_bdy(jbdy)%nbj(ib,igrd)
227               dta_alias%u2d(ib) = dta_alias%u2d(ib) / ( e2u(ii,ij) * hu_0(ii,ij) )
228            END DO
229            igrd = 3                      ! meridional flow (m3/s) to barotropic meridional velocity (m/s)
230            DO ib = 1, idx_bdy(jbdy)%nblen(igrd)
231               ii   = idx_bdy(jbdy)%nbi(ib,igrd)
232               ij   = idx_bdy(jbdy)%nbj(ib,igrd)
233               dta_alias%v2d(ib) = dta_alias%v2d(ib) / ( e1v(ii,ij) * hv_0(ii,ij) )
234            END DO
235         ENDIF
236
237         ! tidal harmonic forcing ONLY: initialise arrays
238         IF( nn_dyn2d_dta(jbdy) == 2 ) THEN   ! we did not read ssh, u/v2d
239            IF( dta_alias%lneed_ssh   ) dta_alias%ssh(:) = 0._wp
240            IF( dta_alias%lneed_dyn2d ) dta_alias%u2d(:) = 0._wp
241            IF( dta_alias%lneed_dyn2d ) dta_alias%v2d(:) = 0._wp
242         ENDIF
243
244         ! If full velocities in boundary data, then split it into barotropic and baroclinic component
245         IF( bf_alias(jp_bdyu3d)%ltotvel ) THEN     ! if we read 3D total velocity (can be true only if u3d was read)
246            !
247            igrd = 2                       ! zonal velocity
248            dta_alias%u2d(:) = 0._wp       ! compute barotrope zonal velocity and put it in u2d
249            DO ib = 1, idx_bdy(jbdy)%nblen(igrd)
250               ii   = idx_bdy(jbdy)%nbi(ib,igrd)
251               ij   = idx_bdy(jbdy)%nbj(ib,igrd)
252               DO ik = 1, jpkm1
253                  dta_alias%u2d(ib) = dta_alias%u2d(ib)   &
254                     &              + e3u(ii,ij,ik,Kmm) * umask(ii,ij,ik) * dta_alias%u3d(ib,ik)
255               END DO
256               dta_alias%u2d(ib) =  dta_alias%u2d(ib) * r1_hu(ii,ij,Kmm)
257               DO ik = 1, jpkm1            ! compute barocline zonal velocity and put it in u3d
258                  dta_alias%u3d(ib,ik) = dta_alias%u3d(ib,ik) - dta_alias%u2d(ib)
259               END DO
260            END DO
261            igrd = 3                       ! meridional velocity
262            dta_alias%v2d(:) = 0._wp       ! compute barotrope meridional velocity and put it in v2d
263            DO ib = 1, idx_bdy(jbdy)%nblen(igrd)
264               ii   = idx_bdy(jbdy)%nbi(ib,igrd)
265               ij   = idx_bdy(jbdy)%nbj(ib,igrd)
266               DO ik = 1, jpkm1
267                  dta_alias%v2d(ib) = dta_alias%v2d(ib)   &
268                     &              + e3v(ii,ij,ik,Kmm) * vmask(ii,ij,ik) * dta_alias%v3d(ib,ik)
269               END DO
270               dta_alias%v2d(ib) =  dta_alias%v2d(ib) * r1_hv(ii,ij,Kmm)
271               DO ik = 1, jpkm1            ! compute barocline meridional velocity and put it in v3d
272                  dta_alias%v3d(ib,ik) = dta_alias%v3d(ib,ik) - dta_alias%v2d(ib)
273               END DO
274            END DO
275         ENDIF   ! ltotvel
276
277         !  atm surface pressure : add inverted barometer effect to ssh if it was read
278         IF ( ln_apr_obc .AND. TRIM(bf_alias(jp_bdyssh)%clrootname) /= 'NOT USED' ) THEN
279            igrd = 1
280            DO ib = 1, idx_bdy(jbdy)%nblenrim(igrd)   ! ssh is used only on the rim
281               ii   = idx_bdy(jbdy)%nbi(ib,igrd)
282               ij   = idx_bdy(jbdy)%nbj(ib,igrd)
283               dta_alias%ssh(ib) = dta_alias%ssh(ib) + ssh_ib(ii,ij)
284            END DO
285         ENDIF
286
287#if defined key_si3
288         IF( dta_alias%lneed_ice ) THEN
289            ! fill temperature and salinity arrays
290            IF( TRIM(bf_alias(jp_bdyt_i)%clrootname) == 'NOT USED' )   bf_alias(jp_bdyt_i)%fnow(:,1,:) = rice_tem (jbdy)
291            IF( TRIM(bf_alias(jp_bdyt_s)%clrootname) == 'NOT USED' )   bf_alias(jp_bdyt_s)%fnow(:,1,:) = rice_tem (jbdy)
292            IF( TRIM(bf_alias(jp_bdytsu)%clrootname) == 'NOT USED' )   bf_alias(jp_bdytsu)%fnow(:,1,:) = rice_tem (jbdy)
293            IF( TRIM(bf_alias(jp_bdys_i)%clrootname) == 'NOT USED' )   bf_alias(jp_bdys_i)%fnow(:,1,:) = rice_sal (jbdy)
294            IF( TRIM(bf_alias(jp_bdyaip)%clrootname) == 'NOT USED' )   bf_alias(jp_bdyaip)%fnow(:,1,:) = rice_apnd(jbdy) * & ! rice_apnd is the pond fraction
295               &                                                                         bf_alias(jp_bdya_i)%fnow(:,1,:)     !   ( a_ip = rice_apnd * a_i )
296            IF( TRIM(bf_alias(jp_bdyhip)%clrootname) == 'NOT USED' )   bf_alias(jp_bdyhip)%fnow(:,1,:) = rice_hpnd(jbdy)
297            ! if T_su is read and not T_i, set T_i = (T_su + T_freeze)/2
298            IF( TRIM(bf_alias(jp_bdytsu)%clrootname) /= 'NOT USED' .AND. TRIM(bf_alias(jp_bdyt_i)%clrootname) == 'NOT USED' ) &
299               &   bf_alias(jp_bdyt_i)%fnow(:,1,:) = 0.5_wp * ( bf_alias(jp_bdytsu)%fnow(:,1,:) + 271.15 )
300            ! if T_su is read and not T_s, set T_s = T_su
301            IF( TRIM(bf_alias(jp_bdytsu)%clrootname) /= 'NOT USED' .AND. TRIM(bf_alias(jp_bdyt_s)%clrootname) == 'NOT USED' ) &
302               &   bf_alias(jp_bdyt_s)%fnow(:,1,:) = bf_alias(jp_bdytsu)%fnow(:,1,:)
303            ! if T_s is read and not T_su, set T_su = T_s
304            IF( TRIM(bf_alias(jp_bdyt_s)%clrootname) /= 'NOT USED' .AND. TRIM(bf_alias(jp_bdytsu)%clrootname) == 'NOT USED' ) &
305               &   bf_alias(jp_bdytsu)%fnow(:,1,:) = bf_alias(jp_bdyt_s)%fnow(:,1,:)
306            ! if T_s is read and not T_i, set T_i = (T_s + T_freeze)/2
307            IF( TRIM(bf_alias(jp_bdyt_s)%clrootname) /= 'NOT USED' .AND. TRIM(bf_alias(jp_bdyt_i)%clrootname) == 'NOT USED' ) &
308               &   bf_alias(jp_bdyt_i)%fnow(:,1,:) = 0.5_wp * ( bf_alias(jp_bdyt_s)%fnow(:,1,:) + 271.15 )
309
310            ! make sure ponds = 0 if no ponds scheme
311            IF ( .NOT.ln_pnd ) THEN
312               bf_alias(jp_bdyaip)%fnow(:,1,:) = 0._wp
313               bf_alias(jp_bdyhip)%fnow(:,1,:) = 0._wp
314            ENDIF
315           
316            ! convert N-cat fields (input) into jpl-cat (output)
317            ipl = SIZE(bf_alias(jp_bdya_i)%fnow, 3)           
318            IF( ipl /= jpl ) THEN      ! ice: convert N-cat fields (input) into jpl-cat (output)
319               CALL ice_var_itd( bf_alias(jp_bdyh_i)%fnow(:,1,:), bf_alias(jp_bdyh_s)%fnow(:,1,:), bf_alias(jp_bdya_i)%fnow(:,1,:), &
320                  &              dta_alias%h_i                  , dta_alias%h_s                  , dta_alias%a_i                  , &
321                  &              bf_alias(jp_bdyt_i)%fnow(:,1,:), bf_alias(jp_bdyt_s)%fnow(:,1,:), &
322                  &              bf_alias(jp_bdytsu)%fnow(:,1,:), bf_alias(jp_bdys_i)%fnow(:,1,:), &
323                  &              bf_alias(jp_bdyaip)%fnow(:,1,:), bf_alias(jp_bdyhip)%fnow(:,1,:), &
324                  &              dta_alias%t_i                  , dta_alias%t_s                  , &
325                  &              dta_alias%tsu                  , dta_alias%s_i                  , &
326                  &              dta_alias%aip                  , dta_alias%hip )
327            ENDIF
328         ENDIF
329#endif
330      END DO  ! jbdy
331
332      IF ( ln_tide ) THEN
333         IF (ln_dynspg_ts) THEN      ! Fill temporary arrays with slow-varying bdy data                           
334            DO jbdy = 1, nb_bdy      ! Tidal component added in ts loop
335               IF ( nn_dyn2d_dta(jbdy) .GE. 2 ) THEN
336                  nblen => idx_bdy(jbdy)%nblen
337                  nblenrim => idx_bdy(jbdy)%nblenrim
338                  IF( cn_dyn2d(jbdy) == 'frs' ) THEN   ;   ilen1(:)=nblen(:)
339                  ELSE                                 ;   ilen1(:)=nblenrim(:)
340                  ENDIF
341                  IF ( dta_bdy(jbdy)%lneed_ssh   ) dta_bdy_s(jbdy)%ssh(1:ilen1(1)) = dta_bdy(jbdy)%ssh(1:ilen1(1))
342                  IF ( dta_bdy(jbdy)%lneed_dyn2d ) dta_bdy_s(jbdy)%u2d(1:ilen1(2)) = dta_bdy(jbdy)%u2d(1:ilen1(2))
343                  IF ( dta_bdy(jbdy)%lneed_dyn2d ) dta_bdy_s(jbdy)%v2d(1:ilen1(3)) = dta_bdy(jbdy)%v2d(1:ilen1(3))
344               ENDIF
345            END DO
346         ELSE ! Add tides if not split-explicit free surface else this is done in ts loop
347            !
348            ! BDY: use pt_offset=1.0 as applied at the end of the step and bdy_dta_tides is referenced at the middle of the step
349            CALL bdy_dta_tides( kt=kt, pt_offset = 1._wp )
350         ENDIF
351      ENDIF
352      !
353      IF( ln_timing )   CALL timing_stop('bdy_dta')
354      !
355   END SUBROUTINE bdy_dta
356
357
358   SUBROUTINE bdy_dta_init
359      !!----------------------------------------------------------------------
360      !!                   ***  SUBROUTINE bdy_dta_init  ***
361      !!                   
362      !! ** Purpose :   Initialise arrays for reading of external data
363      !!                for open boundary conditions
364      !!
365      !! ** Method  :   
366      !!               
367      !!----------------------------------------------------------------------
368      INTEGER ::   jbdy, jfld    ! Local integers
369      INTEGER ::   ierror, ios     !
370      !
371      INTEGER ::   nbdy_rdstart, nbdy_loc
372      CHARACTER(LEN=50)                      ::   cerrmsg       ! error string
373      CHARACTER(len=3)                       ::   cl3           !
374      CHARACTER(len=100)                     ::   cn_dir        ! Root directory for location of data files
375      LOGICAL                                ::   ln_full_vel   ! =T => full velocities in 3D boundary data
376      !                                                         ! =F => baroclinic velocities in 3D boundary data
377      LOGICAL                                ::   ln_zinterp    ! =T => requires a vertical interpolation of the bdydta
378      REAL(wp)                               ::   rn_ice_tem, rn_ice_sal, rn_ice_age, rn_ice_apnd, rn_ice_hpnd 
379      INTEGER                                ::   ipk,ipl       !
380      INTEGER                                ::   idvar         ! variable ID
381      INTEGER                                ::   indims        ! number of dimensions of the variable
382      INTEGER                                ::   iszdim        ! number of dimensions of the variable
383      INTEGER, DIMENSION(4)                  ::   i4dimsz       ! size of variable dimensions
384      INTEGER                                ::   igrd          ! index for grid type (1,2,3 = T,U,V)
385      LOGICAL                                ::   lluld         ! is the variable using the unlimited dimension
386      LOGICAL                                ::   llneed        !
387      LOGICAL                                ::   llread        !
388      TYPE(FLD_N), DIMENSION(1), TARGET  ::   bn_tem, bn_sal, bn_u3d, bn_v3d   ! must be an array to be used with fld_fill
389      TYPE(FLD_N), DIMENSION(1), TARGET  ::   bn_ssh, bn_u2d, bn_v2d           ! informations about the fields to be read
390      TYPE(FLD_N), DIMENSION(1), TARGET  ::   bn_a_i, bn_h_i, bn_h_s, bn_t_i, bn_t_s, bn_tsu, bn_s_i, bn_aip, bn_hip       
391      TYPE(FLD_N), DIMENSION(:), POINTER ::   bn_alias                        ! must be an array to be used with fld_fill
392      TYPE(FLD  ), DIMENSION(:), POINTER ::   bf_alias
393      !
394      NAMELIST/nambdy_dta/ cn_dir, bn_tem, bn_sal, bn_u3d, bn_v3d, bn_ssh, bn_u2d, bn_v2d 
395      NAMELIST/nambdy_dta/ bn_a_i, bn_h_i, bn_h_s, bn_t_i, bn_t_s, bn_tsu, bn_s_i, bn_aip, bn_hip
396      NAMELIST/nambdy_dta/ rn_ice_tem, rn_ice_sal, rn_ice_age, rn_ice_apnd, rn_ice_hpnd
397      NAMELIST/nambdy_dta/ ln_full_vel, ln_zinterp
398      !!---------------------------------------------------------------------------
399      !
400      IF(lwp) WRITE(numout,*)
401      IF(lwp) WRITE(numout,*) 'bdy_dta_ini : initialization of data at the open boundaries'
402      IF(lwp) WRITE(numout,*) '~~~~~~~~~~'
403      IF(lwp) WRITE(numout,*) ''
404
405      ALLOCATE( bf(jpbdyfld,nb_bdy), STAT=ierror )
406      IF( ierror > 0 ) THEN   
407         CALL ctl_stop( 'bdy_dta: unable to allocate bf structure' )   ;   RETURN 
408      ENDIF
409      bf(:,:)%clrootname = 'NOT USED'   ! default definition used as a flag in fld_read to do nothing.
410      bf(:,:)%lzint      = .FALSE.      ! default definition
411      bf(:,:)%ltotvel    = .FALSE.      ! default definition
412 
413      ! Read namelists
414      ! --------------
415      nbdy_rdstart = 1
416      DO jbdy = 1, nb_bdy
417
418         WRITE(ctmp1, '(a,i2)') 'BDY number ', jbdy
419         WRITE(ctmp2, '(a,i2)') 'block nambdy_dta number ', jbdy
420
421         ! There is only one nambdy_dta block in namelist_ref -> use it for each bdy so we read from the beginning
422         READ  ( numnam_ref, nambdy_dta, IOSTAT = ios, ERR = 901)
423901      IF( ios /= 0 )   CALL ctl_nam ( ios , 'nambdy_dta in reference namelist' )
424
425         !   by-pass nambdy_dta reading if no input data used in this bdy   
426         IF(       ( dta_bdy(jbdy)%lneed_dyn2d .AND. MOD(nn_dyn2d_dta(jbdy),2) == 1 )   &
427            & .OR. ( dta_bdy(jbdy)%lneed_dyn3d .AND.     nn_dyn3d_dta(jbdy)    == 1 )   &
428            & .OR. ( dta_bdy(jbdy)%lneed_tra   .AND.       nn_tra_dta(jbdy)    == 1 )   &
429            & .OR. ( dta_bdy(jbdy)%lneed_ice   .AND.       nn_ice_dta(jbdy)    == 1 )   )   THEN
430            !
431            ! Need to support possibility of reading more than one
432            ! nambdy_dta from the namelist_cfg internal file.
433            ! Do this by finding the jbdy'th occurence of nambdy_dta in the
434            ! character buffer as the starting point.
435            !
436            nbdy_loc = INDEX( numnam_cfg( nbdy_rdstart: ), 'nambdy_dta' )
437            IF( nbdy_loc .GT. 0 ) THEN
438               nbdy_rdstart = nbdy_rdstart + nbdy_loc
439            ELSE
440               WRITE(cerrmsg,'(A,I4,A)') 'Error: entry number ',jbdy,' of nambdy_dta not found'
441               ios = -1
442               CALL ctl_nam ( ios , cerrmsg )
443            ENDIF
444            READ  ( numnam_cfg( MAX( 1, nbdy_rdstart - 2 ): ), nambdy_dta, IOSTAT = ios, ERR = 902)
445902         IF( ios >  0 )   CALL ctl_nam ( ios , 'nambdy_dta in configuration namelist' )
446            IF(lwm) WRITE( numond, nambdy_dta )           
447         ENDIF
448
449         ! get the number of ice categories in bdy data file (use a_i information to do this)
450         ipl = jpl   ! default definition
451         IF( dta_bdy(jbdy)%lneed_ice ) THEN    ! if we need ice bdy data
452            IF( nn_ice_dta(jbdy) == 1 ) THEN   ! if we get ice bdy data from netcdf file
453               CALL fld_fill(  bf(jp_bdya_i,jbdy:jbdy), bn_a_i, cn_dir, 'bdy_dta', 'a_i'//' '//ctmp1, ctmp2 )   ! use namelist info
454               CALL fld_def( bf(jp_bdya_i,jbdy) )
455               CALL iom_open( bf(jp_bdya_i,jbdy)%clname, bf(jp_bdya_i,jbdy)%num )
456               idvar = iom_varid( bf(jp_bdya_i,jbdy)%num, bf(jp_bdya_i,jbdy)%clvar, kndims=indims, kdimsz=i4dimsz, lduld=lluld )
457               IF( indims == 4 .OR. ( indims == 3 .AND. .NOT. lluld ) ) THEN   ;   ipl = i4dimsz(3)   ! xylt or xyl
458               ELSE                                                            ;   ipl = 1            ! xy or xyt
459               ENDIF
460               CALL iom_close( bf(jp_bdya_i,jbdy)%num )
461               bf(jp_bdya_i,jbdy)%clrootname = 'NOT USED'   ! reset to default value as this subdomain may not need to read this bdy
462            ENDIF
463         ENDIF
464
465#if defined key_si3
466         IF( .NOT.ln_pnd ) THEN
467            rn_ice_apnd = 0. ; rn_ice_hpnd = 0.
468            CALL ctl_warn( 'rn_ice_apnd & rn_ice_hpnd = 0 when no ponds' )
469         ENDIF
470#endif
471
472         ! temp, salt, age and ponds of incoming ice
473         rice_tem (jbdy) = rn_ice_tem
474         rice_sal (jbdy) = rn_ice_sal
475         rice_age (jbdy) = rn_ice_age
476         rice_apnd(jbdy) = rn_ice_apnd
477         rice_hpnd(jbdy) = rn_ice_hpnd
478         
479         
480         DO jfld = 1, jpbdyfld
481
482            ! =====================
483            !          ssh
484            ! =====================
485            IF( jfld == jp_bdyssh ) THEN
486               cl3 = 'ssh'
487               igrd = 1                                                    ! T point
488               ipk = 1                                                     ! surface data
489               llneed = dta_bdy(jbdy)%lneed_ssh                            ! dta_bdy(jbdy)%ssh will be needed
490               llread = MOD(nn_dyn2d_dta(jbdy),2) == 1                     ! get data from NetCDF file
491               bf_alias => bf(jp_bdyssh,jbdy:jbdy)                         ! alias for ssh structure of bdy number jbdy
492               bn_alias => bn_ssh                                          ! alias for ssh structure of nambdy_dta
493               iszdim = idx_bdy(jbdy)%nblenrim(igrd)                       ! length of this bdy on this MPI processus : used only on the rim
494            ENDIF
495            ! =====================
496            !         dyn2d
497            ! =====================
498            IF( jfld == jp_bdyu2d ) THEN
499               cl3 = 'u2d'
500               igrd = 2                                                    ! U point
501               ipk = 1                                                     ! surface data
502               llneed = dta_bdy(jbdy)%lneed_dyn2d                          ! dta_bdy(jbdy)%ssh will be needed
503               llread = .NOT. ln_full_vel .AND. MOD(nn_dyn2d_dta(jbdy),2) == 1   ! don't get u2d from u3d and read NetCDF file
504               bf_alias => bf(jp_bdyu2d,jbdy:jbdy)                         ! alias for u2d structure of bdy number jbdy
505               bn_alias => bn_u2d                                          ! alias for u2d structure of nambdy_dta
506               IF( ln_full_vel ) THEN  ;   iszdim = idx_bdy(jbdy)%nblen(igrd)      ! will be computed from u3d -> need on the full bdy
507               ELSE                    ;   iszdim = idx_bdy(jbdy)%nblenrim(igrd)   ! used only on the rim
508               ENDIF
509            ENDIF
510            IF( jfld == jp_bdyv2d ) THEN
511               cl3 = 'v2d'
512               igrd = 3                                                    ! V point
513               ipk = 1                                                     ! surface data
514               llneed = dta_bdy(jbdy)%lneed_dyn2d                          ! dta_bdy(jbdy)%ssh will be needed
515               llread = .NOT. ln_full_vel .AND. MOD(nn_dyn2d_dta(jbdy),2) == 1   ! don't get v2d from v3d and read NetCDF file
516               bf_alias => bf(jp_bdyv2d,jbdy:jbdy)                         ! alias for v2d structure of bdy number jbdy
517               bn_alias => bn_v2d                                          ! alias for v2d structure of nambdy_dta
518               IF( ln_full_vel ) THEN  ;   iszdim = idx_bdy(jbdy)%nblen(igrd)      ! will be computed from v3d -> need on the full bdy
519               ELSE                    ;   iszdim = idx_bdy(jbdy)%nblenrim(igrd)   ! used only on the rim
520               ENDIF
521            ENDIF
522            ! =====================
523            !         dyn3d
524            ! =====================
525            IF( jfld == jp_bdyu3d ) THEN
526               cl3 = 'u3d'
527               igrd = 2                                                    ! U point
528               ipk = jpk                                                   ! 3d data
529               llneed = dta_bdy(jbdy)%lneed_dyn3d .OR.               &     ! dta_bdy(jbdy)%u3d will be needed
530                  &   ( dta_bdy(jbdy)%lneed_dyn2d .AND. ln_full_vel )      !   u3d needed to compute u2d
531               llread = nn_dyn3d_dta(jbdy) == 1                            ! get data from NetCDF file
532               bf_alias => bf(jp_bdyu3d,jbdy:jbdy)                         ! alias for u3d structure of bdy number jbdy
533               bn_alias => bn_u3d                                          ! alias for u3d structure of nambdy_dta
534               iszdim = idx_bdy(jbdy)%nblen(igrd)                          ! length of this bdy on this MPI processus
535           ENDIF
536            IF( jfld == jp_bdyv3d ) THEN
537               cl3 = 'v3d'
538               igrd = 3                                                    ! V point
539               ipk = jpk                                                   ! 3d data
540               llneed = dta_bdy(jbdy)%lneed_dyn3d .OR.               &     ! dta_bdy(jbdy)%v3d will be needed
541                  &   ( dta_bdy(jbdy)%lneed_dyn2d .AND. ln_full_vel )      !   v3d needed to compute v2d
542               llread = nn_dyn3d_dta(jbdy) == 1                            ! get data from NetCDF file
543               bf_alias => bf(jp_bdyv3d,jbdy:jbdy)                         ! alias for v3d structure of bdy number jbdy
544               bn_alias => bn_v3d                                          ! alias for v3d structure of nambdy_dta
545               iszdim = idx_bdy(jbdy)%nblen(igrd)                          ! length of this bdy on this MPI processus
546           ENDIF
547
548            ! =====================
549            !          tra
550            ! =====================
551            IF( jfld == jp_bdytem ) THEN
552               cl3 = 'tem'
553               igrd = 1                                                    ! T point
554               ipk = jpk                                                   ! 3d data
555               llneed = dta_bdy(jbdy)%lneed_tra                            ! dta_bdy(jbdy)%tem will be needed
556               llread = nn_tra_dta(jbdy) == 1                              ! get data from NetCDF file
557               bf_alias => bf(jp_bdytem,jbdy:jbdy)                         ! alias for ssh structure of bdy number jbdy
558               bn_alias => bn_tem                                          ! alias for ssh structure of nambdy_dta
559               iszdim = idx_bdy(jbdy)%nblen(igrd)                          ! length of this bdy on this MPI processus
560            ENDIF
561            IF( jfld == jp_bdysal ) THEN
562               cl3 = 'sal'
563               igrd = 1                                                    ! T point
564               ipk = jpk                                                   ! 3d data
565               llneed = dta_bdy(jbdy)%lneed_tra                            ! dta_bdy(jbdy)%sal will be needed
566               llread = nn_tra_dta(jbdy) == 1                              ! get data from NetCDF file
567               bf_alias => bf(jp_bdysal,jbdy:jbdy)                         ! alias for ssh structure of bdy number jbdy
568               bn_alias => bn_sal                                          ! alias for ssh structure of nambdy_dta
569               iszdim = idx_bdy(jbdy)%nblen(igrd)                          ! length of this bdy on this MPI processus
570            ENDIF
571
572            ! =====================
573            !          ice
574            ! =====================
575            IF(  jfld == jp_bdya_i .OR. jfld == jp_bdyh_i .OR. jfld == jp_bdyh_s .OR. &
576               & jfld == jp_bdyt_i .OR. jfld == jp_bdyt_s .OR. jfld == jp_bdytsu .OR. &
577               & jfld == jp_bdys_i .OR. jfld == jp_bdyaip .OR. jfld == jp_bdyhip      ) THEN
578               igrd = 1                                                    ! T point
579               ipk = ipl                                                   ! jpl-cat data
580               llneed = dta_bdy(jbdy)%lneed_ice                            ! ice will be needed
581               llread = nn_ice_dta(jbdy) == 1                              ! get data from NetCDF file
582               iszdim = idx_bdy(jbdy)%nblen(igrd)                          ! length of this bdy on this MPI processus
583            ENDIF
584            IF( jfld == jp_bdya_i ) THEN
585               cl3 = 'a_i'
586               bf_alias => bf(jp_bdya_i,jbdy:jbdy)                         ! alias for a_i structure of bdy number jbdy
587               bn_alias => bn_a_i                                          ! alias for a_i structure of nambdy_dta
588            ENDIF
589            IF( jfld == jp_bdyh_i ) THEN
590               cl3 = 'h_i'
591               bf_alias => bf(jp_bdyh_i,jbdy:jbdy)                         ! alias for h_i structure of bdy number jbdy
592               bn_alias => bn_h_i                                          ! alias for h_i structure of nambdy_dta
593            ENDIF
594            IF( jfld == jp_bdyh_s ) THEN
595               cl3 = 'h_s'
596               bf_alias => bf(jp_bdyh_s,jbdy:jbdy)                         ! alias for h_s structure of bdy number jbdy
597               bn_alias => bn_h_s                                          ! alias for h_s structure of nambdy_dta
598            ENDIF
599            IF( jfld == jp_bdyt_i ) THEN
600               cl3 = 't_i'
601               bf_alias => bf(jp_bdyt_i,jbdy:jbdy)                         ! alias for t_i structure of bdy number jbdy
602               bn_alias => bn_t_i                                          ! alias for t_i structure of nambdy_dta
603            ENDIF
604            IF( jfld == jp_bdyt_s ) THEN
605               cl3 = 't_s'
606               bf_alias => bf(jp_bdyt_s,jbdy:jbdy)                         ! alias for t_s structure of bdy number jbdy
607               bn_alias => bn_t_s                                          ! alias for t_s structure of nambdy_dta
608            ENDIF
609            IF( jfld == jp_bdytsu ) THEN
610               cl3 = 'tsu'
611               bf_alias => bf(jp_bdytsu,jbdy:jbdy)                         ! alias for tsu structure of bdy number jbdy
612               bn_alias => bn_tsu                                          ! alias for tsu structure of nambdy_dta
613            ENDIF
614            IF( jfld == jp_bdys_i ) THEN
615               cl3 = 's_i'
616               bf_alias => bf(jp_bdys_i,jbdy:jbdy)                         ! alias for s_i structure of bdy number jbdy
617               bn_alias => bn_s_i                                          ! alias for s_i structure of nambdy_dta
618            ENDIF
619            IF( jfld == jp_bdyaip ) THEN
620               cl3 = 'aip'
621               bf_alias => bf(jp_bdyaip,jbdy:jbdy)                         ! alias for aip structure of bdy number jbdy
622               bn_alias => bn_aip                                          ! alias for aip structure of nambdy_dta
623            ENDIF
624            IF( jfld == jp_bdyhip ) THEN
625               cl3 = 'hip'
626               bf_alias => bf(jp_bdyhip,jbdy:jbdy)                         ! alias for hip structure of bdy number jbdy
627               bn_alias => bn_hip                                          ! alias for hip structure of nambdy_dta
628            ENDIF
629
630            IF( llneed .AND. iszdim > 0 ) THEN                             ! dta_bdy(jbdy)%xxx will be needed
631               !                                                           !   -> must be associated with an allocated target
632               ALLOCATE( bf_alias(1)%fnow( iszdim, 1, ipk ) )              ! allocate the target
633               !
634               IF( llread ) THEN                                           ! get data from NetCDF file
635                  CALL fld_fill( bf_alias, bn_alias, cn_dir, 'bdy_dta', cl3//' '//ctmp1, ctmp2 )   ! use namelist info
636                  IF( bf_alias(1)%ln_tint ) ALLOCATE( bf_alias(1)%fdta( iszdim, 1, ipk, 2 ) )
637                  bf_alias(1)%imap    => idx_bdy(jbdy)%nbmap(1:iszdim,igrd)   ! associate the mapping used for this bdy
638                  bf_alias(1)%igrd    = igrd                                  ! used only for vertical integration of 3D arrays
639                  bf_alias(1)%ibdy    = jbdy                                  !  "    "    "     "          "      "  "    "   
640                  bf_alias(1)%ltotvel = ln_full_vel                           ! T if u3d is full velocity
641                  bf_alias(1)%lzint   = ln_zinterp                            ! T if it requires a vertical interpolation
642               ENDIF
643
644               ! associate the pointer and get rid of the dimensions with a size equal to 1
645               IF( jfld == jp_bdyssh )        dta_bdy(jbdy)%ssh => bf_alias(1)%fnow(:,1,1)
646               IF( jfld == jp_bdyu2d )        dta_bdy(jbdy)%u2d => bf_alias(1)%fnow(:,1,1)
647               IF( jfld == jp_bdyv2d )        dta_bdy(jbdy)%v2d => bf_alias(1)%fnow(:,1,1)
648               IF( jfld == jp_bdyu3d )        dta_bdy(jbdy)%u3d => bf_alias(1)%fnow(:,1,:)
649               IF( jfld == jp_bdyv3d )        dta_bdy(jbdy)%v3d => bf_alias(1)%fnow(:,1,:)
650               IF( jfld == jp_bdytem )        dta_bdy(jbdy)%tem => bf_alias(1)%fnow(:,1,:)
651               IF( jfld == jp_bdysal )        dta_bdy(jbdy)%sal => bf_alias(1)%fnow(:,1,:)
652               IF( jfld == jp_bdya_i ) THEN
653                  IF( ipk == jpl ) THEN   ;   dta_bdy(jbdy)%a_i => bf_alias(1)%fnow(:,1,:)
654                  ELSE                    ;   ALLOCATE( dta_bdy(jbdy)%a_i(iszdim,jpl) )
655                  ENDIF
656               ENDIF
657               IF( jfld == jp_bdyh_i ) THEN
658                  IF( ipk == jpl ) THEN   ;   dta_bdy(jbdy)%h_i => bf_alias(1)%fnow(:,1,:)
659                  ELSE                    ;   ALLOCATE( dta_bdy(jbdy)%h_i(iszdim,jpl) )
660                  ENDIF
661               ENDIF
662               IF( jfld == jp_bdyh_s ) THEN
663                  IF( ipk == jpl ) THEN   ;   dta_bdy(jbdy)%h_s => bf_alias(1)%fnow(:,1,:)
664                  ELSE                    ;   ALLOCATE( dta_bdy(jbdy)%h_s(iszdim,jpl) )
665                  ENDIF
666               ENDIF
667               IF( jfld == jp_bdyt_i ) THEN
668                  IF( ipk == jpl ) THEN   ;   dta_bdy(jbdy)%t_i => bf_alias(1)%fnow(:,1,:)
669                  ELSE                    ;   ALLOCATE( dta_bdy(jbdy)%t_i(iszdim,jpl) )
670                  ENDIF
671               ENDIF
672               IF( jfld == jp_bdyt_s ) THEN
673                  IF( ipk == jpl ) THEN   ;   dta_bdy(jbdy)%t_s => bf_alias(1)%fnow(:,1,:)
674                  ELSE                    ;   ALLOCATE( dta_bdy(jbdy)%t_s(iszdim,jpl) )
675                  ENDIF
676               ENDIF
677               IF( jfld == jp_bdytsu ) THEN
678                  IF( ipk == jpl ) THEN   ;   dta_bdy(jbdy)%tsu => bf_alias(1)%fnow(:,1,:)
679                  ELSE                    ;   ALLOCATE( dta_bdy(jbdy)%tsu(iszdim,jpl) )
680                  ENDIF
681               ENDIF
682               IF( jfld == jp_bdys_i ) THEN
683                  IF( ipk == jpl ) THEN   ;   dta_bdy(jbdy)%s_i => bf_alias(1)%fnow(:,1,:)
684                  ELSE                    ;   ALLOCATE( dta_bdy(jbdy)%s_i(iszdim,jpl) )
685                  ENDIF
686               ENDIF
687               IF( jfld == jp_bdyaip ) THEN
688                  IF( ipk == jpl ) THEN   ;   dta_bdy(jbdy)%aip => bf_alias(1)%fnow(:,1,:)
689                  ELSE                    ;   ALLOCATE( dta_bdy(jbdy)%aip(iszdim,jpl) )
690                  ENDIF
691               ENDIF
692               IF( jfld == jp_bdyhip ) THEN
693                  IF( ipk == jpl ) THEN   ;   dta_bdy(jbdy)%hip => bf_alias(1)%fnow(:,1,:)
694                  ELSE                    ;   ALLOCATE( dta_bdy(jbdy)%hip(iszdim,jpl) )
695                  ENDIF
696               ENDIF
697            ENDIF
698
699         END DO   ! jpbdyfld
700         !
701      END DO ! jbdy
702      !
703   END SUBROUTINE bdy_dta_init
704   
705   !!==============================================================================
706END MODULE bdydta
Note: See TracBrowser for help on using the repository browser.