source: NEMO/branches/2020/dev_r12512_HPC-04_mcastril_Mixed_Precision_implementation/src/OCE/TRA/traadv_fct.F90 @ 13257

Last change on this file since 13257 was 13257, checked in by orioltp, 3 months ago

Updated with trunk at r13245 and small change allocating variables in icb_oce.F90.

  • Property svn:keywords set to Id
File size: 32.9 KB
Line 
1MODULE traadv_fct
2   !!==============================================================================
3   !!                       ***  MODULE  traadv_fct  ***
4   !! Ocean  tracers:  horizontal & vertical advective trend (2nd/4th order Flux Corrected Transport method)
5   !!==============================================================================
6   !! History :  3.7  !  2015-09  (L. Debreu, G. Madec)  original code (inspired from traadv_tvd.F90)
7   !!----------------------------------------------------------------------
8
9   !!----------------------------------------------------------------------
10   !!  tra_adv_fct    : update the tracer trend with a 3D advective trends using a 2nd or 4th order FCT scheme
11   !!                   with sub-time-stepping in the vertical direction
12   !!  nonosc         : compute monotonic tracer fluxes by a non-oscillatory algorithm
13   !!  interp_4th_cpt : 4th order compact scheme for the vertical component of the advection
14   !!----------------------------------------------------------------------
15   USE oce            ! ocean dynamics and active tracers
16   USE dom_oce        ! ocean space and time domain
17   USE trc_oce        ! share passive tracers/Ocean variables
18   USE trd_oce        ! trends: ocean variables
19   USE trdtra         ! tracers trends
20   USE diaptr         ! poleward transport diagnostics
21   USE diaar5         ! AR5 diagnostics
22   USE phycst  , ONLY : rho0_rcp
23   USE zdf_oce , ONLY : ln_zad_Aimp
24   !
25   USE in_out_manager ! I/O manager
26   USE iom            !
27   USE lib_mpp        ! MPP library
28   USE lbclnk         ! ocean lateral boundary condition (or mpp link)
29   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
30
31   IMPLICIT NONE
32   PRIVATE
33
34   PUBLIC   tra_adv_fct        ! called by traadv.F90
35   PUBLIC   interp_4th_cpt     ! called by traadv_cen.F90
36
37   LOGICAL  ::   l_trd   ! flag to compute trends
38   LOGICAL  ::   l_ptr   ! flag to compute poleward transport
39   LOGICAL  ::   l_hst   ! flag to compute heat/salt transport
40   REAL(wp) ::   r1_6 = 1._wp / 6._wp   ! =1/6
41
42   !                                        ! tridiag solver associated indices:
43   INTEGER, PARAMETER ::   np_NH   = 0   ! Neumann homogeneous boundary condition
44   INTEGER, PARAMETER ::   np_CEN2 = 1   ! 2nd order centered  boundary condition
45
46   !! * Substitutions
47#  include "do_loop_substitute.h90"
48#  include "domzgr_substitute.h90"
49   !!----------------------------------------------------------------------
50   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
51   !! $Id$
52   !! Software governed by the CeCILL license (see ./LICENSE)
53   !!----------------------------------------------------------------------
54CONTAINS
55
56   SUBROUTINE tra_adv_fct( kt, kit000, cdtype, p2dt, pU, pV, pW,       &
57      &                    Kbb, Kmm, pt, kjpt, Krhs, kn_fct_h, kn_fct_v )
58      !!----------------------------------------------------------------------
59      !!                  ***  ROUTINE tra_adv_fct  ***
60      !!
61      !! **  Purpose :   Compute the now trend due to total advection of tracers
62      !!               and add it to the general trend of tracer equations
63      !!
64      !! **  Method  : - 2nd or 4th FCT scheme on the horizontal direction
65      !!               (choice through the value of kn_fct)
66      !!               - on the vertical the 4th order is a compact scheme
67      !!               - corrected flux (monotonic correction)
68      !!
69      !! ** Action : - update pt(:,:,:,:,Krhs)  with the now advective tracer trends
70      !!             - send trends to trdtra module for further diagnostics (l_trdtra=T)
71      !!             - poleward advective heat and salt transport (ln_diaptr=T)
72      !!----------------------------------------------------------------------
73      INTEGER                                  , INTENT(in   ) ::   kt              ! ocean time-step index
74      INTEGER                                  , INTENT(in   ) ::   Kbb, Kmm, Krhs  ! ocean time level indices
75      INTEGER                                  , INTENT(in   ) ::   kit000          ! first time step index
76      CHARACTER(len=3)                         , INTENT(in   ) ::   cdtype          ! =TRA or TRC (tracer indicator)
77      INTEGER                                  , INTENT(in   ) ::   kjpt            ! number of tracers
78      INTEGER                                  , INTENT(in   ) ::   kn_fct_h        ! order of the FCT scheme (=2 or 4)
79      INTEGER                                  , INTENT(in   ) ::   kn_fct_v        ! order of the FCT scheme (=2 or 4)
80      REAL(wp)                                 , INTENT(in   ) ::   p2dt            ! tracer time-step
81      REAL(wp), DIMENSION(jpi,jpj,jpk         ), INTENT(in   ) ::   pU, pV, pW      ! 3 ocean volume flux components
82      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt,jpt), INTENT(inout) ::   pt              ! tracers and RHS of tracer equation
83      !
84      INTEGER  ::   ji, jj, jk, jn                           ! dummy loop indices 
85      REAL(wp) ::   ztra                                     ! local scalar
86      REAL(wp) ::   zfp_ui, zfp_vj, zfp_wk, zC2t_u, zC4t_u   !   -      -
87      REAL(wp) ::   zfm_ui, zfm_vj, zfm_wk, zC2t_v, zC4t_v   !   -      -
88      REAL(wp), DIMENSION(jpi,jpj,jpk)        ::   zwi, zwx, zwy, zwz, ztu, ztv, zltu, zltv, ztw
89      REAL(wp), DIMENSION(:,:,:), ALLOCATABLE ::   ztrdx, ztrdy, ztrdz, zptry
90      REAL(wp), DIMENSION(:,:,:), ALLOCATABLE ::   zwinf, zwdia, zwsup
91      LOGICAL  ::   ll_zAimp                                 ! flag to apply adaptive implicit vertical advection
92      !!----------------------------------------------------------------------
93      !
94      IF( kt == kit000 )  THEN
95         IF(lwp) WRITE(numout,*)
96         IF(lwp) WRITE(numout,*) 'tra_adv_fct : FCT advection scheme on ', cdtype
97         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
98      ENDIF
99      !! -- init to 0
100      zwi(:,:,:) = 0._wp
101      zwx(:,:,:) = 0._wp
102      zwy(:,:,:) = 0._wp
103      zwz(:,:,:) = 0._wp
104      ztu(:,:,:) = 0._wp
105      ztv(:,:,:) = 0._wp
106      zltu(:,:,:) = 0._wp
107      zltv(:,:,:) = 0._wp
108      ztw(:,:,:) = 0._wp
109      !
110      l_trd = .FALSE.            ! set local switches
111      l_hst = .FALSE.
112      l_ptr = .FALSE.
113      ll_zAimp = .FALSE.
114      IF( ( cdtype == 'TRA' .AND. l_trdtra  ) .OR. ( cdtype =='TRC' .AND. l_trdtrc ) )      l_trd = .TRUE.
115      IF(   cdtype == 'TRA' .AND. ( iom_use( 'sophtadv' ) .OR. iom_use( 'sophtadv' ) ) )    l_ptr = .TRUE. 
116      IF(   cdtype == 'TRA' .AND. ( iom_use("uadv_heattr") .OR. iom_use("vadv_heattr") .OR.  &
117         &                         iom_use("uadv_salttr") .OR. iom_use("vadv_salttr")  ) )  l_hst = .TRUE.
118      !
119      IF( l_trd .OR. l_hst )  THEN
120         ALLOCATE( ztrdx(jpi,jpj,jpk), ztrdy(jpi,jpj,jpk), ztrdz(jpi,jpj,jpk) )
121         ztrdx(:,:,:) = 0._wp   ;    ztrdy(:,:,:) = 0._wp   ;   ztrdz(:,:,:) = 0._wp
122      ENDIF
123      !
124      IF( l_ptr ) THEN 
125         ALLOCATE( zptry(jpi,jpj,jpk) )
126         zptry(:,:,:) = 0._wp
127      ENDIF
128      !                          ! surface & bottom value : flux set to zero one for all
129      zwz(:,:, 1 ) = 0._wp           
130      zwx(:,:,jpk) = 0._wp   ;   zwy(:,:,jpk) = 0._wp    ;    zwz(:,:,jpk) = 0._wp
131      !
132      zwi(:,:,:) = 0._wp       
133      !
134      ! If adaptive vertical advection, check if it is needed on this PE at this time
135      IF( ln_zad_Aimp ) THEN
136         IF( MAXVAL( ABS( wi(:,:,:) ) ) > 0._wp ) ll_zAimp = .TRUE.
137      END IF
138      ! If active adaptive vertical advection, build tridiagonal matrix
139      IF( ll_zAimp ) THEN
140         ALLOCATE(zwdia(jpi,jpj,jpk), zwinf(jpi,jpj,jpk),zwsup(jpi,jpj,jpk))
141         DO_3D_00_00( 1, jpkm1 )
142            zwdia(ji,jj,jk) =  1._wp + p2dt * ( MAX( wi(ji,jj,jk) , 0._wp ) - MIN( wi(ji,jj,jk+1) , 0._wp ) )   &
143            &                               / e3t(ji,jj,jk,Krhs)
144            zwinf(ji,jj,jk) =  p2dt * MIN( wi(ji,jj,jk  ) , 0._wp ) / e3t(ji,jj,jk,Krhs)
145            zwsup(ji,jj,jk) = -p2dt * MAX( wi(ji,jj,jk+1) , 0._wp ) / e3t(ji,jj,jk,Krhs)
146         END_3D
147      END IF
148      !
149      DO jn = 1, kjpt            !==  loop over the tracers  ==!
150         !
151         !        !==  upstream advection with initial mass fluxes & intermediate update  ==!
152         !                    !* upstream tracer flux in the i and j direction
153         DO_3D_10_10( 1, jpkm1 )
154            ! upstream scheme
155            zfp_ui = pU(ji,jj,jk) + ABS( pU(ji,jj,jk) )
156            zfm_ui = pU(ji,jj,jk) - ABS( pU(ji,jj,jk) )
157            zfp_vj = pV(ji,jj,jk) + ABS( pV(ji,jj,jk) )
158            zfm_vj = pV(ji,jj,jk) - ABS( pV(ji,jj,jk) )
159            zwx(ji,jj,jk) = 0.5 * ( zfp_ui * pt(ji,jj,jk,jn,Kbb) + zfm_ui * pt(ji+1,jj  ,jk,jn,Kbb) )
160            zwy(ji,jj,jk) = 0.5 * ( zfp_vj * pt(ji,jj,jk,jn,Kbb) + zfm_vj * pt(ji  ,jj+1,jk,jn,Kbb) )
161         END_3D
162         !                    !* upstream tracer flux in the k direction *!
163         DO_3D_11_11( 2, jpkm1 )
164            zfp_wk = pW(ji,jj,jk) + ABS( pW(ji,jj,jk) )
165            zfm_wk = pW(ji,jj,jk) - ABS( pW(ji,jj,jk) )
166            zwz(ji,jj,jk) = 0.5 * ( zfp_wk * pt(ji,jj,jk,jn,Kbb) + zfm_wk * pt(ji,jj,jk-1,jn,Kbb) ) * wmask(ji,jj,jk)
167         END_3D
168         IF( ln_linssh ) THEN    ! top ocean value (only in linear free surface as zwz has been w-masked)
169            IF( ln_isfcav ) THEN             ! top of the ice-shelf cavities and at the ocean surface
170               DO_2D_11_11
171                  zwz(ji,jj, mikt(ji,jj) ) = pW(ji,jj,mikt(ji,jj)) * pt(ji,jj,mikt(ji,jj),jn,Kbb)   ! linear free surface
172               END_2D
173            ELSE                             ! no cavities: only at the ocean surface
174               zwz(:,:,1) = pW(:,:,1) * pt(:,:,1,jn,Kbb)
175            ENDIF
176         ENDIF
177         !               
178         DO_3D_00_00( 1, jpkm1 )
179            !                             ! total intermediate advective trends
180            ztra = - (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
181               &      + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
182               &      + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) ) * r1_e1e2t(ji,jj)
183            !                             ! update and guess with monotonic sheme
184            pt(ji,jj,jk,jn,Krhs) =                   pt(ji,jj,jk,jn,Krhs) +       ztra   &
185               &                                  / e3t(ji,jj,jk,Kmm ) * tmask(ji,jj,jk)
186            zwi(ji,jj,jk)    = ( e3t(ji,jj,jk,Kbb) * pt(ji,jj,jk,jn,Kbb) + p2dt * ztra ) &
187               &                                  / e3t(ji,jj,jk,Krhs) * tmask(ji,jj,jk)
188         END_3D
189         
190         IF ( ll_zAimp ) THEN
191            CALL tridia_solver( zwdia, zwsup, zwinf, zwi, zwi , 0 )
192            !
193            ztw(:,:,1) = 0._wp ; ztw(:,:,jpk) = 0._wp ;
194            DO_3D_00_00( 2, jpkm1 )
195               zfp_wk = wi(ji,jj,jk) + ABS( wi(ji,jj,jk) )
196               zfm_wk = wi(ji,jj,jk) - ABS( wi(ji,jj,jk) )
197               ztw(ji,jj,jk) =  0.5 * e1e2t(ji,jj) * ( zfp_wk * zwi(ji,jj,jk) + zfm_wk * zwi(ji,jj,jk-1) ) * wmask(ji,jj,jk)
198               zwz(ji,jj,jk) = zwz(ji,jj,jk) + ztw(ji,jj,jk) ! update vertical fluxes
199            END_3D
200            DO_3D_00_00( 1, jpkm1 )
201               pt(ji,jj,jk,jn,Krhs) = pt(ji,jj,jk,jn,Krhs) - ( ztw(ji,jj,jk) - ztw(ji  ,jj  ,jk+1) ) &
202                  &                                        * r1_e1e2t(ji,jj) / e3t(ji,jj,jk,Kmm)
203            END_3D
204            !
205         END IF
206         !               
207         IF( l_trd .OR. l_hst )  THEN             ! trend diagnostics (contribution of upstream fluxes)
208            ztrdx(:,:,:) = zwx(:,:,:)   ;   ztrdy(:,:,:) = zwy(:,:,:)   ;   ztrdz(:,:,:) = zwz(:,:,:)
209         END IF
210         !                             ! "Poleward" heat and salt transports (contribution of upstream fluxes)
211         IF( l_ptr )   zptry(:,:,:) = zwy(:,:,:) 
212         !
213         !        !==  anti-diffusive flux : high order minus low order  ==!
214         !
215         SELECT CASE( kn_fct_h )    !* horizontal anti-diffusive fluxes
216         !
217         CASE(  2  )                   !- 2nd order centered
218            DO_3D_10_10( 1, jpkm1 )
219               zwx(ji,jj,jk) = 0.5_wp * pU(ji,jj,jk) * ( pt(ji,jj,jk,jn,Kmm) + pt(ji+1,jj,jk,jn,Kmm) ) - zwx(ji,jj,jk)
220               zwy(ji,jj,jk) = 0.5_wp * pV(ji,jj,jk) * ( pt(ji,jj,jk,jn,Kmm) + pt(ji,jj+1,jk,jn,Kmm) ) - zwy(ji,jj,jk)
221            END_3D
222            !
223         CASE(  4  )                   !- 4th order centered
224            zltu(:,:,jpk) = 0._wp            ! Bottom value : flux set to zero
225            zltv(:,:,jpk) = 0._wp
226            DO jk = 1, jpkm1                 ! Laplacian
227               DO_2D_10_10
228                  ztu(ji,jj,jk) = ( pt(ji+1,jj  ,jk,jn,Kmm) - pt(ji,jj,jk,jn,Kmm) ) * umask(ji,jj,jk)
229                  ztv(ji,jj,jk) = ( pt(ji  ,jj+1,jk,jn,Kmm) - pt(ji,jj,jk,jn,Kmm) ) * vmask(ji,jj,jk)
230               END_2D
231               DO_2D_00_00
232                  zltu(ji,jj,jk) = (  ztu(ji,jj,jk) + ztu(ji-1,jj,jk)  ) * r1_6
233                  zltv(ji,jj,jk) = (  ztv(ji,jj,jk) + ztv(ji,jj-1,jk)  ) * r1_6
234               END_2D
235            END DO
236            CALL lbc_lnk_multi( 'traadv_fct', zltu, 'T', 1.0_wp , zltv, 'T', 1.0_wp )   ! Lateral boundary cond. (unchanged sgn)
237            !
238            DO_3D_10_10( 1, jpkm1 )
239               zC2t_u = pt(ji,jj,jk,jn,Kmm) + pt(ji+1,jj  ,jk,jn,Kmm)   ! 2 x C2 interpolation of T at u- & v-points
240               zC2t_v = pt(ji,jj,jk,jn,Kmm) + pt(ji  ,jj+1,jk,jn,Kmm)
241               !                                                  ! C4 minus upstream advective fluxes
242               zwx(ji,jj,jk) =  0.5_wp * pU(ji,jj,jk) * ( zC2t_u + zltu(ji,jj,jk) - zltu(ji+1,jj,jk) ) - zwx(ji,jj,jk)
243               zwy(ji,jj,jk) =  0.5_wp * pV(ji,jj,jk) * ( zC2t_v + zltv(ji,jj,jk) - zltv(ji,jj+1,jk) ) - zwy(ji,jj,jk)
244            END_3D
245            !
246         CASE(  41 )                   !- 4th order centered       ==>>   !!gm coding attempt   need to be tested
247            ztu(:,:,jpk) = 0._wp             ! Bottom value : flux set to zero
248            ztv(:,:,jpk) = 0._wp
249            DO_3D_10_10( 1, jpkm1 )
250               ztu(ji,jj,jk) = ( pt(ji+1,jj  ,jk,jn,Kmm) - pt(ji,jj,jk,jn,Kmm) ) * umask(ji,jj,jk)
251               ztv(ji,jj,jk) = ( pt(ji  ,jj+1,jk,jn,Kmm) - pt(ji,jj,jk,jn,Kmm) ) * vmask(ji,jj,jk)
252            END_3D
253            CALL lbc_lnk_multi( 'traadv_fct', ztu, 'U', -1.0_wp , ztv, 'V', -1.0_wp )   ! Lateral boundary cond. (unchanged sgn)
254            !
255            DO_3D_00_00( 1, jpkm1 )
256               zC2t_u = pt(ji,jj,jk,jn,Kmm) + pt(ji+1,jj  ,jk,jn,Kmm)   ! 2 x C2 interpolation of T at u- & v-points (x2)
257               zC2t_v = pt(ji,jj,jk,jn,Kmm) + pt(ji  ,jj+1,jk,jn,Kmm)
258               !                                                  ! C4 interpolation of T at u- & v-points (x2)
259               zC4t_u =  zC2t_u + r1_6 * ( ztu(ji-1,jj  ,jk) - ztu(ji+1,jj  ,jk) )
260               zC4t_v =  zC2t_v + r1_6 * ( ztv(ji  ,jj-1,jk) - ztv(ji  ,jj+1,jk) )
261               !                                                  ! C4 minus upstream advective fluxes
262               zwx(ji,jj,jk) =  0.5_wp * pU(ji,jj,jk) * zC4t_u - zwx(ji,jj,jk)
263               zwy(ji,jj,jk) =  0.5_wp * pV(ji,jj,jk) * zC4t_v - zwy(ji,jj,jk)
264            END_3D
265            !
266         END SELECT
267         !                     
268         SELECT CASE( kn_fct_v )    !* vertical anti-diffusive fluxes (w-masked interior values)
269         !
270         CASE(  2  )                   !- 2nd order centered
271            DO_3D_00_00( 2, jpkm1 )
272               zwz(ji,jj,jk) =  (  pW(ji,jj,jk) * 0.5_wp * ( pt(ji,jj,jk,jn,Kmm) + pt(ji,jj,jk-1,jn,Kmm) )   &
273                  &              - zwz(ji,jj,jk)  ) * wmask(ji,jj,jk)
274            END_3D
275            !
276         CASE(  4  )                   !- 4th order COMPACT
277            CALL interp_4th_cpt( pt(:,:,:,jn,Kmm) , ztw )   ! zwt = COMPACT interpolation of T at w-point
278            DO_3D_00_00( 2, jpkm1 )
279               zwz(ji,jj,jk) = ( pW(ji,jj,jk) * ztw(ji,jj,jk) - zwz(ji,jj,jk) ) * wmask(ji,jj,jk)
280            END_3D
281            !
282         END SELECT
283         IF( ln_linssh ) THEN    ! top ocean value: high order = upstream  ==>>  zwz=0
284            zwz(:,:,1) = 0._wp   ! only ocean surface as interior zwz values have been w-masked
285         ENDIF
286         !         
287         IF ( ll_zAimp ) THEN
288            DO_3D_00_00( 1, jpkm1 )
289               !                             ! total intermediate advective trends
290               ztra = - (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
291                  &      + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
292                  &      + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) ) * r1_e1e2t(ji,jj)
293               ztw(ji,jj,jk)  = zwi(ji,jj,jk) + p2dt * ztra / e3t(ji,jj,jk,Krhs) * tmask(ji,jj,jk)
294            END_3D
295            !
296            CALL tridia_solver( zwdia, zwsup, zwinf, ztw, ztw , 0 )
297            !
298            DO_3D_00_00( 2, jpkm1 )
299               zfp_wk = wi(ji,jj,jk) + ABS( wi(ji,jj,jk) )
300               zfm_wk = wi(ji,jj,jk) - ABS( wi(ji,jj,jk) )
301               zwz(ji,jj,jk) =  zwz(ji,jj,jk) + 0.5 * e1e2t(ji,jj) * ( zfp_wk * ztw(ji,jj,jk) + zfm_wk * ztw(ji,jj,jk-1) ) * wmask(ji,jj,jk)
302            END_3D
303         END IF
304         !
305         CALL lbc_lnk_multi( 'traadv_fct', zwi, 'T', 1.0_wp, zwx, 'U', -1.0_wp , zwy, 'V', -1.0_wp,  zwz, 'W',  1.0_wp )
306         !
307         !        !==  monotonicity algorithm  ==!
308         !
309         CALL nonosc( Kmm, pt(:,:,:,jn,Kbb), zwx, zwy, zwz, zwi, p2dt )
310         !
311         !        !==  final trend with corrected fluxes  ==!
312         !
313         DO_3D_00_00( 1, jpkm1 )
314            ztra = - (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
315               &      + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
316               &      + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) ) * r1_e1e2t(ji,jj)
317            pt(ji,jj,jk,jn,Krhs) = pt(ji,jj,jk,jn,Krhs) + ztra / e3t(ji,jj,jk,Kmm)
318            zwi(ji,jj,jk) = zwi(ji,jj,jk) + p2dt * ztra / e3t(ji,jj,jk,Krhs) * tmask(ji,jj,jk)
319         END_3D
320         !
321         IF ( ll_zAimp ) THEN
322            !
323            ztw(:,:,1) = 0._wp ; ztw(:,:,jpk) = 0._wp
324            DO_3D_00_00( 2, jpkm1 )
325               zfp_wk = wi(ji,jj,jk) + ABS( wi(ji,jj,jk) )
326               zfm_wk = wi(ji,jj,jk) - ABS( wi(ji,jj,jk) )
327               ztw(ji,jj,jk) = - 0.5 * e1e2t(ji,jj) * ( zfp_wk * zwi(ji,jj,jk) + zfm_wk * zwi(ji,jj,jk-1) ) * wmask(ji,jj,jk)
328               zwz(ji,jj,jk) = zwz(ji,jj,jk) + ztw(ji,jj,jk) ! Update vertical fluxes for trend diagnostic
329            END_3D
330            DO_3D_00_00( 1, jpkm1 )
331               pt(ji,jj,jk,jn,Krhs) = pt(ji,jj,jk,jn,Krhs) - ( ztw(ji,jj,jk) - ztw(ji  ,jj  ,jk+1) ) &
332                  &                                        * r1_e1e2t(ji,jj) / e3t(ji,jj,jk,Kmm)
333            END_3D
334         END IF         
335         !
336         IF( l_trd .OR. l_hst ) THEN   ! trend diagnostics // heat/salt transport
337            ztrdx(:,:,:) = ztrdx(:,:,:) + zwx(:,:,:)  ! <<< add anti-diffusive fluxes
338            ztrdy(:,:,:) = ztrdy(:,:,:) + zwy(:,:,:)  !     to upstream fluxes
339            ztrdz(:,:,:) = ztrdz(:,:,:) + zwz(:,:,:)  !
340            !
341            IF( l_trd ) THEN              ! trend diagnostics
342               CALL trd_tra( kt, Kmm, Krhs, cdtype, jn, jptra_xad, ztrdx, pU, pt(:,:,:,jn,Kmm) )
343               CALL trd_tra( kt, Kmm, Krhs, cdtype, jn, jptra_yad, ztrdy, pV, pt(:,:,:,jn,Kmm) )
344               CALL trd_tra( kt, Kmm, Krhs, cdtype, jn, jptra_zad, ztrdz, pW, pt(:,:,:,jn,Kmm) )
345            ENDIF
346            !                             ! heat/salt transport
347            IF( l_hst )   CALL dia_ar5_hst( jn, 'adv', ztrdx(:,:,:), ztrdy(:,:,:) )
348            !
349         ENDIF
350         IF( l_ptr ) THEN              ! "Poleward" transports
351            zptry(:,:,:) = zptry(:,:,:) + zwy(:,:,:)  ! <<< add anti-diffusive fluxes
352            CALL dia_ptr_hst( jn, 'adv', zptry(:,:,:) )
353         ENDIF
354         !
355      END DO                     ! end of tracer loop
356      !
357      IF ( ll_zAimp ) THEN
358         DEALLOCATE( zwdia, zwinf, zwsup )
359      ENDIF
360      IF( l_trd .OR. l_hst ) THEN
361         DEALLOCATE( ztrdx, ztrdy, ztrdz )
362      ENDIF
363      IF( l_ptr ) THEN
364         DEALLOCATE( zptry )
365      ENDIF
366      !
367   END SUBROUTINE tra_adv_fct
368
369
370   SUBROUTINE nonosc( Kmm, pbef, paa, pbb, pcc, paft, p2dt )
371      !!---------------------------------------------------------------------
372      !!                    ***  ROUTINE nonosc  ***
373      !!     
374      !! **  Purpose :   compute monotonic tracer fluxes from the upstream
375      !!       scheme and the before field by a nonoscillatory algorithm
376      !!
377      !! **  Method  :   ... ???
378      !!       warning : pbef and paft must be masked, but the boundaries
379      !!       conditions on the fluxes are not necessary zalezak (1979)
380      !!       drange (1995) multi-dimensional forward-in-time and upstream-
381      !!       in-space based differencing for fluid
382      !!----------------------------------------------------------------------
383      INTEGER                          , INTENT(in   ) ::   Kmm             ! time level index
384      REAL(wp)                         , INTENT(in   ) ::   p2dt            ! tracer time-step
385      REAL(wp), DIMENSION (jpi,jpj,jpk), INTENT(in   ) ::   pbef, paft      ! before & after field
386      REAL(wp), DIMENSION (jpi,jpj,jpk), INTENT(inout) ::   paa, pbb, pcc   ! monotonic fluxes in the 3 directions
387      !
388      INTEGER  ::   ji, jj, jk   ! dummy loop indices
389      INTEGER  ::   ikm1         ! local integer
390      REAL(dp) ::   zpos, zneg, zbt, za, zb, zc, zbig, zrtrn    ! local scalars
391      REAL(dp) ::   zau, zbu, zcu, zav, zbv, zcv, zup, zdo            !   -      -
392      REAL(dp), DIMENSION(jpi,jpj,jpk) :: zbetup, zbetdo, zbup, zbdo
393      !!----------------------------------------------------------------------
394      !
395      zbig  = 1.e+40_dp
396      zrtrn = 1.e-15_dp
397      zbetup(:,:,:) = 0._dp   ;   zbetdo(:,:,:) = 0._dp
398
399      ! Search local extrema
400      ! --------------------
401      ! max/min of pbef & paft with large negative/positive value (-/+zbig) inside land
402      zbup = MAX( pbef * tmask - zbig * ( 1._wp - tmask ),   &
403         &        paft * tmask - zbig * ( 1._wp - tmask )  )
404      zbdo = MIN( pbef * tmask + zbig * ( 1._wp - tmask ),   &
405         &        paft * tmask + zbig * ( 1._wp - tmask )  )
406
407      DO jk = 1, jpkm1
408         ikm1 = MAX(jk-1,1)
409         DO_2D_00_00
410
411            ! search maximum in neighbourhood
412            zup = MAX(  zbup(ji  ,jj  ,jk  ),   &
413               &        zbup(ji-1,jj  ,jk  ), zbup(ji+1,jj  ,jk  ),   &
414               &        zbup(ji  ,jj-1,jk  ), zbup(ji  ,jj+1,jk  ),   &
415               &        zbup(ji  ,jj  ,ikm1), zbup(ji  ,jj  ,jk+1)  )
416
417            ! search minimum in neighbourhood
418            zdo = MIN(  zbdo(ji  ,jj  ,jk  ),   &
419               &        zbdo(ji-1,jj  ,jk  ), zbdo(ji+1,jj  ,jk  ),   &
420               &        zbdo(ji  ,jj-1,jk  ), zbdo(ji  ,jj+1,jk  ),   &
421               &        zbdo(ji  ,jj  ,ikm1), zbdo(ji  ,jj  ,jk+1)  )
422
423            ! positive part of the flux
424            zpos = MAX( 0., paa(ji-1,jj  ,jk  ) ) - MIN( 0., paa(ji  ,jj  ,jk  ) )   &
425               & + MAX( 0., pbb(ji  ,jj-1,jk  ) ) - MIN( 0., pbb(ji  ,jj  ,jk  ) )   &
426               & + MAX( 0., pcc(ji  ,jj  ,jk+1) ) - MIN( 0., pcc(ji  ,jj  ,jk  ) )
427
428            ! negative part of the flux
429            zneg = MAX( 0., paa(ji  ,jj  ,jk  ) ) - MIN( 0., paa(ji-1,jj  ,jk  ) )   &
430               & + MAX( 0., pbb(ji  ,jj  ,jk  ) ) - MIN( 0., pbb(ji  ,jj-1,jk  ) )   &
431               & + MAX( 0., pcc(ji  ,jj  ,jk  ) ) - MIN( 0., pcc(ji  ,jj  ,jk+1) )
432
433            ! up & down beta terms
434            zbt = e1e2t(ji,jj) * e3t(ji,jj,jk,Kmm) / p2dt
435            zbetup(ji,jj,jk) = ( zup            - paft(ji,jj,jk) ) / ( zpos + zrtrn ) * zbt
436            zbetdo(ji,jj,jk) = ( paft(ji,jj,jk) - zdo            ) / ( zneg + zrtrn ) * zbt
437         END_2D
438      END DO
439      CALL lbc_lnk_multi( 'traadv_fct', zbetup, 'T', 1.0_wp , zbetdo, 'T', 1.0_wp )   ! lateral boundary cond. (unchanged sign)
440
441      ! 3. monotonic flux in the i & j direction (paa & pbb)
442      ! ----------------------------------------
443      DO_3D_00_00( 1, jpkm1 )
444         zau = MIN( 1._wp, zbetdo(ji,jj,jk), zbetup(ji+1,jj,jk) )
445         zbu = MIN( 1._wp, zbetup(ji,jj,jk), zbetdo(ji+1,jj,jk) )
446         zcu =       ( 0.5  + SIGN( 0.5_wp , paa(ji,jj,jk) ) )
447         paa(ji,jj,jk) = paa(ji,jj,jk) * ( zcu * zau + ( 1._wp - zcu) * zbu )
448
449         zav = MIN( 1._wp, zbetdo(ji,jj,jk), zbetup(ji,jj+1,jk) )
450         zbv = MIN( 1._wp, zbetup(ji,jj,jk), zbetdo(ji,jj+1,jk) )
451         zcv =       ( 0.5  + SIGN( 0.5_wp , pbb(ji,jj,jk) ) )
452         pbb(ji,jj,jk) = pbb(ji,jj,jk) * ( zcv * zav + ( 1._wp - zcv) * zbv )
453
454! monotonic flux in the k direction, i.e. pcc
455! -------------------------------------------
456         za = MIN( 1., zbetdo(ji,jj,jk+1), zbetup(ji,jj,jk) )
457         zb = MIN( 1., zbetup(ji,jj,jk+1), zbetdo(ji,jj,jk) )
458         zc =       ( 0.5  + SIGN( 0.5_wp , pcc(ji,jj,jk+1) ) )
459         pcc(ji,jj,jk+1) = pcc(ji,jj,jk+1) * ( zc * za + ( 1._wp - zc) * zb )
460      END_3D
461      CALL lbc_lnk_multi( 'traadv_fct', paa, 'U', -1.0_wp , pbb, 'V', -1.0_wp )   ! lateral boundary condition (changed sign)
462      !
463   END SUBROUTINE nonosc
464
465
466   SUBROUTINE interp_4th_cpt_org( pt_in, pt_out )
467      !!----------------------------------------------------------------------
468      !!                  ***  ROUTINE interp_4th_cpt_org  ***
469      !!
470      !! **  Purpose :   Compute the interpolation of tracer at w-point
471      !!
472      !! **  Method  :   4th order compact interpolation
473      !!----------------------------------------------------------------------
474      REAL(wp),DIMENSION(jpi,jpj,jpk), INTENT(in   ) ::   pt_in    ! now tracer fields
475      REAL(wp),DIMENSION(jpi,jpj,jpk), INTENT(  out) ::   pt_out   ! now tracer field interpolated at w-pts
476      !
477      INTEGER :: ji, jj, jk   ! dummy loop integers
478      REAL(wp),DIMENSION(jpi,jpj,jpk) :: zwd, zwi, zws, zwrm, zwt
479      !!----------------------------------------------------------------------
480     
481      DO_3D_11_11( 3, jpkm1 )
482         zwd (ji,jj,jk) = 4._wp
483         zwi (ji,jj,jk) = 1._wp
484         zws (ji,jj,jk) = 1._wp
485         zwrm(ji,jj,jk) = 3._wp * ( pt_in(ji,jj,jk-1) + pt_in(ji,jj,jk) )
486         !
487         IF( tmask(ji,jj,jk+1) == 0._wp) THEN   ! Switch to second order centered at bottom
488            zwd (ji,jj,jk) = 1._wp
489            zwi (ji,jj,jk) = 0._wp
490            zws (ji,jj,jk) = 0._wp
491            zwrm(ji,jj,jk) = 0.5 * ( pt_in(ji,jj,jk-1) + pt_in(ji,jj,jk) )   
492         ENDIF
493      END_3D
494      !
495      jk = 2                                          ! Switch to second order centered at top
496      DO_2D_11_11
497         zwd (ji,jj,jk) = 1._wp
498         zwi (ji,jj,jk) = 0._wp
499         zws (ji,jj,jk) = 0._wp
500         zwrm(ji,jj,jk) = 0.5 * ( pt_in(ji,jj,jk-1) + pt_in(ji,jj,jk) )
501      END_2D
502      !
503      !                       !==  tridiagonal solve  ==!
504      DO_2D_11_11
505         zwt(ji,jj,2) = zwd(ji,jj,2)
506      END_2D
507      DO_3D_11_11( 3, jpkm1 )
508         zwt(ji,jj,jk) = zwd(ji,jj,jk) - zwi(ji,jj,jk) * zws(ji,jj,jk-1) /zwt(ji,jj,jk-1)
509      END_3D
510      !
511      DO_2D_11_11
512         pt_out(ji,jj,2) = zwrm(ji,jj,2)
513      END_2D
514      DO_3D_11_11( 3, jpkm1 )
515         pt_out(ji,jj,jk) = zwrm(ji,jj,jk) - zwi(ji,jj,jk) / zwt(ji,jj,jk-1) *pt_out(ji,jj,jk-1)             
516      END_3D
517
518      DO_2D_11_11
519         pt_out(ji,jj,jpkm1) = pt_out(ji,jj,jpkm1) / zwt(ji,jj,jpkm1)
520      END_2D
521      DO_3DS_11_11( jpk-2, 2, -1 )
522         pt_out(ji,jj,jk) = ( pt_out(ji,jj,jk) - zws(ji,jj,jk) * pt_out(ji,jj,jk+1) ) / zwt(ji,jj,jk)
523      END_3D
524      !   
525   END SUBROUTINE interp_4th_cpt_org
526   
527
528   SUBROUTINE interp_4th_cpt( pt_in, pt_out )
529      !!----------------------------------------------------------------------
530      !!                  ***  ROUTINE interp_4th_cpt  ***
531      !!
532      !! **  Purpose :   Compute the interpolation of tracer at w-point
533      !!
534      !! **  Method  :   4th order compact interpolation
535      !!----------------------------------------------------------------------
536      REAL(wp),DIMENSION(jpi,jpj,jpk), INTENT(in   ) ::   pt_in    ! field at t-point
537      REAL(wp),DIMENSION(jpi,jpj,jpk), INTENT(  out) ::   pt_out   ! field interpolated at w-point
538      !
539      INTEGER ::   ji, jj, jk   ! dummy loop integers
540      INTEGER ::   ikt, ikb     ! local integers
541      REAL(wp),DIMENSION(jpi,jpj,jpk) :: zwd, zwi, zws, zwrm, zwt
542      !!----------------------------------------------------------------------
543      !
544      !                      !==  build the three diagonal matrix & the RHS  ==!
545      !
546      DO_3D_00_00( 3, jpkm1 )
547         zwd (ji,jj,jk) = 3._wp * wmask(ji,jj,jk) + 1._wp                 !       diagonal
548         zwi (ji,jj,jk) =         wmask(ji,jj,jk)                         ! lower diagonal
549         zws (ji,jj,jk) =         wmask(ji,jj,jk)                         ! upper diagonal
550         zwrm(ji,jj,jk) = 3._wp * wmask(ji,jj,jk)                     &   ! RHS
551            &           *       ( pt_in(ji,jj,jk) + pt_in(ji,jj,jk-1) )
552      END_3D
553      !
554!!gm
555!      SELECT CASE( kbc )               !* boundary condition
556!      CASE( np_NH   )   ! Neumann homogeneous at top & bottom
557!      CASE( np_CEN2 )   ! 2nd order centered  at top & bottom
558!      END SELECT
559!!gm 
560      !
561      IF ( ln_isfcav ) THEN            ! set level two values which may not be set in ISF case
562         zwd(:,:,2) = 1._wp  ;  zwi(:,:,2) = 0._wp  ;  zws(:,:,2) = 0._wp  ;  zwrm(:,:,2) = 0._wp
563      END IF
564      !
565      DO_2D_00_00
566         ikt = mikt(ji,jj) + 1            ! w-point below the 1st  wet point
567         ikb = MAX(mbkt(ji,jj), 2)        !     -   above the last wet point
568         !
569         zwd (ji,jj,ikt) = 1._wp          ! top
570         zwi (ji,jj,ikt) = 0._wp
571         zws (ji,jj,ikt) = 0._wp
572         zwrm(ji,jj,ikt) = 0.5_wp * ( pt_in(ji,jj,ikt-1) + pt_in(ji,jj,ikt) )
573         !
574         zwd (ji,jj,ikb) = 1._wp          ! bottom
575         zwi (ji,jj,ikb) = 0._wp
576         zws (ji,jj,ikb) = 0._wp
577         zwrm(ji,jj,ikb) = 0.5_wp * ( pt_in(ji,jj,ikb-1) + pt_in(ji,jj,ikb) )           
578      END_2D
579      !
580      !                       !==  tridiagonal solver  ==!
581      !
582      DO_2D_00_00
583         zwt(ji,jj,2) = zwd(ji,jj,2)
584      END_2D
585      DO_3D_00_00( 3, jpkm1 )
586         zwt(ji,jj,jk) = zwd(ji,jj,jk) - zwi(ji,jj,jk) * zws(ji,jj,jk-1) /zwt(ji,jj,jk-1)
587      END_3D
588      !
589      DO_2D_00_00
590         pt_out(ji,jj,2) = zwrm(ji,jj,2)
591      END_2D
592      DO_3D_00_00( 3, jpkm1 )
593         pt_out(ji,jj,jk) = zwrm(ji,jj,jk) - zwi(ji,jj,jk) / zwt(ji,jj,jk-1) *pt_out(ji,jj,jk-1)             
594      END_3D
595
596      DO_2D_00_00
597         pt_out(ji,jj,jpkm1) = pt_out(ji,jj,jpkm1) / zwt(ji,jj,jpkm1)
598      END_2D
599      DO_3DS_00_00( jpk-2, 2, -1 )
600         pt_out(ji,jj,jk) = ( pt_out(ji,jj,jk) - zws(ji,jj,jk) * pt_out(ji,jj,jk+1) ) / zwt(ji,jj,jk)
601      END_3D
602      !   
603   END SUBROUTINE interp_4th_cpt
604
605
606   SUBROUTINE tridia_solver( pD, pU, pL, pRHS, pt_out , klev )
607      !!----------------------------------------------------------------------
608      !!                  ***  ROUTINE tridia_solver  ***
609      !!
610      !! **  Purpose :   solve a symmetric 3diagonal system
611      !!
612      !! **  Method  :   solve M.t_out = RHS(t)  where M is a tri diagonal matrix ( jpk*jpk )
613      !!     
614      !!             ( D_1 U_1  0   0   0  )( t_1 )   ( RHS_1 )
615      !!             ( L_2 D_2 U_2  0   0  )( t_2 )   ( RHS_2 )
616      !!             (  0  L_3 D_3 U_3  0  )( t_3 ) = ( RHS_3 )
617      !!             (        ...          )( ... )   ( ...  )
618      !!             (  0   0   0  L_k D_k )( t_k )   ( RHS_k )
619      !!     
620      !!        M is decomposed in the product of an upper and lower triangular matrix.
621      !!        The tri-diagonals matrix is given as input 3D arrays:   pD, pU, pL
622      !!        (i.e. the Diagonal, the Upper diagonal, and the Lower diagonal).
623      !!        The solution is pta.
624      !!        The 3d array zwt is used as a work space array.
625      !!----------------------------------------------------------------------
626      REAL(wp),DIMENSION(:,:,:), INTENT(in   ) ::   pD, pU, PL    ! 3-diagonal matrix
627      REAL(wp),DIMENSION(:,:,:), INTENT(in   ) ::   pRHS          ! Right-Hand-Side
628      REAL(wp),DIMENSION(:,:,:), INTENT(  out) ::   pt_out        !!gm field at level=F(klev)
629      INTEGER                  , INTENT(in   ) ::   klev          ! =1 pt_out at w-level
630      !                                                           ! =0 pt at t-level
631      INTEGER ::   ji, jj, jk   ! dummy loop integers
632      INTEGER ::   kstart       ! local indices
633      REAL(wp),DIMENSION(jpi,jpj,jpk) ::   zwt   ! 3D work array
634      !!----------------------------------------------------------------------
635      !
636      kstart =  1  + klev
637      !
638      DO_2D_00_00
639         zwt(ji,jj,kstart) = pD(ji,jj,kstart)
640      END_2D
641      DO_3D_00_00( kstart+1, jpkm1 )
642         zwt(ji,jj,jk) = pD(ji,jj,jk) - pL(ji,jj,jk) * pU(ji,jj,jk-1) /zwt(ji,jj,jk-1)
643      END_3D
644      !
645      DO_2D_00_00
646         pt_out(ji,jj,kstart) = pRHS(ji,jj,kstart)
647      END_2D
648      DO_3D_00_00( kstart+1, jpkm1 )
649         pt_out(ji,jj,jk) = pRHS(ji,jj,jk) - pL(ji,jj,jk) / zwt(ji,jj,jk-1) *pt_out(ji,jj,jk-1)             
650      END_3D
651
652      DO_2D_00_00
653         pt_out(ji,jj,jpkm1) = pt_out(ji,jj,jpkm1) / zwt(ji,jj,jpkm1)
654      END_2D
655      DO_3DS_00_00( jpk-2, kstart, -1 )
656         pt_out(ji,jj,jk) = ( pt_out(ji,jj,jk) - pU(ji,jj,jk) * pt_out(ji,jj,jk+1) ) / zwt(ji,jj,jk)
657      END_3D
658      !
659   END SUBROUTINE tridia_solver
660
661   !!======================================================================
662END MODULE traadv_fct
Note: See TracBrowser for help on using the repository browser.