source: NEMO/branches/2020/dev_r12377_KERNEL-06_techene_e3/src/OCE/step.F90 @ 12680

Last change on this file since 12680 was 12680, checked in by techene, 8 months ago

dynatfQCO.F90, stepLF.F90 : fixed (remove pe3. from dyn_atf_qco input arguments), all : remove e3. tables and include gurvan's feedbacks

  • Property svn:keywords set to Id
File size: 21.6 KB
Line 
1MODULE step
2   !!======================================================================
3   !!                       ***  MODULE step  ***
4   !! Time-stepping   : manager of the ocean, tracer and ice time stepping
5   !!======================================================================
6   !! History :  OPA  !  1991-03  (G. Madec)  Original code
7   !!             -   !  1991-11  (G. Madec)
8   !!             -   !  1992-06  (M. Imbard)  add a first output record
9   !!             -   !  1996-04  (G. Madec)  introduction of dynspg
10   !!             -   !  1996-04  (M.A. Foujols)  introduction of passive tracer
11   !!            8.0  !  1997-06  (G. Madec)  new architecture of call
12   !!            8.2  !  1997-06  (G. Madec, M. Imbard, G. Roullet)  free surface
13   !!             -   !  1999-02  (G. Madec, N. Grima)  hpg implicit
14   !!             -   !  2000-07  (J-M Molines, M. Imbard)  Open Bondary Conditions
15   !!   NEMO     1.0  !  2002-06  (G. Madec)  free form, suppress macro-tasking
16   !!             -   !  2004-08  (C. Talandier) New trends organization
17   !!             -   !  2005-01  (C. Ethe) Add the KPP closure scheme
18   !!             -   !  2005-11  (G. Madec)  Reorganisation of tra and dyn calls
19   !!             -   !  2006-01  (L. Debreu, C. Mazauric)  Agrif implementation
20   !!             -   !  2006-07  (S. Masson)  restart using iom
21   !!            3.2  !  2009-02  (G. Madec, R. Benshila)  reintroduicing z*-coordinate
22   !!             -   !  2009-06  (S. Masson, G. Madec)  TKE restart compatible with key_cpl
23   !!            3.3  !  2010-05  (K. Mogensen, A. Weaver, M. Martin, D. Lea) Assimilation interface
24   !!             -   !  2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase + merge TRC-TRA
25   !!            3.4  !  2011-04  (G. Madec, C. Ethe) Merge of dtatem and dtasal
26   !!            3.6  !  2012-07  (J. Simeon, G. Madec. C. Ethe)  Online coarsening of outputs
27   !!            3.6  !  2014-04  (F. Roquet, G. Madec) New equations of state
28   !!            3.6  !  2014-10  (E. Clementi, P. Oddo) Add Qiao vertical mixing in case of waves
29   !!            3.7  !  2014-10  (G. Madec)  LDF simplication
30   !!             -   !  2014-12  (G. Madec) remove KPP scheme
31   !!             -   !  2015-11  (J. Chanut) free surface simplification (remove filtered free surface)
32   !!            4.0  !  2017-05  (G. Madec)  introduction of the vertical physics manager (zdfphy)
33   !!            4.1  !  2019-08  (A. Coward, D. Storkey) rewrite in preparation for new timestepping scheme
34   !!----------------------------------------------------------------------
35#if defined key_qco
36   !!----------------------------------------------------------------------
37   !!   'key_qco'      EMPTY MODULE      Quasi-Eulerian vertical coordonate
38   !!----------------------------------------------------------------------
39#else
40   !!----------------------------------------------------------------------
41   !!   stp             : OPA system time-stepping
42   !!----------------------------------------------------------------------
43   USE step_oce         ! time stepping definition modules
44   !
45   USE iom              ! xIOs server
46
47   IMPLICIT NONE
48   PRIVATE
49
50   PUBLIC   stp   ! called by nemogcm.F90
51
52   !!----------------------------------------------------------------------
53   !! time level indices
54   !!----------------------------------------------------------------------
55   INTEGER, PUBLIC :: Nbb, Nnn, Naa, Nrhs          !! used by nemo_init
56
57   !!----------------------------------------------------------------------
58   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
59   !! $Id$
60   !! Software governed by the CeCILL license (see ./LICENSE)
61   !!----------------------------------------------------------------------
62CONTAINS
63
64#if defined key_agrif
65   RECURSIVE SUBROUTINE stp( )
66      INTEGER             ::   kstp   ! ocean time-step index
67#else
68   SUBROUTINE stp( kstp )
69      INTEGER, INTENT(in) ::   kstp   ! ocean time-step index
70#endif
71      !!----------------------------------------------------------------------
72      !!                     ***  ROUTINE stp  ***
73      !!
74      !! ** Purpose : - Time stepping of OPA  (momentum and active tracer eqs.)
75      !!              - Time stepping of SI3 (dynamic and thermodynamic eqs.)
76      !!              - Time stepping of TRC  (passive tracer eqs.)
77      !!
78      !! ** Method  : -1- Update forcings and data
79      !!              -2- Update ocean physics
80      !!              -3- Compute the t and s trends
81      !!              -4- Update t and s
82      !!              -5- Compute the momentum trends
83      !!              -6- Update the horizontal velocity
84      !!              -7- Compute the diagnostics variables (rd,N2, hdiv,w)
85      !!              -8- Outputs and diagnostics
86      !!----------------------------------------------------------------------
87      INTEGER ::   ji, jj, jk   ! dummy loop indice
88      INTEGER ::   indic        ! error indicator if < 0
89!!gm kcall can be removed, I guess
90      INTEGER ::   kcall        ! optional integer argument (dom_vvl_sf_nxt)
91      !! ---------------------------------------------------------------------
92#if defined key_agrif
93      kstp = nit000 + Agrif_Nb_Step()
94      Kbb_a = Nbb; Kmm_a = Nnn; Krhs_a = Nrhs   ! agrif_oce module copies of time level indices
95      IF( lk_agrif_debug ) THEN
96         IF( Agrif_Root() .and. lwp)   WRITE(*,*) '---'
97         IF(lwp)   WRITE(*,*) 'Grid Number', Agrif_Fixed(),' time step ', kstp, 'int tstep', Agrif_NbStepint()
98      ENDIF
99      IF( kstp == nit000 + 1 )   lk_agrif_fstep = .FALSE.
100# if defined key_iomput
101      IF( Agrif_Nbstepint() == 0 )   CALL iom_swap( cxios_context )
102# endif
103#endif
104      !
105      IF( ln_timing )   CALL timing_start('stp')
106      !
107      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
108      ! update I/O and calendar
109      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
110                             indic = 0                ! reset to no error condition
111                             
112      IF( kstp == nit000 ) THEN                       ! initialize IOM context (must be done after nemo_init for AGRIF+XIOS+OASIS)
113                             CALL iom_init( cxios_context, ld_closedef=.FALSE. )   ! for model grid (including passible AGRIF zoom)
114         IF( lk_diamlr   )   CALL dia_mlr_iom_init    ! with additional setup for multiple-linear-regression analysis
115                             CALL iom_init_closedef
116         IF( ln_crs      )   CALL iom_init( TRIM(cxios_context)//"_crs" )  ! for coarse grid
117      ENDIF
118      IF( kstp /= nit000 )   CALL day( kstp )         ! Calendar (day was already called at nit000 in day_init)
119                             CALL iom_setkt( kstp - nit000 + 1,      cxios_context          )   ! tell IOM we are at time step kstp
120      IF( ln_crs         )   CALL iom_setkt( kstp - nit000 + 1, TRIM(cxios_context)//"_crs" )   ! tell IOM we are at time step kstp
121
122      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
123      ! Update external forcing (tides, open boundaries, ice shelf interaction and surface boundary condition (including sea-ice)
124      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
125      IF( ln_tide    )   CALL tide_update( kstp )                     ! update tide potential
126      IF( ln_apr_dyn )   CALL sbc_apr ( kstp )                        ! atmospheric pressure (NB: call before bdy_dta which needs ssh_ib)
127      IF( ln_bdy     )   CALL bdy_dta ( kstp, Nnn )                   ! update dynamic & tracer data at open boundaries
128      IF( ln_isf     )   CALL isf_stp ( kstp, Nnn )
129                         CALL sbc     ( kstp, Nbb, Nnn )              ! Sea Boundary Condition (including sea-ice)
130
131      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
132      ! Update stochastic parameters and random T/S fluctuations
133      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
134      IF( ln_sto_eos ) CALL sto_par( kstp )          ! Stochastic parameters
135      IF( ln_sto_eos ) CALL sto_pts( ts(:,:,:,:,Nnn)  )          ! Random T/S fluctuations
136
137      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
138      ! Ocean physics update
139      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
140      !  THERMODYNAMICS
141                         CALL eos_rab( ts(:,:,:,:,Nbb), rab_b, Nnn )       ! before local thermal/haline expension ratio at T-points
142                         CALL eos_rab( ts(:,:,:,:,Nnn), rab_n, Nnn )       ! now    local thermal/haline expension ratio at T-points
143                         CALL bn2    ( ts(:,:,:,:,Nbb), rab_b, rn2b, Nnn ) ! before Brunt-Vaisala frequency
144                         CALL bn2    ( ts(:,:,:,:,Nnn), rab_n, rn2, Nnn  ) ! now    Brunt-Vaisala frequency
145
146      !  VERTICAL PHYSICS
147                         CALL zdf_phy( kstp, Nbb, Nnn, Nrhs )   ! vertical physics update (top/bot drag, avt, avs, avm + MLD)
148
149      !  LATERAL  PHYSICS
150      !
151      IF( l_ldfslp ) THEN                             ! slope of lateral mixing
152                         CALL eos( ts(:,:,:,:,Nbb), rhd, gdept_0(:,:,:) )               ! before in situ density
153
154         IF( ln_zps .AND. .NOT. ln_isfcav)                                    &
155            &            CALL zps_hde    ( kstp, Nnn, jpts, ts(:,:,:,:,Nbb), gtsu, gtsv,  &  ! Partial steps: before horizontal gradient
156            &                                          rhd, gru , grv    )       ! of t, s, rd at the last ocean level
157
158         IF( ln_zps .AND.       ln_isfcav)                                                &
159            &            CALL zps_hde_isf( kstp, Nnn, jpts, ts(:,:,:,:,Nbb), gtsu, gtsv, gtui, gtvi,  &  ! Partial steps for top cell (ISF)
160            &                                          rhd, gru , grv , grui, grvi   )       ! of t, s, rd at the first ocean level
161         IF( ln_traldf_triad ) THEN
162                         CALL ldf_slp_triad( kstp, Nbb, Nnn )             ! before slope for triad operator
163         ELSE     
164                         CALL ldf_slp     ( kstp, rhd, rn2b, Nbb, Nnn )   ! before slope for standard operator
165         ENDIF
166      ENDIF
167      !                                                                        ! eddy diffusivity coeff.
168      IF( l_ldftra_time .OR. l_ldfeiv_time )   CALL ldf_tra( kstp, Nbb, Nnn )  !       and/or eiv coeff.
169      IF( l_ldfdyn_time                    )   CALL ldf_dyn( kstp, Nbb )       ! eddy viscosity coeff.
170
171      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
172      !  Ocean dynamics : hdiv, ssh, e3, u, v, w
173      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
174
175                            CALL ssh_nxt       ( kstp, Nbb, Nnn, ssh, Naa )    ! after ssh (includes call to div_hor)
176      IF( .NOT.ln_linssh )  CALL dom_vvl_sf_nxt( kstp, Nbb, Nnn,      Naa )    ! after vertical scale factors
177                            CALL wzv           ( kstp, Nbb, Nnn, Naa, ww  )    ! now cross-level velocity
178      IF( ln_zad_Aimp )     CALL wAimp         ( kstp,      Nnn           )  ! Adaptive-implicit vertical advection partitioning
179                            CALL eos    ( ts(:,:,:,:,Nnn), rhd, rhop, gdept(:,:,:,Nnn) )  ! now in situ density for hpg computation
180                           
181                           
182                         uu(:,:,:,Nrhs) = 0._wp            ! set dynamics trends to zero
183                         vv(:,:,:,Nrhs) = 0._wp
184
185      IF(  lk_asminc .AND. ln_asmiau .AND. ln_dyninc )   &
186               &         CALL dyn_asm_inc   ( kstp, Nbb, Nnn, uu, vv, Nrhs )  ! apply dynamics assimilation increment
187      IF( ln_bdy     )   CALL bdy_dyn3d_dmp ( kstp, Nbb,      uu, vv, Nrhs )  ! bdy damping trends
188#if defined key_agrif
189      IF(.NOT. Agrif_Root())  & 
190               &         CALL Agrif_Sponge_dyn        ! momentum sponge
191#endif
192                         CALL dyn_adv( kstp, Nbb, Nnn      , uu, vv, Nrhs )  ! advection (VF or FF)   ==> RHS
193                         CALL dyn_vor( kstp,      Nnn      , uu, vv, Nrhs )  ! vorticity              ==> RHS
194                         CALL dyn_ldf( kstp, Nbb, Nnn      , uu, vv, Nrhs )  ! lateral mixing
195      IF( ln_zdfosm  )   CALL dyn_osm( kstp,      Nnn      , uu, vv, Nrhs )  ! OSMOSIS non-local velocity fluxes ==> RHS
196                         CALL dyn_hpg( kstp,      Nnn      , uu, vv, Nrhs )  ! horizontal gradient of Hydrostatic pressure
197                         CALL dyn_spg( kstp, Nbb, Nnn, Nrhs, uu, vv, ssh, uu_b, vv_b, Naa )  ! surface pressure gradient
198
199                                                      ! With split-explicit free surface, since now transports have been updated and ssh(:,:,Nrhs) as well
200      IF( ln_dynspg_ts ) THEN                         ! vertical scale factors and vertical velocity need to be updated
201                            CALL div_hor       ( kstp, Nbb, Nnn )                ! Horizontal divergence  (2nd call in time-split case)
202         IF(.NOT.ln_linssh) CALL dom_vvl_sf_nxt( kstp, Nbb, Nnn, Naa, kcall=2 )  ! after vertical scale factors (update depth average component)
203      ENDIF
204                            CALL dyn_zdf    ( kstp, Nbb, Nnn, Nrhs, uu, vv, Naa  )  ! vertical diffusion
205      IF( ln_dynspg_ts ) THEN                                                       ! vertical scale factors and vertical velocity need to be updated
206                            CALL wzv        ( kstp, Nbb, Nnn, Naa, ww )             ! now cross-level velocity
207         IF( ln_zad_Aimp )  CALL wAimp      ( kstp,      Nnn )                      ! Adaptive-implicit vertical advection partitioning
208      ENDIF
209     
210
211      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
212      ! cool skin
213      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<     
214      IF ( ln_diurnal )  CALL diurnal_layers( kstp )
215     
216      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
217      ! diagnostics and outputs
218      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
219      IF( ln_floats  )   CALL flo_stp   ( kstp, Nbb, Nnn )      ! drifting Floats
220      IF( ln_diacfl  )   CALL dia_cfl   ( kstp,      Nnn )      ! Courant number diagnostics
221                         CALL dia_hth   ( kstp,      Nnn )      ! Thermocline depth (20 degres isotherm depth)
222      IF( ln_diadct  )   CALL dia_dct   ( kstp,      Nnn )      ! Transports
223                         CALL dia_ar5   ( kstp,      Nnn )      ! ar5 diag
224                         CALL dia_ptr   ( kstp,      Nnn )      ! Poleward adv/ldf TRansports diagnostics
225                         CALL dia_wri   ( kstp,      Nnn )      ! ocean model: outputs
226      IF( ln_crs     )   CALL crs_fld   ( kstp,      Nnn )      ! ocean model: online field coarsening & output
227      IF( lk_diadetide ) CALL dia_detide( kstp )                ! Weights computation for daily detiding of model diagnostics
228      IF( lk_diamlr  )   CALL dia_mlr                           ! Update time used in multiple-linear-regression analysis
229     
230#if defined key_top
231      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
232      ! Passive Tracer Model
233      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
234                         CALL trc_stp       ( kstp, Nbb, Nnn, Nrhs, Naa )  ! time-stepping
235#endif
236
237      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
238      ! Active tracers                             
239      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
240                         ts(:,:,:,:,Nrhs) = 0._wp         ! set tracer trends to zero
241
242      IF(  lk_asminc .AND. ln_asmiau .AND. &
243         & ln_trainc )   CALL tra_asm_inc( kstp, Nbb, Nnn, ts, Nrhs )  ! apply tracer assimilation increment
244                         CALL tra_sbc    ( kstp,      Nnn, ts, Nrhs )  ! surface boundary condition
245      IF( ln_traqsr  )   CALL tra_qsr    ( kstp,      Nnn, ts, Nrhs )  ! penetrative solar radiation qsr
246      IF( ln_isf     )   CALL tra_isf    ( kstp,      Nnn, ts, Nrhs )  ! ice shelf heat flux
247      IF( ln_trabbc  )   CALL tra_bbc    ( kstp,      Nnn, ts, Nrhs )  ! bottom heat flux
248      IF( ln_trabbl  )   CALL tra_bbl    ( kstp, Nbb, Nnn, ts, Nrhs )  ! advective (and/or diffusive) bottom boundary layer scheme
249      IF( ln_tradmp  )   CALL tra_dmp    ( kstp, Nbb, Nnn, ts, Nrhs )  ! internal damping trends
250      IF( ln_bdy     )   CALL bdy_tra_dmp( kstp, Nbb,      ts, Nrhs )  ! bdy damping trends
251#if defined key_agrif
252      IF(.NOT. Agrif_Root())  & 
253               &         CALL Agrif_Sponge_tra        ! tracers sponge
254#endif
255                         CALL tra_adv    ( kstp, Nbb, Nnn, ts, Nrhs )  ! hor. + vert. advection ==> RHS
256      IF( ln_zdfosm  )   CALL tra_osm    ( kstp,      Nnn, ts, Nrhs )  ! OSMOSIS non-local tracer fluxes ==> RHS
257      IF( lrst_oce .AND. ln_zdfosm ) &
258           &             CALL osm_rst    ( kstp,      Nnn, 'WRITE'  )  ! write OSMOSIS outputs + ww (so must do here) to restarts
259                         CALL tra_ldf    ( kstp, Nbb, Nnn, ts, Nrhs )  ! lateral mixing
260
261                         CALL tra_zdf    ( kstp, Nbb, Nnn, Nrhs, ts, Naa  )  ! vertical mixing and after tracer fields
262      IF( ln_zdfnpc  )   CALL tra_npc    ( kstp,      Nnn, Nrhs, ts, Naa  )  ! update after fields by non-penetrative convection
263
264      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
265      ! Set boundary conditions, time filter and swap time levels
266      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
267!!jc1: For agrif, it would be much better to finalize tracers/momentum here (e.g. bdy conditions) and move the swap
268!!    (and time filtering) after Agrif update. Then restart would be done after and would contain updated fields.
269!!    If so:
270!!    (i) no need to call agrif update at initialization time
271!!    (ii) no need to update "before" fields
272!!
273!!    Apart from creating new tra_swp/dyn_swp routines, this however:
274!!    (i) makes boundary conditions at initialization time computed from updated fields which is not the case between
275!!    two restarts => restartability issue. One can circumvent this, maybe, by assuming "interface separation",
276!!    e.g. a shift of the feedback interface inside child domain.
277!!    (ii) requires that all restart outputs of updated variables by agrif (e.g. passive tracers/tke/barotropic arrays) are done at the same
278!!    place.
279!!
280!!jc2: dynnxt must be the latest call. e3t(:,:,:,Nbb) are indeed updated in that routine
281                         CALL tra_atf       ( kstp, Nbb, Nnn, Naa, ts )                      ! time filtering of "now" tracer arrays
282                         CALL dyn_atf       ( kstp, Nbb, Nnn, Naa, uu, vv, e3t, e3u, e3v  )  ! time filtering of "now" velocities and scale factors
283                         CALL ssh_atf       ( kstp, Nbb, Nnn, Naa, ssh )                     ! time filtering of "now" sea surface height
284      !
285      ! Swap time levels
286      Nrhs = Nbb
287      Nbb = Nnn
288      Nnn = Naa
289      Naa = Nrhs
290      !
291      IF(.NOT.ln_linssh) CALL dom_vvl_sf_update( kstp, Nbb, Nnn, Naa )  ! recompute vertical scale factors
292      !
293      IF( ln_diahsb  )   CALL dia_hsb       ( kstp, Nbb, Nnn )  ! - ML - global conservation diagnostics
294
295!!gm : This does not only concern the dynamics ==>>> add a new title
296!!gm2: why ouput restart before AGRIF update?
297!!
298!!jc: That would be better, but see comment above
299!!
300      IF( lrst_oce   )   CALL rst_write    ( kstp, Nbb, Nnn )   ! write output ocean restart file
301      IF( ln_sto_eos )   CALL sto_rst_write( kstp )   ! write restart file for stochastic parameters
302
303#if defined key_agrif
304      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
305      ! AGRIF
306      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<     
307                         Kbb_a = Nbb; Kmm_a = Nnn; Krhs_a = Nrhs      ! agrif_oce module copies of time level indices
308                         CALL Agrif_Integrate_ChildGrids( stp )       ! allows to finish all the Child Grids before updating
309
310                         IF( Agrif_NbStepint() == 0 ) THEN
311                            CALL Agrif_update_all( )                  ! Update all components
312                         ENDIF
313#endif
314      IF( ln_diaobs  )   CALL dia_obs      ( kstp, Nnn )      ! obs-minus-model (assimilation) diagnostics (call after dynamics update)
315
316      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
317      ! Control
318      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
319                         CALL stp_ctl      ( kstp, Nbb, Nnn, indic )
320                         
321      IF( kstp == nit000 ) THEN                          ! 1st time step only
322                                        CALL iom_close( numror )   ! close input  ocean restart file
323         IF(lwm)                        CALL FLUSH    ( numond )   ! flush output namelist oce
324         IF(lwm .AND. numoni /= -1 )    CALL FLUSH    ( numoni )   ! flush output namelist ice (if exist)
325      ENDIF
326
327      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
328      ! Coupled mode
329      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
330!!gm why lk_oasis and not lk_cpl ????
331      IF( lk_oasis   )   CALL sbc_cpl_snd( kstp, Nbb, Nnn )        ! coupled mode : field exchanges
332      !
333#if defined key_iomput
334      IF( kstp == nitend .OR. indic < 0 ) THEN
335                      CALL iom_context_finalize(      cxios_context          ) ! needed for XIOS+AGRIF
336                      IF(lrxios) CALL iom_context_finalize(      crxios_context          )
337         IF( ln_crs ) CALL iom_context_finalize( trim(cxios_context)//"_crs" ) !
338      ENDIF
339#endif
340      !
341      IF( ln_timing )   CALL timing_stop('stp')
342      !
343   END SUBROUTINE stp
344   !
345#endif
346   !!======================================================================
347END MODULE step
Note: See TracBrowser for help on using the repository browser.