source: NEMO/branches/2020/dev_r12512_HPC-04_mcastril_Mixed_Precision_implementation/src/TOP/PISCES/P4Z/p4zmeso.F90 @ 13135

Last change on this file since 13135 was 13135, checked in by orioltp, 3 months ago

dev_r12512_HPC-04_mcastril_Mixed_Precision_implementation: merge with trunk@13134, see #2364

  • Property svn:keywords set to Id
File size: 18.1 KB
Line 
1MODULE p4zmeso
2   !!======================================================================
3   !!                         ***  MODULE p4zmeso  ***
4   !! TOP :   PISCES Compute the sources/sinks for mesozooplankton
5   !!======================================================================
6   !! History :   1.0  !  2002     (O. Aumont) Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8   !!             3.4  !  2011-06  (O. Aumont, C. Ethe) Quota model for iron
9   !!----------------------------------------------------------------------
10   !!   p4z_meso       : Compute the sources/sinks for mesozooplankton
11   !!   p4z_meso_init  : Initialization of the parameters for mesozooplankton
12   !!----------------------------------------------------------------------
13   USE oce_trc         ! shared variables between ocean and passive tracers
14   USE trc             ! passive tracers common variables
15   USE sms_pisces      ! PISCES Source Minus Sink variables
16   USE p4zprod         ! production
17   USE prtctl_trc      ! print control for debugging
18   USE iom             ! I/O manager
19
20   IMPLICIT NONE
21   PRIVATE
22
23   PUBLIC   p4z_meso              ! called in p4zbio.F90
24   PUBLIC   p4z_meso_init         ! called in trcsms_pisces.F90
25
26   REAL(wp), PUBLIC ::  part2        !: part of calcite not dissolved in mesozoo guts
27   REAL(wp), PUBLIC ::  xpref2d      !: mesozoo preference for diatoms
28   REAL(wp), PUBLIC ::  xpref2n      !: mesozoo preference for nanophyto
29   REAL(wp), PUBLIC ::  xpref2z      !: mesozoo preference for microzooplankton
30   REAL(wp), PUBLIC ::  xpref2c      !: mesozoo preference for POC
31   REAL(wp), PUBLIC ::  xthresh2zoo  !: zoo feeding threshold for mesozooplankton
32   REAL(wp), PUBLIC ::  xthresh2dia  !: diatoms feeding threshold for mesozooplankton
33   REAL(wp), PUBLIC ::  xthresh2phy  !: nanophyto feeding threshold for mesozooplankton
34   REAL(wp), PUBLIC ::  xthresh2poc  !: poc feeding threshold for mesozooplankton
35   REAL(wp), PUBLIC ::  xthresh2     !: feeding threshold for mesozooplankton
36   REAL(wp), PUBLIC ::  resrat2      !: exsudation rate of mesozooplankton
37   REAL(wp), PUBLIC ::  mzrat2       !: microzooplankton mortality rate
38   REAL(wp), PUBLIC ::  grazrat2     !: maximal mesozoo grazing rate
39   REAL(wp), PUBLIC ::  xkgraz2      !: non assimilated fraction of P by mesozoo
40   REAL(wp), PUBLIC ::  unass2       !: Efficicency of mesozoo growth
41   REAL(wp), PUBLIC ::  sigma2       !: Fraction of mesozoo excretion as DOM
42   REAL(wp), PUBLIC ::  epsher2      !: growth efficiency
43   REAL(wp), PUBLIC ::  epsher2min   !: minimum growth efficiency at high food for grazing 2
44   REAL(wp), PUBLIC ::  grazflux     !: mesozoo flux feeding rate
45
46   !! * Substitutions
47#  include "do_loop_substitute.h90"
48   !!----------------------------------------------------------------------
49   !! NEMO/TOP 4.0 , NEMO Consortium (2018)
50   !! $Id$
51   !! Software governed by the CeCILL license (see ./LICENSE)
52   !!----------------------------------------------------------------------
53CONTAINS
54
55   SUBROUTINE p4z_meso( kt, knt, Kbb, Krhs )
56      !!---------------------------------------------------------------------
57      !!                     ***  ROUTINE p4z_meso  ***
58      !!
59      !! ** Purpose :   Compute the sources/sinks for mesozooplankton
60      !!
61      !! ** Method  : - ???
62      !!---------------------------------------------------------------------
63      INTEGER, INTENT(in) ::   kt, knt   ! ocean time step and ???
64      INTEGER, INTENT(in)  ::  Kbb, Krhs ! time level indices
65      !
66      INTEGER  :: ji, jj, jk
67      REAL(wp) :: zcompadi, zcompaph, zcompapoc, zcompaz, zcompam
68      REAL(wp) :: zgraze2 , zdenom, zdenom2
69      REAL(wp) :: zfact   , zfood, zfoodlim, zproport, zbeta
70      REAL(wp) :: zmortzgoc, zfrac, zfracfe, zratio, zratio2, zfracal, zgrazcal
71      REAL(wp) :: zepsherf, zepshert, zepsherv, zepsherq 
72      REAL(wp) :: zgrarsig, zgraztotc, zgraztotn, zgraztotf
73      REAL(wp) :: zgrarem2, zgrafer2, zgrapoc2, zprcaca, zmortz, zgrasrat, zgrasratn
74      REAL(wp) :: zrespz, ztortz, zgrazd, zgrazz, zgrazpof
75      REAL(wp) :: zgrazn, zgrazpoc, zgraznf, zgrazf
76      REAL(wp) :: zgrazfffp, zgrazfffg, zgrazffep, zgrazffeg
77      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zgrazing2, zfezoo2, zz2ligprod
78      CHARACTER (len=25) :: charout
79      !!---------------------------------------------------------------------
80      !
81      IF( ln_timing )   CALL timing_start('p4z_meso')
82      !
83      DO_3D_11_11( 1, jpkm1 )
84         zcompam   = MAX( ( tr(ji,jj,jk,jpmes,Kbb) - 1.e-9 ), 0.e0 )
85         zfact     = xstep * tgfunc2(ji,jj,jk) * zcompam
86
87         !  Respiration rates of both zooplankton
88         !  -------------------------------------
89         zrespz    = resrat2 * zfact * ( tr(ji,jj,jk,jpmes,Kbb) / ( xkmort + tr(ji,jj,jk,jpmes,Kbb) )  &
90         &           + 3. * nitrfac(ji,jj,jk) )
91
92         !  Zooplankton mortality. A square function has been selected with
93         !  no real reason except that it seems to be more stable and may mimic predation
94         !  ---------------------------------------------------------------
95         ztortz    = mzrat2 * 1.e6 * zfact * tr(ji,jj,jk,jpmes,Kbb)  * (1. - nitrfac(ji,jj,jk) )
96         !
97         zcompadi  = MAX( ( tr(ji,jj,jk,jpdia,Kbb) - xthresh2dia ), 0.e0 )
98         zcompaz   = MAX( ( tr(ji,jj,jk,jpzoo,Kbb) - xthresh2zoo ), 0.e0 )
99         zcompapoc = MAX( ( tr(ji,jj,jk,jppoc,Kbb) - xthresh2poc ), 0.e0 )
100         ! Size effect of nanophytoplankton on grazing : the smaller it is, the less prone
101         ! it is to predation by mesozooplankton
102         ! -------------------------------------------------------------------------------
103         zcompaph  = MAX( ( tr(ji,jj,jk,jpphy,Kbb) - xthresh2phy ), 0.e0 ) &
104            &      * MIN(1., MAX( 0., ( quotan(ji,jj,jk) - 0.2) / 0.3 ) )
105
106         !   Mesozooplankton grazing
107         !   ------------------------
108         zfood     = xpref2d * zcompadi + xpref2z * zcompaz + xpref2n * zcompaph + xpref2c * zcompapoc 
109         zfoodlim  = MAX( 0., zfood - MIN( 0.5 * zfood, xthresh2 ) )
110         zdenom    = zfoodlim / ( xkgraz2 + zfoodlim )
111         zdenom2   = zdenom / ( zfood + rtrn )
112         zgraze2   = grazrat2 * xstep * tgfunc2(ji,jj,jk) * tr(ji,jj,jk,jpmes,Kbb) * (1. - nitrfac(ji,jj,jk)) 
113
114         zgrazd    = zgraze2  * xpref2d  * zcompadi  * zdenom2 
115         zgrazz    = zgraze2  * xpref2z  * zcompaz   * zdenom2 
116         zgrazn    = zgraze2  * xpref2n  * zcompaph  * zdenom2 
117         zgrazpoc  = zgraze2  * xpref2c  * zcompapoc * zdenom2 
118
119         zgraznf   = zgrazn   * tr(ji,jj,jk,jpnfe,Kbb) / ( tr(ji,jj,jk,jpphy,Kbb) + rtrn)
120         zgrazf    = zgrazd   * tr(ji,jj,jk,jpdfe,Kbb) / ( tr(ji,jj,jk,jpdia,Kbb) + rtrn)
121         zgrazpof  = zgrazpoc * tr(ji,jj,jk,jpsfe,Kbb) / ( tr(ji,jj,jk,jppoc,Kbb) + rtrn)
122
123         !  Mesozooplankton flux feeding on GOC
124         !  ----------------------------------
125         zgrazffeg = grazflux  * xstep * wsbio4(ji,jj,jk)      &
126         &           * tgfunc2(ji,jj,jk) * tr(ji,jj,jk,jpgoc,Kbb) * tr(ji,jj,jk,jpmes,Kbb) &
127         &           * (1. - nitrfac(ji,jj,jk))
128         zgrazfffg = zgrazffeg * tr(ji,jj,jk,jpbfe,Kbb) / (tr(ji,jj,jk,jpgoc,Kbb) + rtrn)
129         zgrazffep = grazflux  * xstep *  wsbio3(ji,jj,jk)     &
130         &           * tgfunc2(ji,jj,jk) * tr(ji,jj,jk,jppoc,Kbb) * tr(ji,jj,jk,jpmes,Kbb) &
131         &           * (1. - nitrfac(ji,jj,jk))
132         zgrazfffp = zgrazffep * tr(ji,jj,jk,jpsfe,Kbb) / (tr(ji,jj,jk,jppoc,Kbb) + rtrn)
133         !
134         zgraztotc = zgrazd + zgrazz + zgrazn + zgrazpoc + zgrazffep + zgrazffeg
135         ! Compute the proportion of filter feeders
136         zproport  = (zgrazffep + zgrazffeg)/(rtrn + zgraztotc)
137         ! Compute fractionation of aggregates. It is assumed that
138         ! diatoms based aggregates are more prone to fractionation
139         ! since they are more porous (marine snow instead of fecal pellets)
140         zratio    = tr(ji,jj,jk,jpgsi,Kbb) / ( tr(ji,jj,jk,jpgoc,Kbb) + rtrn )
141         zratio2   = zratio * zratio
142         zfrac     = zproport * grazflux  * xstep * wsbio4(ji,jj,jk)      &
143         &          * tr(ji,jj,jk,jpgoc,Kbb) * tr(ji,jj,jk,jpmes,Kbb)          &
144         &          * ( 0.2 + 3.8 * zratio2 / ( 1.**2 + zratio2 ) )
145         zfracfe   = zfrac * tr(ji,jj,jk,jpbfe,Kbb) / (tr(ji,jj,jk,jpgoc,Kbb) + rtrn)
146
147         zgrazffep = zproport * zgrazffep
148         zgrazffeg = zproport * zgrazffeg
149         zgrazfffp = zproport * zgrazfffp
150         zgrazfffg = zproport * zgrazfffg
151         zgraztotc = zgrazd + zgrazz + zgrazn + zgrazpoc + zgrazffep + zgrazffeg
152         zgraztotn = zgrazd * quotad(ji,jj,jk) + zgrazz + zgrazn * quotan(ji,jj,jk)   &
153         &   + zgrazpoc + zgrazffep + zgrazffeg
154         zgraztotf = zgrazf + zgraznf + zgrazz * ferat3 + zgrazpof + zgrazfffp + zgrazfffg
155
156         ! Total grazing ( grazing by microzoo is already computed in p4zmicro )
157         zgrazing2(ji,jj,jk) = zgraztotc
158
159         ! Mesozooplankton efficiency.
160         ! We adopt a formulation proposed by Mitra et al. (2007)
161         ! The gross growth efficiency is controled by the most limiting nutrient.
162         ! Growth is also further decreased when the food quality is poor. This is currently
163         ! hard coded : it can be decreased by up to 50% (zepsherq)
164         ! GGE can also be decreased when food quantity is high, zepsherf (Montagnes and
165         ! Fulton, 2012)
166         ! -----------------------------------------------------------------------------------
167         zgrasrat  =  ( zgraztotf + rtrn )/ ( zgraztotc + rtrn )
168         zgrasratn =  ( zgraztotn + rtrn )/ ( zgraztotc + rtrn )
169         zepshert  = MIN( 1., zgrasratn, zgrasrat / ferat3)
170         zbeta     = MAX(0., (epsher2 - epsher2min) )
171         zepsherf  = epsher2min + zbeta / ( 1.0 + 0.04E6 * 12. * zfood * zbeta ) 
172         zepsherq  = 0.5 + (1.0 - 0.5) * zepshert * ( 1.0 + 1.0 ) / ( zepshert + 1.0 )
173         zepsherv  = zepsherf * zepshert * zepsherq 
174
175         zgrarem2  = zgraztotc * ( 1. - zepsherv - unass2 ) &
176         &         + ( 1. - epsher2 - unass2 ) / ( 1. - epsher2 ) * ztortz
177         zgrafer2  = zgraztotc * MAX( 0. , ( 1. - unass2 ) * zgrasrat - ferat3 * zepsherv )    &
178         &         + ferat3 * ( ( 1. - epsher2 - unass2 ) /( 1. - epsher2 ) * ztortz )
179         zgrapoc2  = zgraztotc * unass2
180
181
182         !   Update the arrays TRA which contain the biological sources and sinks
183         zgrarsig  = zgrarem2 * sigma2
184         tr(ji,jj,jk,jppo4,Krhs) = tr(ji,jj,jk,jppo4,Krhs) + zgrarsig
185         tr(ji,jj,jk,jpnh4,Krhs) = tr(ji,jj,jk,jpnh4,Krhs) + zgrarsig
186         tr(ji,jj,jk,jpdoc,Krhs) = tr(ji,jj,jk,jpdoc,Krhs) + zgrarem2 - zgrarsig
187         !
188         IF( ln_ligand ) THEN
189            tr(ji,jj,jk,jplgw,Krhs) = tr(ji,jj,jk,jplgw,Krhs) + (zgrarem2 - zgrarsig) * ldocz
190            zz2ligprod(ji,jj,jk) = (zgrarem2 - zgrarsig) * ldocz
191         ENDIF
192         !
193         tr(ji,jj,jk,jpoxy,Krhs) = tr(ji,jj,jk,jpoxy,Krhs) - o2ut * zgrarsig
194         tr(ji,jj,jk,jpfer,Krhs) = tr(ji,jj,jk,jpfer,Krhs) + zgrafer2
195         zfezoo2(ji,jj,jk)   = zgrafer2
196         tr(ji,jj,jk,jpdic,Krhs) = tr(ji,jj,jk,jpdic,Krhs) + zgrarsig
197         tr(ji,jj,jk,jptal,Krhs) = tr(ji,jj,jk,jptal,Krhs) + rno3 * zgrarsig             
198
199         zmortz = ztortz + zrespz
200         zmortzgoc = unass2 / ( 1. - epsher2 ) * ztortz + zrespz
201         tr(ji,jj,jk,jpmes,Krhs) = tr(ji,jj,jk,jpmes,Krhs) - zmortz + zepsherv * zgraztotc 
202         tr(ji,jj,jk,jpdia,Krhs) = tr(ji,jj,jk,jpdia,Krhs) - zgrazd
203         tr(ji,jj,jk,jpzoo,Krhs) = tr(ji,jj,jk,jpzoo,Krhs) - zgrazz
204         tr(ji,jj,jk,jpphy,Krhs) = tr(ji,jj,jk,jpphy,Krhs) - zgrazn
205         tr(ji,jj,jk,jpnch,Krhs) = tr(ji,jj,jk,jpnch,Krhs) - zgrazn * tr(ji,jj,jk,jpnch,Kbb) / ( tr(ji,jj,jk,jpphy,Kbb) + rtrn )
206         tr(ji,jj,jk,jpdch,Krhs) = tr(ji,jj,jk,jpdch,Krhs) - zgrazd * tr(ji,jj,jk,jpdch,Kbb) / ( tr(ji,jj,jk,jpdia,Kbb) + rtrn )
207         tr(ji,jj,jk,jpdsi,Krhs) = tr(ji,jj,jk,jpdsi,Krhs) - zgrazd * tr(ji,jj,jk,jpdsi,Kbb) / ( tr(ji,jj,jk,jpdia,Kbb) + rtrn )
208         tr(ji,jj,jk,jpgsi,Krhs) = tr(ji,jj,jk,jpgsi,Krhs) + zgrazd * tr(ji,jj,jk,jpdsi,Kbb) / ( tr(ji,jj,jk,jpdia,Kbb) + rtrn )
209         tr(ji,jj,jk,jpnfe,Krhs) = tr(ji,jj,jk,jpnfe,Krhs) - zgraznf
210         tr(ji,jj,jk,jpdfe,Krhs) = tr(ji,jj,jk,jpdfe,Krhs) - zgrazf
211
212         tr(ji,jj,jk,jppoc,Krhs) = tr(ji,jj,jk,jppoc,Krhs) - zgrazpoc - zgrazffep + zfrac
213         prodpoc(ji,jj,jk) = prodpoc(ji,jj,jk) + zfrac
214         conspoc(ji,jj,jk) = conspoc(ji,jj,jk) - zgrazpoc - zgrazffep
215         tr(ji,jj,jk,jpgoc,Krhs) = tr(ji,jj,jk,jpgoc,Krhs) + zmortzgoc - zgrazffeg + zgrapoc2 - zfrac
216         prodgoc(ji,jj,jk) = prodgoc(ji,jj,jk) + zmortzgoc + zgrapoc2
217         consgoc(ji,jj,jk) = consgoc(ji,jj,jk) - zgrazffeg - zfrac
218         tr(ji,jj,jk,jpsfe,Krhs) = tr(ji,jj,jk,jpsfe,Krhs) - zgrazpof - zgrazfffp + zfracfe
219         tr(ji,jj,jk,jpbfe,Krhs) = tr(ji,jj,jk,jpbfe,Krhs) + ferat3 * zmortzgoc - zgrazfffg     &
220           &                + zgraztotf * unass2 - zfracfe
221         zfracal = tr(ji,jj,jk,jpcal,Kbb) / (tr(ji,jj,jk,jppoc,Kbb) + tr(ji,jj,jk,jpgoc,Kbb) + rtrn )
222         zgrazcal = (zgrazffeg + zgrazpoc) * (1. - part2) * zfracal
223         ! calcite production
224         zprcaca = xfracal(ji,jj,jk) * zgrazn
225         prodcal(ji,jj,jk) = prodcal(ji,jj,jk) + zprcaca  ! prodcal=prodcal(nanophy)+prodcal(microzoo)+prodcal(mesozoo)
226         !
227         zprcaca = part2 * zprcaca
228         tr(ji,jj,jk,jpdic,Krhs) = tr(ji,jj,jk,jpdic,Krhs) + zgrazcal - zprcaca
229         tr(ji,jj,jk,jptal,Krhs) = tr(ji,jj,jk,jptal,Krhs) - 2. * ( zgrazcal + zprcaca )
230         tr(ji,jj,jk,jpcal,Krhs) = tr(ji,jj,jk,jpcal,Krhs) - zgrazcal + zprcaca
231      END_3D
232      !
233      IF( lk_iomput .AND. knt == nrdttrc ) THEN
234        CALL iom_put( "PCAL"  , prodcal(:,:,:) * 1.e+3  * rfact2r * tmask(:,:,:) )  !  Calcite production
235        IF( iom_use("GRAZ2") ) THEN  !   Total grazing of phyto by zooplankton
236           zgrazing2(:,:,jpk) = 0._wp ;  CALL iom_put( "GRAZ2" , zgrazing2(:,:,:) * 1.e+3  * rfact2r * tmask(:,:,:) ) 
237         ENDIF
238         IF( iom_use("FEZOO2") ) THEN 
239           zfezoo2 (:,:,jpk) = 0._wp ; CALL iom_put( "FEZOO2", zfezoo2(:,:,:) * 1e9 * 1.e+3 * rfact2r * tmask(:,:,:) )
240         ENDIF
241         IF( ln_ligand ) THEN
242            zz2ligprod(:,:,jpk) = 0._wp ; CALL iom_put( "LPRODZ2", zz2ligprod(:,:,:) * 1e9 * 1.e+3 * rfact2r * tmask(:,:,:)  )
243         ENDIF
244      ENDIF
245      !
246      IF(sn_cfctl%l_prttrc)   THEN  ! print mean trends (used for debugging)
247        WRITE(charout, FMT="('meso')")
248        CALL prt_ctl_trc_info(charout)
249        CALL prt_ctl_trc(tab4d=tr(:,:,:,:,Krhs), mask=tmask, clinfo=ctrcnm)
250      ENDIF
251      !
252      IF( ln_timing )   CALL timing_stop('p4z_meso')
253      !
254   END SUBROUTINE p4z_meso
255
256
257   SUBROUTINE p4z_meso_init
258      !!----------------------------------------------------------------------
259      !!                  ***  ROUTINE p4z_meso_init  ***
260      !!
261      !! ** Purpose :   Initialization of mesozooplankton parameters
262      !!
263      !! ** Method  :   Read the nampismes namelist and check the parameters
264      !!      called at the first timestep (nittrc000)
265      !!
266      !! ** input   :   Namelist nampismes
267      !!----------------------------------------------------------------------
268      INTEGER ::   ios   ! Local integer
269      !
270      NAMELIST/namp4zmes/ part2, grazrat2, resrat2, mzrat2, xpref2n, xpref2d, xpref2z,   &
271         &                xpref2c, xthresh2dia, xthresh2phy, xthresh2zoo, xthresh2poc, &
272         &                xthresh2, xkgraz2, epsher2, epsher2min, sigma2, unass2, grazflux
273      !!----------------------------------------------------------------------
274      !
275      IF(lwp) THEN
276         WRITE(numout,*) 
277         WRITE(numout,*) 'p4z_meso_init : Initialization of mesozooplankton parameters'
278         WRITE(numout,*) '~~~~~~~~~~~~~'
279      ENDIF
280      !
281      READ  ( numnatp_ref, namp4zmes, IOSTAT = ios, ERR = 901)
282901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namp4zmes in reference namelist' )
283      READ  ( numnatp_cfg, namp4zmes, IOSTAT = ios, ERR = 902 )
284902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namp4zmes in configuration namelist' )
285      IF(lwm) WRITE( numonp, namp4zmes )
286      !
287      IF(lwp) THEN                         ! control print
288         WRITE(numout,*) '   Namelist : namp4zmes'
289         WRITE(numout,*) '      part of calcite not dissolved in mesozoo guts  part2        =', part2
290         WRITE(numout,*) '      mesozoo preference for phyto                   xpref2n      =', xpref2n
291         WRITE(numout,*) '      mesozoo preference for diatoms                 xpref2d      =', xpref2d
292         WRITE(numout,*) '      mesozoo preference for zoo                     xpref2z      =', xpref2z
293         WRITE(numout,*) '      mesozoo preference for poc                     xpref2c      =', xpref2c
294         WRITE(numout,*) '      microzoo feeding threshold  for mesozoo        xthresh2zoo  =', xthresh2zoo
295         WRITE(numout,*) '      diatoms feeding threshold  for mesozoo         xthresh2dia  =', xthresh2dia
296         WRITE(numout,*) '      nanophyto feeding threshold for mesozoo        xthresh2phy  =', xthresh2phy
297         WRITE(numout,*) '      poc feeding threshold for mesozoo              xthresh2poc  =', xthresh2poc
298         WRITE(numout,*) '      feeding threshold for mesozooplankton          xthresh2     =', xthresh2
299         WRITE(numout,*) '      exsudation rate of mesozooplankton             resrat2      =', resrat2
300         WRITE(numout,*) '      mesozooplankton mortality rate                 mzrat2       =', mzrat2
301         WRITE(numout,*) '      maximal mesozoo grazing rate                   grazrat2     =', grazrat2
302         WRITE(numout,*) '      mesozoo flux feeding rate                      grazflux     =', grazflux
303         WRITE(numout,*) '      non assimilated fraction of P by mesozoo       unass2       =', unass2
304         WRITE(numout,*) '      Efficiency of Mesozoo growth                   epsher2      =', epsher2
305         WRITE(numout,*) '      Minimum Efficiency of Mesozoo growth           epsher2min  =', epsher2min
306         WRITE(numout,*) '      Fraction of mesozoo excretion as DOM           sigma2       =', sigma2
307         WRITE(numout,*) '      half sturation constant for grazing 2          xkgraz2      =', xkgraz2
308      ENDIF
309      !
310   END SUBROUTINE p4z_meso_init
311
312   !!======================================================================
313END MODULE p4zmeso
Note: See TracBrowser for help on using the repository browser.