source: NEMO/branches/2020/dev_r12377_KERNEL-06_techene_e3/src/TOP/PISCES/SED/seddta.F90 @ 12680

Last change on this file since 12680 was 12680, checked in by techene, 8 months ago

dynatfQCO.F90, stepLF.F90 : fixed (remove pe3. from dyn_atf_qco input arguments), all : remove e3. tables and include gurvan's feedbacks

  • Property svn:keywords set to Id
File size: 9.5 KB
Line 
1MODULE seddta
2   !!======================================================================
3   !!                     ***  MODULE  seddta  ***
4   !! Sediment data  :  read sediment input data from a file
5   !!=====================================================================
6
7   !! * Modules used
8   USE sed
9   USE sedarr
10   USE phycst, ONLY : rday
11   USE iom
12   USE lib_mpp         ! distribued memory computing library
13
14   IMPLICIT NONE
15   PRIVATE
16
17   !! * Routine accessibility
18   PUBLIC sed_dta   !
19
20   !! *  Module variables
21   REAL(wp) ::  rsecday  ! number of second per a day
22   REAL(wp) ::  conv2    ! [kg/m2/month]-->[g/cm2/s] ( 1 month has 30 days )
23
24   !! * Substitutions
25#  include "do_loop_substitute.h90"
26#  include "domzgr_substitute.h90"
27   !! $Id$
28CONTAINS
29
30   !!---------------------------------------------------------------------------
31   !!   sed_dta  : read the NetCDF data file in online version using module iom
32   !!---------------------------------------------------------------------------
33
34   SUBROUTINE sed_dta( kt, Kbb, Kmm )
35      !!----------------------------------------------------------------------
36      !!                   ***  ROUTINE sed_dta  ***
37      !!                   
38      !! ** Purpose :   Reads data from a netcdf file and
39      !!                initialization of rain and pore water (k=1) components
40      !!
41      !!
42      !!   History :
43      !!        !  04-10  (N. Emprin, M. Gehlen )  Original code
44      !!        !  06-04  (C. Ethe)  Re-organization ; Use of iom
45      !!----------------------------------------------------------------------
46
47      !! Arguments
48      INTEGER, INTENT(in) ::  kt         ! time-step
49      INTEGER, INTENT(in) ::  Kbb, Kmm   ! time level indices
50
51      !! * Local declarations
52      INTEGER  ::  ji, jj, js, jw, ikt
53
54      REAL(wp), DIMENSION(jpoce) :: zdtap, zdtag
55      REAL(wp), DIMENSION(jpi,jpj) :: zwsbio4, zwsbio3
56      REAL(wp) :: zf0, zf1, zf2, zkapp, zratio, zdep
57
58      !----------------------------------------------------------------------
59
60      ! Initialization of sediment variable
61      ! Spatial dimension is merged, and unity converted if needed
62      !-------------------------------------------------------------
63
64      IF( ln_timing )  CALL timing_start('sed_dta')
65
66      IF (lwp) THEN
67         WRITE(numsed,*)
68         WRITE(numsed,*) ' sed_dta : Bottom layer fields'
69         WRITE(numsed,*) ' ~~~~~~'
70         WRITE(numsed,*) ' Data from SMS model'
71         WRITE(numsed,*)
72      ENDIF
73
74
75      ! open file
76      IF( kt == nitsed000 ) THEN
77         IF (lwp) WRITE(numsed,*) ' sed_dta : Sediment fields'
78         dtsed = r2dttrc
79         rsecday = 60.* 60. * 24.
80!         conv2   = 1.0e+3 / ( 1.0e+4 * rsecday * 30. )
81         conv2 = 1.0e+3 /  1.0e+4 
82         rdtsed(2:jpksed) = dtsed / ( denssol * por1(2:jpksed) )
83      ENDIF
84
85      ! Initialization of temporaries arrays 
86      zdtap(:)    = 0. 
87      zdtag(:)    = 0. 
88
89      ! reading variables
90      IF (lwp) WRITE(numsed,*)
91      IF (lwp) WRITE(numsed,*) ' sed_dta : Bottom layer fields at time  kt = ', kt
92      ! reading variables
93      !
94      !    Sinking speeds of detritus is increased with depth as shown
95      !    by data and from the coagulation theory
96      !    -----------------------------------------------------------
97      IF (ln_sediment_offline) THEN
98         DO_2D_11_11
99            ikt = mbkt(ji,jj)
100            zwsbio4(ji,jj) = wsbio2 / rday
101            zwsbio3(ji,jj) = wsbio  / rday
102         END_2D
103      ELSE
104         DO_2D_11_11
105            ikt = mbkt(ji,jj)
106            zdep = e3t(ji,jj,ikt,Kmm) / r2dttrc
107            zwsbio4(ji,jj) = MIN( 0.99 * zdep, wsbio4(ji,jj,ikt) / rday )
108            zwsbio3(ji,jj) = MIN( 0.99 * zdep, wsbio3(ji,jj,ikt) / rday )
109         END_2D
110      ENDIF
111
112      trc_data(:,:,:) = 0.
113      DO_2D_11_11
114         ikt = mbkt(ji,jj)
115         IF ( tmask(ji,jj,ikt) == 1 ) THEN
116            trc_data(ji,jj,1)   = tr(ji,jj,ikt,jpsil,Kbb)
117            trc_data(ji,jj,2)   = tr(ji,jj,ikt,jpoxy,Kbb)
118            trc_data(ji,jj,3)   = tr(ji,jj,ikt,jpdic,Kbb)
119            trc_data(ji,jj,4)   = tr(ji,jj,ikt,jpno3,Kbb) / 7.625
120            trc_data(ji,jj,5)   = tr(ji,jj,ikt,jppo4,Kbb) / 122.
121            trc_data(ji,jj,6)   = tr(ji,jj,ikt,jptal,Kbb)
122            trc_data(ji,jj,7)   = tr(ji,jj,ikt,jpnh4,Kbb) / 7.625
123            trc_data(ji,jj,8)   = 0.0
124            trc_data(ji,jj,9)   = 28.0E-3
125            trc_data(ji,jj,10)  = tr(ji,jj,ikt,jpfer,Kbb)
126            trc_data(ji,jj,11 ) = MIN(tr(ji,jj,ikt,jpgsi,Kbb), 1E-4) * zwsbio4(ji,jj) * 1E3
127            trc_data(ji,jj,12 ) = MIN(tr(ji,jj,ikt,jppoc,Kbb), 1E-4) * zwsbio3(ji,jj) * 1E3
128            trc_data(ji,jj,13 ) = MIN(tr(ji,jj,ikt,jpgoc,Kbb), 1E-4) * zwsbio4(ji,jj) * 1E3
129            trc_data(ji,jj,14)  = MIN(tr(ji,jj,ikt,jpcal,Kbb), 1E-4) * zwsbio4(ji,jj) * 1E3
130            trc_data(ji,jj,15)  = ts(ji,jj,ikt,jp_tem,Kmm)
131            trc_data(ji,jj,16)  = ts(ji,jj,ikt,jp_sal,Kmm)
132            trc_data(ji,jj,17 ) = ( tr(ji,jj,ikt,jpsfe,Kbb) * zwsbio3(ji,jj) + tr(ji,jj,ikt,jpbfe,Kbb)  &
133            &                     * zwsbio4(ji,jj)  ) * 1E3 / ( trc_data(ji,jj,12 ) + trc_data(ji,jj,13 ) + rtrn )
134            trc_data(ji,jj,17 ) = MIN(1E-3, trc_data(ji,jj,17 ) )
135         ENDIF
136      END_2D
137
138      ! Pore water initial concentration [mol/l] in  k=1
139      !-------------------------------------------------
140      DO jw = 1, jpwat
141         CALL pack_arr ( jpoce,  pwcp_dta(1:jpoce,jw), trc_data(1:jpi,1:jpj,jw), iarroce(1:jpoce) )
142      END DO
143      !  Solid components :
144      !-----------------------
145      !  Sinking fluxes for OPAL in mol.m-2.s-1 ; conversion in mol.cm-2.s-1
146      CALL pack_arr ( jpoce, rainrm_dta(1:jpoce,jsopal), trc_data(1:jpi,1:jpj,11), iarroce(1:jpoce) ) 
147      rainrm_dta(1:jpoce,jsopal) = rainrm_dta(1:jpoce,jsopal) * 1e-4
148      !  Sinking fluxes for POC in mol.m-2.s-1 ; conversion in mol.cm-2.s-1
149      CALL pack_arr ( jpoce, zdtap(1:jpoce), trc_data(1:jpi,1:jpj,12) , iarroce(1:jpoce) )     
150      CALL pack_arr ( jpoce, zdtag(1:jpoce), trc_data(1:jpi,1:jpj,13) , iarroce(1:jpoce) )
151      DO ji = 1, jpoce
152!        zkapp  = MIN( (1.0 - 0.02 ) * reac_poc, 3731.0 * max(100.0, zkbot(ji) )**(-1.011) / ( 365.0 * 24.0 * 3600.0 ) )
153!        zkapp   = MIN( 0.98 * reac_poc, 100.0 * max(100.0, zkbot(ji) )**(-0.6) / ( 365.0 * 24.0 * 3600.0 ) )
154!        zratio = ( ( 1.0 - 0.02 ) * reac_poc + 0.02 * reac_poc * 0. - zkapp) / ( ( 0.02 - 1.0 ) * reac_poc / 100. - 0.02 * reac_poc * 0. + zkapp )
155!        zf1    = ( 0.02 * (reac_poc - reac_poc * 0.) + zkapp - reac_poc ) / ( reac_poc / 100. - reac_poc )
156!        zf1    = MIN(0.98, MAX(0., zf1 ) )
157         zf1    = 0.48
158         zf0    = 1.0 - 0.02 - zf1
159         zf2    = 0.02
160         rainrm_dta(ji,jspoc) =   ( zdtap(ji) +  zdtag(ji) ) * 1e-4 * zf0
161         rainrm_dta(ji,jspos) =   ( zdtap(ji) +  zdtag(ji) ) * 1e-4 * zf1
162         rainrm_dta(ji,jspor) =   ( zdtap(ji) +  zdtag(ji) ) * 1e-4 * zf2
163      END DO
164      !  Sinking fluxes for Calcite in mol.m-2.s-1 ; conversion in mol.cm-2.s-1
165      CALL pack_arr ( jpoce,  rainrm_dta(1:jpoce,jscal), trc_data(1:jpi,1:jpj,14), iarroce(1:jpoce) )
166      rainrm_dta(1:jpoce,jscal) = rainrm_dta(1:jpoce,jscal) * 1e-4
167      ! vector temperature [�C] and salinity
168      CALL pack_arr ( jpoce,  temp(1:jpoce), trc_data(1:jpi,1:jpj,15), iarroce(1:jpoce) )
169      CALL pack_arr ( jpoce,  salt(1:jpoce), trc_data(1:jpi,1:jpj,16), iarroce(1:jpoce) )
170     
171      ! Clay rain rate in [mol/(cm**2.s)]
172      ! inputs data in [kg.m-2.sec-1] ---> 1e+3/(1e+4) [g.cm-2.s-1]   
173      ! divided after by molecular weight g.mol-1     
174      CALL pack_arr ( jpoce,  rainrm_dta(1:jpoce,jsclay), dust(1:jpi,1:jpj), iarroce(1:jpoce) )
175      rainrm_dta(1:jpoce,jsclay) = rainrm_dta(1:jpoce,jsclay) * conv2 / mol_wgt(jsclay)   &
176      &                            + wacc(1:jpoce) * por1(2) * denssol / mol_wgt(jsclay) / ( rsecday * 365.0 )
177      rainrm_dta(1:jpoce,jsclay) = rainrm_dta(1:jpoce,jsclay) * 0.965
178      rainrm_dta(1:jpoce,jsfeo)  = rainrm_dta(1:jpoce,jsclay) * mol_wgt(jsclay) / mol_wgt(jsfeo) * 0.035 / 0.965
179!    rainrm_dta(1:jpoce,jsclay) = 1.0E-4 * conv2 / mol_wgt(jsclay)
180
181      ! Iron monosulphide rain rates. Set to 0
182      rainrm_dta(1:jpoce,jsfes)  = 0. 
183
184      ! Fe/C ratio in sinking particles that fall to the sediments
185      CALL pack_arr ( jpoce,  fecratio(1:jpoce), trc_data(1:jpi,1:jpj,17), iarroce(1:jpoce) )
186
187      sedligand(:,1) = 1.E-9
188
189      ! sediment pore water at 1st layer (k=1)
190      DO jw = 1, jpwat
191         pwcp(1:jpoce,1,jw) = pwcp_dta(1:jpoce,jw)
192      ENDDO
193
194      !  rain
195      DO js = 1, jpsol
196         rainrm(1:jpoce,js) = rainrm_dta(1:jpoce,js)
197      ENDDO
198
199      ! Calculation of raintg of each sol. comp.: rainrm in [g/(cm**2.s)]
200      DO js = 1, jpsol
201         rainrg(1:jpoce,js) = rainrm(1:jpoce,js) *  mol_wgt(js)
202      ENDDO
203
204      ! Calculation of raintg = total massic flux rained in each cell (sum of sol. comp.)
205      raintg(:) = 0.
206      DO js = 1, jpsol
207         raintg(1:jpoce) = raintg(1:jpoce) + rainrg(1:jpoce,js)
208      ENDDO
209
210      ! computation of dzdep = total thickness of solid material rained [cm] in each cell
211      dzdep(1:jpoce) = raintg(1:jpoce) * rdtsed(2) 
212
213      IF( lk_iomput ) THEN
214          IF( iom_use("sflxclay" ) ) CALL iom_put( "sflxclay", dust(:,:) * conv2 * 1E4 )
215          IF( iom_use("sflxcal" ) )  CALL iom_put( "sflxcal", trc_data(:,:,13) )
216          IF( iom_use("sflxbsi" ) )  CALL iom_put( "sflxbsi", trc_data(:,:,10) )
217          IF( iom_use("sflxpoc" ) )  CALL iom_put( "sflxpoc", trc_data(:,:,11) + trc_data(:,:,12) )
218      ENDIF
219
220      IF( ln_timing )  CALL timing_stop('sed_dta')
221     
222   END SUBROUTINE sed_dta
223
224END MODULE seddta
Note: See TracBrowser for help on using the repository browser.