source: NEMO/branches/2020/dev_r12512_HPC-04_mcastril_Mixed_Precision_implementation/tests/STATION_ASF/MY_SRC/sbcssm.F90 @ 13135

Last change on this file since 13135 was 13135, checked in by orioltp, 3 months ago

dev_r12512_HPC-04_mcastril_Mixed_Precision_implementation: merge with trunk@13134, see #2364

File size: 15.6 KB
Line 
1MODULE sbcssm
2   !!======================================================================
3   !!                       ***  MODULE  sbcssm  ***
4   !! Off-line : interpolation of the physical fields
5   !!======================================================================
6   !! History :  3.4  ! 2012-03 (S. Alderson)  original code
7   !!----------------------------------------------------------------------
8
9   !!----------------------------------------------------------------------
10   !!   sbc_ssm_init  : initialization, namelist read, and SAVEs control
11   !!   sbc_ssm       : Interpolation of the fields
12   !!----------------------------------------------------------------------
13   USE oce            ! ocean dynamics and tracers variables
14   USE c1d            ! 1D configuration: lk_c1d
15   USE dom_oce        ! ocean domain: variables
16   USE sbc_oce        ! surface module: variables
17   USE phycst         ! physical constants
18   USE eosbn2         ! equation of state - Brunt Vaisala frequency
19   USE lbclnk         ! ocean lateral boundary conditions (or mpp link)
20   !
21   USE in_out_manager ! I/O manager
22   USE iom            ! I/O library
23   USE lib_mpp        ! distributed memory computing library
24   USE prtctl         ! print control
25   USE fldread        ! read input fields
26   USE timing         ! Timing
27
28   IMPLICIT NONE
29   PRIVATE
30
31   PUBLIC   sbc_ssm_init   ! called by sbc_init
32   PUBLIC   sbc_ssm        ! called by sbc
33
34   CHARACTER(len=100) ::   cn_dir        ! Root directory for location of ssm files
35   LOGICAL            ::   ln_3d_uve     ! specify whether input velocity data is 3D
36   LOGICAL            ::   ln_read_frq   ! specify whether we must read frq or not
37
38   LOGICAL            ::   l_sasread     ! Ice intilisation: =T read a file ; =F anaytical initilaistion
39   LOGICAL            ::   l_initdone = .false.
40   INTEGER     ::   nfld_3d
41   INTEGER     ::   nfld_2d
42
43   INTEGER     ::   jf_tem         ! index of temperature
44   INTEGER     ::   jf_sal         ! index of salinity
45   INTEGER     ::   jf_usp         ! index of u velocity component
46   INTEGER     ::   jf_vsp         ! index of v velocity component
47   INTEGER     ::   jf_ssh         ! index of sea surface height
48   INTEGER     ::   jf_e3t         ! index of first T level thickness
49   INTEGER     ::   jf_frq         ! index of fraction of qsr absorbed in the 1st T level
50
51   TYPE(FLD), ALLOCATABLE, DIMENSION(:) :: sf_ssm_3d  ! structure of input fields (file information, fields read)
52   TYPE(FLD), ALLOCATABLE, DIMENSION(:) :: sf_ssm_2d  ! structure of input fields (file information, fields read)
53
54   !!----------------------------------------------------------------------
55   !! NEMO/SAS 4.0 , NEMO Consortium (2018)
56   !! $Id: sbcssm.F90 12615 2020-03-26 15:18:49Z laurent $
57   !! Software governed by the CeCILL license (see ./LICENSE)
58   !!----------------------------------------------------------------------
59CONTAINS
60
61   SUBROUTINE sbc_ssm( kt, Kbb, Kmm )
62      !!----------------------------------------------------------------------
63      !!                  ***  ROUTINE sbc_ssm  ***
64      !!
65      !! ** Purpose :  Prepares dynamics and physics fields from a NEMO run
66      !!               for an off-line simulation using surface processes only
67      !!
68      !! ** Method : calculates the position of data
69      !!             - interpolates data if needed
70      !!----------------------------------------------------------------------
71      INTEGER, INTENT(in) ::   kt   ! ocean time-step index
72      INTEGER, INTENT(in) ::   Kbb, Kmm   ! ocean time level indices
73      ! (not needed for SAS but needed to keep a consistent interface in sbcmod.F90)
74      !
75      INTEGER  ::   ji, jj     ! dummy loop indices
76      REAL(wp) ::   ztinta     ! ratio applied to after  records when doing time interpolation
77      REAL(wp) ::   ztintb     ! ratio applied to before records when doing time interpolation
78      !!----------------------------------------------------------------------
79      !
80      IF( ln_timing )   CALL timing_start( 'sbc_ssm')
81
82      IF ( l_sasread ) THEN
83         IF( nfld_3d > 0 ) CALL fld_read( kt, 1, sf_ssm_3d )      !==   read data at kt time step   ==!
84         IF( nfld_2d > 0 ) CALL fld_read( kt, 1, sf_ssm_2d )      !==   read data at kt time step   ==!
85         !
86         IF( ln_3d_uve ) THEN
87            IF( .NOT. ln_linssh ) THEN
88               e3t_m(:,:) = sf_ssm_3d(jf_e3t)%fnow(:,:,1) * tmask(:,:,1) ! vertical scale factor
89            ELSE
90               e3t_m(:,:) = e3t_0(:,:,1)                                 ! vertical scale factor
91            ENDIF
92            ssu_m(:,:) = sf_ssm_3d(jf_usp)%fnow(:,:,1) * umask(:,:,1)    ! u-velocity
93            ssv_m(:,:) = sf_ssm_3d(jf_vsp)%fnow(:,:,1) * vmask(:,:,1)    ! v-velocity
94         ELSE
95            IF( .NOT. ln_linssh ) THEN
96               e3t_m(:,:) = sf_ssm_2d(jf_e3t)%fnow(:,:,1) * tmask(:,:,1) ! vertical scale factor
97            ELSE
98               e3t_m(:,:) = e3t_0(:,:,1)                                 ! vertical scale factor
99            ENDIF
100            ssu_m(:,:) = sf_ssm_2d(jf_usp)%fnow(:,:,1) * umask(:,:,1)    ! u-velocity
101            ssv_m(:,:) = sf_ssm_2d(jf_vsp)%fnow(:,:,1) * vmask(:,:,1)    ! v-velocity
102         ENDIF
103         !
104         sst_m(:,:) = sf_ssm_2d(jf_tem)%fnow(:,:,1) * tmask(:,:,1)    ! temperature
105         sss_m(:,:) = sf_ssm_2d(jf_sal)%fnow(:,:,1) * tmask(:,:,1)    ! salinity
106         ssh_m(:,:) = sf_ssm_2d(jf_ssh)%fnow(:,:,1) * tmask(:,:,1)    ! sea surface height
107         IF( ln_read_frq ) THEN
108            frq_m(:,:) = sf_ssm_2d(jf_frq)%fnow(:,:,1) * tmask(:,:,1) ! solar penetration
109         ELSE
110            frq_m(:,:) = 1._wp
111         ENDIF
112      ELSE
113         sss_m(:,:) = 35._wp                             ! =35. to obtain a physical value for the freezing point
114         CALL eos_fzp( sss_m(:,:), sst_m(:,:) )          ! sst_m is set at the freezing point
115         ssu_m(:,:) = 0._wp
116         ssv_m(:,:) = 0._wp
117         ssh_m(:,:) = 0._wp
118         IF( .NOT. ln_linssh ) e3t_m(:,:) = e3t_0(:,:,1) !clem: necessary at least for sas2D
119         frq_m(:,:) = 1._wp                              !              - -
120         ssh  (:,:,Kmm) = 0._wp                              !              - -
121      ENDIF
122
123      IF ( nn_ice == 1 ) THEN
124         ts(:,:,1,jp_tem,Kmm) = sst_m(:,:)
125         ts(:,:,1,jp_sal,Kmm) = sss_m(:,:)
126         ts(:,:,1,jp_tem,Kbb) = sst_m(:,:)
127         ts(:,:,1,jp_sal,Kbb) = sss_m(:,:)
128      ENDIF
129      uu (:,:,1,Kbb) = ssu_m(:,:)
130      vv (:,:,1,Kbb) = ssv_m(:,:)
131
132      IF(sn_cfctl%l_prtctl) THEN            ! print control
133         CALL prt_ctl(tab2d_1=sst_m, clinfo1=' sst_m   - : ', mask1=tmask   )
134         CALL prt_ctl(tab2d_1=sss_m, clinfo1=' sss_m   - : ', mask1=tmask   )
135         CALL prt_ctl(tab2d_1=ssu_m, clinfo1=' ssu_m   - : ', mask1=umask   )
136         CALL prt_ctl(tab2d_1=ssv_m, clinfo1=' ssv_m   - : ', mask1=vmask   )
137         CALL prt_ctl(tab2d_1=ssh_m, clinfo1=' ssh_m   - : ', mask1=tmask   )
138         IF( .NOT.ln_linssh )   CALL prt_ctl(tab2d_1=ssh_m, clinfo1=' e3t_m   - : ', mask1=tmask   )
139         IF( ln_read_frq    )   CALL prt_ctl(tab2d_1=frq_m, clinfo1=' frq_m   - : ', mask1=tmask   )
140      ENDIF
141      !
142      IF( l_initdone ) THEN          !   Mean value at each nn_fsbc time-step   !
143         CALL iom_put( 'ssu_m', ssu_m )
144         CALL iom_put( 'ssv_m', ssv_m )
145         CALL iom_put( 'sst_m', sst_m )
146         CALL iom_put( 'sss_m', sss_m )
147         CALL iom_put( 'ssh_m', ssh_m )
148         IF( .NOT.ln_linssh )   CALL iom_put( 'e3t_m', e3t_m )
149         IF( ln_read_frq    )   CALL iom_put( 'frq_m', frq_m )
150      ENDIF
151      !
152      IF( ln_timing )   CALL timing_stop( 'sbc_ssm')
153      !
154   END SUBROUTINE sbc_ssm
155
156
157   SUBROUTINE sbc_ssm_init( Kbb, Kmm )
158      !!----------------------------------------------------------------------
159      !!                  ***  ROUTINE sbc_ssm_init  ***
160      !!
161      !! ** Purpose :   Initialisation of sea surface mean data
162      !!----------------------------------------------------------------------
163      INTEGER, INTENT(in) ::   Kbb, Kmm   ! ocean time level indices
164      ! (not needed for SAS but needed to keep a consistent interface in sbcmod.F90)
165      INTEGER  :: ierr, ierr0, ierr1, ierr2, ierr3   ! return error code
166      INTEGER  :: ifpr                               ! dummy loop indice
167      INTEGER  :: inum, idv, idimv, jpm              ! local integer
168      INTEGER  ::   ios                              ! Local integer output status for namelist read
169      !!
170      CHARACTER(len=100)                     ::  cn_dir       ! Root directory for location of core files
171      TYPE(FLD_N), ALLOCATABLE, DIMENSION(:) ::  slf_3d       ! array of namelist information on the fields to read
172      TYPE(FLD_N), ALLOCATABLE, DIMENSION(:) ::  slf_2d       ! array of namelist information on the fields to read
173      TYPE(FLD_N) ::   sn_tem, sn_sal                     ! information about the fields to be read
174      TYPE(FLD_N) ::   sn_usp, sn_vsp
175      TYPE(FLD_N) ::   sn_ssh, sn_e3t, sn_frq
176      !!
177      NAMELIST/namsbc_sas/ l_sasread, cn_dir, ln_3d_uve, ln_read_frq,   &
178         &                 sn_tem, sn_sal, sn_usp, sn_vsp, sn_ssh, sn_e3t, sn_frq
179      !!----------------------------------------------------------------------
180      !
181      IF( ln_rstart .AND. nn_components == jp_iam_sas )   RETURN
182      !
183      IF(lwp) THEN
184         WRITE(numout,*)
185         WRITE(numout,*) 'sbc_ssm_init : sea surface mean data initialisation '
186         WRITE(numout,*) '~~~~~~~~~~~~ '
187      ENDIF
188      !
189      READ  ( numnam_ref, namsbc_sas, IOSTAT = ios, ERR = 901)
190901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namsbc_sas in reference namelist' )
191      READ  ( numnam_cfg, namsbc_sas, IOSTAT = ios, ERR = 902 )
192902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namsbc_sas in configuration namelist' )
193      IF(lwm) WRITE ( numond, namsbc_sas )
194      !
195      IF(lwp) THEN                              ! Control print
196         WRITE(numout,*) '   Namelist namsbc_sas'
197         WRITE(numout,*) '      Initialisation using an input file                                 l_sasread   = ', l_sasread
198         WRITE(numout,*) '      Are we supplying a 3D u,v and e3 field                             ln_3d_uve   = ', ln_3d_uve
199         WRITE(numout,*) '      Are we reading frq (fraction of qsr absorbed in the 1st T level)   ln_read_frq = ', ln_read_frq
200      ENDIF
201      !
202      !! switch off stuff that isn't sensible with a standalone module
203      !! note that we need sbc_ssm called first in sbc
204      !
205      IF( ln_apr_dyn ) THEN
206         IF( lwp ) WRITE(numout,*) '         ==>>>   No atmospheric gradient needed with StandAlone Surface scheme'
207         ln_apr_dyn = .FALSE.
208      ENDIF
209      IF( ln_rnf ) THEN
210         IF( lwp ) WRITE(numout,*) '         ==>>>   No runoff needed with StandAlone Surface scheme'
211         ln_rnf = .FALSE.
212      ENDIF
213      IF( ln_ssr ) THEN
214         IF( lwp ) WRITE(numout,*) '         ==>>>   No surface relaxation needed with StandAlone Surface scheme'
215         ln_ssr = .FALSE.
216      ENDIF
217      IF( nn_fwb > 0 ) THEN
218         IF( lwp ) WRITE(numout,*) '         ==>>>   No freshwater budget adjustment needed with StandAlone Surface scheme'
219         nn_fwb = 0
220      ENDIF
221
222      !
223      IF( l_sasread ) THEN                       ! store namelist information in an array
224         !
225         !! following code is a bit messy, but distinguishes between when u,v are 3d arrays and
226         !! when we have other 3d arrays that we need to read in
227         !! so if a new field is added i.e. jf_new, just give it the next integer in sequence
228         !! for the corresponding dimension (currently if ln_3d_uve is true, 4 for 2d and 3 for 3d,
229         !! alternatively if ln_3d_uve is false, 6 for 2d and 1 for 3d), reset nfld_3d, nfld_2d,
230         !! and the rest of the logic should still work
231         !
232         jf_tem = 1   ;   jf_ssh = 3   ! default 2D fields index
233         jf_sal = 2   ;   jf_frq = 4   !
234         !
235         IF( ln_3d_uve ) THEN
236            jf_usp = 1   ;   jf_vsp = 2   ;   jf_e3t = 3     ! define 3D fields index
237            nfld_3d  = 2 + COUNT( (/.NOT.ln_linssh/) )       ! number of 3D fields to read
238            nfld_2d  = 3 + COUNT( (/ln_read_frq/) )          ! number of 2D fields to read
239         ELSE
240            jf_usp = 4   ;   jf_e3t = 6                      ! update 2D fields index
241            jf_vsp = 5   ;   jf_frq = 6 + COUNT( (/.NOT.ln_linssh/) )
242            !
243            nfld_3d  = 0                                     ! no 3D fields to read
244            nfld_2d  = 5 + COUNT( (/.NOT.ln_linssh/) ) + COUNT( (/ln_read_frq/) )    ! number of 2D fields to read
245         ENDIF
246         !
247         IF( nfld_3d > 0 ) THEN
248            ALLOCATE( slf_3d(nfld_3d), STAT=ierr )         ! set slf structure
249            IF( ierr > 0 ) THEN
250               CALL ctl_stop( 'sbc_ssm_init: unable to allocate slf 3d structure' )   ;   RETURN
251            ENDIF
252            slf_3d(jf_usp) = sn_usp
253            slf_3d(jf_vsp) = sn_vsp
254            IF( .NOT.ln_linssh )   slf_3d(jf_e3t) = sn_e3t
255         ENDIF
256         !
257         IF( nfld_2d > 0 ) THEN
258            ALLOCATE( slf_2d(nfld_2d), STAT=ierr )         ! set slf structure
259            IF( ierr > 0 ) THEN
260               CALL ctl_stop( 'sbc_ssm_init: unable to allocate slf 2d structure' )   ;   RETURN
261            ENDIF
262            slf_2d(jf_tem) = sn_tem   ;   slf_2d(jf_sal) = sn_sal   ;   slf_2d(jf_ssh) = sn_ssh
263            IF( ln_read_frq )   slf_2d(jf_frq) = sn_frq
264            IF( .NOT. ln_3d_uve ) THEN
265               slf_2d(jf_usp) = sn_usp ; slf_2d(jf_vsp) = sn_vsp
266               IF( .NOT.ln_linssh )   slf_2d(jf_e3t) = sn_e3t
267            ENDIF
268         ENDIF
269         !
270         ierr1 = 0    ! default definition if slf_?d(ifpr)%ln_tint = .false.
271         IF( nfld_3d > 0 ) THEN
272            ALLOCATE( sf_ssm_3d(nfld_3d), STAT=ierr )         ! set sf structure
273            IF( ierr > 0 ) THEN
274               CALL ctl_stop( 'sbc_ssm_init: unable to allocate sf structure' )   ;   RETURN
275            ENDIF
276            DO ifpr = 1, nfld_3d
277               ALLOCATE( sf_ssm_3d(ifpr)%fnow(jpi,jpj,jpk)    , STAT=ierr0 )
278               IF( slf_3d(ifpr)%ln_tint )   ALLOCATE( sf_ssm_3d(ifpr)%fdta(jpi,jpj,jpk,2)  , STAT=ierr1 )
279               IF( ierr0 + ierr1 > 0 ) THEN
280                  CALL ctl_stop( 'sbc_ssm_init : unable to allocate sf_ssm_3d array structure' )   ;   RETURN
281               ENDIF
282            END DO
283            !                                         ! fill sf with slf_i and control print
284            CALL fld_fill( sf_ssm_3d, slf_3d, cn_dir, 'sbc_ssm_init', '3D Data in file', 'namsbc_ssm' )
285         ENDIF
286         !
287         IF( nfld_2d > 0 ) THEN
288            ALLOCATE( sf_ssm_2d(nfld_2d), STAT=ierr )         ! set sf structure
289            IF( ierr > 0 ) THEN
290               CALL ctl_stop( 'sbc_ssm_init: unable to allocate sf 2d structure' )   ;   RETURN
291            ENDIF
292            DO ifpr = 1, nfld_2d
293               ALLOCATE( sf_ssm_2d(ifpr)%fnow(jpi,jpj,1)    , STAT=ierr0 )
294               IF( slf_2d(ifpr)%ln_tint )   ALLOCATE( sf_ssm_2d(ifpr)%fdta(jpi,jpj,1,2)  , STAT=ierr1 )
295               IF( ierr0 + ierr1 > 0 ) THEN
296                  CALL ctl_stop( 'sbc_ssm_init : unable to allocate sf_ssm_2d array structure' )   ;   RETURN
297               ENDIF
298            END DO
299            !
300            CALL fld_fill( sf_ssm_2d, slf_2d, cn_dir, 'sbc_ssm_init', '2D Data in file', 'namsbc_ssm' )
301         ENDIF
302         !
303         IF( nfld_3d > 0 )   DEALLOCATE( slf_3d, STAT=ierr )
304         IF( nfld_2d > 0 )   DEALLOCATE( slf_2d, STAT=ierr )
305         !
306      ENDIF
307      !
308      CALL sbc_ssm( nit000, Kbb, Kmm )   ! need to define ss?_m arrays used in iceistate
309      l_initdone = .TRUE.
310      !
311   END SUBROUTINE sbc_ssm_init
312
313   !!======================================================================
314END MODULE sbcssm
Note: See TracBrowser for help on using the repository browser.