source: NEMO/branches/2020/dev_r12377_KERNEL-06_techene_e3/src/OCE/nemogcm.F90 @ 13219

Last change on this file since 13219 was 13219, checked in by smasson, 3 months ago

better e3: update with trunk@13218 see #2385

  • Property svn:keywords set to Id
File size: 35.4 KB
Line 
1MODULE nemogcm
2   !!======================================================================
3   !!                       ***  MODULE nemogcm   ***
4   !! Ocean system   : NEMO GCM (ocean dynamics, on-line tracers, biochemistry and sea-ice)
5   !!======================================================================
6   !! History :  OPA  ! 1990-10  (C. Levy, G. Madec)  Original code
7   !!            7.0  ! 1991-11  (M. Imbard, C. Levy, G. Madec)
8   !!            7.1  ! 1993-03  (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
9   !!                             P. Delecluse, C. Perigaud, G. Caniaux, B. Colot, C. Maes) release 7.1
10   !!             -   ! 1992-06  (L.Terray)  coupling implementation
11   !!             -   ! 1993-11  (M.A. Filiberti) IGLOO sea-ice
12   !!            8.0  ! 1996-03  (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
13   !!                             P. Delecluse, L.Terray, M.A. Filiberti, J. Vialar, A.M. Treguier, M. Levy) release 8.0
14   !!            8.1  ! 1997-06  (M. Imbard, G. Madec)
15   !!            8.2  ! 1999-11  (M. Imbard, H. Goosse)  sea-ice model
16   !!                 ! 1999-12  (V. Thierry, A-M. Treguier, M. Imbard, M-A. Foujols)  OPEN-MP
17   !!                 ! 2000-07  (J-M Molines, M. Imbard)  Open Boundary Conditions  (CLIPPER)
18   !!   NEMO     1.0  ! 2002-08  (G. Madec)  F90: Free form and modules
19   !!             -   ! 2004-06  (R. Redler, NEC CCRLE, Germany) add OASIS[3/4] coupled interfaces
20   !!             -   ! 2004-08  (C. Talandier) New trends organization
21   !!             -   ! 2005-06  (C. Ethe) Add the 1D configuration possibility
22   !!             -   ! 2005-11  (V. Garnier) Surface pressure gradient organization
23   !!             -   ! 2006-03  (L. Debreu, C. Mazauric)  Agrif implementation
24   !!             -   ! 2006-04  (G. Madec, R. Benshila)  Step reorganization
25   !!             -   ! 2007-07  (J. Chanut, A. Sellar) Unstructured open boundaries (BDY)
26   !!            3.2  ! 2009-08  (S. Masson)  open/write in the listing file in mpp
27   !!            3.3  ! 2010-05  (K. Mogensen, A. Weaver, M. Martin, D. Lea) Assimilation interface
28   !!             -   ! 2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase
29   !!            3.3.1! 2011-01  (A. R. Porter, STFC Daresbury) dynamical allocation
30   !!             -   ! 2011-11  (C. Harris) decomposition changes for running with CICE
31   !!            3.6  ! 2012-05  (C. Calone, J. Simeon, G. Madec, C. Ethe) Add grid coarsening
32   !!             -   ! 2014-12  (G. Madec) remove KPP scheme and cross-land advection (cla)
33   !!            4.0  ! 2016-10  (G. Madec, S. Flavoni)  domain configuration / user defined interface
34   !!----------------------------------------------------------------------
35
36   !!----------------------------------------------------------------------
37   !!   nemo_gcm      : solve ocean dynamics, tracer, biogeochemistry and/or sea-ice
38   !!   nemo_init     : initialization of the NEMO system
39   !!   nemo_ctl      : initialisation of the contol print
40   !!   nemo_closefile: close remaining open files
41   !!   nemo_alloc    : dynamical allocation
42   !!----------------------------------------------------------------------
43   USE step_oce       ! module used in the ocean time stepping module (step.F90)
44   USE phycst         ! physical constant                  (par_cst routine)
45   USE domain         ! domain initialization   (dom_init & dom_cfg routines)
46   USE closea         ! treatment of closed seas (for ln_closea)
47   USE usrdef_nam     ! user defined configuration
48   USE tide_mod, ONLY : tide_init ! tidal components initialization   (tide_init routine)
49   USE bdy_oce,  ONLY : ln_bdy
50   USE bdyini         ! open boundary cond. setting       (bdy_init routine)
51   USE istate         ! initial state setting          (istate_init routine)
52   USE ldfdyn         ! lateral viscosity setting      (ldfdyn_init routine)
53   USE ldftra         ! lateral diffusivity setting    (ldftra_init routine)
54   USE trdini         ! dyn/tra trends initialization     (trd_init routine)
55   USE asminc         ! assimilation increments
56   USE asmbkg         ! writing out state trajectory
57   USE diaptr         ! poleward transports           (dia_ptr_init routine)
58   USE diadct         ! sections transports           (dia_dct_init routine)
59   USE diaobs         ! Observation diagnostics       (dia_obs_init routine)
60   USE diacfl         ! CFL diagnostics               (dia_cfl_init routine)
61   USE diamlr         ! IOM context management for multiple-linear-regression analysis
62#if defined key_qco
63   USE stepMLF        ! NEMO time-stepping               (stp_MLF   routine)
64#else
65   USE step           ! NEMO time-stepping               (stp       routine)
66#endif
67   USE isfstp         ! ice shelf                     (isf_stp_init routine)
68   USE icbini         ! handle bergs, initialisation
69   USE icbstp         ! handle bergs, calving, themodynamics and transport
70   USE cpl_oasis3     ! OASIS3 coupling
71   USE c1d            ! 1D configuration
72   USE step_c1d       ! Time stepping loop for the 1D configuration
73   USE dyndmp         ! Momentum damping
74   USE stopar         ! Stochastic param.: ???
75   USE stopts         ! Stochastic param.: ???
76   USE diu_layers     ! diurnal bulk SST and coolskin
77   USE step_diu       ! diurnal bulk SST timestepping (called from here if run offline)
78   USE crsini         ! initialise grid coarsening utility
79   USE dia25h         ! 25h mean output
80   USE diadetide      ! Weights computation for daily detiding of model diagnostics
81   USE sbc_oce , ONLY : lk_oasis
82   USE wet_dry        ! Wetting and drying setting   (wad_init routine)
83#if defined key_top
84   USE trcini         ! passive tracer initialisation
85#endif
86#if defined key_nemocice_decomp
87   USE ice_domain_size, only: nx_global, ny_global
88#endif
89   !
90   USE in_out_manager ! I/O manager
91   USE lib_mpp        ! distributed memory computing
92   USE mppini         ! shared/distributed memory setting (mpp_init routine)
93   USE lbcnfd  , ONLY : isendto, nsndto, nfsloop, nfeloop   ! Setup of north fold exchanges
94   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined)
95#if defined key_iomput
96   USE xios           ! xIOserver
97#endif
98#if defined key_agrif
99   USE agrif_all_update   ! Master Agrif update
100#endif
101
102   IMPLICIT NONE
103   PRIVATE
104
105   PUBLIC   nemo_gcm    ! called by model.F90
106   PUBLIC   nemo_init   ! needed by AGRIF
107   PUBLIC   nemo_alloc  ! needed by TAM
108
109   CHARACTER(lc) ::   cform_aaa="( /, 'AAAAAAAA', / ) "     ! flag for output listing
110
111#if defined key_mpp_mpi
112   ! need MPI_Wtime
113   INCLUDE 'mpif.h'
114#endif
115
116   !!----------------------------------------------------------------------
117   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
118   !! $Id$
119   !! Software governed by the CeCILL license (see ./LICENSE)
120   !!----------------------------------------------------------------------
121CONTAINS
122
123   SUBROUTINE nemo_gcm
124      !!----------------------------------------------------------------------
125      !!                     ***  ROUTINE nemo_gcm  ***
126      !!
127      !! ** Purpose :   NEMO solves the primitive equations on an orthogonal
128      !!              curvilinear mesh on the sphere.
129      !!
130      !! ** Method  : - model general initialization
131      !!              - launch the time-stepping (stp routine)
132      !!              - finalize the run by closing files and communications
133      !!
134      !! References : Madec, Delecluse, Imbard, and Levy, 1997:  internal report, IPSL.
135      !!              Madec, 2008, internal report, IPSL.
136      !!----------------------------------------------------------------------
137      INTEGER ::   istp   ! time step index
138      REAL(wp)::   zstptiming   ! elapsed time for 1 time step
139      !!----------------------------------------------------------------------
140      !
141#if defined key_agrif
142      CALL Agrif_Init_Grids()      ! AGRIF: set the meshes
143#endif
144      !                            !-----------------------!
145      CALL nemo_init               !==  Initialisations  ==!
146      !                            !-----------------------!
147#if defined key_agrif
148      Kbb_a = Nbb; Kmm_a = Nnn; Krhs_a = Nrhs   ! agrif_oce module copies of time level indices
149      CALL Agrif_Declare_Var       !  "      "   "   "      "  DYN/TRA
150# if defined key_top
151      CALL Agrif_Declare_Var_top   !  "      "   "   "      "  TOP
152# endif
153#endif
154      ! check that all process are still there... If some process have an error,
155      ! they will never enter in step and other processes will wait until the end of the cpu time!
156      CALL mpp_max( 'nemogcm', nstop )
157
158      IF(lwp) WRITE(numout,cform_aaa)   ! Flag AAAAAAA
159
160      !                            !-----------------------!
161      !                            !==   time stepping   ==!
162      !                            !-----------------------!
163      !
164      !                                               !== set the model time-step  ==!
165      !
166      istp = nit000
167      !
168#if defined key_c1d
169      DO WHILE ( istp <= nitend .AND. nstop == 0 )    !==  C1D time-stepping  ==!
170         CALL stp_c1d( istp )
171         istp = istp + 1
172      END DO
173#else
174      !
175# if defined key_agrif
176      !                                               !==  AGRIF time-stepping  ==!
177      CALL Agrif_Regrid()
178      !
179      ! Recursive update from highest nested level to lowest:
180      Kbb_a = Nbb; Kmm_a = Nnn; Krhs_a = Nrhs   ! agrif_oce module copies of time level indices
181      CALL Agrif_step_child_adj(Agrif_Update_All)
182      !
183      DO WHILE( istp <= nitend .AND. nstop == 0 )
184#if defined key_qco
185         CALL stp_MLF
186#else
187         CALL stp
188#endif
189         istp = istp + 1
190      END DO
191      !
192# else
193      !
194      IF( .NOT.ln_diurnal_only ) THEN                 !==  Standard time-stepping  ==!
195         !
196         DO WHILE( istp <= nitend .AND. nstop == 0 )
197
198            ncom_stp = istp
199            IF( ln_timing ) THEN
200               zstptiming = MPI_Wtime()
201               IF ( istp == ( nit000 + 1 ) ) elapsed_time = zstptiming
202               IF ( istp ==         nitend ) elapsed_time = zstptiming - elapsed_time
203            ENDIF
204
205#if defined key_qco
206            CALL stp_MLF      ( istp )
207#else
208            CALL stp          ( istp )
209#endif
210            istp = istp + 1
211
212            IF( lwp .AND. ln_timing )   WRITE(numtime,*) 'timing step ', istp-1, ' : ', MPI_Wtime() - zstptiming
213
214         END DO
215         !
216      ELSE                                            !==  diurnal SST time-steeping only  ==!
217         !
218         DO WHILE( istp <= nitend .AND. nstop == 0 )
219            CALL stp_diurnal( istp )   ! time step only the diurnal SST
220            istp = istp + 1
221         END DO
222         !
223      ENDIF
224      !
225# endif
226      !
227#endif
228      !
229      IF( ln_diaobs   )   CALL dia_obs_wri
230      !
231      IF( ln_icebergs )   CALL icb_end( nitend )
232
233      !                            !------------------------!
234      !                            !==  finalize the run  ==!
235      !                            !------------------------!
236      IF(lwp) WRITE(numout,cform_aaa)        ! Flag AAAAAAA
237      !
238      IF( nstop /= 0 .AND. lwp ) THEN        ! error print
239         WRITE(ctmp1,*) '   ==>>>   nemo_gcm: a total of ', nstop, ' errors have been found'
240         IF( ngrdstop > 0 ) THEN
241            WRITE(ctmp9,'(i2)') ngrdstop
242            WRITE(ctmp2,*) '           E R R O R detected in Agrif grid '//TRIM(ctmp9)
243            WRITE(ctmp3,*) '           Look for "E R R O R" messages in all existing '//TRIM(ctmp9)//'_ocean_output* files'
244            CALL ctl_stop( ' ', ctmp1, ' ', ctmp2, ' ', ctmp3 )
245         ELSE
246            WRITE(ctmp2,*) '           Look for "E R R O R" messages in all existing ocean_output* files'
247            CALL ctl_stop( ' ', ctmp1, ' ', ctmp2 )
248         ENDIF
249      ENDIF
250      !
251      IF( ln_timing )   CALL timing_finalize
252      !
253      CALL nemo_closefile
254      !
255#if defined key_iomput
256                                    CALL xios_finalize  ! end mpp communications with xios
257      IF( lk_oasis     )            CALL cpl_finalize   ! end coupling and mpp communications with OASIS
258#else
259      IF    ( lk_oasis ) THEN   ;   CALL cpl_finalize   ! end coupling and mpp communications with OASIS
260      ELSEIF( lk_mpp   ) THEN   ;   CALL mppstop        ! end mpp communications
261      ENDIF
262#endif
263      !
264      IF(lwm) THEN
265         IF( nstop == 0 ) THEN   ;   STOP 0
266         ELSE                    ;   STOP 123
267         ENDIF
268      ENDIF
269      !
270   END SUBROUTINE nemo_gcm
271
272
273   SUBROUTINE nemo_init
274      !!----------------------------------------------------------------------
275      !!                     ***  ROUTINE nemo_init  ***
276      !!
277      !! ** Purpose :   initialization of the NEMO GCM
278      !!----------------------------------------------------------------------
279      INTEGER ::   ios, ilocal_comm   ! local integers
280      !!
281      NAMELIST/namctl/ sn_cfctl,  nn_print, nn_ictls, nn_ictle,             &
282         &             nn_isplt , nn_jsplt, nn_jctls, nn_jctle,             &
283         &             ln_timing, ln_diacfl
284      NAMELIST/namcfg/ ln_read_cfg, cn_domcfg, ln_closea, ln_write_cfg, cn_domcfg_out, ln_use_jattr
285      !!----------------------------------------------------------------------
286      !
287      cxios_context = 'nemo'
288      !
289      !                             !-------------------------------------------------!
290      !                             !     set communicator & select the local rank    !
291      !                             !  must be done as soon as possible to get narea  !
292      !                             !-------------------------------------------------!
293      !
294#if defined key_iomput
295      IF( Agrif_Root() ) THEN
296         IF( lk_oasis ) THEN
297            CALL cpl_init( "oceanx", ilocal_comm )                               ! nemo local communicator given by oasis
298            CALL xios_initialize( "not used"       , local_comm =ilocal_comm )   ! send nemo communicator to xios
299         ELSE
300            CALL xios_initialize( "for_xios_mpi_id", return_comm=ilocal_comm )   ! nemo local communicator given by xios
301         ENDIF
302      ENDIF
303      CALL mpp_start( ilocal_comm )
304#else
305      IF( lk_oasis ) THEN
306         IF( Agrif_Root() ) THEN
307            CALL cpl_init( "oceanx", ilocal_comm )          ! nemo local communicator given by oasis
308         ENDIF
309         CALL mpp_start( ilocal_comm )
310      ELSE
311         CALL mpp_start( )
312      ENDIF
313#endif
314      !
315      narea = mpprank + 1               ! mpprank: the rank of proc (0 --> mppsize -1 )
316      lwm = (narea == 1)                ! control of output namelists
317      !
318      !                             !---------------------------------------------------------------!
319      !                             ! Open output files, reference and configuration namelist files !
320      !                             !---------------------------------------------------------------!
321      !
322      ! open ocean.output as soon as possible to get all output prints (including errors messages)
323      IF( lwm )   CALL ctl_opn(     numout,        'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. )
324      ! open reference and configuration namelist files
325                  CALL load_nml( numnam_ref,        'namelist_ref',                                           -1, lwm )
326                  CALL load_nml( numnam_cfg,        'namelist_cfg',                                           -1, lwm )
327      IF( lwm )   CALL ctl_opn(     numond, 'output.namelist.dyn', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. )
328      ! open /dev/null file to be able to supress output write easily
329      IF( Agrif_Root() ) THEN
330                  CALL ctl_opn(     numnul,           '/dev/null', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. )
331#ifdef key_agrif
332      ELSE
333                  numnul = Agrif_Parent(numnul)   
334#endif
335      ENDIF
336      !                             !--------------------!
337      !                             ! Open listing units !  -> need sn_cfctl from namctl to define lwp
338      !                             !--------------------!
339      !
340      READ  ( numnam_ref, namctl, IOSTAT = ios, ERR = 901 )
341901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namctl in reference namelist' )
342      READ  ( numnam_cfg, namctl, IOSTAT = ios, ERR = 902 )
343902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namctl in configuration namelist' )
344      !
345      ! finalize the definition of namctl variables
346      IF( narea < sn_cfctl%procmin .OR. narea > sn_cfctl%procmax .OR. MOD( narea - sn_cfctl%procmin, sn_cfctl%procincr ) /= 0 )   &
347         &   CALL nemo_set_cfctl( sn_cfctl, .FALSE. )
348      !
349      lwp = (narea == 1) .OR. sn_cfctl%l_oceout    ! control of all listing output print
350      !
351      IF(lwp) THEN                      ! open listing units
352         !
353         IF( .NOT. lwm )   &            ! alreay opened for narea == 1
354            &            CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE., narea )
355         !
356         WRITE(numout,*)
357         WRITE(numout,*) '   CNRS - NERC - Met OFFICE - MERCATOR-ocean - CMCC'
358         WRITE(numout,*) '                       NEMO team'
359         WRITE(numout,*) '            Ocean General Circulation Model'
360         WRITE(numout,*) '                NEMO version 4.0  (2019) '
361         WRITE(numout,*)
362         WRITE(numout,*) "           ._      ._      ._      ._      ._    "
363         WRITE(numout,*) "       _.-._)`\_.-._)`\_.-._)`\_.-._)`\_.-._)`\_ "
364         WRITE(numout,*)
365         WRITE(numout,*) "           o         _,           _,             "
366         WRITE(numout,*) "            o      .' (        .-' /             "
367         WRITE(numout,*) "           o     _/..._'.    .'   /              "
368         WRITE(numout,*) "      (    o .-'`      ` '-./  _.'               "
369         WRITE(numout,*) "       )    ( o)           ;= <_         (       "
370         WRITE(numout,*) "      (      '-.,\\__ __.-;`\   '.        )      "
371         WRITE(numout,*) "       )  )       \) |`\ \)  '.   \      (   (   "
372         WRITE(numout,*) "      (  (           \_/       '-._\      )   )  "
373         WRITE(numout,*) "       )  ) jgs                     `    (   (   "
374         WRITE(numout,*) "     ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^ "
375         WRITE(numout,*)
376         !
377         WRITE(numout,cform_aaa)                                        ! Flag AAAAAAA
378         !
379      ENDIF
380      !
381      IF(lwm) WRITE( numond, namctl )
382      !
383      !                             !------------------------------------!
384      !                             !  Set global domain size parameters !
385      !                             !------------------------------------!
386      !
387      READ  ( numnam_ref, namcfg, IOSTAT = ios, ERR = 903 )
388903   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namcfg in reference namelist' )
389      READ  ( numnam_cfg, namcfg, IOSTAT = ios, ERR = 904 )
390904   IF( ios >  0 )   CALL ctl_nam ( ios , 'namcfg in configuration namelist' )
391      !
392      IF( ln_read_cfg ) THEN            ! Read sizes in domain configuration file
393         CALL domain_cfg ( cn_cfg, nn_cfg, jpiglo, jpjglo, jpkglo, jperio )
394      ELSE                              ! user-defined namelist
395         CALL usr_def_nam( cn_cfg, nn_cfg, jpiglo, jpjglo, jpkglo, jperio )
396      ENDIF
397      !
398      IF(lwm)   WRITE( numond, namcfg )
399      !
400      !                             !-----------------------------------------!
401      !                             ! mpp parameters and domain decomposition !
402      !                             !-----------------------------------------!
403      CALL mpp_init
404
405      ! Now we know the dimensions of the grid and numout has been set: we can allocate arrays
406      CALL nemo_alloc()
407
408      ! Initialise time level indices
409      Nbb = 1; Nnn = 2; Naa = 3; Nrhs = Naa
410#if defined key_agrif
411      Kbb_a = Nbb; Kmm_a = Nnn; Krhs_a = Nrhs   ! agrif_oce module copies of time level indices
412#endif 
413      !                             !-------------------------------!
414      !                             !  NEMO general initialization  !
415      !                             !-------------------------------!
416
417      CALL nemo_ctl                          ! Control prints
418      !
419      !                                      ! General initialization
420      IF( ln_timing    )   CALL timing_init     ! timing
421      IF( ln_timing    )   CALL timing_start( 'nemo_init')
422      !
423                           CALL     phy_cst         ! Physical constants
424                           CALL     eos_init        ! Equation of state
425      IF( lk_c1d       )   CALL     c1d_init        ! 1D column configuration
426                           CALL     wad_init        ! Wetting and drying options
427
428#if defined key_agrif
429     CALL Agrif_Declare_Var_ini   !  "      "   "   "      "  DOM
430#endif
431                           CALL     dom_init( Nbb, Nnn, Naa, "OPA") ! Domain
432      IF( ln_crs       )   CALL     crs_init(      Nnn )       ! coarsened grid: domain initialization
433      IF( sn_cfctl%l_prtctl )   &
434         &                 CALL prt_ctl_init        ! Print control
435
436                           CALL diurnal_sst_bulk_init       ! diurnal sst
437      IF( ln_diurnal   )   CALL diurnal_sst_coolskin_init   ! cool skin
438      !
439      IF( ln_diurnal_only ) THEN                    ! diurnal only: a subset of the initialisation routines
440         CALL  istate_init( Nbb, Nnn, Naa )         ! ocean initial state (Dynamics and tracers)
441         CALL     sbc_init( Nbb, Nnn, Naa )         ! Forcings : surface module
442         CALL tra_qsr_init                          ! penetrative solar radiation qsr
443         IF( ln_diaobs ) THEN                       ! Observation & model comparison
444            CALL dia_obs_init( Nnn )                ! Initialize observational data
445            CALL dia_obs( nit000 - 1, Nnn )         ! Observation operator for restart
446         ENDIF
447         IF( lk_asminc )   CALL asm_inc_init( Nbb, Nnn, Nrhs )   ! Assimilation increments
448         !
449         RETURN                                       ! end of initialization
450      ENDIF
451      !
452
453                           CALL  istate_init( Nbb, Nnn, Naa )    ! ocean initial state (Dynamics and tracers)
454
455      !                                      ! external forcing
456                           CALL    tide_init                     ! tidal harmonics
457                           CALL     sbc_init( Nbb, Nnn, Naa )    ! surface boundary conditions (including sea-ice)
458                           CALL     bdy_init                     ! Open boundaries initialisation
459
460      !                                      ! Ocean physics
461                           CALL zdf_phy_init( Nnn )    ! Vertical physics
462
463      !                                         ! Lateral physics
464                           CALL ldf_tra_init      ! Lateral ocean tracer physics
465                           CALL ldf_eiv_init      ! eddy induced velocity param.
466                           CALL ldf_dyn_init      ! Lateral ocean momentum physics
467
468      !                                      ! Active tracers
469      IF( ln_traqsr    )   CALL tra_qsr_init      ! penetrative solar radiation qsr
470                           CALL tra_bbc_init      ! bottom heat flux
471                           CALL tra_bbl_init      ! advective (and/or diffusive) bottom boundary layer scheme
472                           CALL tra_dmp_init      ! internal tracer damping
473                           CALL tra_adv_init      ! horizontal & vertical advection
474                           CALL tra_ldf_init      ! lateral mixing
475
476      !                                      ! Dynamics
477      IF( lk_c1d       )   CALL dyn_dmp_init         ! internal momentum damping
478                           CALL dyn_adv_init         ! advection (vector or flux form)
479                           CALL dyn_vor_init         ! vorticity term including Coriolis
480                           CALL dyn_ldf_init         ! lateral mixing
481                           CALL dyn_hpg_init( Nnn )  ! horizontal gradient of Hydrostatic pressure
482                           CALL dyn_spg_init         ! surface pressure gradient
483
484#if defined key_top
485      !                                      ! Passive tracers
486                           CALL     trc_init( Nbb, Nnn, Naa )
487#endif
488      IF( l_ldfslp     )   CALL ldf_slp_init    ! slope of lateral mixing
489
490      !                                      ! Icebergs
491                           CALL icb_init( rn_Dt, nit000)   ! initialise icebergs instance
492
493                                                ! ice shelf
494                           CALL isf_init( Nbb, Nnn, Naa )
495
496      !                                      ! Misc. options
497                           CALL sto_par_init    ! Stochastic parametrization
498      IF( ln_sto_eos   )   CALL sto_pts_init    ! RRandom T/S fluctuations
499
500      !                                      ! Diagnostics
501                           CALL     flo_init( Nnn )    ! drifting Floats
502      IF( ln_diacfl    )   CALL dia_cfl_init    ! Initialise CFL diagnostics
503!                           CALL dia_ptr_init    ! Poleward TRansports initialization
504                           CALL dia_dct_init    ! Sections tranports
505                           CALL dia_hsb_init( Nnn )    ! heat content, salt content and volume budgets
506                           CALL     trd_init( Nnn )    ! Mixed-layer/Vorticity/Integral constraints trends
507                           CALL dia_obs_init( Nnn )    ! Initialize observational data
508                           CALL dia_25h_init( Nbb )    ! 25h mean  outputs
509                           CALL dia_detide_init ! Weights computation for daily detiding of model diagnostics
510      IF( ln_diaobs    )   CALL dia_obs( nit000-1, Nnn )   ! Observation operator for restart
511                           CALL dia_mlr_init    ! Initialisation of IOM context management for multiple-linear-regression analysis
512
513      !                                      ! Assimilation increments
514      IF( lk_asminc    )   CALL asm_inc_init( Nbb, Nnn, Nrhs )   ! Initialize assimilation increments
515      !
516      IF(lwp) WRITE(numout,cform_aaa)           ! Flag AAAAAAA
517      !
518      IF( ln_timing    )   CALL timing_stop( 'nemo_init')
519      !
520   END SUBROUTINE nemo_init
521
522
523   SUBROUTINE nemo_ctl
524      !!----------------------------------------------------------------------
525      !!                     ***  ROUTINE nemo_ctl  ***
526      !!
527      !! ** Purpose :   control print setting
528      !!
529      !! ** Method  : - print namctl and namcfg information and check some consistencies
530      !!----------------------------------------------------------------------
531      !
532      IF(lwp) THEN                  ! control print
533         WRITE(numout,*)
534         WRITE(numout,*) 'nemo_ctl: Control prints'
535         WRITE(numout,*) '~~~~~~~~'
536         WRITE(numout,*) '   Namelist namctl'
537         WRITE(numout,*) '                              sn_cfctl%l_runstat = ', sn_cfctl%l_runstat
538         WRITE(numout,*) '                              sn_cfctl%l_trcstat = ', sn_cfctl%l_trcstat
539         WRITE(numout,*) '                              sn_cfctl%l_oceout  = ', sn_cfctl%l_oceout
540         WRITE(numout,*) '                              sn_cfctl%l_layout  = ', sn_cfctl%l_layout
541         WRITE(numout,*) '                              sn_cfctl%l_prtctl  = ', sn_cfctl%l_prtctl
542         WRITE(numout,*) '                              sn_cfctl%l_prttrc  = ', sn_cfctl%l_prttrc
543         WRITE(numout,*) '                              sn_cfctl%l_oasout  = ', sn_cfctl%l_oasout
544         WRITE(numout,*) '                              sn_cfctl%procmin   = ', sn_cfctl%procmin
545         WRITE(numout,*) '                              sn_cfctl%procmax   = ', sn_cfctl%procmax
546         WRITE(numout,*) '                              sn_cfctl%procincr  = ', sn_cfctl%procincr
547         WRITE(numout,*) '                              sn_cfctl%ptimincr  = ', sn_cfctl%ptimincr
548         WRITE(numout,*) '      level of print                  nn_print   = ', nn_print
549         WRITE(numout,*) '      Start i indice for SUM control  nn_ictls   = ', nn_ictls
550         WRITE(numout,*) '      End i indice for SUM control    nn_ictle   = ', nn_ictle
551         WRITE(numout,*) '      Start j indice for SUM control  nn_jctls   = ', nn_jctls
552         WRITE(numout,*) '      End j indice for SUM control    nn_jctle   = ', nn_jctle
553         WRITE(numout,*) '      number of proc. following i     nn_isplt   = ', nn_isplt
554         WRITE(numout,*) '      number of proc. following j     nn_jsplt   = ', nn_jsplt
555         WRITE(numout,*) '      timing by routine               ln_timing  = ', ln_timing
556         WRITE(numout,*) '      CFL diagnostics                 ln_diacfl  = ', ln_diacfl
557      ENDIF
558      !
559      nprint    = nn_print          ! convert DOCTOR namelist names into OLD names
560      nictls    = nn_ictls
561      nictle    = nn_ictle
562      njctls    = nn_jctls
563      njctle    = nn_jctle
564      isplt     = nn_isplt
565      jsplt     = nn_jsplt
566
567      IF(lwp) THEN                  ! control print
568         WRITE(numout,*)
569         WRITE(numout,*) '   Namelist namcfg'
570         WRITE(numout,*) '      read domain configuration file                ln_read_cfg      = ', ln_read_cfg
571         WRITE(numout,*) '         filename to be read                           cn_domcfg     = ', TRIM(cn_domcfg)
572         WRITE(numout,*) '         keep closed seas in the domain (if exist)     ln_closea     = ', ln_closea
573         WRITE(numout,*) '      create a configuration definition file        ln_write_cfg     = ', ln_write_cfg
574         WRITE(numout,*) '         filename to be written                        cn_domcfg_out = ', TRIM(cn_domcfg_out)
575         WRITE(numout,*) '      use file attribute if exists as i/p j-start   ln_use_jattr     = ', ln_use_jattr
576      ENDIF
577      IF( .NOT.ln_read_cfg )   ln_closea = .false.   ! dealing possible only with a domcfg file
578      !
579      !                             ! Parameter control
580      !
581      IF( sn_cfctl%l_prtctl .OR. sn_cfctl%l_prttrc ) THEN              ! sub-domain area indices for the control prints
582         IF( lk_mpp .AND. jpnij > 1 ) THEN
583            isplt = jpni   ;   jsplt = jpnj   ;   ijsplt = jpni*jpnj   ! the domain is forced to the real split domain
584         ELSE
585            IF( isplt == 1 .AND. jsplt == 1  ) THEN
586               CALL ctl_warn( ' - isplt & jsplt are equal to 1',   &
587                  &           ' - the print control will be done over the whole domain' )
588            ENDIF
589            ijsplt = isplt * jsplt            ! total number of processors ijsplt
590         ENDIF
591         IF(lwp) WRITE(numout,*)'          - The total number of processors over which the'
592         IF(lwp) WRITE(numout,*)'            print control will be done is ijsplt : ', ijsplt
593         !
594         !                              ! indices used for the SUM control
595         IF( nictls+nictle+njctls+njctle == 0 )   THEN    ! print control done over the default area
596            lsp_area = .FALSE.
597         ELSE                                             ! print control done over a specific  area
598            lsp_area = .TRUE.
599            IF( nictls < 1 .OR. nictls > jpiglo )   THEN
600               CALL ctl_warn( '          - nictls must be 1<=nictls>=jpiglo, it is forced to 1' )
601               nictls = 1
602            ENDIF
603            IF( nictle < 1 .OR. nictle > jpiglo )   THEN
604               CALL ctl_warn( '          - nictle must be 1<=nictle>=jpiglo, it is forced to jpiglo' )
605               nictle = jpiglo
606            ENDIF
607            IF( njctls < 1 .OR. njctls > jpjglo )   THEN
608               CALL ctl_warn( '          - njctls must be 1<=njctls>=jpjglo, it is forced to 1' )
609               njctls = 1
610            ENDIF
611            IF( njctle < 1 .OR. njctle > jpjglo )   THEN
612               CALL ctl_warn( '          - njctle must be 1<=njctle>=jpjglo, it is forced to jpjglo' )
613               njctle = jpjglo
614            ENDIF
615         ENDIF
616      ENDIF
617      !
618      IF( 1._wp /= SIGN(1._wp,-0._wp)  )   CALL ctl_stop( 'nemo_ctl: The intrinsec SIGN function follows f2003 standard.',  &
619         &                                                'Compile with key_nosignedzero enabled:',   &
620         &                                                '--> add -Dkey_nosignedzero to the definition of %CPP in your arch file' )
621      !
622#if defined key_agrif
623      IF( ln_timing )   CALL ctl_stop( 'AGRIF not implemented with ln_timing = true')
624#endif
625      !
626   END SUBROUTINE nemo_ctl
627
628
629   SUBROUTINE nemo_closefile
630      !!----------------------------------------------------------------------
631      !!                     ***  ROUTINE nemo_closefile  ***
632      !!
633      !! ** Purpose :   Close the files
634      !!----------------------------------------------------------------------
635      !
636      IF( lk_mpp )   CALL mppsync
637      !
638      CALL iom_close                                 ! close all input/output files managed by iom_*
639      !
640      IF( numstp          /= -1 )   CLOSE( numstp          )   ! time-step file
641      IF( numrun          /= -1 )   CLOSE( numrun          )   ! run statistics file
642      IF( lwm.AND.numond  /= -1 )   CLOSE( numond          )   ! oce output namelist
643      IF( lwm.AND.numoni  /= -1 )   CLOSE( numoni          )   ! ice output namelist
644      IF( numevo_ice      /= -1 )   CLOSE( numevo_ice      )   ! ice variables (temp. evolution)
645      IF( numout          /=  6 )   CLOSE( numout          )   ! standard model output file
646      IF( numdct_vol      /= -1 )   CLOSE( numdct_vol      )   ! volume transports
647      IF( numdct_heat     /= -1 )   CLOSE( numdct_heat     )   ! heat transports
648      IF( numdct_salt     /= -1 )   CLOSE( numdct_salt     )   ! salt transports
649      !
650      numout = 6                                     ! redefine numout in case it is used after this point...
651      !
652   END SUBROUTINE nemo_closefile
653
654
655   SUBROUTINE nemo_alloc
656      !!----------------------------------------------------------------------
657      !!                     ***  ROUTINE nemo_alloc  ***
658      !!
659      !! ** Purpose :   Allocate all the dynamic arrays of the OPA modules
660      !!
661      !! ** Method  :
662      !!----------------------------------------------------------------------
663      USE diawri    , ONLY : dia_wri_alloc
664      USE dom_oce   , ONLY : dom_oce_alloc
665      USE trc_oce   , ONLY : trc_oce_alloc
666      USE bdy_oce   , ONLY : bdy_oce_alloc
667      !
668      INTEGER :: ierr
669      !!----------------------------------------------------------------------
670      !
671      ierr =        oce_alloc    ()    ! ocean
672      ierr = ierr + dia_wri_alloc()
673      ierr = ierr + dom_oce_alloc()    ! ocean domain
674      ierr = ierr + zdf_oce_alloc()    ! ocean vertical physics
675      ierr = ierr + trc_oce_alloc()    ! shared TRC / TRA arrays
676      ierr = ierr + bdy_oce_alloc()    ! bdy masks (incl. initialization)
677      !
678      CALL mpp_sum( 'nemogcm', ierr )
679      IF( ierr /= 0 )   CALL ctl_stop( 'STOP', 'nemo_alloc: unable to allocate standard ocean arrays' )
680      !
681   END SUBROUTINE nemo_alloc
682
683
684   SUBROUTINE nemo_set_cfctl(sn_cfctl, setto )
685      !!----------------------------------------------------------------------
686      !!                     ***  ROUTINE nemo_set_cfctl  ***
687      !!
688      !! ** Purpose :   Set elements of the output control structure to setto.
689      !!
690      !! ** Method  :   Note this routine can be used to switch on/off some
691      !!                types of output for selected areas.
692      !!----------------------------------------------------------------------
693      TYPE(sn_ctl), INTENT(inout) :: sn_cfctl
694      LOGICAL     , INTENT(in   ) :: setto
695      !!----------------------------------------------------------------------
696      sn_cfctl%l_runstat = setto
697      sn_cfctl%l_trcstat = setto
698      sn_cfctl%l_oceout  = setto
699      sn_cfctl%l_layout  = setto
700      sn_cfctl%l_prtctl  = setto
701      sn_cfctl%l_prttrc  = setto
702      sn_cfctl%l_oasout  = setto
703   END SUBROUTINE nemo_set_cfctl
704
705   !!======================================================================
706END MODULE nemogcm
Note: See TracBrowser for help on using the repository browser.