source: NEMO/branches/2020/dev_r12512_HPC-04_mcastril_Mixed_Precision_implementation/src/OCE/CRS/crsfld.F90 @ 13257

Last change on this file since 13257 was 13257, checked in by orioltp, 3 months ago

Updated with trunk at r13245 and small change allocating variables in icb_oce.F90.

  • Property svn:keywords set to Id
File size: 11.6 KB
Line 
1MODULE crsfld
2   !!======================================================================
3   !!                     ***  MODULE  crsdfld  ***
4   !!  Ocean coarsening :  coarse ocean fields
5   !!=====================================================================
6   !!   2012-07  (J. Simeon, C. Calone, G. Madec, C. Ethe)
7   !!----------------------------------------------------------------------
8
9   !!----------------------------------------------------------------------
10   !!   crs_fld       : create the standard output files for coarse grid and prep
11   !!                       other variables needed to be passed to TOP
12   !!----------------------------------------------------------------------
13   USE crs
14   USE crsdom
15   USE crslbclnk
16   USE oce             ! ocean dynamics and tracers
17   USE dom_oce         ! ocean space and time domain
18   USE sbc_oce         ! Surface boundary condition: ocean fields
19   USE zdf_oce         ! vertical  physics: ocean fields
20   USE ldftra          ! ocean active tracers: lateral diffusivity & EIV coefficients
21   USE zdfddm          ! vertical  physics: double diffusion
22   !
23   USE in_out_manager  ! I/O manager
24   USE iom             !
25   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
26   USE timing          ! preformance summary
27
28   IMPLICIT NONE
29   PRIVATE
30
31   PUBLIC   crs_fld                 ! routines called by step.F90
32
33   !! * Substitutions
34#  include "do_loop_substitute.h90"
35#  include "domzgr_substitute.h90"
36   !!----------------------------------------------------------------------
37   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
38   !! $Id$
39   !! Software governed by the CeCILL license (see ./LICENSE)
40   !!----------------------------------------------------------------------
41CONTAINS
42
43   SUBROUTINE crs_fld( kt, Kmm )
44      !!---------------------------------------------------------------------
45      !!                  ***  ROUTINE crs_fld  ***
46      !!                   
47      !! ** Purpose :   Basic output of coarsened dynamics and tracer fields
48      !!      NETCDF format is used by default
49      !!      1. Accumulate in time the dimensionally-weighted fields
50      !!      2. At time of output, rescale [1] by dimension and time
51      !!         to yield the spatial and temporal average.
52      !!  See. sbcmod.F90
53      !!
54      !! ** Method  : 
55      !!----------------------------------------------------------------------
56      INTEGER, INTENT(in) ::   kt   ! ocean time-step index
57      INTEGER, INTENT(in) ::   Kmm  ! time level index
58      !
59      INTEGER  ::   ji, jj, jk        ! dummy loop indices
60      REAL(wp) ::   z2dcrsu, z2dcrsv  ! local scalars
61      REAL(wp) ::   zztmp             !   -      -
62      !
63      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   ze3t, ze3u, ze3v, ze3w   ! 3D workspace for e3
64      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zt  , zs  , z3d
65      REAL(wp), DIMENSION(jpi_crs,jpj_crs,jpk) ::   zt_crs, zs_crs 
66      !!----------------------------------------------------------------------
67      !
68      IF( ln_timing )   CALL timing_start('crs_fld')
69
70      ! Depth work arrrays
71      DO jk = 1 , jpk 
72         ze3t(:,:,jk) = e3t(:,:,jk,Kmm)
73         ze3u(:,:,jk) = e3u(:,:,jk,Kmm)
74         ze3v(:,:,jk) = e3v(:,:,jk,Kmm)
75         ze3w(:,:,jk) = e3w(:,:,jk,Kmm)
76      END DO
77
78      IF( kt == nit000  ) THEN
79         tsn_crs  (:,:,:,:) = 0._wp    ! temp/sal  array, now
80         un_crs   (:,:,:  ) = 0._wp    ! u-velocity
81         vn_crs   (:,:,:  ) = 0._wp    ! v-velocity
82         wn_crs   (:,:,:  ) = 0._wp    ! w
83         avs_crs  (:,:,:  ) = 0._wp    ! avt
84         hdivn_crs(:,:,:  ) = 0._wp    ! hdiv
85         sshn_crs (:,:    ) = 0._wp    ! ssh
86         utau_crs (:,:    ) = 0._wp    ! taux
87         vtau_crs (:,:    ) = 0._wp    ! tauy
88         wndm_crs (:,:    ) = 0._wp    ! wind speed
89         qsr_crs  (:,:    ) = 0._wp    ! qsr
90         emp_crs  (:,:    ) = 0._wp    ! emp
91         emp_b_crs(:,:    ) = 0._wp    ! emp
92         rnf_crs  (:,:    ) = 0._wp    ! runoff
93         fr_i_crs (:,:    ) = 0._wp    ! ice cover
94      ENDIF
95
96      CALL iom_swap( "nemo_crs" )    ! swap on the coarse grid
97
98      ! 2. Coarsen fields at each time step
99      ! --------------------------------------------------------
100
101      !  Temperature
102      zt(:,:,:) = ts(:,:,:,jp_tem,Kmm)  ;      zt_crs(:,:,:) = 0._wp
103      CALL crs_dom_ope( zt, 'VOL', 'T', tmask, zt_crs, p_e12=e1e2t, p_e3=ze3t, psgn=1.0_wp )
104      tsn_crs(:,:,:,jp_tem) = zt_crs(:,:,:)
105
106      CALL iom_put( "toce", tsn_crs(:,:,:,jp_tem) )    ! temp
107      CALL iom_put( "sst" , tsn_crs(:,:,1,jp_tem) )    ! sst
108
109     
110      !  Salinity
111      zs(:,:,:) = ts(:,:,:,jp_sal,Kmm)  ;      zs_crs(:,:,:) = 0._wp
112      CALL crs_dom_ope( zs, 'VOL', 'T', tmask, zs_crs, p_e12=e1e2t, p_e3=ze3t, psgn=1.0_wp )
113      tsn_crs(:,:,:,jp_sal) = zt_crs(:,:,:)
114
115      CALL iom_put( "soce" , tsn_crs(:,:,:,jp_sal) )    ! sal
116      CALL iom_put( "sss"  , tsn_crs(:,:,1,jp_sal) )    ! sss
117
118      !  U-velocity
119      CALL crs_dom_ope( uu(:,:,:,Kmm), 'SUM', 'U', umask, un_crs, p_e12=e2u, p_e3=ze3u, p_surf_crs=e2e3u_msk, psgn=-1.0_wp )
120      !
121      zt(:,:,:) = 0._wp     ;    zs(:,:,:) = 0._wp  ;   zt_crs(:,:,:) = 0._wp   ;    zs_crs(:,:,:) = 0._wp
122      DO_3D_00_00( 1, jpkm1 )
123         zt(ji,jj,jk)  = uu(ji,jj,jk,Kmm) * 0.5 * ( ts(ji,jj,jk,jp_tem,Kmm) + ts(ji+1,jj,jk,jp_tem,Kmm) ) 
124         zs(ji,jj,jk)  = uu(ji,jj,jk,Kmm) * 0.5 * ( ts(ji,jj,jk,jp_sal,Kmm) + ts(ji+1,jj,jk,jp_sal,Kmm) ) 
125      END_3D
126      CALL crs_dom_ope( zt, 'SUM', 'U', umask, zt_crs, p_e12=e2u, p_e3=ze3u, p_surf_crs=e2e3u_msk, psgn=-1.0_wp )
127      CALL crs_dom_ope( zs, 'SUM', 'U', umask, zs_crs, p_e12=e2u, p_e3=ze3u, p_surf_crs=e2e3u_msk, psgn=-1.0_wp )
128
129      CALL iom_put( "uoce"  , un_crs )   ! i-current
130      CALL iom_put( "uocet" , zt_crs )   ! uT
131      CALL iom_put( "uoces" , zs_crs )   ! uS
132
133      !  V-velocity
134      CALL crs_dom_ope( vv(:,:,:,Kmm), 'SUM', 'V', vmask, vn_crs, p_e12=e1v, p_e3=ze3v, p_surf_crs=e1e3v_msk, psgn=-1.0_wp )
135      !                                                                                 
136      zt(:,:,:) = 0._wp     ;    zs(:,:,:) = 0._wp  ;   zt_crs(:,:,:) = 0._wp   ;    zs_crs(:,:,:) = 0._wp
137      DO_3D_00_00( 1, jpkm1 )
138         zt(ji,jj,jk)  = vv(ji,jj,jk,Kmm) * 0.5 * ( ts(ji,jj,jk,jp_tem,Kmm) + ts(ji,jj+1,jk,jp_tem,Kmm) ) 
139         zs(ji,jj,jk)  = vv(ji,jj,jk,Kmm) * 0.5 * ( ts(ji,jj,jk,jp_sal,Kmm) + ts(ji,jj+1,jk,jp_sal,Kmm) ) 
140      END_3D
141      CALL crs_dom_ope( zt, 'SUM', 'V', vmask, zt_crs, p_e12=e1v, p_e3=ze3v, p_surf_crs=e1e3v_msk, psgn=-1.0_wp )
142      CALL crs_dom_ope( zs, 'SUM', 'V', vmask, zs_crs, p_e12=e1v, p_e3=ze3v, p_surf_crs=e1e3v_msk, psgn=-1.0_wp )
143 
144      CALL iom_put( "voce"  , vn_crs )   ! i-current
145      CALL iom_put( "vocet" , zt_crs )   ! vT
146      CALL iom_put( "voces" , zs_crs )   ! vS
147
148      IF( iom_use( "eken") ) THEN     !      kinetic energy
149         z3d(:,:,jk) = 0._wp 
150         DO_3D_00_00( 1, jpkm1 )
151            zztmp  = r1_e1e2t(ji,jj) / e3t(ji,jj,jk,Kmm)
152            z3d(ji,jj,jk) = 0.25_wp * zztmp * (                                    &
153               &            uu(ji-1,jj,jk,Kmm)**2 * e2u(ji-1,jj) * e3u(ji-1,jj,jk,Kmm)   &
154               &          + uu(ji  ,jj,jk,Kmm)**2 * e2u(ji  ,jj) * e3u(ji  ,jj,jk,Kmm)   &
155               &          + vv(ji,jj-1,jk,Kmm)**2 * e1v(ji,jj-1) * e3v(ji,jj-1,jk,Kmm)   &
156               &          + vv(ji,jj  ,jk,Kmm)**2 * e1v(ji,jj  ) * e3v(ji,jj  ,jk,Kmm)   )
157         END_3D
158         CALL lbc_lnk( 'crsfld', z3d, 'T', 1.0_wp )
159         !
160         CALL crs_dom_ope( z3d, 'VOL', 'T', tmask, zt_crs, p_e12=e1e2t, p_e3=ze3t, psgn=1.0_wp )
161         CALL iom_put( "eken", zt_crs )
162      ENDIF
163      !  Horizontal divergence ( following OCE/DYN/divhor.F90 )
164      DO jk = 1, jpkm1
165         DO ji = 2, jpi_crsm1
166            DO jj = 2, jpj_crsm1
167               IF( tmask_crs(ji,jj,jk ) > 0 ) THEN
168                   z2dcrsu =  ( un_crs(ji  ,jj  ,jk) * crs_surfu_wgt(ji  ,jj  ,jk) ) &
169                      &     - ( un_crs(ji-1,jj  ,jk) * crs_surfu_wgt(ji-1,jj  ,jk) )
170                   z2dcrsv =  ( vn_crs(ji  ,jj  ,jk) * crs_surfv_wgt(ji  ,jj  ,jk) ) &
171                      &     - ( vn_crs(ji  ,jj-1,jk) * crs_surfv_wgt(ji  ,jj-1,jk) )
172                   !
173                   hdivn_crs(ji,jj,jk) = ( z2dcrsu + z2dcrsv ) / crs_volt_wgt(ji,jj,jk) 
174               ENDIF
175            END DO
176         END DO
177      END DO
178      CALL crs_lbc_lnk( hdivn_crs, 'T', 1.0_wp )
179      !
180      CALL iom_put( "hdiv", hdivn_crs ) 
181
182
183      !  W-velocity
184      IF( ln_crs_wn ) THEN
185         CALL crs_dom_ope( ww, 'SUM', 'W', tmask, wn_crs, p_e12=e1e2t, p_surf_crs=e1e2w_msk, psgn=1.0_wp )
186       !  CALL crs_dom_ope( ww, 'VOL', 'W', tmask, wn_crs, p_e12=e1e2t, p_e3=ze3w )
187      ELSE
188        wn_crs(:,:,jpk) = 0._wp
189        DO jk = jpkm1, 1, -1
190           wn_crs(:,:,jk) = wn_crs(:,:,jk+1) - e3t_crs(:,:,jk) * hdivn_crs(:,:,jk)
191        ENDDO
192      ENDIF
193      CALL iom_put( "woce", wn_crs  )   ! vertical velocity
194      !  free memory
195
196      !  avs
197      SELECT CASE ( nn_crs_kz )
198         CASE ( 0 )
199            CALL crs_dom_ope( avt, 'VOL', 'W', tmask, avt_crs, p_e12=e1e2t, p_e3=ze3w, psgn=1.0_wp )
200            CALL crs_dom_ope( avs, 'VOL', 'W', tmask, avs_crs, p_e12=e1e2t, p_e3=ze3w, psgn=1.0_wp )
201         CASE ( 1 )
202            CALL crs_dom_ope( avt, 'MAX', 'W', tmask, avt_crs, p_e12=e1e2t, p_e3=ze3w, psgn=1.0_wp )
203            CALL crs_dom_ope( avs, 'MAX', 'W', tmask, avs_crs, p_e12=e1e2t, p_e3=ze3w, psgn=1.0_wp )
204         CASE ( 2 )
205            CALL crs_dom_ope( avt, 'MIN', 'W', tmask, avt_crs, p_e12=e1e2t, p_e3=ze3w, psgn=1.0_wp )
206            CALL crs_dom_ope( avs, 'MIN', 'W', tmask, avs_crs, p_e12=e1e2t, p_e3=ze3w, psgn=1.0_wp )
207      END SELECT
208      !
209      CALL iom_put( "avt", avt_crs )   !  Kz on T
210      CALL iom_put( "avs", avs_crs )   !  Kz on S
211     
212      !  sbc fields 
213      CALL crs_dom_ope( ssh(:,:,Kmm) , 'VOL', 'T', tmask, sshn_crs , p_e12=e1e2t, p_e3=ze3t           , psgn=1.0_wp ) 
214      CALL crs_dom_ope( utau , 'SUM', 'U', umask, utau_crs , p_e12=e2u  , p_surf_crs=e2u_crs  , psgn=1.0_wp )
215      CALL crs_dom_ope( vtau , 'SUM', 'V', vmask, vtau_crs , p_e12=e1v  , p_surf_crs=e1v_crs  , psgn=1.0_wp )
216      CALL crs_dom_ope( wndm , 'SUM', 'T', tmask, wndm_crs , p_e12=e1e2t, p_surf_crs=e1e2t_crs, psgn=1.0_wp )
217      CALL crs_dom_ope( rnf  , 'MAX', 'T', tmask, rnf_crs                                     , psgn=1.0_wp )
218      CALL crs_dom_ope( qsr  , 'SUM', 'T', tmask, qsr_crs  , p_e12=e1e2t, p_surf_crs=e1e2t_crs, psgn=1.0_wp )
219      CALL crs_dom_ope( emp_b, 'SUM', 'T', tmask, emp_b_crs, p_e12=e1e2t, p_surf_crs=e1e2t_crs, psgn=1.0_wp )
220      CALL crs_dom_ope( emp  , 'SUM', 'T', tmask, emp_crs  , p_e12=e1e2t, p_surf_crs=e1e2t_crs, psgn=1.0_wp )
221      CALL crs_dom_ope( sfx  , 'SUM', 'T', tmask, sfx_crs  , p_e12=e1e2t, p_surf_crs=e1e2t_crs, psgn=1.0_wp )
222      CALL crs_dom_ope( fr_i , 'SUM', 'T', tmask, fr_i_crs , p_e12=e1e2t, p_surf_crs=e1e2t_crs, psgn=1.0_wp )
223
224      CALL iom_put( "ssh"      , sshn_crs )   ! ssh output
225      CALL iom_put( "utau"     , utau_crs )   ! i-tau output
226      CALL iom_put( "vtau"     , vtau_crs )   ! j-tau output
227      CALL iom_put( "wspd"     , wndm_crs )   ! wind speed output
228      CALL iom_put( "runoffs"  , rnf_crs  )   ! runoff output
229      CALL iom_put( "qsr"      , qsr_crs  )   ! qsr output
230      CALL iom_put( "empmr"    , emp_crs  )   ! water flux output
231      CALL iom_put( "saltflx"  , sfx_crs  )   ! salt flux output
232      CALL iom_put( "ice_cover", fr_i_crs )   ! ice cover output
233
234      !
235      CALL iom_swap( "nemo" )     ! return back on high-resolution grid
236      !
237      IF( ln_timing )   CALL timing_stop('crs_fld')
238      !
239   END SUBROUTINE crs_fld
240
241   !!======================================================================
242END MODULE crsfld
Note: See TracBrowser for help on using the repository browser.