source: NEMO/branches/2020/dev_r12377_KERNEL-06_techene_e3/src/OCE/stpMLF.F90 @ 12732

Last change on this file since 12732 was 12732, checked in by techene, 11 months ago

some cleaning and proper module/routine name, mini bug introduced and corrected in sbcice_cice

File size: 27.1 KB
Line 
1MODULE stepMLF
2   !!======================================================================
3   !!                       ***  MODULE step  ***
4   !! Time-stepping   : manager of the ocean, tracer and ice time stepping
5   !!======================================================================
6   !! History :  OPA  !  1991-03  (G. Madec)  Original code
7   !!             -   !  1991-11  (G. Madec)
8   !!             -   !  1992-06  (M. Imbard)  add a first output record
9   !!             -   !  1996-04  (G. Madec)  introduction of dynspg
10   !!             -   !  1996-04  (M.A. Foujols)  introduction of passive tracer
11   !!            8.0  !  1997-06  (G. Madec)  new architecture of call
12   !!            8.2  !  1997-06  (G. Madec, M. Imbard, G. Roullet)  free surface
13   !!             -   !  1999-02  (G. Madec, N. Grima)  hpg implicit
14   !!             -   !  2000-07  (J-M Molines, M. Imbard)  Open Bondary Conditions
15   !!   NEMO     1.0  !  2002-06  (G. Madec)  free form, suppress macro-tasking
16   !!             -   !  2004-08  (C. Talandier) New trends organization
17   !!             -   !  2005-01  (C. Ethe) Add the KPP closure scheme
18   !!             -   !  2005-11  (G. Madec)  Reorganisation of tra and dyn calls
19   !!             -   !  2006-01  (L. Debreu, C. Mazauric)  Agrif implementation
20   !!             -   !  2006-07  (S. Masson)  restart using iom
21   !!            3.2  !  2009-02  (G. Madec, R. Benshila)  reintroduicing z*-coordinate
22   !!             -   !  2009-06  (S. Masson, G. Madec)  TKE restart compatible with key_cpl
23   !!            3.3  !  2010-05  (K. Mogensen, A. Weaver, M. Martin, D. Lea) Assimilation interface
24   !!             -   !  2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase + merge TRC-TRA
25   !!            3.4  !  2011-04  (G. Madec, C. Ethe) Merge of dtatem and dtasal
26   !!            3.6  !  2012-07  (J. Simeon, G. Madec. C. Ethe)  Online coarsening of outputs
27   !!            3.6  !  2014-04  (F. Roquet, G. Madec) New equations of state
28   !!            3.6  !  2014-10  (E. Clementi, P. Oddo) Add Qiao vertical mixing in case of waves
29   !!            3.7  !  2014-10  (G. Madec)  LDF simplication
30   !!             -   !  2014-12  (G. Madec) remove KPP scheme
31   !!             -   !  2015-11  (J. Chanut) free surface simplification (remove filtered free surface)
32   !!            4.0  !  2017-05  (G. Madec)  introduction of the vertical physics manager (zdfphy)
33   !!            4.1  !  2019-08  (A. Coward, D. Storkey) rewrite in preparation for new timestepping scheme
34   !!----------------------------------------------------------------------
35
36   !!----------------------------------------------------------------------
37   !!   stp_MLF       : OPA system time-stepping
38   !!----------------------------------------------------------------------
39   USE step_oce       ! time stepping definition modules
40   !
41   USE iom            ! xIOs server
42   USE domqco
43   USE traatfqco      ! time filtering                   (tra_atf_qco routine)
44   USE dynatfqco      ! time filtering                   (dyn_atf_qco routine)
45   USE dynspg_ts      ! surface pressure gradient: split-explicit scheme (define un_adv)
46   USE bdydyn         ! ocean open boundary conditions (define bdy_dyn)
47
48   IMPLICIT NONE
49   PRIVATE
50
51   PUBLIC   stp_MLF   ! called by nemogcm.F90
52
53   !!----------------------------------------------------------------------
54   !! time level indices
55   !!----------------------------------------------------------------------
56   INTEGER, PUBLIC :: Nbb, Nnn, Naa, Nrhs          !! used by nemo_init
57#  include "domzgr_substitute.h90"
58   !!----------------------------------------------------------------------
59   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
60   !! $Id: step.F90 12377 2020-02-12 14:39:06Z acc $
61   !! Software governed by the CeCILL license (see ./LICENSE)
62   !!----------------------------------------------------------------------
63CONTAINS
64
65#if defined key_agrif
66   RECURSIVE SUBROUTINE stp_MLF( )
67      INTEGER             ::   kstp   ! ocean time-step index
68#else
69   SUBROUTINE stp_MLF( kstp )
70      INTEGER, INTENT(in) ::   kstp   ! ocean time-step index
71#endif
72      !!----------------------------------------------------------------------
73      !!                     ***  ROUTINE stp_MLF  ***
74      !!
75      !! ** Purpose : - Time stepping of OPA  (momentum and active tracer eqs.)
76      !!              - Time stepping of SI3 (dynamic and thermodynamic eqs.)
77      !!              - Time stepping of TRC  (passive tracer eqs.)
78      !!
79      !! ** Method  : -1- Update forcings and data
80      !!              -2- Update ocean physics
81      !!              -3- Compute the t and s trends
82      !!              -4- Update t and s
83      !!              -5- Compute the momentum trends
84      !!              -6- Update the horizontal velocity
85      !!              -7- Compute the diagnostics variables (rd,N2, hdiv,w)
86      !!              -8- Outputs and diagnostics
87      !!----------------------------------------------------------------------
88      INTEGER ::   ji, jj, jk   ! dummy loop indice
89      INTEGER ::   indic        ! error indicator if < 0
90!!gm kcall can be removed, I guess
91      INTEGER ::   kcall        ! optional integer argument (dom_vvl_sf_nxt)
92!!st patch
93      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zgdept 
94      !! ---------------------------------------------------------------------
95#if defined key_agrif
96      kstp = nit000 + Agrif_Nb_Step()
97      Kbb_a = Nbb; Kmm_a = Nnn; Krhs_a = Nrhs   ! agrif_oce module copies of time level indices
98      IF( lk_agrif_debug ) THEN
99         IF( Agrif_Root() .and. lwp)   WRITE(*,*) '---'
100         IF(lwp)   WRITE(*,*) 'Grid Number', Agrif_Fixed(),' time step ', kstp, 'int tstep', Agrif_NbStepint()
101      ENDIF
102      IF( kstp == nit000 + 1 )   lk_agrif_fstep = .FALSE.
103# if defined key_iomput
104      IF( Agrif_Nbstepint() == 0 )   CALL iom_swap( cxios_context )
105# endif
106#endif
107      !
108      IF( ln_timing )   CALL timing_start('stp_MLF')
109      !
110      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
111      ! model timestep
112      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
113      !
114      IF( l_1st_euler ) THEN 
115         ! start or restart with Euler 1st time-step
116         rDt =  rn_Dt   
117         r1_Dt = 1._wp / rDt
118      ENDIF
119      !
120      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
121
122      ! update I/O and calendar
123      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
124                             indic = 0                ! reset to no error condition
125
126      IF( kstp == nit000 ) THEN                       ! initialize IOM context (must be done after nemo_init for AGRIF+XIOS+OASIS)
127                             CALL iom_init( cxios_context, ld_closedef=.FALSE. )   ! for model grid (including passible AGRIF zoom)
128         IF( lk_diamlr   )   CALL dia_mlr_iom_init    ! with additional setup for multiple-linear-regression analysis
129                             CALL iom_init_closedef
130         IF( ln_crs      )   CALL iom_init( TRIM(cxios_context)//"_crs" )  ! for coarse grid
131      ENDIF
132      IF( kstp /= nit000 )   CALL day( kstp )         ! Calendar (day was already called at nit000 in day_init)
133                             CALL iom_setkt( kstp - nit000 + 1,      cxios_context          )   ! tell IOM we are at time step kstp
134      IF( ln_crs         )   CALL iom_setkt( kstp - nit000 + 1, TRIM(cxios_context)//"_crs" )   ! tell IOM we are at time step kstp
135
136      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
137      ! Update external forcing (tides, open boundaries, ice shelf interaction and surface boundary condition (including sea-ice)
138      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
139      IF( ln_tide    )   CALL tide_update( kstp )                     ! update tide potential
140      IF( ln_apr_dyn )   CALL sbc_apr ( kstp )                        ! atmospheric pressure (NB: call before bdy_dta which needs ssh_ib)
141      IF( ln_bdy     )   CALL bdy_dta ( kstp, Nnn )                   ! update dynamic & tracer data at open boundaries
142      IF( ln_isf     )   CALL isf_stp ( kstp, Nnn )
143                         CALL sbc     ( kstp, Nbb, Nnn )              ! Sea Boundary Condition (including sea-ice)
144
145      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
146      ! Update stochastic parameters and random T/S fluctuations
147      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
148      IF( ln_sto_eos ) CALL sto_par( kstp )          ! Stochastic parameters
149      IF( ln_sto_eos ) CALL sto_pts( ts(:,:,:,:,Nnn)  )          ! Random T/S fluctuations
150
151      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
152      ! Ocean physics update
153      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
154      !  THERMODYNAMICS
155                         CALL eos_rab( ts(:,:,:,:,Nbb), rab_b, Nnn )       ! before local thermal/haline expension ratio at T-points
156                         CALL eos_rab( ts(:,:,:,:,Nnn), rab_n, Nnn )       ! now    local thermal/haline expension ratio at T-points
157                         CALL bn2    ( ts(:,:,:,:,Nbb), rab_b, rn2b, Nnn ) ! before Brunt-Vaisala frequency
158                         CALL bn2    ( ts(:,:,:,:,Nnn), rab_n, rn2, Nnn  ) ! now    Brunt-Vaisala frequency
159
160      !  VERTICAL PHYSICS
161                         CALL zdf_phy( kstp, Nbb, Nnn, Nrhs )   ! vertical physics update (top/bot drag, avt, avs, avm + MLD)
162
163      !  LATERAL  PHYSICS
164      !
165      IF( l_ldfslp ) THEN                             ! slope of lateral mixing
166                         CALL eos( ts(:,:,:,:,Nbb), rhd, gdept_0(:,:,:) )               ! before in situ density
167
168         IF( ln_zps .AND. .NOT. ln_isfcav)                                    &
169            &            CALL zps_hde    ( kstp, Nnn, jpts, ts(:,:,:,:,Nbb), gtsu, gtsv,  &  ! Partial steps: before horizontal gradient
170            &                                          rhd, gru , grv    )       ! of t, s, rd at the last ocean level
171
172         IF( ln_zps .AND.       ln_isfcav)                                                &
173            &            CALL zps_hde_isf( kstp, Nnn, jpts, ts(:,:,:,:,Nbb), gtsu, gtsv, gtui, gtvi,  &  ! Partial steps for top cell (ISF)
174            &                                          rhd, gru , grv , grui, grvi   )       ! of t, s, rd at the first ocean level
175         IF( ln_traldf_triad ) THEN
176                         CALL ldf_slp_triad( kstp, Nbb, Nnn )             ! before slope for triad operator
177         ELSE
178                         CALL ldf_slp     ( kstp, rhd, rn2b, Nbb, Nnn )   ! before slope for standard operator
179         ENDIF
180      ENDIF
181      !                                                                        ! eddy diffusivity coeff.
182      IF( l_ldftra_time .OR. l_ldfeiv_time )   CALL ldf_tra( kstp, Nbb, Nnn )  !       and/or eiv coeff.
183      IF( l_ldfdyn_time                    )   CALL ldf_dyn( kstp, Nbb )       ! eddy viscosity coeff.
184
185      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
186      !  Ocean dynamics : hdiv, ssh, e3, u, v, w
187      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
188      DO jk = 1, jpk
189         zgdept(:,:,jk) = gdept(:,:,jk,Nnn)
190      END DO
191                            CALL ssh_nxt       ( kstp, Nbb, Nnn, ssh,  Naa )   ! after ssh (includes call to div_hor)
192      IF( .NOT.ln_linssh )  CALL dom_qco_r3c    ( ssh(:,:,Naa), r3t(:,:,Naa), r3u(:,:,Naa), r3v(:,:,Naa) )   ! "after" ssh./h._0 ratio
193                            CALL wzv           ( kstp, Nbb, Nnn, Naa, ww  )    ! Nnn cross-level velocity
194      IF( ln_zad_Aimp )     CALL wAimp         ( kstp,      Nnn           )    ! Adaptive-implicit vertical advection partitioning
195                            CALL eos    ( ts(:,:,:,:,Nnn), rhd, rhop, zgdept ) ! now in situ density for hpg computation
196
197
198                         uu(:,:,:,Nrhs) = 0._wp            ! set dynamics trends to zero
199                         vv(:,:,:,Nrhs) = 0._wp
200
201      IF(  lk_asminc .AND. ln_asmiau .AND. ln_dyninc )   &
202               &         CALL dyn_asm_inc   ( kstp, Nbb, Nnn, uu, vv, Nrhs )  ! apply dynamics assimilation increment
203      IF( ln_bdy     )   CALL bdy_dyn3d_dmp ( kstp, Nbb,      uu, vv, Nrhs )  ! bdy damping trends
204#if defined key_agrif
205      IF(.NOT. Agrif_Root())  &
206               &         CALL Agrif_Sponge_dyn        ! momentum sponge
207#endif
208                         CALL dyn_adv( kstp, Nbb, Nnn      , uu, vv, Nrhs )  ! advection (VF or FF)   ==> RHS
209                         CALL dyn_vor( kstp,      Nnn      , uu, vv, Nrhs )  ! vorticity              ==> RHS
210                         CALL dyn_ldf( kstp, Nbb, Nnn      , uu, vv, Nrhs )  ! lateral mixing
211      IF( ln_zdfosm  )   CALL dyn_osm( kstp,      Nnn      , uu, vv, Nrhs )  ! OSMOSIS non-local velocity fluxes ==> RHS
212                         CALL dyn_hpg( kstp,      Nnn      , uu, vv, Nrhs )  ! horizontal gradient of Hydrostatic pressure
213                         CALL dyn_spg( kstp, Nbb, Nnn, Nrhs, uu, vv, ssh, uu_b, vv_b, Naa )  ! surface pressure gradient
214
215                                                      ! With split-explicit free surface, since now transports have been updated and ssh(:,:,Nrhs) as well
216      IF( ln_dynspg_ts ) THEN                         ! vertical scale factors and vertical velocity need to be updated
217                            CALL div_hor    ( kstp, Nbb, Nnn )                ! Horizontal divergence  (2nd call in time-split case)
218         IF(.NOT.ln_linssh) CALL dom_qco_r3c ( ssh(:,:,Naa), r3t(:,:,Naa), r3u(:,:,Naa), r3v(:,:,Naa), r3f(:,:) )   ! "after" ssh./h._0 ratio
219      ENDIF
220                            CALL dyn_zdf    ( kstp, Nbb, Nnn, Nrhs, uu, vv, Naa  )  ! vertical diffusion
221      IF( ln_dynspg_ts ) THEN                                                       ! vertical scale factors and vertical velocity need to be updated
222                            CALL wzv        ( kstp, Nbb, Nnn, Naa, ww )             ! Nnn cross-level velocity
223         IF( ln_zad_Aimp )  CALL wAimp      ( kstp,      Nnn )                      ! Adaptive-implicit vertical advection partitioning
224      ENDIF
225
226
227      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
228      ! cool skin
229      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
230      IF ( ln_diurnal )  CALL diurnal_layers( kstp )
231
232      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
233      ! diagnostics and outputs
234      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
235      IF( ln_floats  )   CALL flo_stp   ( kstp, Nbb, Nnn )      ! drifting Floats
236      IF( ln_diacfl  )   CALL dia_cfl   ( kstp,      Nnn )      ! Courant number diagnostics
237                         CALL dia_hth   ( kstp,      Nnn )      ! Thermocline depth (20 degres isotherm depth)
238      IF( ln_diadct  )   CALL dia_dct   ( kstp,      Nnn )      ! Transports
239                         CALL dia_ar5   ( kstp,      Nnn )      ! ar5 diag
240                         CALL dia_ptr   ( kstp,      Nnn )      ! Poleward adv/ldf TRansports diagnostics
241                         CALL dia_wri   ( kstp,      Nnn )      ! ocean model: outputs
242      IF( ln_crs     )   CALL crs_fld   ( kstp,      Nnn )      ! ocean model: online field coarsening & output
243      IF( lk_diadetide ) CALL dia_detide( kstp )                ! Weights computation for daily detiding of model diagnostics
244      IF( lk_diamlr  )   CALL dia_mlr                           ! Update time used in multiple-linear-regression analysis
245
246#if defined key_top
247      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
248      ! Passive Tracer Model
249      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
250                         CALL trc_stp       ( kstp, Nbb, Nnn, Nrhs, Naa )  ! time-stepping
251#endif
252
253      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
254      ! Active tracers
255      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
256                         ts(:,:,:,:,Nrhs) = 0._wp         ! set tracer trends to zero
257
258      IF(  lk_asminc .AND. ln_asmiau .AND. &
259         & ln_trainc )   CALL tra_asm_inc( kstp, Nbb, Nnn, ts, Nrhs )  ! apply tracer assimilation increment
260                         CALL tra_sbc    ( kstp,      Nnn, ts, Nrhs )  ! surface boundary condition
261      IF( ln_traqsr  )   CALL tra_qsr    ( kstp,      Nnn, ts, Nrhs )  ! penetrative solar radiation qsr
262      IF( ln_isf     )   CALL tra_isf    ( kstp,      Nnn, ts, Nrhs )  ! ice shelf heat flux
263      IF( ln_trabbc  )   CALL tra_bbc    ( kstp,      Nnn, ts, Nrhs )  ! bottom heat flux
264      IF( ln_trabbl  )   CALL tra_bbl    ( kstp, Nbb, Nnn, ts, Nrhs )  ! advective (and/or diffusive) bottom boundary layer scheme
265      IF( ln_tradmp  )   CALL tra_dmp    ( kstp, Nbb, Nnn, ts, Nrhs )  ! internal damping trends
266      IF( ln_bdy     )   CALL bdy_tra_dmp( kstp, Nbb,      ts, Nrhs )  ! bdy damping trends
267#if defined key_agrif
268      IF(.NOT. Agrif_Root())  &
269               &         CALL Agrif_Sponge_tra        ! tracers sponge
270#endif
271                         CALL tra_adv    ( kstp, Nbb, Nnn, ts, Nrhs )  ! hor. + vert. advection ==> RHS
272      IF( ln_zdfosm  )   CALL tra_osm    ( kstp,      Nnn, ts, Nrhs )  ! OSMOSIS non-local tracer fluxes ==> RHS
273      IF( lrst_oce .AND. ln_zdfosm ) &
274           &             CALL osm_rst    ( kstp,      Nnn, 'WRITE'  )  ! write OSMOSIS outputs + ww (so must do here) to restarts
275                         CALL tra_ldf    ( kstp, Nbb, Nnn, ts, Nrhs )  ! lateral mixing
276
277                         CALL tra_zdf    ( kstp, Nbb, Nnn, Nrhs, ts, Naa  )  ! vertical mixing and after tracer fields
278      IF( ln_zdfnpc  )   CALL tra_npc    ( kstp,      Nnn, Nrhs, ts, Naa  )  ! update after fields by non-penetrative convection
279
280      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
281      ! Set boundary conditions, time filter and swap time levels
282      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
283!!jc1: For agrif, it would be much better to finalize tracers/momentum here (e.g. bdy conditions) and move the swap
284!!    (and time filtering) after Agrif update. Then restart would be done after and would contain updated fields.
285!!    If so:
286!!    (i) no need to call agrif update at initialization time
287!!    (ii) no need to update "before" fields
288!!
289!!    Apart from creating new tra_swp/dyn_swp routines, this however:
290!!    (i) makes boundary conditions at initialization time computed from updated fields which is not the case between
291!!    two restarts => restartability issue. One can circumvent this, maybe, by assuming "interface separation",
292!!    e.g. a shift of the feedback interface inside child domain.
293!!    (ii) requires that all restart outputs of updated variables by agrif (e.g. passive tracers/tke/barotropic arrays) are done at the same
294!!    place.
295!!
296                         CALL zdyn_ts       ( Nnn, Naa, uu, vv )                    ! barotrope ajustment
297                         CALL finalize_sbc  ( kstp, Nbb, Naa, uu, vv, ts )          ! boundary condifions
298                         CALL ssh_atf       ( kstp, Nbb, Nnn, Naa, ssh )            ! time filtering of "now" sea surface height
299                         CALL dom_qco_r3c    ( ssh(:,:,Nnn), r3t_f, r3u_f, r3v_f )   ! "now" ssh/h_0 ratio from filtrered ssh
300                         CALL tra_atf_qco   ( kstp, Nbb, Nnn, Naa, ts )             ! time filtering of "now" tracer arrays
301                         CALL dyn_atf_qco   ( kstp, Nbb, Nnn, Naa, uu, vv  )        ! time filtering of "now" velocities and scale factors
302                         r3t(:,:,Nnn) = r3t_f(:,:)
303                         r3u(:,:,Nnn) = r3u_f(:,:)
304                         r3v(:,:,Nnn) = r3v_f(:,:)
305
306      !
307      ! Swap time levels
308      Nrhs = Nbb
309      Nbb = Nnn
310      Nnn = Naa
311      Naa = Nrhs
312      !
313      !
314      IF( ln_diahsb  )   CALL dia_hsb       ( kstp, Nbb, Nnn )  ! - ML - global conservation diagnostics
315
316!!gm : This does not only concern the dynamics ==>>> add a new title
317!!gm2: why ouput restart before AGRIF update?
318!!
319!!jc: That would be better, but see comment above
320!!
321      IF( lrst_oce   )   CALL rst_write    ( kstp, Nbb, Nnn )   ! write output ocean restart file
322      IF( ln_sto_eos )   CALL sto_rst_write( kstp )   ! write restart file for stochastic parameters
323
324#if defined key_agrif
325      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
326      ! AGRIF
327      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
328                         Kbb_a = Nbb; Kmm_a = Nnn; Krhs_a = Nrhs      ! agrif_oce module copies of time level indices
329                         CALL Agrif_Integrate_ChildGrids( stp_MLF )       ! allows to finish all the Child Grids before updating
330
331                         IF( Agrif_NbStepint() == 0 ) THEN
332                            CALL Agrif_update_all( )                  ! Update all components
333                         ENDIF
334#endif
335      IF( ln_diaobs  )   CALL dia_obs      ( kstp, Nnn )      ! obs-minus-model (assimilation) diagnostics (call after dynamics update)
336
337      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
338      ! Control
339      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
340                         CALL stp_ctl      ( kstp, Nbb, Nnn, indic )
341
342      IF( kstp == nit000 ) THEN                          ! 1st time step only
343                                        CALL iom_close( numror )   ! close input  ocean restart file
344         IF(lwm)                        CALL FLUSH    ( numond )   ! flush output namelist oce
345         IF(lwm .AND. numoni /= -1 )    CALL FLUSH    ( numoni )   ! flush output namelist ice (if exist)
346      ENDIF
347
348      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
349      ! Coupled mode
350      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
351!!gm why lk_oasis and not lk_cpl ????
352      IF( lk_oasis   )   CALL sbc_cpl_snd( kstp, Nbb, Nnn )        ! coupled mode : field exchanges
353      !
354#if defined key_iomput
355      IF( kstp == nitend .OR. indic < 0 ) THEN
356                      CALL iom_context_finalize(      cxios_context          ) ! needed for XIOS+AGRIF
357         IF(lrxios) CALL iom_context_finalize(      crxios_context          )
358         IF( ln_crs ) CALL iom_context_finalize( trim(cxios_context)//"_crs" ) !
359      ENDIF
360#endif
361      !
362      IF( l_1st_euler ) THEN         ! recover Leap-frog timestep
363         rDt = 2._wp * rn_Dt   
364         r1_Dt = 1._wp / rDt
365         l_1st_euler = .FALSE.     
366      ENDIF
367      !
368      IF( ln_timing )   CALL timing_stop('stp_MLF')
369      !
370   END SUBROUTINE stp_MLF
371
372
373   SUBROUTINE zdyn_ts (Kmm, Kaa, puu, pvv)
374      !!----------------------------------------------------------------------
375      !!                  ***  ROUTINE zdyn_ts  ***
376      !!
377      !! ** Purpose :   Finalize after horizontal velocity.
378      !!
379      !! ** Method  : * Ensure after velocities transport matches time splitting
380      !!             estimate (ln_dynspg_ts=T)
381      !!
382      !! ** Action :   puu(Kmm),pvv(Kmm),puu(Kaa),pvv(Kaa)   now and after horizontal velocity
383      !!----------------------------------------------------------------------
384      INTEGER                             , INTENT(in   ) :: Kmm, Kaa    ! before and after time level indices
385      REAL(wp), DIMENSION(jpi,jpj,jpk,jpt), INTENT(inout) :: puu, pvv         ! velocities
386      !
387      REAL(wp), ALLOCATABLE, DIMENSION(:,:)   ::   zue, zve
388      !
389      INTEGER  ::   jk   ! dummy loop indices
390      !!----------------------------------------------------------------------
391
392      IF ( ln_dynspg_ts ) THEN
393         ALLOCATE( zue(jpi,jpj)     , zve(jpi,jpj)     )
394         ! Ensure below that barotropic velocities match time splitting estimate
395         ! Compute actual transport and replace it with ts estimate at "after" time step
396         zue(:,:) = e3u(:,:,1,Kaa) * puu(:,:,1,Kaa) * umask(:,:,1)
397         zve(:,:) = e3v(:,:,1,Kaa) * pvv(:,:,1,Kaa) * vmask(:,:,1)
398         DO jk = 2, jpkm1
399            zue(:,:) = zue(:,:) + e3u(:,:,jk,Kaa) * puu(:,:,jk,Kaa) * umask(:,:,jk)
400            zve(:,:) = zve(:,:) + e3v(:,:,jk,Kaa) * pvv(:,:,jk,Kaa) * vmask(:,:,jk)
401         END DO
402         DO jk = 1, jpkm1
403            puu(:,:,jk,Kaa) = ( puu(:,:,jk,Kaa) - zue(:,:) * r1_hu(:,:,Kaa) + uu_b(:,:,Kaa) ) * umask(:,:,jk)
404            pvv(:,:,jk,Kaa) = ( pvv(:,:,jk,Kaa) - zve(:,:) * r1_hv(:,:,Kaa) + vv_b(:,:,Kaa) ) * vmask(:,:,jk)
405         END DO
406         !
407         IF( .NOT.ln_bt_fw ) THEN
408            ! Remove advective velocity from "now velocities"
409            ! prior to asselin filtering
410            ! In the forward case, this is done below after asselin filtering
411            ! so that asselin contribution is removed at the same time
412            DO jk = 1, jpkm1
413               puu(:,:,jk,Kmm) = ( puu(:,:,jk,Kmm) - un_adv(:,:)*r1_hu(:,:,Kmm) + uu_b(:,:,Kmm) )*umask(:,:,jk)
414               pvv(:,:,jk,Kmm) = ( pvv(:,:,jk,Kmm) - vn_adv(:,:)*r1_hv(:,:,Kmm) + vv_b(:,:,Kmm) )*vmask(:,:,jk)
415            END DO
416         ENDIF
417         !
418         DEALLOCATE( zue, zve )
419         !
420      ENDIF
421      !
422   END SUBROUTINE zdyn_ts
423
424
425   SUBROUTINE finalize_sbc (kt, Kbb, Kaa, puu, pvv, pts)
426      !!----------------------------------------------------------------------
427      !!                  ***  ROUTINE finalize_sbc  ***
428      !!
429      !! ** Purpose :   Apply the boundary condition on the after velocity
430      !!
431      !! ** Method  : * Apply lateral boundary conditions on after velocity
432      !!             at the local domain boundaries through lbc_lnk call,
433      !!             at the one-way open boundaries (ln_bdy=T),
434      !!             at the AGRIF zoom   boundaries (lk_agrif=T)
435      !!
436      !! ** Action :   puu(Kaa),pvv(Kaa)   after horizontal velocity and tracers
437      !!----------------------------------------------------------------------
438      INTEGER                             , INTENT(in   ) :: kt               ! ocean time-step index
439      INTEGER                             , INTENT(in   ) :: Kbb, Kaa    ! before and after time level indices
440      REAL(wp), DIMENSION(jpi,jpj,jpk,jpt), INTENT(inout) :: puu, pvv         ! velocities to be time filtered
441      REAL(wp), DIMENSION(jpi,jpj,jpk,jpts,jpt), INTENT(inout) :: pts            ! active tracers
442      !
443      ! Update after tracer and velocity on domain lateral boundaries
444      !
445#if defined key_agrif
446            CALL Agrif_tra                     ! AGRIF zoom boundaries
447            CALL Agrif_dyn( kt )               !* AGRIF zoom boundaries
448#endif
449      !                                        ! local domain boundaries  (T-point, unchanged sign)
450      CALL lbc_lnk_multi( 'finalize_sbc', puu(:,:,:,       Kaa), 'U', -1., pvv(:,:,:       ,Kaa), 'V', -1.   &
451                       &                , pts(:,:,:,jp_tem,Kaa), 'T',  1., pts(:,:,:,jp_sal,Kaa), 'T',  1. )     !* local domain boundaries
452      !
453      !                                        !* BDY open boundaries
454      IF( ln_bdy )   THEN
455                               CALL bdy_tra( kt, Kbb, pts,      Kaa )
456         IF( ln_dynspg_exp )   CALL bdy_dyn( kt, Kbb, puu, pvv, Kaa )
457         IF( ln_dynspg_ts  )   CALL bdy_dyn( kt, Kbb, puu, pvv, Kaa, dyn3d_only=.true. )
458      ENDIF
459      !
460   END SUBROUTINE finalize_sbc
461
462   !
463   !!======================================================================
464END MODULE stepMLF
Note: See TracBrowser for help on using the repository browser.