source: NEMO/branches/2020/dev_r12512_HPC-04_mcastril_Mixed_Precision_implementation/src/OCE/DYN/dynzad.F90 @ 13257

Last change on this file since 13257 was 13257, checked in by orioltp, 2 months ago

Updated with trunk at r13245 and small change allocating variables in icb_oce.F90.

  • Property svn:keywords set to Id
File size: 5.5 KB
Line 
1MODULE dynzad
2   !!======================================================================
3   !!                       ***  MODULE  dynzad  ***
4   !! Ocean dynamics : vertical advection trend
5   !!======================================================================
6   !! History :  OPA  ! 1991-01  (G. Madec) Original code
7   !!   NEMO     0.5  ! 2002-07  (G. Madec) Free form, F90
8   !!----------------------------------------------------------------------
9   
10   !!----------------------------------------------------------------------
11   !!   dyn_zad       : vertical advection momentum trend
12   !!----------------------------------------------------------------------
13   USE oce            ! ocean dynamics and tracers
14   USE dom_oce        ! ocean space and time domain
15   USE sbc_oce        ! surface boundary condition: ocean
16   USE trd_oce        ! trends: ocean variables
17   USE trddyn         ! trend manager: dynamics
18   !
19   USE in_out_manager ! I/O manager
20   USE lib_mpp        ! MPP library
21   USE prtctl         ! Print control
22   USE timing         ! Timing
23
24   IMPLICIT NONE
25   PRIVATE
26   
27   PUBLIC   dyn_zad       ! routine called by dynadv.F90
28
29   !! * Substitutions
30#  include "do_loop_substitute.h90"
31#  include "domzgr_substitute.h90"
32   !!----------------------------------------------------------------------
33   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
34   !! $Id$
35   !! Software governed by the CeCILL license (see ./LICENSE)
36   !!----------------------------------------------------------------------
37CONTAINS
38
39   SUBROUTINE dyn_zad ( kt, Kmm, puu, pvv, Krhs )
40      !!----------------------------------------------------------------------
41      !!                  ***  ROUTINE dynzad  ***
42      !!
43      !! ** Purpose :   Compute the now vertical momentum advection trend and
44      !!      add it to the general trend of momentum equation.
45      !!
46      !! ** Method  :   The now vertical advection of momentum is given by:
47      !!         w dz(u) = u(rhs) + 1/(e1e2u*e3u) mk+1[ mi(e1e2t*ww) dk(u) ]
48      !!         w dz(v) = v(rhs) + 1/(e1e2v*e3v) mk+1[ mj(e1e2t*ww) dk(v) ]
49      !!      Add this trend to the general trend (puu(:,:,:,Krhs),pvv(:,:,:,Krhs)):
50      !!         (u(rhs),v(rhs)) = (u(rhs),v(rhs)) + w dz(u,v)
51      !!
52      !! ** Action  : - Update (puu(:,:,:,Krhs),pvv(:,:,:,Krhs)) with the vert. momentum adv. trends
53      !!              - Send the trends to trddyn for diagnostics (l_trddyn=T)
54      !!----------------------------------------------------------------------
55      INTEGER                             , INTENT( in )  ::  kt               ! ocean time-step inedx
56      INTEGER                             , INTENT( in )  ::  Kmm, Krhs        ! ocean time level indices
57      REAL(wp), DIMENSION(jpi,jpj,jpk,jpt), INTENT(inout) ::  puu, pvv         ! ocean velocities and RHS of momentum equation
58      !
59      INTEGER  ::   ji, jj, jk   ! dummy loop indices
60      REAL(wp) ::   zua, zva     ! local scalars
61      REAL(wp), DIMENSION(jpi,jpj)     ::   zww
62      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zwuw, zwvw
63      REAL(wp), DIMENSION(:,:,:), ALLOCATABLE ::   ztrdu, ztrdv
64      !!----------------------------------------------------------------------
65      !
66      IF( ln_timing )   CALL timing_start('dyn_zad')
67      !
68      IF( kt == nit000 ) THEN
69         IF(lwp) WRITE(numout,*)
70         IF(lwp) WRITE(numout,*) 'dyn_zad : 2nd order vertical advection scheme'
71      ENDIF
72
73      IF( l_trddyn )   THEN         ! Save puu(:,:,:,Krhs) and pvv(:,:,:,Krhs) trends
74         ALLOCATE( ztrdu(jpi,jpj,jpk) , ztrdv(jpi,jpj,jpk) ) 
75         ztrdu(:,:,:) = puu(:,:,:,Krhs) 
76         ztrdv(:,:,:) = pvv(:,:,:,Krhs) 
77      ENDIF
78     
79      DO jk = 2, jpkm1              ! Vertical momentum advection at level w and u- and v- vertical
80         DO_2D_01_01
81            zww(ji,jj) = 0.25_wp * e1e2t(ji,jj) * ww(ji,jj,jk)
82         END_2D
83         DO_2D_00_00
84            zwuw(ji,jj,jk) = ( zww(ji+1,jj  ) + zww(ji,jj) ) * ( puu(ji,jj,jk-1,Kmm) - puu(ji,jj,jk,Kmm) )
85            zwvw(ji,jj,jk) = ( zww(ji  ,jj+1) + zww(ji,jj) ) * ( pvv(ji,jj,jk-1,Kmm) - pvv(ji,jj,jk,Kmm) )
86         END_2D
87      END DO
88      !
89      ! Surface and bottom advective fluxes set to zero
90      DO_2D_00_00
91         zwuw(ji,jj, 1 ) = 0._wp
92         zwvw(ji,jj, 1 ) = 0._wp
93         zwuw(ji,jj,jpk) = 0._wp
94         zwvw(ji,jj,jpk) = 0._wp
95      END_2D
96      !
97      DO_3D_00_00( 1, jpkm1 )
98         puu(ji,jj,jk,Krhs) = puu(ji,jj,jk,Krhs) - ( zwuw(ji,jj,jk) + zwuw(ji,jj,jk+1) ) * r1_e1e2u(ji,jj)   &
99            &                                      / e3u(ji,jj,jk,Kmm)
100         pvv(ji,jj,jk,Krhs) = pvv(ji,jj,jk,Krhs) - ( zwvw(ji,jj,jk) + zwvw(ji,jj,jk+1) ) * r1_e1e2v(ji,jj)   &
101            &                                      / e3v(ji,jj,jk,Kmm)
102      END_3D
103
104      IF( l_trddyn ) THEN           ! save the vertical advection trends for diagnostic
105         ztrdu(:,:,:) = puu(:,:,:,Krhs) - ztrdu(:,:,:)
106         ztrdv(:,:,:) = pvv(:,:,:,Krhs) - ztrdv(:,:,:)
107         CALL trd_dyn( ztrdu, ztrdv, jpdyn_zad, kt, Kmm )
108         DEALLOCATE( ztrdu, ztrdv ) 
109      ENDIF
110      !                             ! Control print
111      IF(sn_cfctl%l_prtctl)   CALL prt_ctl( tab3d_1=puu(:,:,:,Krhs), clinfo1=' zad  - Ua: ', mask1=umask,   &
112         &                                  tab3d_2=pvv(:,:,:,Krhs), clinfo2=       ' Va: ', mask2=vmask, clinfo3='dyn' )
113      !
114      IF( ln_timing )   CALL timing_stop('dyn_zad')
115      !
116   END SUBROUTINE dyn_zad
117
118   !!======================================================================
119END MODULE dynzad
Note: See TracBrowser for help on using the repository browser.