source: NEMO/branches/2020/dev_r12377_KERNEL-06_techene_e3/src/OCE/TRA/traatf.F90 @ 12656

Last change on this file since 12656 was 12656, checked in by techene, 8 months ago

change key_QCO into key_qco, stepLF & traatf: add substitute, dynatfQCO: remove pe3 arguments

  • Property svn:keywords set to Id
File size: 20.4 KB
Line 
1MODULE traatf
2   !!======================================================================
3   !!                       ***  MODULE  traatf  ***
4   !! Ocean active tracers:  Asselin time filtering for temperature and salinity
5   !!======================================================================
6   !! History :  OPA  !  1991-11  (G. Madec)  Original code
7   !!            7.0  !  1993-03  (M. Guyon)  symetrical conditions
8   !!            8.0  !  1996-02  (G. Madec & M. Imbard)  opa release 8.0
9   !!             -   !  1996-04  (A. Weaver)  Euler forward step
10   !!            8.2  !  1999-02  (G. Madec, N. Grima)  semi-implicit pressure grad.
11   !!  NEMO      1.0  !  2002-08  (G. Madec)  F90: Free form and module
12   !!             -   !  2002-11  (C. Talandier, A-M Treguier) Open boundaries
13   !!             -   !  2005-04  (C. Deltel) Add Asselin trend in the ML budget
14   !!            2.0  !  2006-02  (L. Debreu, C. Mazauric) Agrif implementation
15   !!            3.0  !  2008-06  (G. Madec)  time stepping always done in trazdf
16   !!            3.1  !  2009-02  (G. Madec, R. Benshila)  re-introduce the vvl option
17   !!            3.3  !  2010-04  (M. Leclair, G. Madec)  semi-implicit hpg with asselin filter + modified LF-RA
18   !!             -   !  2010-05  (C. Ethe, G. Madec)  merge TRC-TRA
19   !!            4.1  !  2019-08  (A. Coward, D. Storkey) rename tranxt.F90 -> traatf.F90. Now only does time filtering.
20   !!----------------------------------------------------------------------
21
22   !!----------------------------------------------------------------------
23   !!   tra_atf       : time filtering on tracers
24   !!   tra_atf_fix   : time filtering on tracers : fixed    volume case
25   !!   tra_atf_vvl   : time filtering on tracers : variable volume case
26   !!----------------------------------------------------------------------
27   USE oce             ! ocean dynamics and tracers variables
28   USE dom_oce         ! ocean space and time domain variables
29   USE sbc_oce         ! surface boundary condition: ocean
30   USE sbcrnf          ! river runoffs
31   USE isf_oce         ! ice shelf melting
32   USE zdf_oce         ! ocean vertical mixing
33   USE domvvl          ! variable volume
34   USE trd_oce         ! trends: ocean variables
35   USE trdtra          ! trends manager: tracers
36   USE traqsr          ! penetrative solar radiation (needed for nksr)
37   USE phycst          ! physical constant
38   USE ldftra          ! lateral physics : tracers
39   USE ldfslp          ! lateral physics : slopes
40   USE bdy_oce  , ONLY : ln_bdy
41   USE bdytra          ! open boundary condition (bdy_tra routine)
42   !
43   USE in_out_manager  ! I/O manager
44   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
45   USE prtctl          ! Print control
46   USE timing          ! Timing
47#if defined key_agrif
48   USE agrif_oce_interp
49#endif
50
51   IMPLICIT NONE
52   PRIVATE
53
54   PUBLIC   tra_atf       ! routine called by step.F90
55   PUBLIC   tra_atf_fix   ! to be used in trcnxt
56   PUBLIC   tra_atf_vvl   ! to be used in trcnxt
57
58   !! * Substitutions
59#  include "do_loop_substitute.h90"
60#  include "domzgr_substitute.h90"
61   !!----------------------------------------------------------------------
62   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
63   !! $Id$
64   !! Software governed by the CeCILL license (see ./LICENSE)
65   !!----------------------------------------------------------------------
66CONTAINS
67
68   SUBROUTINE tra_atf( kt, Kbb, Kmm, Kaa, pts )
69      !!----------------------------------------------------------------------
70      !!                   ***  ROUTINE traatf  ***
71      !!
72      !! ** Purpose :   Apply the boundary condition on the after temperature
73      !!             and salinity fields and add the Asselin time filter on now fields.
74      !!
75      !! ** Method  :   At this stage of the computation, ta and sa are the
76      !!             after temperature and salinity as the time stepping has
77      !!             been performed in trazdf_imp or trazdf_exp module.
78      !!
79      !!              - Apply lateral boundary conditions on (ta,sa)
80      !!             at the local domain   boundaries through lbc_lnk call,
81      !!             at the one-way open boundaries (ln_bdy=T),
82      !!             at the AGRIF zoom   boundaries (lk_agrif=T)
83      !!
84      !!              - Update lateral boundary conditions on AGRIF children
85      !!             domains (lk_agrif=T)
86      !!
87      !! ** Action  : - ts(Kmm) time filtered
88      !!----------------------------------------------------------------------
89      INTEGER                                  , INTENT(in   ) :: kt             ! ocean time-step index
90      INTEGER                                  , INTENT(in   ) :: Kbb, Kmm, Kaa  ! time level indices
91      REAL(wp), DIMENSION(jpi,jpj,jpk,jpts,jpt), INTENT(inout) :: pts            ! active tracers
92      !!
93      INTEGER  ::   ji, jj, jk, jn   ! dummy loop indices
94      REAL(wp) ::   zfact            ! local scalars
95      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) ::   ztrdt, ztrds
96      !!----------------------------------------------------------------------
97      !
98      IF( ln_timing )   CALL timing_start( 'tra_atf')
99      !
100      IF( kt == nit000 ) THEN
101         IF(lwp) WRITE(numout,*)
102         IF(lwp) WRITE(numout,*) 'tra_atf : apply Asselin time filter to "now" fields'
103         IF(lwp) WRITE(numout,*) '~~~~~~~'
104      ENDIF
105
106      ! Update after tracer on domain lateral boundaries
107      !
108#if defined key_agrif
109      CALL Agrif_tra                     ! AGRIF zoom boundaries
110#endif
111      !                                              ! local domain boundaries  (T-point, unchanged sign)
112      CALL lbc_lnk_multi( 'traatf', pts(:,:,:,jp_tem,Kaa), 'T', 1., pts(:,:,:,jp_sal,Kaa), 'T', 1. )
113      !
114      IF( ln_bdy )   CALL bdy_tra( kt, Kbb, pts, Kaa )  ! BDY open boundaries
115
116      ! set time step size (Euler/Leapfrog)
117      IF( neuler == 0 .AND. kt == nit000 ) THEN   ;   r2dt =        rdt   ! at nit000             (Euler)
118      ELSEIF( kt <= nit000 + 1 )           THEN   ;   r2dt = 2._wp* rdt   ! at nit000 or nit000+1 (Leapfrog)
119      ENDIF
120
121      ! trends computation initialisation
122      IF( l_trdtra )   THEN
123         ALLOCATE( ztrdt(jpi,jpj,jpk) , ztrds(jpi,jpj,jpk) )
124         ztrdt(:,:,jpk) = 0._wp
125         ztrds(:,:,jpk) = 0._wp
126         IF( ln_traldf_iso ) THEN              ! diagnose the "pure" Kz diffusive trend
127            CALL trd_tra( kt, Kmm, Kaa, 'TRA', jp_tem, jptra_zdfp, ztrdt )
128            CALL trd_tra( kt, Kmm, Kaa, 'TRA', jp_sal, jptra_zdfp, ztrds )
129         ENDIF
130         ! total trend for the non-time-filtered variables.
131         zfact = 1.0 / rdt
132         ! G Nurser 23 Mar 2017. Recalculate trend as Delta(e3t*T)/e3tn; e3tn cancel from pts(Kmm) terms
133         DO jk = 1, jpkm1
134            ztrdt(:,:,jk) = ( pts(:,:,jk,jp_tem,Kaa)*e3t(:,:,jk,Kaa)   &
135               &                                   / e3t(:,:,jk,Kmm)   &
136               &            - pts(:,:,jk,jp_tem,Kmm)) * zfact
137            ztrds(:,:,jk) = ( pts(:,:,jk,jp_sal,Kaa)*e3t(:,:,jk,Kaa)   &
138               &                                   / e3t(:,:,jk,Kmm)   &
139               &            - pts(:,:,jk,jp_sal,Kmm)) * zfact
140         END DO
141         CALL trd_tra( kt, Kmm, Kaa, 'TRA', jp_tem, jptra_tot, ztrdt )
142         CALL trd_tra( kt, Kmm, Kaa, 'TRA', jp_sal, jptra_tot, ztrds )
143         IF( ln_linssh ) THEN       ! linear sea surface height only
144            ! Store now fields before applying the Asselin filter
145            ! in order to calculate Asselin filter trend later.
146            ztrdt(:,:,:) = pts(:,:,:,jp_tem,Kmm)
147            ztrds(:,:,:) = pts(:,:,:,jp_sal,Kmm)
148         ENDIF
149      ENDIF
150
151      IF( neuler == 0 .AND. kt == nit000 ) THEN       ! Euler time-stepping
152         !
153         IF (l_trdtra .AND. .NOT. ln_linssh ) THEN   ! Zero Asselin filter contribution must be explicitly written out since for vvl
154            !                                        ! Asselin filter is output by tra_atf_vvl that is not called on this time step
155            ztrdt(:,:,:) = 0._wp
156            ztrds(:,:,:) = 0._wp
157            CALL trd_tra( kt, Kmm, Kaa, 'TRA', jp_tem, jptra_atf, ztrdt )
158            CALL trd_tra( kt, Kmm, Kaa, 'TRA', jp_sal, jptra_atf, ztrds )
159         END IF
160         !
161      ELSE                                            ! Leap-Frog + Asselin filter time stepping
162         !
163         IF( ln_linssh ) THEN   ;   CALL tra_atf_fix( kt, Kbb, Kmm, Kaa, nit000,      'TRA', pts, jpts )  ! linear free surface
164         ELSE                   ;   CALL tra_atf_vvl( kt, Kbb, Kmm, Kaa, nit000, rdt, 'TRA', pts, sbc_tsc, sbc_tsc_b, jpts )  ! non-linear free surface
165         ENDIF
166         !
167         CALL lbc_lnk_multi( 'traatf', pts(:,:,:,jp_tem,Kbb) , 'T', 1., pts(:,:,:,jp_sal,Kbb) , 'T', 1., &
168                  &                    pts(:,:,:,jp_tem,Kmm) , 'T', 1., pts(:,:,:,jp_sal,Kmm) , 'T', 1., &
169                  &                    pts(:,:,:,jp_tem,Kaa), 'T', 1., pts(:,:,:,jp_sal,Kaa), 'T', 1.  )
170         !
171      ENDIF
172      !
173      IF( l_trdtra .AND. ln_linssh ) THEN      ! trend of the Asselin filter (tb filtered - tb)/dt
174         zfact = 1._wp / r2dt
175         DO jk = 1, jpkm1
176            ztrdt(:,:,jk) = ( pts(:,:,jk,jp_tem,Kmm) - ztrdt(:,:,jk) ) * zfact
177            ztrds(:,:,jk) = ( pts(:,:,jk,jp_sal,Kmm) - ztrds(:,:,jk) ) * zfact
178         END DO
179         CALL trd_tra( kt, Kmm, Kaa, 'TRA', jp_tem, jptra_atf, ztrdt )
180         CALL trd_tra( kt, Kmm, Kaa, 'TRA', jp_sal, jptra_atf, ztrds )
181      END IF
182      IF( l_trdtra )   DEALLOCATE( ztrdt , ztrds )
183      !
184      !                        ! control print
185      IF(sn_cfctl%l_prtctl)   CALL prt_ctl( tab3d_1=pts(:,:,:,jp_tem,Kmm), clinfo1=' nxt  - Tn: ', mask1=tmask,   &
186         &                                  tab3d_2=pts(:,:,:,jp_sal,Kmm), clinfo2=       ' Sn: ', mask2=tmask )
187      !
188      IF( ln_timing )   CALL timing_stop('tra_atf')
189      !
190   END SUBROUTINE tra_atf
191
192
193   SUBROUTINE tra_atf_fix( kt, Kbb, Kmm, Kaa, kit000, cdtype, pt, kjpt )
194      !!----------------------------------------------------------------------
195      !!                   ***  ROUTINE tra_atf_fix  ***
196      !!
197      !! ** Purpose :   fixed volume: apply the Asselin time filter to the "now" field
198      !!
199      !! ** Method  : - Apply a Asselin time filter on now fields.
200      !!
201      !! ** Action  : - pt(Kmm) ready for the next time step
202      !!----------------------------------------------------------------------
203      INTEGER                                  , INTENT(in   ) ::  kt            ! ocean time-step index
204      INTEGER                                  , INTENT(in   ) ::  Kbb, Kmm, Kaa ! time level indices
205      INTEGER                                  , INTENT(in   ) ::  kit000        ! first time step index
206      CHARACTER(len=3)                         , INTENT(in   ) ::  cdtype        ! =TRA or TRC (tracer indicator)
207      INTEGER                                  , INTENT(in   ) ::  kjpt          ! number of tracers
208      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt,jpt), INTENT(inout) ::  pt            ! tracer fields
209      !
210      INTEGER  ::   ji, jj, jk, jn   ! dummy loop indices
211      REAL(wp) ::   ztn, ztd         ! local scalars
212      !!----------------------------------------------------------------------
213      !
214      IF( kt == kit000 )  THEN
215         IF(lwp) WRITE(numout,*)
216         IF(lwp) WRITE(numout,*) 'tra_atf_fix : time filtering', cdtype
217         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
218      ENDIF
219      !
220      DO jn = 1, kjpt
221         !
222         DO_3D_00_00( 1, jpkm1 )
223            ztn = pt(ji,jj,jk,jn,Kmm)
224            ztd = pt(ji,jj,jk,jn,Kaa) - 2._wp * ztn + pt(ji,jj,jk,jn,Kbb)  ! time laplacian on tracers
225            !
226            pt(ji,jj,jk,jn,Kmm) = ztn + atfp * ztd                      ! pt <-- filtered pt
227         END_3D
228         !
229      END DO
230      !
231   END SUBROUTINE tra_atf_fix
232
233
234   SUBROUTINE tra_atf_vvl( kt, Kbb, Kmm, Kaa, kit000, p2dt, cdtype, pt, psbc_tc, psbc_tc_b, kjpt )
235      !!----------------------------------------------------------------------
236      !!                   ***  ROUTINE tra_atf_vvl  ***
237      !!
238      !! ** Purpose :   Time varying volume: apply the Asselin time filter
239      !!
240      !! ** Method  : - Apply a thickness weighted Asselin time filter on now fields.
241      !!             pt(Kmm)  = ( e3t_Kmm*pt(Kmm) + atfp*[ e3t_Kbb*pt(Kbb) - 2 e3t_Kmm*pt(Kmm) + e3t_Kaa*pt(Kaa) ] )
242      !!                       /( e3t_Kmm         + atfp*[ e3t_Kbb         - 2 e3t_Kmm         + e3t_Kaa    ] )
243      !!
244      !! ** Action  : - pt(Kmm) ready for the next time step
245      !!----------------------------------------------------------------------
246      INTEGER                                  , INTENT(in   ) ::  kt        ! ocean time-step index
247      INTEGER                                  , INTENT(in   ) ::  Kbb, Kmm, Kaa ! time level indices
248      INTEGER                                  , INTENT(in   ) ::  kit000    ! first time step index
249      REAL(wp)                                 , INTENT(in   ) ::  p2dt      ! time-step
250      CHARACTER(len=3)                         , INTENT(in   ) ::  cdtype    ! =TRA or TRC (tracer indicator)
251      INTEGER                                  , INTENT(in   ) ::  kjpt      ! number of tracers
252      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt,jpt), INTENT(inout) ::  pt        ! tracer fields
253      REAL(wp), DIMENSION(jpi,jpj    ,kjpt)    , INTENT(in   ) ::  psbc_tc   ! surface tracer content
254      REAL(wp), DIMENSION(jpi,jpj    ,kjpt)    , INTENT(in   ) ::  psbc_tc_b ! before surface tracer content
255      !
256      LOGICAL  ::   ll_traqsr, ll_rnf, ll_isf   ! local logical
257      INTEGER  ::   ji, jj, jk, jn              ! dummy loop indices
258      REAL(wp) ::   zfact, zfact1, ztc_a , ztc_n , ztc_b , ztc_f , ztc_d    ! local scalar
259      REAL(wp) ::   zfact2, ze3t_b, ze3t_n, ze3t_a, ze3t_f, ze3t_d, zscale  !   -      -
260      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:,:) ::   ztrd_atf
261      !!----------------------------------------------------------------------
262      !
263      IF( kt == kit000 )  THEN
264         IF(lwp) WRITE(numout,*)
265         IF(lwp) WRITE(numout,*) 'tra_atf_vvl : time filtering', cdtype
266         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
267      ENDIF
268      !
269      IF( cdtype == 'TRA' )  THEN
270         ll_traqsr  = ln_traqsr        ! active  tracers case  and  solar penetration
271         ll_rnf     = ln_rnf           ! active  tracers case  and  river runoffs
272         ll_isf     = ln_isf           ! active  tracers case  and  ice shelf melting
273      ELSE                          ! passive tracers case
274         ll_traqsr  = .FALSE.          ! NO solar penetration
275         ll_rnf     = .FALSE.          ! NO river runoffs ????          !!gm BUG ?
276         ll_isf     = .FALSE.          ! NO ice shelf melting/freezing  !!gm BUG ??
277      ENDIF
278      !
279      IF( ( l_trdtra .AND. cdtype == 'TRA' ) .OR. ( l_trdtrc .AND. cdtype == 'TRC' ) )   THEN
280         ALLOCATE( ztrd_atf(jpi,jpj,jpk,kjpt) )
281         ztrd_atf(:,:,:,:) = 0.0_wp
282      ENDIF
283      zfact = 1._wp / p2dt
284      zfact1 = atfp * p2dt
285      zfact2 = zfact1 * r1_rau0
286      DO jn = 1, kjpt
287         DO_3D_00_00( 1, jpkm1 )
288            ze3t_b = e3t(ji,jj,jk,Kbb)
289            ze3t_n = e3t(ji,jj,jk,Kmm)
290            ze3t_a = e3t(ji,jj,jk,Kaa)
291            !                                         ! tracer content at Before, now and after
292            ztc_b  = pt(ji,jj,jk,jn,Kbb) * ze3t_b
293            ztc_n  = pt(ji,jj,jk,jn,Kmm) * ze3t_n
294            ztc_a  = pt(ji,jj,jk,jn,Kaa) * ze3t_a
295            !
296            ze3t_d = ze3t_a - 2. * ze3t_n + ze3t_b
297            ztc_d  = ztc_a  - 2. * ztc_n  + ztc_b
298            !
299            ze3t_f = ze3t_n + atfp * ze3t_d
300            ztc_f  = ztc_n  + atfp * ztc_d
301            !
302            ! Add asselin correction on scale factors:
303            zscale = tmask(ji,jj,jk) * e3t(ji,jj,jk,Kmm) / ( ht(ji,jj) + 1._wp - ssmask(ji,jj) )
304            ze3t_f = ze3t_f - zfact2 * zscale * ( emp_b(ji,jj) - emp(ji,jj) )
305            IF ( ll_rnf ) ze3t_f = ze3t_f + zfact2 * zscale * (    rnf_b(ji,jj) -    rnf(ji,jj) )
306            IF ( ll_isf ) THEN
307               IF ( ln_isfcav_mlt ) ze3t_f = ze3t_f - zfact2 * zscale * ( fwfisf_cav_b(ji,jj) - fwfisf_cav(ji,jj) )
308               IF ( ln_isfpar_mlt ) ze3t_f = ze3t_f - zfact2 * zscale * ( fwfisf_par_b(ji,jj) - fwfisf_par(ji,jj) )
309            ENDIF
310            !
311            IF( jk == mikt(ji,jj) ) THEN           ! first level
312               ztc_f  = ztc_f  - zfact1 * ( psbc_tc(ji,jj,jn) - psbc_tc_b(ji,jj,jn) )
313            ENDIF
314            !
315            ! solar penetration (temperature only)
316            IF( ll_traqsr .AND. jn == jp_tem .AND. jk <= nksr )                            &
317               &     ztc_f  = ztc_f  - zfact1 * ( qsr_hc(ji,jj,jk) - qsr_hc_b(ji,jj,jk) )
318               !
319            !
320            IF( ll_rnf .AND. jk <= nk_rnf(ji,jj) )                                          &
321               &     ztc_f  = ztc_f  - zfact1 * ( rnf_tsc(ji,jj,jn) - rnf_tsc_b(ji,jj,jn) ) &
322               &                              * e3t(ji,jj,jk,Kmm) / h_rnf(ji,jj)
323
324            !
325            ! ice shelf
326            IF( ll_isf ) THEN
327               !
328               ! melt in the cavity
329               IF ( ln_isfcav_mlt ) THEN
330                  ! level fully include in the Losch_2008 ice shelf boundary layer
331                  IF ( jk >= misfkt_cav(ji,jj) .AND. jk < misfkb_cav(ji,jj) ) THEN
332                     ztc_f  = ztc_f  - zfact1 * ( risf_cav_tsc(ji,jj,jn) - risf_cav_tsc_b(ji,jj,jn) ) &
333                        &                     * e3t(ji,jj,jk,Kmm) / rhisf_tbl_cav(ji,jj)
334                  END IF
335                  ! level partially include in Losch_2008 ice shelf boundary layer
336                  IF ( jk == misfkb_cav(ji,jj) ) THEN
337                     ztc_f  = ztc_f  - zfact1 * ( risf_cav_tsc(ji,jj,jn) - risf_cav_tsc_b(ji,jj,jn) )  &
338                            &                 * e3t(ji,jj,jk,Kmm) / rhisf_tbl_cav(ji,jj)   &
339                            &                 * rfrac_tbl_cav(ji,jj)
340                  END IF
341               END IF
342               !
343               ! parametrised melt (cavity closed)
344               IF ( ln_isfpar_mlt ) THEN
345                  ! level fully include in the Losch_2008 ice shelf boundary layer
346                  IF ( jk >= misfkt_par(ji,jj) .AND. jk < misfkb_par(ji,jj) ) THEN
347                     ztc_f  = ztc_f  - zfact1 * ( risf_par_tsc(ji,jj,jn) - risf_par_tsc_b(ji,jj,jn) )  &
348                            &                 * e3t(ji,jj,jk,Kmm) / rhisf_tbl_par(ji,jj)
349                  END IF
350                  ! level partially include in Losch_2008 ice shelf boundary layer
351                  IF ( jk == misfkb_par(ji,jj) ) THEN
352                     ztc_f  = ztc_f  - zfact1 * ( risf_par_tsc(ji,jj,jn) - risf_par_tsc_b(ji,jj,jn) )  &
353                            &                 * e3t(ji,jj,jk,Kmm) / rhisf_tbl_par(ji,jj)   &
354                            &                 * rfrac_tbl_par(ji,jj)
355                  END IF
356               END IF
357               !
358               ! ice sheet coupling correction
359               IF ( ln_isfcpl ) THEN
360                  !
361                  ! at kt = nit000,  risfcpl_vol_n = 0 and risfcpl_vol_b = risfcpl_vol so contribution nul
362                  IF ( ln_rstart .AND. kt == nit000+1 ) THEN
363                     ztc_f  = ztc_f  + zfact1 * risfcpl_tsc(ji,jj,jk,jn) * r1_e1e2t(ji,jj)
364                     ! Shouldn't volume increment be spread according thanks to zscale  ?
365                     ze3t_f = ze3t_f - zfact1 * risfcpl_vol(ji,jj,jk   ) * r1_e1e2t(ji,jj)
366                  END IF
367                  !
368               END IF
369               !
370            END IF
371            !
372            ze3t_f = 1.e0 / ze3t_f
373            pt(ji,jj,jk,jn,Kmm) = ztc_f * ze3t_f    ! time filtered "now" field
374            !
375            IF( ( l_trdtra .and. cdtype == 'TRA' ) .OR. ( l_trdtrc .and. cdtype == 'TRC' ) ) THEN
376               ztrd_atf(ji,jj,jk,jn) = (ztc_f - ztc_n) * zfact/ze3t_n
377            ENDIF
378            !
379         END_3D
380         !
381      END DO
382      !
383      IF( ( l_trdtra .AND. cdtype == 'TRA' ) .OR. ( l_trdtrc .AND. cdtype == 'TRC' ) )   THEN
384         IF( l_trdtra .AND. cdtype == 'TRA' ) THEN
385            CALL trd_tra( kt, Kmm, Kaa, cdtype, jp_tem, jptra_atf, ztrd_atf(:,:,:,jp_tem) )
386            CALL trd_tra( kt, Kmm, Kaa, cdtype, jp_sal, jptra_atf, ztrd_atf(:,:,:,jp_sal) )
387         ENDIF
388         IF( l_trdtrc .AND. cdtype == 'TRC' ) THEN
389            DO jn = 1, kjpt
390               CALL trd_tra( kt, Kmm, Kaa, cdtype, jn, jptra_atf, ztrd_atf(:,:,:,jn) )
391            END DO
392         ENDIF
393         DEALLOCATE( ztrd_atf )
394      ENDIF
395      !
396   END SUBROUTINE tra_atf_vvl
397
398   !!======================================================================
399END MODULE traatf
Note: See TracBrowser for help on using the repository browser.