source: NEMO/branches/2020/dev_r12512_HPC-04_mcastril_Mixed_Precision_implementation/src/OCE/DIA/diacfl.F90 @ 13257

Last change on this file since 13257 was 13257, checked in by orioltp, 3 months ago

Updated with trunk at r13245 and small change allocating variables in icb_oce.F90.

  • Property svn:keywords set to Id
File size: 7.9 KB
Line 
1MODULE diacfl
2   !!======================================================================
3   !!                       ***  MODULE  diacfl  ***
4   !! Output CFL diagnostics to ascii file
5   !!======================================================================
6   !! History :  3.4  !  2010-03  (E. Blockley)  Original code
7   !!            3.6  !  2014-06  (T. Graham)  Removed CPP key & Updated to vn3.6
8   !!            4.0  !  2017-09  (G. Madec)  style + comments
9   !!----------------------------------------------------------------------
10   !!   dia_cfl        : Compute and output Courant numbers at each timestep
11   !!----------------------------------------------------------------------
12   USE oce             ! ocean dynamics and active tracers
13   USE dom_oce         ! ocean space and time domain
14   USE domvvl          !
15   !
16   USE lib_mpp         ! distribued memory computing
17   USE lbclnk          ! ocean lateral boundary condition (or mpp link)
18   USE in_out_manager  ! I/O manager
19   USE iom             !
20   USE timing          ! Performance output
21
22   IMPLICIT NONE
23   PRIVATE
24
25   CHARACTER(LEN=50) :: clname="cfl_diagnostics.ascii"    ! ascii filename
26   INTEGER           :: numcfl                            ! outfile unit
27   !
28   INTEGER, DIMENSION(3) ::   nCu_loc, nCv_loc, nCw_loc   ! U, V, and W run max locations in the global domain
29   REAL(wp)              ::   rCu_max, rCv_max, rCw_max   ! associated run max Courant number
30
31   PUBLIC   dia_cfl       ! routine called by step.F90
32   PUBLIC   dia_cfl_init  ! routine called by nemogcm
33
34   !! * Substitutions
35#  include "do_loop_substitute.h90"
36#  include "domzgr_substitute.h90"
37   !!----------------------------------------------------------------------
38   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
39   !! $Id$
40   !! Software governed by the CeCILL license (see ./LICENSE)
41   !!----------------------------------------------------------------------
42CONTAINS
43
44   SUBROUTINE dia_cfl ( kt, Kmm )
45      !!----------------------------------------------------------------------
46      !!                  ***  ROUTINE dia_cfl  ***
47      !!
48      !! ** Purpose :  Compute the Courant numbers Cu=u*dt/dx and Cv=v*dt/dy
49      !!               and output to ascii file 'cfl_diagnostics.ascii'
50      !!----------------------------------------------------------------------
51      INTEGER, INTENT(in) ::   kt   ! ocean time-step index
52      INTEGER, INTENT(in) ::   Kmm  ! ocean time level index
53      !
54      INTEGER                          ::   ji, jj, jk                       ! dummy loop indices
55      REAL(wp)                         ::   zCu_max, zCv_max, zCw_max        ! local scalars
56      INTEGER , DIMENSION(3)           ::   iloc_u , iloc_v , iloc_w , iloc  ! workspace
57      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zCu_cfl, zCv_cfl, zCw_cfl        ! workspace
58      !!----------------------------------------------------------------------
59      !
60      IF( ln_timing )   CALL timing_start('dia_cfl')
61      !
62      DO_3D_11_11( 1, jpk )
63         zCu_cfl(ji,jj,jk) = ABS( uu(ji,jj,jk,Kmm) ) * rDt / e1u  (ji,jj)      ! for i-direction
64         zCv_cfl(ji,jj,jk) = ABS( vv(ji,jj,jk,Kmm) ) * rDt / e2v  (ji,jj)      ! for j-direction
65         zCw_cfl(ji,jj,jk) = ABS( ww(ji,jj,jk) ) * rDt / e3w(ji,jj,jk,Kmm)   ! for k-direction
66      END_3D
67      !
68      ! write outputs
69      IF( iom_use('cfl_cu') )   CALL iom_put( 'cfl_cu', MAXVAL( zCu_cfl, dim=3 ) )
70      IF( iom_use('cfl_cv') )   CALL iom_put( 'cfl_cv', MAXVAL( zCv_cfl, dim=3 ) )
71      IF( iom_use('cfl_cw') )   CALL iom_put( 'cfl_cw', MAXVAL( zCw_cfl, dim=3 ) )
72
73      !                    ! calculate maximum values and locations
74      IF( lk_mpp ) THEN
75         CALL mpp_maxloc( 'diacfl', zCu_cfl, umask, zCu_max, iloc_u )
76         CALL mpp_maxloc( 'diacfl', zCv_cfl, vmask, zCv_max, iloc_v )
77         CALL mpp_maxloc( 'diacfl', zCw_cfl, wmask, zCw_max, iloc_w )
78      ELSE
79         iloc = MAXLOC( ABS( zcu_cfl(:,:,:) ) )
80         iloc_u(1) = iloc(1) + nimpp - 1
81         iloc_u(2) = iloc(2) + njmpp - 1
82         iloc_u(3) = iloc(3)
83         zCu_max = zCu_cfl(iloc(1),iloc(2),iloc(3))
84         !
85         iloc = MAXLOC( ABS( zcv_cfl(:,:,:) ) )
86         iloc_v(1) = iloc(1) + nimpp - 1
87         iloc_v(2) = iloc(2) + njmpp - 1
88         iloc_v(3) = iloc(3)
89         zCv_max = zCv_cfl(iloc(1),iloc(2),iloc(3))
90         !
91         iloc = MAXLOC( ABS( zcw_cfl(:,:,:) ) )
92         iloc_w(1) = iloc(1) + nimpp - 1
93         iloc_w(2) = iloc(2) + njmpp - 1
94         iloc_w(3) = iloc(3)
95         zCw_max = zCw_cfl(iloc(1),iloc(2),iloc(3))
96      ENDIF
97      !
98      !                    ! write out to file
99      IF( lwp ) THEN
100         WRITE(numcfl,FMT='(2x,i6,3x,a6,4x,f7.4,1x,i4,1x,i4,1x,i4)') kt, 'Max Cu', zCu_max, iloc_u(1), iloc_u(2), iloc_u(3)
101         WRITE(numcfl,FMT='(11x,     a6,4x,f7.4,1x,i4,1x,i4,1x,i4)')     'Max Cv', zCv_max, iloc_v(1), iloc_v(2), iloc_v(3)
102         WRITE(numcfl,FMT='(11x,     a6,4x,f7.4,1x,i4,1x,i4,1x,i4)')     'Max Cw', zCw_max, iloc_w(1), iloc_w(2), iloc_w(3)
103      ENDIF
104      !
105      !                    ! update maximum Courant numbers from whole run if applicable
106      IF( zCu_max > rCu_max ) THEN   ;   rCu_max = zCu_max   ;   nCu_loc(:) = iloc_u(:)   ;   ENDIF
107      IF( zCv_max > rCv_max ) THEN   ;   rCv_max = zCv_max   ;   nCv_loc(:) = iloc_v(:)   ;   ENDIF
108      IF( zCw_max > rCw_max ) THEN   ;   rCw_max = zCw_max   ;   nCw_loc(:) = iloc_w(:)   ;   ENDIF
109
110      !                    ! at end of run output max Cu and Cv and close ascii file
111      IF( kt == nitend .AND. lwp ) THEN
112         ! to ascii file
113         WRITE(numcfl,*) '******************************************'
114         WRITE(numcfl,FMT='(3x,a12,6x,f7.4,1x,i4,1x,i4,1x,i4)') 'Run Max Cu', rCu_max, nCu_loc(1), nCu_loc(2), nCu_loc(3)
115         WRITE(numcfl,FMT='(3x,a8,11x,f15.1)') ' => dt/C', rDt/rCu_max
116         WRITE(numcfl,*) '******************************************'
117         WRITE(numcfl,FMT='(3x,a12,6x,f7.4,1x,i4,1x,i4,1x,i4)') 'Run Max Cv', rCv_max, nCv_loc(1), nCv_loc(2), nCv_loc(3)
118         WRITE(numcfl,FMT='(3x,a8,11x,f15.1)') ' => dt/C', rDt/rCv_max
119         WRITE(numcfl,*) '******************************************'
120         WRITE(numcfl,FMT='(3x,a12,6x,f7.4,1x,i4,1x,i4,1x,i4)') 'Run Max Cw', rCw_max, nCw_loc(1), nCw_loc(2), nCw_loc(3)
121         WRITE(numcfl,FMT='(3x,a8,11x,f15.1)') ' => dt/C', rDt/rCw_max
122         CLOSE( numcfl ) 
123         !
124         ! to ocean output
125         WRITE(numout,*)
126         WRITE(numout,*) 'dia_cfl : Maximum Courant number information for the run '
127         WRITE(numout,*) '~~~~~~~'
128         WRITE(numout,*) '   Max Cu = ', rCu_max, ' at (i,j,k) = (',nCu_loc(1),nCu_loc(2),nCu_loc(3),') => dt/C = ', rDt/rCu_max
129         WRITE(numout,*) '   Max Cv = ', rCv_max, ' at (i,j,k) = (',nCv_loc(1),nCv_loc(2),nCv_loc(3),') => dt/C = ', rDt/rCv_max
130         WRITE(numout,*) '   Max Cw = ', rCw_max, ' at (i,j,k) = (',nCw_loc(1),nCw_loc(2),nCw_loc(3),') => dt/C = ', rDt/rCw_max
131      ENDIF
132      !
133      IF( ln_timing )   CALL timing_stop('dia_cfl')
134      !
135   END SUBROUTINE dia_cfl
136
137
138   SUBROUTINE dia_cfl_init
139      !!----------------------------------------------------------------------
140      !!                  ***  ROUTINE dia_cfl_init  ***
141      !!                   
142      !! ** Purpose :   create output file, initialise arrays
143      !!----------------------------------------------------------------------
144      !
145      IF(lwp) THEN
146         WRITE(numout,*)
147         WRITE(numout,*) 'dia_cfl : Outputting CFL diagnostics to ',TRIM(clname), ' file'
148         WRITE(numout,*) '~~~~~~~'
149         WRITE(numout,*)
150         !
151         ! create output ascii file
152         CALL ctl_opn( numcfl, clname, 'UNKNOWN', 'FORMATTED', 'SEQUENTIAL', 1, numout, lwp, 1 )
153         WRITE(numcfl,*) 'Timestep  Direction  Max C     i    j    k'
154         WRITE(numcfl,*) '******************************************'
155      ENDIF
156      !
157      rCu_max = 0._wp
158      rCv_max = 0._wp
159      rCw_max = 0._wp
160      !
161   END SUBROUTINE dia_cfl_init
162
163   !!======================================================================
164END MODULE diacfl
Note: See TracBrowser for help on using the repository browser.