New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traatfQCO.F90 in NEMO/branches/2020/dev_r12377_KERNEL-06_techene_e3/src/OCE/TRA – NEMO

source: NEMO/branches/2020/dev_r12377_KERNEL-06_techene_e3/src/OCE/TRA/traatfQCO.F90 @ 12724

Last change on this file since 12724 was 12724, checked in by techene, 4 years ago

branch KERNEL-06 : merge with trunk@12698 #2385 - in duplcated files : changes to comply to the new trunk variables and some loop bug fixes

  • Property svn:keywords set to Id
File size: 19.9 KB
Line 
1MODULE traatfqco
2   !!======================================================================
3   !!                       ***  MODULE  traatfqco  ***
4   !! Ocean active tracers:  Asselin time filtering for temperature and salinity
5   !!======================================================================
6   !! History :  OPA  !  1991-11  (G. Madec)  Original code
7   !!            7.0  !  1993-03  (M. Guyon)  symetrical conditions
8   !!            8.0  !  1996-02  (G. Madec & M. Imbard)  opa release 8.0
9   !!             -   !  1996-04  (A. Weaver)  Euler forward step
10   !!            8.2  !  1999-02  (G. Madec, N. Grima)  semi-implicit pressure grad.
11   !!  NEMO      1.0  !  2002-08  (G. Madec)  F90: Free form and module
12   !!             -   !  2002-11  (C. Talandier, A-M Treguier) Open boundaries
13   !!             -   !  2005-04  (C. Deltel) Add Asselin trend in the ML budget
14   !!            2.0  !  2006-02  (L. Debreu, C. Mazauric) Agrif implementation
15   !!            3.0  !  2008-06  (G. Madec)  time stepping always done in trazdf
16   !!            3.1  !  2009-02  (G. Madec, R. Benshila)  re-introduce the vvl option
17   !!            3.3  !  2010-04  (M. Leclair, G. Madec)  semi-implicit hpg with asselin filter + modified LF-RA
18   !!             -   !  2010-05  (C. Ethe, G. Madec)  merge TRC-TRA
19   !!            4.1  !  2019-08  (A. Coward, D. Storkey) rename tranxt.F90 -> traatfLF.F90. Now only does time filtering.
20   !!----------------------------------------------------------------------
21
22   !!----------------------------------------------------------------------
23   !!   tra_atf       : time filtering on tracers
24   !!   tra_atf_fix   : time filtering on tracers : fixed    volume case
25   !!   tra_atf_vvl   : time filtering on tracers : variable volume case
26   !!----------------------------------------------------------------------
27   USE oce             ! ocean dynamics and tracers variables
28   USE dom_oce         ! ocean space and time domain variables
29   USE sbc_oce         ! surface boundary condition: ocean
30   USE sbcrnf          ! river runoffs
31   USE isf_oce         ! ice shelf melting
32   USE zdf_oce         ! ocean vertical mixing
33   USE domvvl          ! variable volume
34   USE trd_oce         ! trends: ocean variables
35   USE trdtra          ! trends manager: tracers
36   USE traqsr          ! penetrative solar radiation (needed for nksr)
37   USE phycst          ! physical constant
38   USE ldftra          ! lateral physics : tracers
39   USE ldfslp          ! lateral physics : slopes
40   USE bdy_oce  , ONLY : ln_bdy
41   USE bdytra          ! open boundary condition (bdy_tra routine)
42   !
43   USE in_out_manager  ! I/O manager
44   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
45   USE prtctl          ! Print control
46   USE timing          ! Timing
47#if defined key_agrif
48   USE agrif_oce_interp
49#endif
50
51   IMPLICIT NONE
52   PRIVATE
53
54   PUBLIC   tra_atf_qco       ! routine called by step.F90
55   PUBLIC   tra_atf_fix_lf   ! to be used in trcnxt !!st WARNING discrepancy here interpol is used
56   PUBLIC   tra_atf_qco_lf    ! to be used in trcnxt !!st WARNING discrepancy here interpol is used
57
58   !! * Substitutions
59#  include "do_loop_substitute.h90"
60#  include "domzgr_substitute.h90"
61   !!----------------------------------------------------------------------
62   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
63   !! $Id$
64   !! Software governed by the CeCILL license (see ./LICENSE)
65   !!----------------------------------------------------------------------
66CONTAINS
67
68   SUBROUTINE tra_atf_qco( kt, Kbb, Kmm, Kaa, pts )
69      !!----------------------------------------------------------------------
70      !!                   ***  ROUTINE traatfLF  ***
71      !!
72      !! ** Purpose :   Apply the boundary condition on the after temperature
73      !!             and salinity fields and add the Asselin time filter on now fields.
74      !!
75      !! ** Method  :   At this stage of the computation, ta and sa are the
76      !!             after temperature and salinity as the time stepping has
77      !!             been performed in trazdf_imp or trazdf_exp module.
78      !!
79      !!              - Apply lateral boundary conditions on (ta,sa)
80      !!             at the local domain   boundaries through lbc_lnk call,
81      !!             at the one-way open boundaries (ln_bdy=T),
82      !!             at the AGRIF zoom   boundaries (lk_agrif=T)
83      !!
84      !!              - Update lateral boundary conditions on AGRIF children
85      !!             domains (lk_agrif=T)
86      !!
87      !! ** Action  : - ts(Kmm) time filtered
88      !!----------------------------------------------------------------------
89      INTEGER                                  , INTENT(in   ) :: kt             ! ocean time-step index
90      INTEGER                                  , INTENT(in   ) :: Kbb, Kmm, Kaa  ! time level indices
91      REAL(wp), DIMENSION(jpi,jpj,jpk,jpts,jpt), INTENT(inout) :: pts            ! active tracers
92      !!
93      INTEGER  ::   ji, jj, jk, jn   ! dummy loop indices
94      REAL(wp) ::   zfact            ! local scalars
95      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) ::   ztrdt, ztrds
96      !!----------------------------------------------------------------------
97      !
98      IF( ln_timing )   CALL timing_start( 'tra_atf_qco')
99      !
100      IF( kt == nit000 ) THEN
101         IF(lwp) WRITE(numout,*)
102         IF(lwp) WRITE(numout,*) 'tra_atf_qco : apply Asselin time filter to "now" fields'
103         IF(lwp) WRITE(numout,*) '~~~~~~~'
104      ENDIF
105
106!       ! Update after tracer on domain lateral boundaries
107!       !
108! #if defined key_agrif
109!       CALL Agrif_tra                     ! AGRIF zoom boundaries
110! #endif
111!       !                                              ! local domain boundaries  (T-point, unchanged sign)
112!       CALL lbc_lnk_multi( 'traatfLF', pts(:,:,:,jp_tem,Kaa), 'T', 1., pts(:,:,:,jp_sal,Kaa), 'T', 1. )
113!       !
114!       IF( ln_bdy )   CALL bdy_tra( kt, Kbb, pts, Kaa )  ! BDY open boundaries
115
116      ! trends computation initialisation
117      IF( l_trdtra )   THEN
118         ALLOCATE( ztrdt(jpi,jpj,jpk) , ztrds(jpi,jpj,jpk) )
119         ztrdt(:,:,jpk) = 0._wp
120         ztrds(:,:,jpk) = 0._wp
121         IF( ln_traldf_iso ) THEN              ! diagnose the "pure" Kz diffusive trend
122            CALL trd_tra( kt, Kmm, Kaa, 'TRA', jp_tem, jptra_zdfp, ztrdt )
123            CALL trd_tra( kt, Kmm, Kaa, 'TRA', jp_sal, jptra_zdfp, ztrds )
124         ENDIF
125         ! total trend for the non-time-filtered variables.
126         zfact = 1.0 / rn_Dt
127         ! G Nurser 23 Mar 2017. Recalculate trend as Delta(e3t*T)/e3tn; e3tn cancel from pts(Kmm) terms
128         DO jk = 1, jpkm1
129            ! ztrdt(:,:,jk) = ( pts(:,:,jk,jp_tem,Kaa)*e3t(:,:,jk,Kaa) / e3t(:,:,jk,Kmm) - pts(:,:,jk,jp_tem,Kmm)) * zfact
130            ! ztrds(:,:,jk) = ( pts(:,:,jk,jp_sal,Kaa)*e3t(:,:,jk,Kaa) / e3t(:,:,jk,Kmm) - pts(:,:,jk,jp_sal,Kmm)) * zfact
131            ztrdt(:,:,jk) = ( pts(:,:,jk,jp_tem,Kaa) * (1._wp + r3t(:,:,Kaa) * tmask(:,:,jk))/(1._wp + r3t(:,:,Kmm) * tmask(:,:,jk))  &
132               &            - pts(:,:,jk,jp_tem,Kmm) ) * zfact
133            ztrds(:,:,jk) = ( pts(:,:,jk,jp_sal,Kaa) * (1._wp + r3t(:,:,Kaa) * tmask(:,:,jk))/(1._wp + r3t(:,:,Kmm) * tmask(:,:,jk))  &
134               &            - pts(:,:,jk,jp_sal,Kmm) ) * zfact
135         END DO
136         CALL trd_tra( kt, Kmm, Kaa, 'TRA', jp_tem, jptra_tot, ztrdt )
137         CALL trd_tra( kt, Kmm, Kaa, 'TRA', jp_sal, jptra_tot, ztrds )
138         IF( ln_linssh ) THEN       ! linear sea surface height only
139            ! Store now fields before applying the Asselin filter
140            ! in order to calculate Asselin filter trend later.
141            ztrdt(:,:,:) = pts(:,:,:,jp_tem,Kmm)
142            ztrds(:,:,:) = pts(:,:,:,jp_sal,Kmm)
143         ENDIF
144      ENDIF
145
146      IF( l_1st_euler ) THEN       ! Euler time-stepping
147         !
148         IF (l_trdtra .AND. .NOT. ln_linssh ) THEN   ! Zero Asselin filter contribution must be explicitly written out since for vvl
149            !                                        ! Asselin filter is output by tra_atf_vvl that is not called on this time step
150            ztrdt(:,:,:) = 0._wp
151            ztrds(:,:,:) = 0._wp
152            CALL trd_tra( kt, Kmm, Kaa, 'TRA', jp_tem, jptra_atf, ztrdt )
153            CALL trd_tra( kt, Kmm, Kaa, 'TRA', jp_sal, jptra_atf, ztrds )
154         END IF
155         !
156      ELSE                                            ! Leap-Frog + Asselin filter time stepping
157         !
158         IF ( ln_linssh ) THEN   ;   CALL tra_atf_fix_lf( kt, Kbb, Kmm, Kaa, nit000,        'TRA', pts, jpts )  ! linear free surface
159         ELSE                    ;   CALL tra_atf_qco_lf( kt, Kbb, Kmm, Kaa, nit000, rn_Dt, 'TRA', pts, sbc_tsc, sbc_tsc_b, jpts )  ! non-linear free surface
160         ENDIF
161         !
162         CALL lbc_lnk_multi( 'traatfqco', pts(:,:,:,jp_tem,Kbb) , 'T', 1., pts(:,:,:,jp_sal,Kbb) , 'T', 1., &
163                  &                    pts(:,:,:,jp_tem,Kmm) , 'T', 1., pts(:,:,:,jp_sal,Kmm) , 'T', 1., &
164                  &                    pts(:,:,:,jp_tem,Kaa), 'T', 1., pts(:,:,:,jp_sal,Kaa), 'T', 1.  )
165         !
166      ENDIF
167      !
168      IF( l_trdtra .AND. ln_linssh ) THEN      ! trend of the Asselin filter (tb filtered - tb)/dt
169         DO jk = 1, jpkm1
170            ztrdt(:,:,jk) = ( pts(:,:,jk,jp_tem,Kmm) - ztrdt(:,:,jk) ) * r1_Dt
171            ztrds(:,:,jk) = ( pts(:,:,jk,jp_sal,Kmm) - ztrds(:,:,jk) ) * r1_Dt
172         END DO
173         CALL trd_tra( kt, Kmm, Kaa, 'TRA', jp_tem, jptra_atf, ztrdt )
174         CALL trd_tra( kt, Kmm, Kaa, 'TRA', jp_sal, jptra_atf, ztrds )
175      END IF
176      IF( l_trdtra )   DEALLOCATE( ztrdt , ztrds )
177      !
178      !                        ! control print
179      IF(sn_cfctl%l_prtctl)   CALL prt_ctl( tab3d_1=pts(:,:,:,jp_tem,Kmm), clinfo1=' nxt  - Tn: ', mask1=tmask,   &
180         &                                  tab3d_2=pts(:,:,:,jp_sal,Kmm), clinfo2=       ' Sn: ', mask2=tmask )
181      !
182      IF( ln_timing )   CALL timing_stop('tra_atf_qco')
183      !
184   END SUBROUTINE tra_atf_qco
185
186
187   SUBROUTINE tra_atf_fix_lf( kt, Kbb, Kmm, Kaa, kit000, cdtype, pt, kjpt )
188      !!----------------------------------------------------------------------
189      !!                   ***  ROUTINE tra_atf_fix  ***
190      !!
191      !! ** Purpose :   fixed volume: apply the Asselin time filter to the "now" field
192      !!
193      !! ** Method  : - Apply a Asselin time filter on now fields.
194      !!
195      !! ** Action  : - pt(Kmm) ready for the next time step
196      !!----------------------------------------------------------------------
197      INTEGER                                  , INTENT(in   ) ::  kt            ! ocean time-step index
198      INTEGER                                  , INTENT(in   ) ::  Kbb, Kmm, Kaa ! time level indices
199      INTEGER                                  , INTENT(in   ) ::  kit000        ! first time step index
200      CHARACTER(len=3)                         , INTENT(in   ) ::  cdtype        ! =TRA or TRC (tracer indicator)
201      INTEGER                                  , INTENT(in   ) ::  kjpt          ! number of tracers
202      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt,jpt), INTENT(inout) ::  pt            ! tracer fields
203      !
204      INTEGER  ::   ji, jj, jk, jn   ! dummy loop indices
205      REAL(wp) ::   ztn, ztd         ! local scalars
206      !!----------------------------------------------------------------------
207      !
208      IF( kt == kit000 )  THEN
209         IF(lwp) WRITE(numout,*)
210         IF(lwp) WRITE(numout,*) 'tra_atf_fix_lf : time filtering', cdtype
211         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
212      ENDIF
213      !
214      DO jn = 1, kjpt
215         !
216         DO_3D_00_00( 1, jpkm1 )
217            ztn = pt(ji,jj,jk,jn,Kmm)
218            ztd = pt(ji,jj,jk,jn,Kaa) - 2._wp * ztn + pt(ji,jj,jk,jn,Kbb)  ! time laplacian on tracers
219            !
220            pt(ji,jj,jk,jn,Kmm) = ztn + rn_atfp * ztd                      ! pt <-- filtered pt
221         END_3D
222         !
223      END DO
224      !
225   END SUBROUTINE tra_atf_fix_lf
226
227
228   SUBROUTINE tra_atf_qco_lf( kt, Kbb, Kmm, Kaa, kit000, p2dt, cdtype, pt, psbc_tc, psbc_tc_b, kjpt )
229      !!----------------------------------------------------------------------
230      !!                   ***  ROUTINE tra_atf_vvl  ***
231      !!
232      !! ** Purpose :   Time varying volume: apply the Asselin time filter
233      !!
234      !! ** Method  : - Apply a thickness weighted Asselin time filter on now fields.
235      !!             pt(Kmm)  = ( e3t_m*pt(Kmm) + rn_atfp*[ e3t_b*pt(Kbb) - 2 e3t_m*pt(Kmm) + e3t_a*pt(Kaa) ] )
236      !!                       /( e3t_m         + rn_atfp*[ e3t_b         - 2 e3t_m         + e3t_a    ] )
237      !!
238      !! ** Action  : - pt(Kmm) ready for the next time step
239      !!----------------------------------------------------------------------
240      INTEGER                                  , INTENT(in   ) ::  kt        ! ocean time-step index
241      INTEGER                                  , INTENT(in   ) ::  Kbb, Kmm, Kaa ! time level indices
242      INTEGER                                  , INTENT(in   ) ::  kit000    ! first time step index
243      REAL(wp)                                 , INTENT(in   ) ::  p2dt      ! time-step
244      CHARACTER(len=3)                         , INTENT(in   ) ::  cdtype    ! =TRA or TRC (tracer indicator)
245      INTEGER                                  , INTENT(in   ) ::  kjpt      ! number of tracers
246      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt,jpt), INTENT(inout) ::  pt        ! tracer fields
247      REAL(wp), DIMENSION(jpi,jpj    ,kjpt)    , INTENT(in   ) ::  psbc_tc   ! surface tracer content
248      REAL(wp), DIMENSION(jpi,jpj    ,kjpt)    , INTENT(in   ) ::  psbc_tc_b ! before surface tracer content
249      !
250      LOGICAL  ::   ll_traqsr, ll_rnf, ll_isf   ! local logical
251      INTEGER  ::   ji, jj, jk, jn              ! dummy loop indices
252      REAL(wp) ::   zfact, zfact1, ztc_a , ztc_n , ztc_b , ztc_f , ztc_d    ! local scalar
253      REAL(wp) ::   zfact2, ze3t_b, ze3t_n, ze3t_a, ze3t_f, ze3t_d  !   -      -
254      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:,:) ::   ztrd_atf
255      !!----------------------------------------------------------------------
256      !
257      IF( kt == kit000 )  THEN
258         IF(lwp) WRITE(numout,*)
259         IF(lwp) WRITE(numout,*) 'tra_atf_qco : time filtering', cdtype
260         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
261      ENDIF
262      !
263      IF( cdtype == 'TRA' )  THEN
264         ll_traqsr  = ln_traqsr        ! active  tracers case  and  solar penetration
265         ll_rnf     = ln_rnf           ! active  tracers case  and  river runoffs
266         ll_isf     = ln_isf           ! active  tracers case  and  ice shelf melting
267      ELSE                          ! passive tracers case
268         ll_traqsr  = .FALSE.          ! NO solar penetration
269         ll_rnf     = .FALSE.          ! NO river runoffs ????          !!gm BUG ?
270         ll_isf     = .FALSE.          ! NO ice shelf melting/freezing  !!gm BUG ??
271      ENDIF
272      !
273      IF( ( l_trdtra .AND. cdtype == 'TRA' ) .OR. ( l_trdtrc .AND. cdtype == 'TRC' ) )   THEN
274         ALLOCATE( ztrd_atf(jpi,jpj,jpk,kjpt) )
275         ztrd_atf(:,:,:,:) = 0.0_wp
276      ENDIF
277      zfact = 1._wp / p2dt
278      zfact1 = rn_atfp * p2dt
279      zfact2 = zfact1 * r1_rho0
280      DO jn = 1, kjpt
281         DO_3D_00_00( 1, jpkm1 )
282            ze3t_b = e3t(ji,jj,jk,Kbb)
283            ze3t_n = e3t(ji,jj,jk,Kmm)
284            ze3t_a = e3t(ji,jj,jk,Kaa)
285            !                                         ! tracer content at Before, now and after
286            ztc_b  = pt(ji,jj,jk,jn,Kbb) * ze3t_b
287            ztc_n  = pt(ji,jj,jk,jn,Kmm) * ze3t_n
288            ztc_a  = pt(ji,jj,jk,jn,Kaa) * ze3t_a
289            !
290            ze3t_d = ze3t_a - 2. * ze3t_n + ze3t_b
291            ztc_d  = ztc_a  - 2. * ztc_n  + ztc_b
292            !
293            ztc_f  = ztc_n  + rn_atfp * ztc_d
294            !
295            ! Asselin correction on scale factors is done via ssh in r3t_f
296            ze3t_f = e3t_0(ji,jj,jk) * ( 1._wp + r3t_f(ji,jj) * tmask(ji,jj,jk) )
297
298            !
299            IF( jk == mikt(ji,jj) ) THEN           ! first level
300               ztc_f  = ztc_f  - zfact1 * ( psbc_tc(ji,jj,jn) - psbc_tc_b(ji,jj,jn) )
301            ENDIF
302            !
303            ! solar penetration (temperature only)
304            IF( ll_traqsr .AND. jn == jp_tem .AND. jk <= nksr )                            &
305               &     ztc_f  = ztc_f  - zfact1 * ( qsr_hc(ji,jj,jk) - qsr_hc_b(ji,jj,jk) )
306               !
307            !
308            IF( ll_rnf .AND. jk <= nk_rnf(ji,jj) )                                          &
309               &     ztc_f  = ztc_f  - zfact1 * ( rnf_tsc(ji,jj,jn) - rnf_tsc_b(ji,jj,jn) ) &
310               &                              * e3t(ji,jj,jk,Kmm) / h_rnf(ji,jj)
311
312            !
313            ! ice shelf
314            IF( ll_isf ) THEN
315               !
316               ! melt in the cavity
317               IF ( ln_isfcav_mlt ) THEN
318                  ! level fully include in the Losch_2008 ice shelf boundary layer
319                  IF ( jk >= misfkt_cav(ji,jj) .AND. jk < misfkb_cav(ji,jj) ) THEN
320                     ztc_f  = ztc_f  - zfact1 * ( risf_cav_tsc(ji,jj,jn) - risf_cav_tsc_b(ji,jj,jn) ) &
321                        &                     * e3t(ji,jj,jk,Kmm) / rhisf_tbl_cav(ji,jj)
322                  END IF
323                  ! level partially include in Losch_2008 ice shelf boundary layer
324                  IF ( jk == misfkb_cav(ji,jj) ) THEN
325                     ztc_f  = ztc_f  - zfact1 * ( risf_cav_tsc(ji,jj,jn) - risf_cav_tsc_b(ji,jj,jn) )  &
326                            &                 * e3t(ji,jj,jk,Kmm) / rhisf_tbl_cav(ji,jj)               &
327                            &                 * rfrac_tbl_cav(ji,jj)
328                  END IF
329               END IF
330               !
331               ! parametrised melt (cavity closed)
332               IF ( ln_isfpar_mlt ) THEN
333                  ! level fully include in the Losch_2008 ice shelf boundary layer
334                  IF ( jk >= misfkt_par(ji,jj) .AND. jk < misfkb_par(ji,jj) ) THEN
335                     ztc_f  = ztc_f  - zfact1 * ( risf_par_tsc(ji,jj,jn) - risf_par_tsc_b(ji,jj,jn) )  &
336                            &                 * e3t(ji,jj,jk,Kmm) / rhisf_tbl_par(ji,jj)
337                  END IF
338                  ! level partially include in Losch_2008 ice shelf boundary layer
339                  IF ( jk == misfkb_par(ji,jj) ) THEN
340                     ztc_f  = ztc_f  - zfact1 * ( risf_par_tsc(ji,jj,jn) - risf_par_tsc_b(ji,jj,jn) )  &
341                            &                 * e3t(ji,jj,jk,Kmm) / rhisf_tbl_par(ji,jj)               &
342                            &                 * rfrac_tbl_par(ji,jj)
343                  END IF
344               END IF
345               !
346               ! ice sheet coupling correction
347               IF ( ln_isfcpl ) THEN
348                  !
349                  ! at kt = nit000,  risfcpl_vol_n = 0 and risfcpl_vol_b = risfcpl_vol so contribution nul
350                  IF ( ln_rstart .AND. kt == nit000+1 ) THEN
351                     ztc_f  = ztc_f  + zfact1 * risfcpl_tsc(ji,jj,jk,jn) * r1_e1e2t(ji,jj)
352                     ! Shouldn't volume increment be spread according thanks to zscale  ?
353                  END IF
354                  !
355               END IF
356               !
357            END IF
358            !
359            ze3t_f = 1.e0 / ze3t_f
360            pt(ji,jj,jk,jn,Kmm) = ztc_f * ze3t_f    ! time filtered "now" field
361            !
362            IF( ( l_trdtra .and. cdtype == 'TRA' ) .OR. ( l_trdtrc .and. cdtype == 'TRC' ) ) THEN
363               ztrd_atf(ji,jj,jk,jn) = (ztc_f - ztc_n) * zfact/ze3t_n
364            ENDIF
365            !
366         END_3D
367         !
368      END DO
369      !
370      IF( ( l_trdtra .AND. cdtype == 'TRA' ) .OR. ( l_trdtrc .AND. cdtype == 'TRC' ) )   THEN
371         IF( l_trdtra .AND. cdtype == 'TRA' ) THEN
372            CALL trd_tra( kt, Kmm, Kaa, cdtype, jp_tem, jptra_atf, ztrd_atf(:,:,:,jp_tem) )
373            CALL trd_tra( kt, Kmm, Kaa, cdtype, jp_sal, jptra_atf, ztrd_atf(:,:,:,jp_sal) )
374         ENDIF
375         IF( l_trdtrc .AND. cdtype == 'TRC' ) THEN
376            DO jn = 1, kjpt
377               CALL trd_tra( kt, Kmm, Kaa, cdtype, jn, jptra_atf, ztrd_atf(:,:,:,jn) )
378            END DO
379         ENDIF
380         DEALLOCATE( ztrd_atf )
381      ENDIF
382      !
383   END SUBROUTINE tra_atf_qco_lf
384
385   !!======================================================================
386END MODULE traatfqco
Note: See TracBrowser for help on using the repository browser.