New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traqsr.F90 in NEMO/branches/2020/dev_r12377_KERNEL-06_techene_e3/src/OCE/TRA – NEMO

source: NEMO/branches/2020/dev_r12377_KERNEL-06_techene_e3/src/OCE/TRA/traqsr.F90 @ 12590

Last change on this file since 12590 was 12590, checked in by techene, 2 years ago

all: add e3 substitute, OCE/DOM/domzgr_substitute.h90: correct a bug for e3f

  • Property svn:keywords set to Id
File size: 21.2 KB
Line 
1MODULE traqsr
2   !!======================================================================
3   !!                       ***  MODULE  traqsr  ***
4   !! Ocean physics:   solar radiation penetration in the top ocean levels
5   !!======================================================================
6   !! History :  OPA  !  1990-10  (B. Blanke)  Original code
7   !!            7.0  !  1991-11  (G. Madec)
8   !!                 !  1996-01  (G. Madec)  s-coordinates
9   !!   NEMO     1.0  !  2002-06  (G. Madec)  F90: Free form and module
10   !!             -   !  2005-11  (G. Madec) zco, zps, sco coordinate
11   !!            3.2  !  2009-04  (G. Madec & NEMO team)
12   !!            3.6  !  2012-05  (C. Rousset) store attenuation coef for use in ice model
13   !!            3.6  !  2015-12  (O. Aumont, J. Jouanno, C. Ethe) use vertical profile of chlorophyll
14   !!            3.7  !  2015-11  (G. Madec, A. Coward)  remove optimisation for fix volume
15   !!----------------------------------------------------------------------
16
17   !!----------------------------------------------------------------------
18   !!   tra_qsr       : temperature trend due to the penetration of solar radiation
19   !!   tra_qsr_init  : initialization of the qsr penetration
20   !!----------------------------------------------------------------------
21   USE oce            ! ocean dynamics and active tracers
22   USE phycst         ! physical constants
23   USE dom_oce        ! ocean space and time domain
24   USE sbc_oce        ! surface boundary condition: ocean
25   USE trc_oce        ! share SMS/Ocean variables
26   USE trd_oce        ! trends: ocean variables
27   USE trdtra         ! trends manager: tracers
28   !
29   USE in_out_manager ! I/O manager
30   USE prtctl         ! Print control
31   USE iom            ! I/O library
32   USE fldread        ! read input fields
33   USE restart        ! ocean restart
34   USE lib_mpp        ! MPP library
35   USE lbclnk         ! ocean lateral boundary conditions (or mpp link)
36   USE timing         ! Timing
37
38   IMPLICIT NONE
39   PRIVATE
40
41   PUBLIC   tra_qsr       ! routine called by step.F90 (ln_traqsr=T)
42   PUBLIC   tra_qsr_init  ! routine called by nemogcm.F90
43
44   !                                 !!* Namelist namtra_qsr: penetrative solar radiation
45   LOGICAL , PUBLIC ::   ln_traqsr    !: light absorption (qsr) flag
46   LOGICAL , PUBLIC ::   ln_qsr_rgb   !: Red-Green-Blue light absorption flag
47   LOGICAL , PUBLIC ::   ln_qsr_2bd   !: 2 band         light absorption flag
48   LOGICAL , PUBLIC ::   ln_qsr_bio   !: bio-model      light absorption flag
49   INTEGER , PUBLIC ::   nn_chldta    !: use Chlorophyll data (=1) or not (=0)
50   REAL(wp), PUBLIC ::   rn_abs       !: fraction absorbed in the very near surface (RGB & 2 bands)
51   REAL(wp), PUBLIC ::   rn_si0       !: very near surface depth of extinction      (RGB & 2 bands)
52   REAL(wp), PUBLIC ::   rn_si1       !: deepest depth of extinction (water type I)       (2 bands)
53   !
54   INTEGER , PUBLIC ::   nksr         !: levels below which the light cannot penetrate (depth larger than 391 m)
55
56   INTEGER, PARAMETER ::   np_RGB  = 1   ! R-G-B     light penetration with constant Chlorophyll
57   INTEGER, PARAMETER ::   np_RGBc = 2   ! R-G-B     light penetration with Chlorophyll data
58   INTEGER, PARAMETER ::   np_2BD  = 3   ! 2 bands   light penetration
59   INTEGER, PARAMETER ::   np_BIO  = 4   ! bio-model light penetration
60   !
61   INTEGER  ::   nqsr    ! user choice of the type of light penetration
62   REAL(wp) ::   xsi0r   ! inverse of rn_si0
63   REAL(wp) ::   xsi1r   ! inverse of rn_si1
64   !
65   REAL(wp) , DIMENSION(3,61)           ::   rkrgb    ! tabulated attenuation coefficients for RGB absorption
66   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_chl   ! structure of input Chl (file informations, fields read)
67
68   !! * Substitutions
69#  include "do_loop_substitute.h90"
70#  include "domzgr_substitute.h90"
71   !!----------------------------------------------------------------------
72   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
73   !! $Id$
74   !! Software governed by the CeCILL license (see ./LICENSE)
75   !!----------------------------------------------------------------------
76CONTAINS
77
78   SUBROUTINE tra_qsr( kt, Kmm, pts, Krhs )
79      !!----------------------------------------------------------------------
80      !!                  ***  ROUTINE tra_qsr  ***
81      !!
82      !! ** Purpose :   Compute the temperature trend due to the solar radiation
83      !!              penetration and add it to the general temperature trend.
84      !!
85      !! ** Method  : The profile of the solar radiation within the ocean is defined
86      !!      through 2 wavebands (rn_si0,rn_si1) or 3 wavebands (RGB) and a ratio rn_abs
87      !!      Considering the 2 wavebands case:
88      !!         I(k) = Qsr*( rn_abs*EXP(z(k)/rn_si0) + (1.-rn_abs)*EXP(z(k)/rn_si1) )
89      !!         The temperature trend associated with the solar radiation penetration
90      !!         is given by : zta = 1/e3t dk[ I ] / (rau0*Cp)
91      !!         At the bottom, boudary condition for the radiation is no flux :
92      !!      all heat which has not been absorbed in the above levels is put
93      !!      in the last ocean level.
94      !!         The computation is only done down to the level where
95      !!      I(k) < 1.e-15 W/m2 (i.e. over the top nksr levels) .
96      !!
97      !! ** Action  : - update ta with the penetrative solar radiation trend
98      !!              - send  trend for further diagnostics (l_trdtra=T)
99      !!
100      !! Reference  : Jerlov, N. G., 1968 Optical Oceanography, Elsevier, 194pp.
101      !!              Lengaigne et al. 2007, Clim. Dyn., V28, 5, 503-516.
102      !!              Morel, A. et Berthon, JF, 1989, Limnol Oceanogr 34(8), 1545-1562
103      !!----------------------------------------------------------------------
104      INTEGER,                                   INTENT(in   ) :: kt            ! ocean time-step
105      INTEGER,                                   INTENT(in   ) :: Kmm, Krhs     ! time level indices
106      REAL(wp), DIMENSION(jpi,jpj,jpk,jpts,jpt), INTENT(inout) :: pts           ! active tracers and RHS of tracer equation
107      !
108      INTEGER  ::   ji, jj, jk               ! dummy loop indices
109      INTEGER  ::   irgb                     ! local integers
110      REAL(wp) ::   zchl, zcoef, z1_2        ! local scalars
111      REAL(wp) ::   zc0 , zc1 , zc2 , zc3    !    -         -
112      REAL(wp) ::   zzc0, zzc1, zzc2, zzc3   !    -         -
113      REAL(wp) ::   zz0 , zz1                !    -         -
114      REAL(wp) ::   zCb, zCmax, zze, zpsi, zpsimax, zdelpsi, zCtot, zCze
115      REAL(wp) ::   zlogc, zlogc2, zlogc3
116      REAL(wp), ALLOCATABLE, DIMENSION(:,:)   :: zekb, zekg, zekr
117      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) :: ze0, ze1, ze2, ze3, zea, ztrdt
118      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) :: zetot, zchl3d
119      !!----------------------------------------------------------------------
120      !
121      IF( ln_timing )   CALL timing_start('tra_qsr')
122      !
123      IF( kt == nit000 ) THEN
124         IF(lwp) WRITE(numout,*)
125         IF(lwp) WRITE(numout,*) 'tra_qsr : penetration of the surface solar radiation'
126         IF(lwp) WRITE(numout,*) '~~~~~~~'
127      ENDIF
128      !
129      IF( l_trdtra ) THEN      ! trends diagnostic: save the input temperature trend
130         ALLOCATE( ztrdt(jpi,jpj,jpk) )
131         ztrdt(:,:,:) = pts(:,:,:,jp_tem,Krhs)
132      ENDIF
133      !
134      !                         !-----------------------------------!
135      !                         !  before qsr induced heat content  !
136      !                         !-----------------------------------!
137      IF( kt == nit000 ) THEN          !==  1st time step  ==!
138!!gm case neuler  not taken into account....
139         IF( ln_rstart .AND. iom_varid( numror, 'qsr_hc_b', ldstop = .FALSE. ) > 0 ) THEN    ! read in restart
140            IF(lwp) WRITE(numout,*) '          nit000-1 qsr tracer content forcing field read in the restart file'
141            z1_2 = 0.5_wp
142            CALL iom_get( numror, jpdom_autoglo, 'qsr_hc_b', qsr_hc_b, ldxios = lrxios )   ! before heat content trend due to Qsr flux
143         ELSE                                           ! No restart or restart not found: Euler forward time stepping
144            z1_2 = 1._wp
145            qsr_hc_b(:,:,:) = 0._wp
146         ENDIF
147      ELSE                             !==  Swap of qsr heat content  ==!
148         z1_2 = 0.5_wp
149         qsr_hc_b(:,:,:) = qsr_hc(:,:,:)
150      ENDIF
151      !
152      !                         !--------------------------------!
153      SELECT CASE( nqsr )       !  now qsr induced heat content  !
154      !                         !--------------------------------!
155      !
156      CASE( np_BIO )                   !==  bio-model fluxes  ==!
157         !
158         DO jk = 1, nksr
159            qsr_hc(:,:,jk) = r1_rau0_rcp * ( etot3(:,:,jk) - etot3(:,:,jk+1) )
160         END DO
161         !
162      CASE( np_RGB , np_RGBc )         !==  R-G-B fluxes  ==!
163         !
164         ALLOCATE( zekb(jpi,jpj)     , zekg(jpi,jpj)     , zekr  (jpi,jpj)     , &
165            &      ze0 (jpi,jpj,jpk) , ze1 (jpi,jpj,jpk) , ze2   (jpi,jpj,jpk) , &
166            &      ze3 (jpi,jpj,jpk) , zea (jpi,jpj,jpk) , zchl3d(jpi,jpj,jpk)   )
167         !
168         IF( nqsr == np_RGBc ) THEN          !*  Variable Chlorophyll
169            CALL fld_read( kt, 1, sf_chl )         ! Read Chl data and provides it at the current time step
170            DO jk = 1, nksr + 1
171               DO jj = 2, jpjm1                       ! Separation in R-G-B depending of the surface Chl
172                  DO ji = 2, jpim1
173                     zchl    = MIN( 10. , MAX( 0.03, sf_chl(1)%fnow(ji,jj,1) ) )
174                     zCtot   = 40.6  * zchl**0.459
175                     zze     = 568.2 * zCtot**(-0.746)
176                     IF( zze > 102. ) zze = 200.0 * zCtot**(-0.293)
177                     zpsi    = gdepw(ji,jj,jk,Kmm) / zze
178                     !
179                     zlogc   = LOG( zchl )
180                     zlogc2  = zlogc * zlogc
181                     zlogc3  = zlogc * zlogc * zlogc
182                     zCb     = 0.768 + 0.087 * zlogc - 0.179 * zlogc2 - 0.025 * zlogc3
183                     zCmax   = 0.299 - 0.289 * zlogc + 0.579 * zlogc2
184                     zpsimax = 0.6   - 0.640 * zlogc + 0.021 * zlogc2 + 0.115 * zlogc3
185                     zdelpsi = 0.710 + 0.159 * zlogc + 0.021 * zlogc2
186                     zCze    = 1.12  * (zchl)**0.803
187                     !
188                     zchl3d(ji,jj,jk) = zCze * ( zCb + zCmax * EXP( -( (zpsi - zpsimax) / zdelpsi )**2 ) )
189                  END DO
190                  !
191               END DO
192            END DO
193         ELSE                                !* constant chrlorophyll
194           DO jk = 1, nksr + 1
195              zchl3d(:,:,jk) = 0.05
196            ENDDO
197         ENDIF
198         !
199         zcoef  = ( 1. - rn_abs ) / 3._wp    !* surface equi-partition in R-G-B
200         DO_2D_00_00
201            ze0(ji,jj,1) = rn_abs * qsr(ji,jj)
202            ze1(ji,jj,1) = zcoef  * qsr(ji,jj)
203            ze2(ji,jj,1) = zcoef  * qsr(ji,jj)
204            ze3(ji,jj,1) = zcoef  * qsr(ji,jj)
205            zea(ji,jj,1) =          qsr(ji,jj)
206         END_2D
207         !
208         DO jk = 2, nksr+1                   !* interior equi-partition in R-G-B depending of vertical profile of Chl
209            DO_2D_00_00
210               zchl = MIN( 10. , MAX( 0.03, zchl3d(ji,jj,jk) ) )
211               irgb = NINT( 41 + 20.*LOG10(zchl) + 1.e-15 )
212               zekb(ji,jj) = rkrgb(1,irgb)
213               zekg(ji,jj) = rkrgb(2,irgb)
214               zekr(ji,jj) = rkrgb(3,irgb)
215            END_2D
216
217            DO_2D_00_00
218               zc0 = ze0(ji,jj,jk-1) * EXP( - e3t(ji,jj,jk-1,Kmm) * xsi0r       )
219               zc1 = ze1(ji,jj,jk-1) * EXP( - e3t(ji,jj,jk-1,Kmm) * zekb(ji,jj) )
220               zc2 = ze2(ji,jj,jk-1) * EXP( - e3t(ji,jj,jk-1,Kmm) * zekg(ji,jj) )
221               zc3 = ze3(ji,jj,jk-1) * EXP( - e3t(ji,jj,jk-1,Kmm) * zekr(ji,jj) )
222               ze0(ji,jj,jk) = zc0
223               ze1(ji,jj,jk) = zc1
224               ze2(ji,jj,jk) = zc2
225               ze3(ji,jj,jk) = zc3
226               zea(ji,jj,jk) = ( zc0 + zc1 + zc2 + zc3 ) * wmask(ji,jj,jk)
227            END_2D
228         END DO
229         !
230         DO_3D_00_00( 1, nksr )
231            qsr_hc(ji,jj,jk) = r1_rau0_rcp * ( zea(ji,jj,jk) - zea(ji,jj,jk+1) )
232         END_3D
233         !
234         DEALLOCATE( zekb , zekg , zekr , ze0 , ze1 , ze2 , ze3 , zea , zchl3d )
235         !
236      CASE( np_2BD  )            !==  2-bands fluxes  ==!
237         !
238         zz0 =        rn_abs   * r1_rau0_rcp      ! surface equi-partition in 2-bands
239         zz1 = ( 1. - rn_abs ) * r1_rau0_rcp
240         DO_3D_00_00( 1, nksr )
241            zc0 = zz0 * EXP( -gdepw(ji,jj,jk  ,Kmm)*xsi0r ) + zz1 * EXP( -gdepw(ji,jj,jk  ,Kmm)*xsi1r )
242            zc1 = zz0 * EXP( -gdepw(ji,jj,jk+1,Kmm)*xsi0r ) + zz1 * EXP( -gdepw(ji,jj,jk+1,Kmm)*xsi1r )
243            qsr_hc(ji,jj,jk) = qsr(ji,jj) * ( zc0 * wmask(ji,jj,jk) - zc1 * wmask(ji,jj,jk+1) )
244         END_3D
245         !
246      END SELECT
247      !
248      !                          !-----------------------------!
249      DO_3D_00_00( 1, nksr )
250         pts(ji,jj,jk,jp_tem,Krhs) = pts(ji,jj,jk,jp_tem,Krhs)   &
251            &                      + z1_2 * ( qsr_hc_b(ji,jj,jk) + qsr_hc(ji,jj,jk) )   &
252            &                             / e3t(ji,jj,jk,Kmm)
253      END_3D
254      !
255      ! sea-ice: store the 1st ocean level attenuation coefficient
256      DO_2D_00_00
257         IF( qsr(ji,jj) /= 0._wp ) THEN   ;   fraqsr_1lev(ji,jj) = qsr_hc(ji,jj,1) / ( r1_rau0_rcp * qsr(ji,jj) )
258         ELSE                             ;   fraqsr_1lev(ji,jj) = 1._wp
259         ENDIF
260      END_2D
261      CALL lbc_lnk( 'traqsr', fraqsr_1lev(:,:), 'T', 1._wp )
262      !
263      IF( iom_use('qsr3d') ) THEN      ! output the shortwave Radiation distribution
264         ALLOCATE( zetot(jpi,jpj,jpk) )
265         zetot(:,:,nksr+1:jpk) = 0._wp     ! below ~400m set to zero
266         DO jk = nksr, 1, -1
267            zetot(:,:,jk) = zetot(:,:,jk+1) + qsr_hc(:,:,jk) * rau0_rcp
268         END DO
269         CALL iom_put( 'qsr3d', zetot )   ! 3D distribution of shortwave Radiation
270         DEALLOCATE( zetot )
271      ENDIF
272      !
273      IF( lrst_oce ) THEN     ! write in the ocean restart file
274         IF( lwxios ) CALL iom_swap(      cwxios_context          )
275         CALL iom_rstput( kt, nitrst, numrow, 'qsr_hc_b'   , qsr_hc     , ldxios = lwxios )
276         CALL iom_rstput( kt, nitrst, numrow, 'fraqsr_1lev', fraqsr_1lev, ldxios = lwxios )
277         IF( lwxios ) CALL iom_swap(      cxios_context          )
278      ENDIF
279      !
280      IF( l_trdtra ) THEN     ! qsr tracers trends saved for diagnostics
281         ztrdt(:,:,:) = pts(:,:,:,jp_tem,Krhs) - ztrdt(:,:,:)
282         CALL trd_tra( kt, Kmm, Krhs, 'TRA', jp_tem, jptra_qsr, ztrdt )
283         DEALLOCATE( ztrdt )
284      ENDIF
285      !                       ! print mean trends (used for debugging)
286      IF(sn_cfctl%l_prtctl)   CALL prt_ctl( tab3d_1=pts(:,:,:,jp_tem,Krhs), clinfo1=' qsr  - Ta: ', mask1=tmask, clinfo3='tra-ta' )
287      !
288      IF( ln_timing )   CALL timing_stop('tra_qsr')
289      !
290   END SUBROUTINE tra_qsr
291
292
293   SUBROUTINE tra_qsr_init
294      !!----------------------------------------------------------------------
295      !!                  ***  ROUTINE tra_qsr_init  ***
296      !!
297      !! ** Purpose :   Initialization for the penetrative solar radiation
298      !!
299      !! ** Method  :   The profile of solar radiation within the ocean is set
300      !!      from two length scale of penetration (rn_si0,rn_si1) and a ratio
301      !!      (rn_abs). These parameters are read in the namtra_qsr namelist. The
302      !!      default values correspond to clear water (type I in Jerlov'
303      !!      (1968) classification.
304      !!         called by tra_qsr at the first timestep (nit000)
305      !!
306      !! ** Action  : - initialize rn_si0, rn_si1 and rn_abs
307      !!
308      !! Reference : Jerlov, N. G., 1968 Optical Oceanography, Elsevier, 194pp.
309      !!----------------------------------------------------------------------
310      INTEGER  ::   ji, jj, jk                  ! dummy loop indices
311      INTEGER  ::   ios, irgb, ierror, ioptio   ! local integer
312      REAL(wp) ::   zz0, zc0 , zc1, zcoef      ! local scalars
313      REAL(wp) ::   zz1, zc2 , zc3, zchl       !   -      -
314      !
315      CHARACTER(len=100) ::   cn_dir   ! Root directory for location of ssr files
316      TYPE(FLD_N)        ::   sn_chl   ! informations about the chlorofyl field to be read
317      !!
318      NAMELIST/namtra_qsr/  sn_chl, cn_dir, ln_qsr_rgb, ln_qsr_2bd, ln_qsr_bio,  &
319         &                  nn_chldta, rn_abs, rn_si0, rn_si1
320      !!----------------------------------------------------------------------
321      !
322      READ  ( numnam_ref, namtra_qsr, IOSTAT = ios, ERR = 901)
323901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namtra_qsr in reference namelist' )
324      !
325      READ  ( numnam_cfg, namtra_qsr, IOSTAT = ios, ERR = 902 )
326902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namtra_qsr in configuration namelist' )
327      IF(lwm) WRITE ( numond, namtra_qsr )
328      !
329      IF(lwp) THEN                ! control print
330         WRITE(numout,*)
331         WRITE(numout,*) 'tra_qsr_init : penetration of the surface solar radiation'
332         WRITE(numout,*) '~~~~~~~~~~~~'
333         WRITE(numout,*) '   Namelist namtra_qsr : set the parameter of penetration'
334         WRITE(numout,*) '      RGB (Red-Green-Blue) light penetration       ln_qsr_rgb = ', ln_qsr_rgb
335         WRITE(numout,*) '      2 band               light penetration       ln_qsr_2bd = ', ln_qsr_2bd
336         WRITE(numout,*) '      bio-model            light penetration       ln_qsr_bio = ', ln_qsr_bio
337         WRITE(numout,*) '      RGB : Chl data (=1) or cst value (=0)        nn_chldta  = ', nn_chldta
338         WRITE(numout,*) '      RGB & 2 bands: fraction of light (rn_si1)    rn_abs     = ', rn_abs
339         WRITE(numout,*) '      RGB & 2 bands: shortess depth of extinction  rn_si0     = ', rn_si0
340         WRITE(numout,*) '      2 bands: longest depth of extinction         rn_si1     = ', rn_si1
341         WRITE(numout,*)
342      ENDIF
343      !
344      ioptio = 0                    ! Parameter control
345      IF( ln_qsr_rgb  )   ioptio = ioptio + 1
346      IF( ln_qsr_2bd  )   ioptio = ioptio + 1
347      IF( ln_qsr_bio  )   ioptio = ioptio + 1
348      !
349      IF( ioptio /= 1 )   CALL ctl_stop( 'Choose ONE type of light penetration in namelist namtra_qsr',  &
350         &                               ' 2 bands, 3 RGB bands or bio-model light penetration' )
351      !
352      IF( ln_qsr_rgb .AND. nn_chldta == 0 )   nqsr = np_RGB
353      IF( ln_qsr_rgb .AND. nn_chldta == 1 )   nqsr = np_RGBc
354      IF( ln_qsr_2bd                      )   nqsr = np_2BD
355      IF( ln_qsr_bio                      )   nqsr = np_BIO
356      !
357      !                             ! Initialisation
358      xsi0r = 1._wp / rn_si0
359      xsi1r = 1._wp / rn_si1
360      !
361      SELECT CASE( nqsr )
362      !
363      CASE( np_RGB , np_RGBc )         !==  Red-Green-Blue light penetration  ==!
364         !
365         IF(lwp)   WRITE(numout,*) '   ==>>>   R-G-B   light penetration '
366         !
367         CALL trc_oce_rgb( rkrgb )                 ! tabulated attenuation coef.
368         !
369         nksr = trc_oce_ext_lev( r_si2, 33._wp )   ! level of light extinction
370         !
371         IF(lwp) WRITE(numout,*) '        level of light extinction = ', nksr, ' ref depth = ', gdepw_1d(nksr+1), ' m'
372         !
373         IF( nqsr == np_RGBc ) THEN                ! Chl data : set sf_chl structure
374            IF(lwp) WRITE(numout,*) '   ==>>>   Chlorophyll read in a file'
375            ALLOCATE( sf_chl(1), STAT=ierror )
376            IF( ierror > 0 ) THEN
377               CALL ctl_stop( 'tra_qsr_init: unable to allocate sf_chl structure' )   ;   RETURN
378            ENDIF
379            ALLOCATE( sf_chl(1)%fnow(jpi,jpj,1)   )
380            IF( sn_chl%ln_tint )   ALLOCATE( sf_chl(1)%fdta(jpi,jpj,1,2) )
381            !                                        ! fill sf_chl with sn_chl and control print
382            CALL fld_fill( sf_chl, (/ sn_chl /), cn_dir, 'tra_qsr_init',   &
383               &           'Solar penetration function of read chlorophyll', 'namtra_qsr' , no_print )
384         ENDIF
385         IF( nqsr == np_RGB ) THEN                 ! constant Chl
386            IF(lwp) WRITE(numout,*) '   ==>>>   Constant Chlorophyll concentration = 0.05'
387         ENDIF
388         !
389      CASE( np_2BD )                   !==  2 bands light penetration  ==!
390         !
391         IF(lwp)  WRITE(numout,*) '   ==>>>   2 bands light penetration'
392         !
393         nksr = trc_oce_ext_lev( rn_si1, 100._wp )    ! level of light extinction
394         IF(lwp) WRITE(numout,*) '        level of light extinction = ', nksr, ' ref depth = ', gdepw_1d(nksr+1), ' m'
395         !
396      CASE( np_BIO )                   !==  BIO light penetration  ==!
397         !
398         IF(lwp) WRITE(numout,*) '   ==>>>   bio-model light penetration'
399         IF( .NOT.lk_top )   CALL ctl_stop( 'No bio model : ln_qsr_bio = true impossible ' )
400         !
401      END SELECT
402      !
403      qsr_hc(:,:,:) = 0._wp     ! now qsr heat content set to zero where it will not be computed
404      !
405      ! 1st ocean level attenuation coefficient (used in sbcssm)
406      IF( iom_varid( numror, 'fraqsr_1lev', ldstop = .FALSE. ) > 0 ) THEN
407         CALL iom_get( numror, jpdom_autoglo, 'fraqsr_1lev'  , fraqsr_1lev, ldxios = lrxios  )
408      ELSE
409         fraqsr_1lev(:,:) = 1._wp   ! default : no penetration
410      ENDIF
411      !
412      IF( lwxios ) THEN
413         CALL iom_set_rstw_var_active('qsr_hc_b')
414         CALL iom_set_rstw_var_active('fraqsr_1lev')
415      ENDIF
416      !
417   END SUBROUTINE tra_qsr_init
418
419   !!======================================================================
420END MODULE traqsr
Note: See TracBrowser for help on using the repository browser.