source: NEMO/branches/2020/dev_r12512_HPC-04_mcastril_Mixed_Precision_implementation/src/OCE/step.F90 @ 13257

Last change on this file since 13257 was 13257, checked in by orioltp, 3 months ago

Updated with trunk at r13245 and small change allocating variables in icb_oce.F90.

  • Property svn:keywords set to Id
File size: 22.7 KB
Line 
1MODULE step
2   !!======================================================================
3   !!                       ***  MODULE step  ***
4   !! Time-stepping   : manager of the ocean, tracer and ice time stepping
5   !!======================================================================
6   !! History :  OPA  !  1991-03  (G. Madec)  Original code
7   !!             -   !  1991-11  (G. Madec)
8   !!             -   !  1992-06  (M. Imbard)  add a first output record
9   !!             -   !  1996-04  (G. Madec)  introduction of dynspg
10   !!             -   !  1996-04  (M.A. Foujols)  introduction of passive tracer
11   !!            8.0  !  1997-06  (G. Madec)  new architecture of call
12   !!            8.2  !  1997-06  (G. Madec, M. Imbard, G. Roullet)  free surface
13   !!             -   !  1999-02  (G. Madec, N. Grima)  hpg implicit
14   !!             -   !  2000-07  (J-M Molines, M. Imbard)  Open Bondary Conditions
15   !!   NEMO     1.0  !  2002-06  (G. Madec)  free form, suppress macro-tasking
16   !!             -   !  2004-08  (C. Talandier) New trends organization
17   !!             -   !  2005-01  (C. Ethe) Add the KPP closure scheme
18   !!             -   !  2005-11  (G. Madec)  Reorganisation of tra and dyn calls
19   !!             -   !  2006-01  (L. Debreu, C. Mazauric)  Agrif implementation
20   !!             -   !  2006-07  (S. Masson)  restart using iom
21   !!            3.2  !  2009-02  (G. Madec, R. Benshila)  reintroduicing z*-coordinate
22   !!             -   !  2009-06  (S. Masson, G. Madec)  TKE restart compatible with key_cpl
23   !!            3.3  !  2010-05  (K. Mogensen, A. Weaver, M. Martin, D. Lea) Assimilation interface
24   !!             -   !  2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase + merge TRC-TRA
25   !!            3.4  !  2011-04  (G. Madec, C. Ethe) Merge of dtatem and dtasal
26   !!            3.6  !  2012-07  (J. Simeon, G. Madec. C. Ethe)  Online coarsening of outputs
27   !!            3.6  !  2014-04  (F. Roquet, G. Madec) New equations of state
28   !!            3.6  !  2014-10  (E. Clementi, P. Oddo) Add Qiao vertical mixing in case of waves
29   !!            3.7  !  2014-10  (G. Madec)  LDF simplication
30   !!             -   !  2014-12  (G. Madec) remove KPP scheme
31   !!             -   !  2015-11  (J. Chanut) free surface simplification (remove filtered free surface)
32   !!            4.0  !  2017-05  (G. Madec)  introduction of the vertical physics manager (zdfphy)
33   !!            4.1  !  2019-08  (A. Coward, D. Storkey) rewrite in preparation for new timestepping scheme
34   !!----------------------------------------------------------------------
35#if defined key_qco
36   !!----------------------------------------------------------------------
37   !!   'key_qco'      EMPTY MODULE      Quasi-Eulerian vertical coordonate
38   !!----------------------------------------------------------------------
39#else
40   !!----------------------------------------------------------------------
41   !!   stp             : OPA system time-stepping
42   !!----------------------------------------------------------------------
43   USE step_oce         ! time stepping definition modules
44   !
45   USE iom              ! xIOs server
46
47   IMPLICIT NONE
48   PRIVATE
49
50   PUBLIC   stp   ! called by nemogcm.F90
51
52   !!----------------------------------------------------------------------
53   !! time level indices
54   !!----------------------------------------------------------------------
55   INTEGER, PUBLIC :: Nbb, Nnn, Naa, Nrhs          !! used by nemo_init
56
57   !!----------------------------------------------------------------------
58   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
59   !! $Id$
60   !! Software governed by the CeCILL license (see ./LICENSE)
61   !!----------------------------------------------------------------------
62CONTAINS
63
64#if defined key_agrif
65   RECURSIVE SUBROUTINE stp( )
66      INTEGER             ::   kstp   ! ocean time-step index
67#else
68   SUBROUTINE stp( kstp )
69      INTEGER, INTENT(in) ::   kstp   ! ocean time-step index
70#endif
71      !!----------------------------------------------------------------------
72      !!                     ***  ROUTINE stp  ***
73      !!
74      !! ** Purpose : - Time stepping of OPA  (momentum and active tracer eqs.)
75      !!              - Time stepping of SI3 (dynamic and thermodynamic eqs.)
76      !!              - Time stepping of TRC  (passive tracer eqs.)
77      !!
78      !! ** Method  : -1- Update forcings and data
79      !!              -2- Update ocean physics
80      !!              -3- Compute the t and s trends
81      !!              -4- Update t and s
82      !!              -5- Compute the momentum trends
83      !!              -6- Update the horizontal velocity
84      !!              -7- Compute the diagnostics variables (rd,N2, hdiv,w)
85      !!              -8- Outputs and diagnostics
86      !!----------------------------------------------------------------------
87      INTEGER ::   ji, jj, jk   ! dummy loop indice
88!!gm kcall can be removed, I guess
89      INTEGER ::   kcall        ! optional integer argument (dom_vvl_sf_nxt)
90      !! ---------------------------------------------------------------------
91#if defined key_agrif
92      IF( nstop > 0 ) RETURN   ! avoid to go further if an error was detected during previous time step (child grid)
93      kstp = nit000 + Agrif_Nb_Step()
94      Kbb_a = Nbb; Kmm_a = Nnn; Krhs_a = Nrhs   ! agrif_oce module copies of time level indices
95      IF( lk_agrif_debug ) THEN
96         IF( Agrif_Root() .and. lwp)   WRITE(*,*) '---'
97         IF(lwp)   WRITE(*,*) 'Grid Number', Agrif_Fixed(),' time step ', kstp, 'int tstep', Agrif_NbStepint()
98      ENDIF
99      IF( kstp == nit000 + 1 )   lk_agrif_fstep = .FALSE.
100# if defined key_iomput
101      IF( Agrif_Nbstepint() == 0 )   CALL iom_swap( cxios_context )
102# endif
103#endif
104      !
105      IF( ln_timing )   CALL timing_start('stp')
106      !
107      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
108      ! model timestep
109      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
110      !
111      IF( l_1st_euler ) THEN 
112         ! start or restart with Euler 1st time-step
113         rDt =  rn_Dt   
114         r1_Dt = 1._wp / rDt
115      ENDIF
116      !
117      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
118      ! update I/O and calendar
119      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
120      IF( kstp == nit000 ) THEN                       ! initialize IOM context (must be done after nemo_init for AGRIF+XIOS+OASIS)
121                             CALL iom_init( cxios_context, ld_closedef=.FALSE. )   ! for model grid (including possible AGRIF zoom)
122         IF( lk_diamlr   )   CALL dia_mlr_iom_init    ! with additional setup for multiple-linear-regression analysis
123                             CALL iom_init_closedef
124         IF( ln_crs      )   CALL iom_init( TRIM(cxios_context)//"_crs" )  ! for coarse grid
125      ENDIF
126      IF( kstp /= nit000 )   CALL day( kstp )         ! Calendar (day was already called at nit000 in day_init)
127                             CALL iom_setkt( kstp - nit000 + 1,      cxios_context          )   ! tell IOM we are at time step kstp
128      IF( ln_crs         )   CALL iom_setkt( kstp - nit000 + 1, TRIM(cxios_context)//"_crs" )   ! tell IOM we are at time step kstp
129
130      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
131      ! Update external forcing (tides, open boundaries, ice shelf interaction and surface boundary condition (including sea-ice)
132      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
133      IF( ln_tide    )   CALL tide_update( kstp )                     ! update tide potential
134      IF( ln_apr_dyn )   CALL sbc_apr ( kstp )                        ! atmospheric pressure (NB: call before bdy_dta which needs ssh_ib)
135      IF( ln_bdy     )   CALL bdy_dta ( kstp, Nnn )                   ! update dynamic & tracer data at open boundaries
136      IF( ln_isf     )   CALL isf_stp ( kstp, Nnn )
137                         CALL sbc     ( kstp, Nbb, Nnn )              ! Sea Boundary Condition (including sea-ice)
138
139      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
140      ! Update stochastic parameters and random T/S fluctuations
141      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
142      IF( ln_sto_eos ) CALL sto_par( kstp )          ! Stochastic parameters
143      IF( ln_sto_eos ) CALL sto_pts( ts(:,:,:,:,Nnn)  )          ! Random T/S fluctuations
144
145      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
146      ! Ocean physics update
147      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
148      !  THERMODYNAMICS
149                         CALL eos_rab( ts(:,:,:,:,Nbb), rab_b, Nnn )       ! before local thermal/haline expension ratio at T-points
150                         CALL eos_rab( ts(:,:,:,:,Nnn), rab_n, Nnn )       ! now    local thermal/haline expension ratio at T-points
151                         CALL bn2    ( ts(:,:,:,:,Nbb), rab_b, rn2b, Nnn ) ! before Brunt-Vaisala frequency
152                         CALL bn2    ( ts(:,:,:,:,Nnn), rab_n, rn2, Nnn  ) ! now    Brunt-Vaisala frequency
153
154      !  VERTICAL PHYSICS
155                         CALL zdf_phy( kstp, Nbb, Nnn, Nrhs )   ! vertical physics update (top/bot drag, avt, avs, avm + MLD)
156
157      !  LATERAL  PHYSICS
158      !
159      IF( l_ldfslp ) THEN                             ! slope of lateral mixing
160                         CALL eos( ts(:,:,:,:,Nbb), rhd, gdept_0(:,:,:) )               ! before in situ density
161
162         IF( ln_zps .AND. .NOT. ln_isfcav)                                    &
163            &            CALL zps_hde    ( kstp, Nnn, jpts, ts(:,:,:,:,Nbb), gtsu, gtsv,  &  ! Partial steps: before horizontal gradient
164            &                                          rhd, gru , grv    )       ! of t, s, rd at the last ocean level
165
166         IF( ln_zps .AND.       ln_isfcav)                                                &
167            &            CALL zps_hde_isf( kstp, Nnn, jpts, ts(:,:,:,:,Nbb), gtsu, gtsv, gtui, gtvi,  &  ! Partial steps for top cell (ISF)
168            &                                          rhd, gru , grv , grui, grvi   )       ! of t, s, rd at the first ocean level
169         IF( ln_traldf_triad ) THEN
170                         CALL ldf_slp_triad( kstp, Nbb, Nnn )             ! before slope for triad operator
171         ELSE     
172                         CALL ldf_slp     ( kstp, rhd, rn2b, Nbb, Nnn )   ! before slope for standard operator
173         ENDIF
174      ENDIF
175      !                                                                        ! eddy diffusivity coeff.
176      IF( l_ldftra_time .OR. l_ldfeiv_time )   CALL ldf_tra( kstp, Nbb, Nnn )  !       and/or eiv coeff.
177      IF( l_ldfdyn_time                    )   CALL ldf_dyn( kstp, Nbb )       ! eddy viscosity coeff.
178
179      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
180      !  Ocean dynamics : hdiv, ssh, e3, u, v, w
181      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
182
183                            CALL ssh_nxt       ( kstp, Nbb, Nnn, ssh, Naa )    ! after ssh (includes call to div_hor)
184      IF( .NOT.ln_linssh )  CALL dom_vvl_sf_nxt( kstp, Nbb, Nnn,      Naa )    ! after vertical scale factors
185                            CALL wzv           ( kstp, Nbb, Nnn, Naa, ww  )    ! now cross-level velocity
186      IF( ln_zad_Aimp )     CALL wAimp         ( kstp,      Nnn           )  ! Adaptive-implicit vertical advection partitioning
187                            CALL eos    ( ts(:,:,:,:,Nnn), rhd, rhop, gdept(:,:,:,Nnn) )  ! now in situ density for hpg computation
188                           
189                           
190                         uu(:,:,:,Nrhs) = 0._wp            ! set dynamics trends to zero
191                         vv(:,:,:,Nrhs) = 0._wp
192
193      IF(  lk_asminc .AND. ln_asmiau .AND. ln_dyninc )   &
194               &         CALL dyn_asm_inc   ( kstp, Nbb, Nnn, uu, vv, Nrhs )  ! apply dynamics assimilation increment
195      IF( ln_bdy     )   CALL bdy_dyn3d_dmp ( kstp, Nbb,      uu, vv, Nrhs )  ! bdy damping trends
196#if defined key_agrif
197      IF(.NOT. Agrif_Root())  & 
198               &         CALL Agrif_Sponge_dyn        ! momentum sponge
199#endif
200                         CALL dyn_adv( kstp, Nbb, Nnn      , uu, vv, Nrhs )  ! advection (VF or FF)   ==> RHS
201                         CALL dyn_vor( kstp,      Nnn      , uu, vv, Nrhs )  ! vorticity              ==> RHS
202                         CALL dyn_ldf( kstp, Nbb, Nnn      , uu, vv, Nrhs )  ! lateral mixing
203      IF( ln_zdfosm  )   CALL dyn_osm( kstp,      Nnn      , uu, vv, Nrhs )  ! OSMOSIS non-local velocity fluxes ==> RHS
204                         CALL dyn_hpg( kstp,      Nnn      , uu, vv, Nrhs )  ! horizontal gradient of Hydrostatic pressure
205                         CALL dyn_spg( kstp, Nbb, Nnn, Nrhs, uu, vv, ssh, uu_b, vv_b, Naa )  ! surface pressure gradient
206
207                                                      ! With split-explicit free surface, since now transports have been updated and ssh(:,:,Nrhs) as well
208      IF( ln_dynspg_ts ) THEN                         ! vertical scale factors and vertical velocity need to be updated
209                            CALL div_hor       ( kstp, Nbb, Nnn )                ! Horizontal divergence  (2nd call in time-split case)
210         IF(.NOT.ln_linssh) CALL dom_vvl_sf_nxt( kstp, Nbb, Nnn, Naa, kcall=2 )  ! after vertical scale factors (update depth average component)
211      ENDIF
212                            CALL dyn_zdf    ( kstp, Nbb, Nnn, Nrhs, uu, vv, Naa  )  ! vertical diffusion
213      IF( ln_dynspg_ts ) THEN                                                       ! vertical scale factors and vertical velocity need to be updated
214                            CALL wzv        ( kstp, Nbb, Nnn, Naa, ww )             ! now cross-level velocity
215         IF( ln_zad_Aimp )  CALL wAimp      ( kstp,      Nnn )                      ! Adaptive-implicit vertical advection partitioning
216      ENDIF
217     
218
219      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
220      ! cool skin
221      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<     
222      IF ( ln_diurnal )  CALL diurnal_layers( kstp )
223     
224      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
225      ! diagnostics and outputs
226      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
227      IF( ln_floats  )   CALL flo_stp   ( kstp, Nbb, Nnn )      ! drifting Floats
228      IF( ln_diacfl  )   CALL dia_cfl   ( kstp,      Nnn )      ! Courant number diagnostics
229                         CALL dia_hth   ( kstp,      Nnn )      ! Thermocline depth (20 degres isotherm depth)
230      IF( ln_diadct  )   CALL dia_dct   ( kstp,      Nnn )      ! Transports
231                         CALL dia_ar5   ( kstp,      Nnn )      ! ar5 diag
232                         CALL dia_ptr   ( kstp,      Nnn )      ! Poleward adv/ldf TRansports diagnostics
233                         CALL dia_wri   ( kstp,      Nnn )      ! ocean model: outputs
234      IF( ln_crs     )   CALL crs_fld   ( kstp,      Nnn )      ! ocean model: online field coarsening & output
235      IF( lk_diadetide ) CALL dia_detide( kstp )                ! Weights computation for daily detiding of model diagnostics
236      IF( lk_diamlr  )   CALL dia_mlr                           ! Update time used in multiple-linear-regression analysis
237     
238#if defined key_top
239      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
240      ! Passive Tracer Model
241      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
242                         CALL trc_stp       ( kstp, Nbb, Nnn, Nrhs, Naa )  ! time-stepping
243#endif
244
245      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
246      ! Active tracers                             
247      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
248                         ts(:,:,:,:,Nrhs) = 0._wp         ! set tracer trends to zero
249
250      IF(  lk_asminc .AND. ln_asmiau .AND. &
251         & ln_trainc )   CALL tra_asm_inc( kstp, Nbb, Nnn, ts, Nrhs )  ! apply tracer assimilation increment
252                         CALL tra_sbc    ( kstp,      Nnn, ts, Nrhs )  ! surface boundary condition
253      IF( ln_traqsr  )   CALL tra_qsr    ( kstp,      Nnn, ts, Nrhs )  ! penetrative solar radiation qsr
254      IF( ln_isf     )   CALL tra_isf    ( kstp,      Nnn, ts, Nrhs )  ! ice shelf heat flux
255      IF( ln_trabbc  )   CALL tra_bbc    ( kstp,      Nnn, ts, Nrhs )  ! bottom heat flux
256      IF( ln_trabbl  )   CALL tra_bbl    ( kstp, Nbb, Nnn, ts, Nrhs )  ! advective (and/or diffusive) bottom boundary layer scheme
257      IF( ln_tradmp  )   CALL tra_dmp    ( kstp, Nbb, Nnn, ts, Nrhs )  ! internal damping trends
258      IF( ln_bdy     )   CALL bdy_tra_dmp( kstp, Nbb,      ts, Nrhs )  ! bdy damping trends
259#if defined key_agrif
260      IF(.NOT. Agrif_Root())  & 
261               &         CALL Agrif_Sponge_tra        ! tracers sponge
262#endif
263                         CALL tra_adv    ( kstp, Nbb, Nnn, ts, Nrhs )  ! hor. + vert. advection ==> RHS
264      IF( ln_zdfosm  )   CALL tra_osm    ( kstp,      Nnn, ts, Nrhs )  ! OSMOSIS non-local tracer fluxes ==> RHS
265      IF( lrst_oce .AND. ln_zdfosm ) &
266           &             CALL osm_rst    ( kstp,      Nnn, 'WRITE'  )  ! write OSMOSIS outputs + ww (so must do here) to restarts
267                         CALL tra_ldf    ( kstp, Nbb, Nnn, ts, Nrhs )  ! lateral mixing
268
269                         CALL tra_zdf    ( kstp, Nbb, Nnn, Nrhs, ts, Naa  )  ! vertical mixing and after tracer fields
270      IF( ln_zdfnpc  )   CALL tra_npc    ( kstp,      Nnn, Nrhs, ts, Naa  )  ! update after fields by non-penetrative convection
271
272      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
273      ! Set boundary conditions, time filter and swap time levels
274      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
275!!jc1: For agrif, it would be much better to finalize tracers/momentum here (e.g. bdy conditions) and move the swap
276!!    (and time filtering) after Agrif update. Then restart would be done after and would contain updated fields.
277!!    If so:
278!!    (i) no need to call agrif update at initialization time
279!!    (ii) no need to update "before" fields
280!!
281!!    Apart from creating new tra_swp/dyn_swp routines, this however:
282!!    (i) makes boundary conditions at initialization time computed from updated fields which is not the case between
283!!    two restarts => restartability issue. One can circumvent this, maybe, by assuming "interface separation",
284!!    e.g. a shift of the feedback interface inside child domain.
285!!    (ii) requires that all restart outputs of updated variables by agrif (e.g. passive tracers/tke/barotropic arrays) are done at the same
286!!    place.
287!!
288!!jc2: dynnxt must be the latest call. e3t(:,:,:,Nbb) are indeed updated in that routine
289                         CALL tra_atf       ( kstp, Nbb, Nnn, Naa, ts )                      ! time filtering of "now" tracer arrays
290                         CALL dyn_atf       ( kstp, Nbb, Nnn, Naa, uu, vv, e3t, e3u, e3v  )  ! time filtering of "now" velocities and scale factors
291                         CALL ssh_atf       ( kstp, Nbb, Nnn, Naa, ssh )                     ! time filtering of "now" sea surface height
292      !
293      ! Swap time levels
294      Nrhs = Nbb
295      Nbb = Nnn
296      Nnn = Naa
297      Naa = Nrhs
298      !
299      IF(.NOT.ln_linssh) CALL dom_vvl_sf_update( kstp, Nbb, Nnn, Naa )  ! recompute vertical scale factors
300      !
301      IF( ln_diahsb  )   CALL dia_hsb       ( kstp, Nbb, Nnn )  ! - ML - global conservation diagnostics
302
303!!gm : This does not only concern the dynamics ==>>> add a new title
304!!gm2: why ouput restart before AGRIF update?
305!!
306!!jc: That would be better, but see comment above
307!!
308      IF( lrst_oce   )   CALL rst_write    ( kstp, Nbb, Nnn )   ! write output ocean restart file
309      IF( ln_sto_eos )   CALL sto_rst_write( kstp )   ! write restart file for stochastic parameters
310
311#if defined key_agrif
312      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
313      ! AGRIF recursive integration
314      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<     
315                         Kbb_a = Nbb; Kmm_a = Nnn; Krhs_a = Nrhs      ! agrif_oce module copies of time level indices
316                         CALL Agrif_Integrate_ChildGrids( stp )       ! allows to finish all the Child Grids before updating
317
318#endif
319      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
320      ! Control
321      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
322                         CALL stp_ctl      ( kstp, Nnn )
323
324#if defined key_agrif
325      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
326      ! AGRIF update
327      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<     
328      IF( Agrif_NbStepint() == 0 .AND. nstop == 0 ) THEN
329                         CALL Agrif_update_all( )                  ! Update all components
330      ENDIF
331
332#endif
333      IF( ln_diaobs .AND. nstop == 0 )  CALL dia_obs( kstp, Nnn )  ! obs-minus-model (assimilation) diags (after dynamics update)
334
335      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
336      ! File manipulation at the end of the first time step
337      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<                         
338      IF( kstp == nit000 ) THEN                          ! 1st time step only
339                                        CALL iom_close( numror )   ! close input  ocean restart file
340         IF(lwm)                        CALL FLUSH    ( numond )   ! flush output namelist oce
341         IF(lwm .AND. numoni /= -1 )    CALL FLUSH    ( numoni )   ! flush output namelist ice (if exist)
342      ENDIF
343
344      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
345      ! Coupled mode
346      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
347      IF( lk_oasis .AND. nstop == 0 )   CALL sbc_cpl_snd( kstp, Nbb, Nnn )     ! coupled mode : field exchanges
348      !
349#if defined key_iomput
350      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
351      ! Finalize contextes if end of simulation or error detected
352      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<                         
353      IF( kstp == nitend .OR. nstop > 0 ) THEN
354                      CALL iom_context_finalize(      cxios_context          ) ! needed for XIOS+AGRIF
355         IF( lrxios ) CALL iom_context_finalize(      crxios_context         )
356         IF( ln_crs ) CALL iom_context_finalize( trim(cxios_context)//"_crs" ) !
357      ENDIF
358#endif
359      !
360      IF( l_1st_euler ) THEN         ! recover Leap-frog timestep
361         rDt = 2._wp * rn_Dt   
362         r1_Dt = 1._wp / rDt
363         l_1st_euler = .FALSE.     
364      ENDIF
365      !
366      IF( ln_timing )   CALL timing_stop('stp')
367      !
368   END SUBROUTINE stp
369   !
370#endif
371   !!======================================================================
372END MODULE step
Note: See TracBrowser for help on using the repository browser.