source: NEMO/branches/2020/dev_r12377_KERNEL-06_techene_e3/src/OFF/nemogcm.F90 @ 12748

Last change on this file since 12748 was 12724, checked in by techene, 16 months ago

branch KERNEL-06 : merge with trunk@12698 #2385 - in duplcated files : changes to comply to the new trunk variables and some loop bug fixes

  • Property svn:keywords set to Id
File size: 29.2 KB
Line 
1MODULE nemogcm
2   !!======================================================================
3   !!                       ***  MODULE nemogcm   ***
4   !! Off-line Ocean   : passive tracer evolution, dynamics read in files
5   !!======================================================================
6   !! History :  3.3  ! 2010-05  (C. Ethe)  Full reorganization of the off-line: phasing with the on-line
7   !!            3.4  ! 2011-01  (C. Ethe, A. R. Porter, STFC Daresbury) dynamical allocation
8   !!            4.0  ! 2016-10  (C. Ethe, G. Madec, S. Flavoni)  domain configuration / user defined interface
9   !!            4.1  ! 2019-08  (A. Coward, D. Storkey) rewrite in preparation for new timestepping scheme
10   !!----------------------------------------------------------------------
11
12   !!----------------------------------------------------------------------
13   !!   nemo_gcm      : off-line: solve ocean tracer only
14   !!   nemo_gcm      : solve ocean dynamics, tracer, biogeochemistry and/or sea-ice
15   !!   nemo_init     : initialization of the NEMO system
16   !!   nemo_ctl      : initialisation of the contol print
17   !!   nemo_closefile: close remaining open files
18   !!   nemo_alloc    : dynamical allocation
19   !!   istate_init   : simple initialization to zero of ocean fields
20   !!   stp_ctl       : reduced step control (no dynamics in off-line)
21   !!----------------------------------------------------------------------
22   USE dom_oce        ! ocean space domain variables
23   USE oce            ! dynamics and tracers variables
24   USE trc_oce        ! Shared ocean/passive tracers variables
25   USE c1d            ! 1D configuration
26   USE domain         ! domain initialization from coordinate & bathymetry (dom_init routine)
27   USE closea         ! treatment of closed seas (for ln_closea)
28   USE usrdef_nam     ! user defined configuration
29   USE eosbn2         ! equation of state            (eos bn2 routine)
30   !              ! ocean physics
31   USE ldftra         ! lateral diffusivity setting    (ldf_tra_init routine)
32   USE ldfslp         ! slopes of neutral surfaces     (ldf_slp_init routine)
33   USE traqsr         ! solar radiation penetration    (tra_qsr_init routine)
34   USE trabbl         ! bottom boundary layer          (tra_bbl_init routine)
35   USE traldf         ! lateral physics                (tra_ldf_init routine)
36   USE sbcmod         ! surface boundary condition     (sbc_init     routine)
37   USE phycst         ! physical constant                   (par_cst routine)
38   USE dtadyn         ! Lecture and Interpolation of the dynamical fields
39   USE trcini         ! Initilization of the passive tracers
40   USE daymod         ! calendar                            (day     routine)
41   USE trcstp         ! passive tracer time-stepping        (trc_stp routine)
42   USE dtadyn         ! Lecture and interpolation of the dynamical fields
43   !              ! Passive tracers needs
44   USE trc            ! passive tracer : variables
45   USE trcnam         ! passive tracer : namelist
46   USE trcrst         ! passive tracer restart
47   USE diaptr         ! Need to initialise this as some variables are used in if statements later
48   USE sbc_oce , ONLY : ln_rnf
49   USE sbcrnf         ! surface boundary condition : runoffs
50   !              ! I/O & MPP
51   USE iom            ! I/O library
52   USE in_out_manager ! I/O manager
53   USE mppini         ! shared/distributed memory setting (mpp_init routine)
54   USE lib_mpp        ! distributed memory computing
55#if defined key_iomput
56   USE xios           ! xIOserver
57#endif
58   USE prtctl         ! Print control                    (prt_ctl_init routine)
59   USE timing         ! Timing
60   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined)
61   USE lbcnfd  , ONLY : isendto, nsndto, nfsloop, nfeloop   ! Setup of north fold exchanges
62   USE step, ONLY : Nbb, Nnn, Naa, Nrhs   ! time level indices
63
64   IMPLICIT NONE
65   PRIVATE
66   
67   PUBLIC   nemo_gcm   ! called by nemo.F90
68
69   CHARACTER (len=64) ::   cform_aaa="( /, 'AAAAAAAA', / ) "   ! flag for output listing
70
71   !!----------------------------------------------------------------------
72   !! NEMO/OFF 4.0 , NEMO Consortium (2018)
73   !! $Id$
74   !! Software governed by the CeCILL license (see ./LICENSE)
75   !!----------------------------------------------------------------------
76CONTAINS
77
78   SUBROUTINE nemo_gcm
79      !!----------------------------------------------------------------------
80      !!                     ***  ROUTINE nemo_gcm  ***
81      !!
82      !! ** Purpose :   NEMO solves the primitive equations on an orthogonal
83      !!              curvilinear mesh on the sphere.
84      !!
85      !! ** Method  : - model general initialization
86      !!              - launch the time-stepping (dta_dyn and trc_stp)
87      !!              - finalize the run by closing files and communications
88      !!
89      !! References : Madec, Delecluse,Imbard, and Levy, 1997:  internal report, IPSL.
90      !!              Madec, 2008, internal report, IPSL.
91      !!----------------------------------------------------------------------
92      INTEGER :: istp, indic       ! time step index
93      !!----------------------------------------------------------------------
94
95      CALL nemo_init  ! Initializations
96
97      ! check that all process are still there... If some process have an error,
98      ! they will never enter in step and other processes will wait until the end of the cpu time!
99      CALL mpp_max( 'nemogcm', nstop )
100
101      !                            !-----------------------!
102      !                            !==   time stepping   ==!
103      !                            !-----------------------!
104      istp = nit000
105      !
106      IF( ln_rnf )   CALL sbc_rnf(istp)   ! runoffs initialization
107      !
108      CALL iom_init( cxios_context )      ! iom_put initialization (must be done after nemo_init for AGRIF+XIOS+OASIS)
109      !
110      DO WHILE ( istp <= nitend .AND. nstop == 0 )    !==  OFF time-stepping  ==!
111         !
112         IF( istp /= nit000 )   CALL day        ( istp )         ! Calendar (day was already called at nit000 in day_init)
113                                CALL iom_setkt  ( istp - nit000 + 1, cxios_context )   ! say to iom that we are at time step kstp
114#if defined key_sed_off
115                                CALL dta_dyn_sed( istp,      Nnn      )       ! Interpolation of the dynamical fields
116#else
117                                CALL dta_dyn    ( istp, Nbb, Nnn, Naa )       ! Interpolation of the dynamical fields
118#endif
119                                CALL trc_stp    ( istp, Nbb, Nnn, Nrhs, Naa ) ! time-stepping
120#if ! defined key_sed_off
121         IF( .NOT.ln_linssh )   CALL dta_dyn_atf( istp, Nbb, Nnn, Naa )       ! time filter of sea  surface height and vertical scale factors
122#endif
123         ! Swap time levels
124         Nrhs = Nbb
125         Nbb = Nnn
126         Nnn = Naa
127         Naa = Nrhs
128         !
129#if ! defined key_sed_off
130         IF( .NOT.ln_linssh )   CALL dta_dyn_sf_interp( istp, Nnn )  ! calculate now grid parameters
131#endif
132                                CALL stp_ctl    ( istp, indic )  ! Time loop: control and print
133         istp = istp + 1
134      END DO
135      !
136#if defined key_iomput
137      CALL iom_context_finalize( cxios_context ) ! needed for XIOS+AGRIF
138#endif
139
140      !                            !------------------------!
141      !                            !==  finalize the run  ==!
142      !                            !------------------------!
143      IF(lwp) WRITE(numout,cform_aaa)                 ! Flag AAAAAAA
144
145      IF( nstop /= 0 .AND. lwp ) THEN                 ! error print
146         WRITE(ctmp1,*) '   ==>>>   nemo_gcm: a total of ', nstop, ' errors have been found'
147         CALL ctl_stop( ctmp1 )
148      ENDIF
149      !
150      IF( ln_timing )   CALL timing_finalize
151      !
152      CALL nemo_closefile
153      !
154#if defined key_iomput
155                     CALL xios_finalize   ! end mpp communications with xios
156#else
157      IF( lk_mpp )   CALL mppstop         ! end mpp communications
158#endif
159      !
160      IF(lwm) THEN
161         IF( nstop == 0 ) THEN   ;   STOP 0
162         ELSE                    ;   STOP 123
163         ENDIF
164      ENDIF
165      !
166   END SUBROUTINE nemo_gcm
167
168
169   SUBROUTINE nemo_init
170      !!----------------------------------------------------------------------
171      !!                     ***  ROUTINE nemo_init  ***
172      !!
173      !! ** Purpose :   initialization of the nemo model in off-line mode
174      !!----------------------------------------------------------------------
175      INTEGER ::   ios, ilocal_comm   ! local integers
176      !!
177      NAMELIST/namctl/ sn_cfctl, nn_print, nn_ictls, nn_ictle,              &
178         &             nn_isplt , nn_jsplt, nn_jctls, nn_jctle,             &
179         &             ln_timing, ln_diacfl
180      NAMELIST/namcfg/ ln_read_cfg, cn_domcfg, ln_closea, ln_write_cfg, cn_domcfg_out, ln_use_jattr
181      !!----------------------------------------------------------------------
182      !
183      cxios_context = 'nemo'
184      !
185      !                             !-------------------------------------------------!
186      !                             !     set communicator & select the local rank    !
187      !                             !  must be done as soon as possible to get narea  !
188      !                             !-------------------------------------------------!
189      !
190#if defined key_iomput
191      CALL xios_initialize( "for_xios_mpi_id", return_comm=ilocal_comm )   ! nemo local communicator given by xios
192      CALL mpp_start( ilocal_comm )
193#else
194      CALL mpp_start( )
195#endif
196      !
197      narea = mpprank + 1               ! mpprank: the rank of proc (0 --> mppsize -1 )
198      lwm = (narea == 1)                ! control of output namelists
199      !
200      !                             !---------------------------------------------------------------!
201      !                             ! Open output files, reference and configuration namelist files !
202      !                             !---------------------------------------------------------------!
203      !
204      ! open ocean.output as soon as possible to get all output prints (including errors messages)
205      IF( lwm )   CALL ctl_opn(     numout,        'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. )
206      ! open reference and configuration namelist files
207                  CALL load_nml( numnam_ref,        'namelist_ref',                                           -1, lwm )
208                  CALL load_nml( numnam_cfg,        'namelist_cfg',                                           -1, lwm )
209      IF( lwm )   CALL ctl_opn(     numond, 'output.namelist.dyn', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. )
210      ! open /dev/null file to be able to supress output write easily
211      IF( Agrif_Root() ) THEN
212                  CALL ctl_opn(     numnul,           '/dev/null', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. )
213#ifdef key_agrif
214      ELSE
215                  numnul = Agrif_Parent(numnul)   
216#endif
217      ENDIF
218      !
219      !                             !--------------------!
220      !                             ! Open listing units !  -> need sn_cfctl from namctl to define lwp
221      !                             !--------------------!
222      !
223      READ  ( numnam_ref, namctl, IOSTAT = ios, ERR = 901 )
224901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namctl in reference namelist' )
225      READ  ( numnam_cfg, namctl, IOSTAT = ios, ERR = 902 )
226902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namctl in configuration namelist' )
227      !
228      ! finalize the definition of namctl variables
229      IF( sn_cfctl%l_allon ) THEN
230         ! Turn on all options.
231         CALL nemo_set_cfctl( sn_cfctl, .TRUE., .TRUE. )
232         ! Ensure all processors are active
233         sn_cfctl%procmin = 0 ; sn_cfctl%procmax = 1000000 ; sn_cfctl%procincr = 1
234      ELSEIF( sn_cfctl%l_config ) THEN
235         ! Activate finer control of report outputs
236         ! optionally switch off output from selected areas (note this only
237         ! applies to output which does not involve global communications)
238         IF( ( narea < sn_cfctl%procmin .OR. narea > sn_cfctl%procmax  ) .OR. &
239           & ( MOD( narea - sn_cfctl%procmin, sn_cfctl%procincr ) /= 0 ) )    &
240           &   CALL nemo_set_cfctl( sn_cfctl, .FALSE., .FALSE. )
241      ELSE
242         ! turn off all options.
243         CALL nemo_set_cfctl( sn_cfctl, .FALSE., .TRUE. )
244      ENDIF
245      !
246      lwp = (narea == 1) .OR. sn_cfctl%l_oceout    ! control of all listing output print
247      !
248      IF(lwp) THEN                            ! open listing units
249         !
250         IF( .NOT. lwm )   &           ! alreay opened for narea == 1
251            &     CALL ctl_opn(     numout,        'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE., narea )
252         !
253         WRITE(numout,*)
254         WRITE(numout,*) '   CNRS - NERC - Met OFFICE - MERCATOR-ocean - CMCC'
255         WRITE(numout,*) '                       NEMO team'
256         WRITE(numout,*) '                   Off-line TOP Model'
257         WRITE(numout,*) '                NEMO version 4.0  (2019) '
258         WRITE(numout,*)
259         WRITE(numout,*) "           ._      ._      ._      ._      ._    "
260         WRITE(numout,*) "       _.-._)`\_.-._)`\_.-._)`\_.-._)`\_.-._)`\_ "
261         WRITE(numout,*)
262         WRITE(numout,*) "           o         _,           _,             "
263         WRITE(numout,*) "            o      .' (        .-' /             "
264         WRITE(numout,*) "           o     _/..._'.    .'   /              "
265         WRITE(numout,*) "      (    o .-'`      ` '-./  _.'               "
266         WRITE(numout,*) "       )    ( o)           ;= <_         (       "
267         WRITE(numout,*) "      (      '-.,\\__ __.-;`\   '.        )      "
268         WRITE(numout,*) "       )  )       \) |`\ \)  '.   \      (   (   "
269         WRITE(numout,*) "      (  (           \_/       '-._\      )   )  "
270         WRITE(numout,*) "       )  )                        `     (   (   "
271         WRITE(numout,*) "     ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^ "
272         WRITE(numout,*)
273         !
274         WRITE(numout,cform_aaa)                                        ! Flag AAAAAAA
275         !
276      ENDIF
277      !
278      IF(lwm) WRITE( numond, namctl )
279      !
280      !                             !------------------------------------!
281      !                             !  Set global domain size parameters !
282      !                             !------------------------------------!
283      !     
284      READ  ( numnam_ref, namcfg, IOSTAT = ios, ERR = 903 )
285903   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namcfg in reference namelist' )
286      READ  ( numnam_cfg, namcfg, IOSTAT = ios, ERR = 904 )
287904   IF( ios >  0 )   CALL ctl_nam ( ios , 'namcfg in configuration namelist' )   
288      !
289      IF( ln_read_cfg ) THEN              ! Read sizes in domain configuration file
290         CALL domain_cfg ( cn_cfg, nn_cfg, jpiglo, jpjglo, jpkglo, jperio )
291      ELSE                                ! user-defined namelist
292         CALL usr_def_nam( cn_cfg, nn_cfg, jpiglo, jpjglo, jpkglo, jperio )
293      ENDIF
294      !
295      IF(lwm)   WRITE( numond, namcfg )
296      l_offline = .true.                  ! passive tracers are run offline
297      !
298      !                             !-----------------------------------------!
299      !                             ! mpp parameters and domain decomposition !
300      !                             !-----------------------------------------!
301      !
302      CALL mpp_init
303
304      ! Now we know the dimensions of the grid and numout has been set: we can allocate arrays
305      CALL nemo_alloc()
306
307      ! Initialise time level indices
308      Nbb = 1; Nnn = 2; Naa = 3; Nrhs = Naa
309   
310
311      !                             !-------------------------------!
312      !                             !  NEMO general initialization  !
313      !                             !-------------------------------!
314
315      CALL nemo_ctl                          ! Control prints
316      !
317      !                                      ! General initialization
318      IF( ln_timing    )   CALL timing_init
319      IF( ln_timing    )   CALL timing_start( 'nemo_init')
320      !
321                           CALL     phy_cst         ! Physical constants
322                           CALL     eos_init        ! Equation of state
323      IF( lk_c1d       )   CALL     c1d_init        ! 1D column configuration
324                           CALL     dom_init( Nbb, Nnn, Naa, "OPA") ! Domain
325      IF( sn_cfctl%l_prtctl )   &
326         &                 CALL prt_ctl_init        ! Print control
327
328                           CALL  istate_init( Nnn, Naa )    ! ocean initial state (Dynamics and tracers)
329
330                           CALL     sbc_init( Nbb, Nnn, Naa )    ! Forcings : surface module
331
332      !                                      ! Tracer physics
333                           CALL ldf_tra_init    ! Lateral ocean tracer physics
334                           CALL ldf_eiv_init    ! Eddy induced velocity param
335                           CALL tra_ldf_init    ! lateral mixing
336      IF( l_ldfslp     )   CALL ldf_slp_init    ! slope of lateral mixing
337      IF( ln_traqsr    )   CALL tra_qsr_init    ! penetrative solar radiation
338      IF( ln_trabbl    )   CALL tra_bbl_init    ! advective (and/or diffusive) bottom boundary layer scheme
339
340      !                                      ! Passive tracers
341                           CALL trc_nam_run    ! Needed to get restart parameters for passive tracers
342                           CALL trc_rst_cal( nit000, 'READ' )   ! calendar
343#if defined key_sed_off
344                           CALL dta_dyn_sed_init(  Nnn      )        ! Initialization for the dynamics
345#else
346                           CALL dta_dyn_init( Nbb, Nnn, Naa )        ! Initialization for the dynamics
347#endif
348
349                           CALL     trc_init( Nbb, Nnn, Naa )        ! Passive tracers initialization
350                           CALL dia_ptr_init   ! Poleward TRansports initialization
351                           
352      IF(lwp) WRITE(numout,cform_aaa)           ! Flag AAAAAAA
353      !
354      IF( ln_timing    )   CALL timing_stop( 'nemo_init')
355      !
356   END SUBROUTINE nemo_init
357
358
359   SUBROUTINE nemo_ctl
360      !!----------------------------------------------------------------------
361      !!                     ***  ROUTINE nemo_ctl  ***
362      !!
363      !! ** Purpose :   control print setting
364      !!
365      !! ** Method  : - print namctl and namcfg information and check some consistencies
366      !!----------------------------------------------------------------------
367      !
368      IF(lwp) THEN                  ! control print
369         WRITE(numout,*)
370         WRITE(numout,*) 'nemo_ctl: Control prints'
371         WRITE(numout,*) '~~~~~~~~'
372         WRITE(numout,*) '   Namelist namctl'
373         WRITE(numout,*) '                              sn_cfctl%l_glochk  = ', sn_cfctl%l_glochk
374         WRITE(numout,*) '                              sn_cfctl%l_allon   = ', sn_cfctl%l_allon
375         WRITE(numout,*) '       finer control over o/p sn_cfctl%l_config  = ', sn_cfctl%l_config
376         WRITE(numout,*) '                              sn_cfctl%l_runstat = ', sn_cfctl%l_runstat
377         WRITE(numout,*) '                              sn_cfctl%l_trcstat = ', sn_cfctl%l_trcstat
378         WRITE(numout,*) '                              sn_cfctl%l_oceout  = ', sn_cfctl%l_oceout
379         WRITE(numout,*) '                              sn_cfctl%l_layout  = ', sn_cfctl%l_layout
380         WRITE(numout,*) '                              sn_cfctl%l_prtctl  = ', sn_cfctl%l_prtctl
381         WRITE(numout,*) '                              sn_cfctl%l_prttrc  = ', sn_cfctl%l_prttrc
382         WRITE(numout,*) '                              sn_cfctl%l_oasout  = ', sn_cfctl%l_oasout
383         WRITE(numout,*) '                              sn_cfctl%procmin   = ', sn_cfctl%procmin 
384         WRITE(numout,*) '                              sn_cfctl%procmax   = ', sn_cfctl%procmax 
385         WRITE(numout,*) '                              sn_cfctl%procincr  = ', sn_cfctl%procincr 
386         WRITE(numout,*) '                              sn_cfctl%ptimincr  = ', sn_cfctl%ptimincr 
387         WRITE(numout,*) '      level of print                  nn_print   = ', nn_print
388         WRITE(numout,*) '      Start i indice for SUM control  nn_ictls   = ', nn_ictls
389         WRITE(numout,*) '      End i indice for SUM control    nn_ictle   = ', nn_ictle
390         WRITE(numout,*) '      Start j indice for SUM control  nn_jctls   = ', nn_jctls
391         WRITE(numout,*) '      End j indice for SUM control    nn_jctle   = ', nn_jctle
392         WRITE(numout,*) '      number of proc. following i     nn_isplt   = ', nn_isplt
393         WRITE(numout,*) '      number of proc. following j     nn_jsplt   = ', nn_jsplt
394         WRITE(numout,*) '      timing by routine               ln_timing  = ', ln_timing
395         WRITE(numout,*) '      CFL diagnostics                 ln_diacfl  = ', ln_diacfl
396      ENDIF
397      !
398      nprint    = nn_print          ! convert DOCTOR namelist names into OLD names
399      nictls    = nn_ictls
400      nictle    = nn_ictle
401      njctls    = nn_jctls
402      njctle    = nn_jctle
403      isplt     = nn_isplt
404      jsplt     = nn_jsplt
405
406      IF(lwp) THEN                  ! control print
407         WRITE(numout,*)
408         WRITE(numout,*) '   Namelist namcfg'
409         WRITE(numout,*) '      read domain configuration file              ln_read_cfg      = ', ln_read_cfg
410         WRITE(numout,*) '         filename to be read                         cn_domcfg     = ', TRIM(cn_domcfg)
411         WRITE(numout,*) '         keep closed seas in the domain (if exist)   ln_closea     = ', ln_closea
412         WRITE(numout,*) '      create a configuration definition file      ln_write_cfg     = ', ln_write_cfg
413         WRITE(numout,*) '         filename to be written                      cn_domcfg_out = ', TRIM(cn_domcfg_out)
414         WRITE(numout,*) '      use file attribute if exists as i/p j-start ln_use_jattr     = ', ln_use_jattr
415      ENDIF
416      IF( .NOT.ln_read_cfg )   ln_closea = .false.   ! dealing possible only with a domcfg file
417      !
418      !                             ! Parameter control
419      !
420      IF( sn_cfctl%l_prtctl .OR. sn_cfctl%l_prttrc ) THEN              ! sub-domain area indices for the control prints
421         IF( lk_mpp .AND. jpnij > 1 ) THEN
422            isplt = jpni   ;   jsplt = jpnj   ;   ijsplt = jpni*jpnj   ! the domain is forced to the real split domain
423         ELSE
424            IF( isplt == 1 .AND. jsplt == 1  ) THEN
425               CALL ctl_warn( ' - isplt & jsplt are equal to 1',   &
426                  &           ' - the print control will be done over the whole domain' )
427            ENDIF
428            ijsplt = isplt * jsplt            ! total number of processors ijsplt
429         ENDIF
430         IF(lwp) WRITE(numout,*)'          - The total number of processors over which the'
431         IF(lwp) WRITE(numout,*)'            print control will be done is ijsplt : ', ijsplt
432         !
433         !                              ! indices used for the SUM control
434         IF( nictls+nictle+njctls+njctle == 0 )   THEN    ! print control done over the default area
435            lsp_area = .FALSE.
436         ELSE                                             ! print control done over a specific  area
437            lsp_area = .TRUE.
438            IF( nictls < 1 .OR. nictls > jpiglo )   THEN
439               CALL ctl_warn( '          - nictls must be 1<=nictls>=jpiglo, it is forced to 1' )
440               nictls = 1
441            ENDIF
442            IF( nictle < 1 .OR. nictle > jpiglo )   THEN
443               CALL ctl_warn( '          - nictle must be 1<=nictle>=jpiglo, it is forced to jpiglo' )
444               nictle = jpiglo
445            ENDIF
446            IF( njctls < 1 .OR. njctls > jpjglo )   THEN
447               CALL ctl_warn( '          - njctls must be 1<=njctls>=jpjglo, it is forced to 1' )
448               njctls = 1
449            ENDIF
450            IF( njctle < 1 .OR. njctle > jpjglo )   THEN
451               CALL ctl_warn( '          - njctle must be 1<=njctle>=jpjglo, it is forced to jpjglo' )
452               njctle = jpjglo
453            ENDIF
454         ENDIF
455      ENDIF
456      !
457      IF( 1._wp /= SIGN(1._wp,-0._wp)  )   CALL ctl_stop( 'nemo_ctl: The intrinsec SIGN function follows f2003 standard.',  &
458         &                                                'Compile with key_nosignedzero enabled' )
459      !
460   END SUBROUTINE nemo_ctl
461
462
463   SUBROUTINE nemo_closefile
464      !!----------------------------------------------------------------------
465      !!                     ***  ROUTINE nemo_closefile  ***
466      !!
467      !! ** Purpose :   Close the files
468      !!----------------------------------------------------------------------
469      !
470      IF( lk_mpp )   CALL mppsync
471      !
472      CALL iom_close                                 ! close all input/output files managed by iom_*
473      !
474      IF( numstp     /= -1 )   CLOSE( numstp     )   ! time-step file
475      IF( lwm.AND.numond  /= -1 )   CLOSE( numond          )   ! oce output namelist
476      !
477      numout = 6                                     ! redefine numout in case it is used after this point...
478      !
479   END SUBROUTINE nemo_closefile
480
481
482   SUBROUTINE nemo_alloc
483      !!----------------------------------------------------------------------
484      !!                     ***  ROUTINE nemo_alloc  ***
485      !!
486      !! ** Purpose :   Allocate all the dynamic arrays of the OPA modules
487      !!
488      !! ** Method  :
489      !!----------------------------------------------------------------------
490      USE diawri ,   ONLY : dia_wri_alloc
491      USE dom_oce,   ONLY : dom_oce_alloc
492      USE zdf_oce,   ONLY : zdf_oce_alloc
493      USE trc_oce,   ONLY : trc_oce_alloc
494      !
495      INTEGER :: ierr
496      !!----------------------------------------------------------------------
497      !
498      ierr =        oce_alloc    ()          ! ocean
499      ierr = ierr + dia_wri_alloc()
500      ierr = ierr + dom_oce_alloc()          ! ocean domain
501      ierr = ierr + zdf_oce_alloc()          ! ocean vertical physics
502      ierr = ierr + trc_oce_alloc()          ! shared TRC / TRA arrays
503      !
504      CALL mpp_sum( 'nemogcm', ierr )
505      IF( ierr /= 0 )   CALL ctl_stop( 'STOP', 'nemo_alloc: unable to allocate standard ocean arrays' )
506      !
507   END SUBROUTINE nemo_alloc
508
509   SUBROUTINE nemo_set_cfctl(sn_cfctl, setto, for_all )
510      !!----------------------------------------------------------------------
511      !!                     ***  ROUTINE nemo_set_cfctl  ***
512      !!
513      !! ** Purpose :   Set elements of the output control structure to setto.
514      !!                for_all should be .false. unless all areas are to be
515      !!                treated identically.
516      !!
517      !! ** Method  :   Note this routine can be used to switch on/off some
518      !!                types of output for selected areas but any output types
519      !!                that involve global communications (e.g. mpp_max, glob_sum)
520      !!                should be protected from selective switching by the
521      !!                for_all argument
522      !!----------------------------------------------------------------------
523      LOGICAL :: setto, for_all
524      TYPE(sn_ctl) :: sn_cfctl
525      !!----------------------------------------------------------------------
526      IF( for_all ) THEN
527         sn_cfctl%l_runstat = setto
528         sn_cfctl%l_trcstat = setto
529      ENDIF
530      sn_cfctl%l_oceout  = setto
531      sn_cfctl%l_layout  = setto
532      sn_cfctl%l_prtctl  = setto
533      sn_cfctl%l_prttrc  = setto
534      sn_cfctl%l_oasout  = setto
535   END SUBROUTINE nemo_set_cfctl
536
537   SUBROUTINE istate_init( Kmm, Kaa )
538      !!----------------------------------------------------------------------
539      !!                   ***  ROUTINE istate_init  ***
540      !!
541      !! ** Purpose :   Initialization to zero of the dynamics and tracers.
542      !!----------------------------------------------------------------------
543      INTEGER, INTENT(in) ::   Kmm, Kaa  ! ocean time level indices
544      !
545      !     now fields         !     after fields      !
546      uu   (:,:,:,Kmm)   = 0._wp   ;   uu(:,:,:,Kaa) = 0._wp   !
547      vv   (:,:,:,Kmm)   = 0._wp   ;   vv(:,:,:,Kaa) = 0._wp   !
548      ww   (:,:,:)   = 0._wp   !                       !
549      hdiv (:,:,:)   = 0._wp   !                       !
550      ts  (:,:,:,:,Kmm) = 0._wp   !                       !
551      !
552      rhd  (:,:,:) = 0.e0
553      rhop (:,:,:) = 0.e0
554      rn2  (:,:,:) = 0.e0
555      !
556   END SUBROUTINE istate_init
557
558
559   SUBROUTINE stp_ctl( kt, kindic )
560      !!----------------------------------------------------------------------
561      !!                    ***  ROUTINE stp_ctl  ***
562      !!
563      !! ** Purpose :   Control the run
564      !!
565      !! ** Method  : - Save the time step in numstp
566      !!
567      !! ** Actions :   'time.step' file containing the last ocean time-step
568      !!----------------------------------------------------------------------
569      INTEGER, INTENT(in   ) ::   kt      ! ocean time-step index
570      INTEGER, INTENT(inout) ::   kindic  ! indicator of solver convergence
571      !!----------------------------------------------------------------------
572      !
573      IF( kt == nit000 .AND. lwm ) THEN
574         WRITE(numout,*)
575         WRITE(numout,*) 'stp_ctl : time-stepping control'
576         WRITE(numout,*) '~~~~~~~'
577         ! open time.step file
578         CALL ctl_opn( numstp, 'time.step', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, numout, lwp, narea )
579      ENDIF
580      !
581      IF(lwm) WRITE ( numstp, '(1x, i8)' )   kt      !* save the current time step in numstp
582      IF(lwm) REWIND( numstp )                       ! --------------------------
583      !
584   END SUBROUTINE stp_ctl
585   !!======================================================================
586END MODULE nemogcm
Note: See TracBrowser for help on using the repository browser.