source: NEMO/branches/2020/dev_r12512_HPC-04_mcastril_Mixed_Precision_implementation/tests/STATION_ASF/MY_SRC/stpctl.F90 @ 13135

Last change on this file since 13135 was 13135, checked in by orioltp, 3 months ago

dev_r12512_HPC-04_mcastril_Mixed_Precision_implementation: merge with trunk@13134, see #2364

File size: 15.2 KB
Line 
1MODULE stpctl
2   !!======================================================================
3   !!                       ***  MODULE  stpctl  ***
4   !! Ocean run control :  gross check of the ocean time stepping
5   !!                      version for STATION_ASF test-case
6   !!======================================================================
7   !! History :  OPA  ! 1991-03  (G. Madec) Original code
8   !!            6.0  ! 1992-06  (M. Imbard)
9   !!            8.0  ! 1997-06  (A.M. Treguier)
10   !!   NEMO     1.0  ! 2002-06  (G. Madec)  F90: Free form and module
11   !!            2.0  ! 2009-07  (G. Madec)  Add statistic for time-spliting
12   !!            3.7  ! 2016-09  (G. Madec)  Remove solver
13   !!            4.0  ! 2017-04  (G. Madec)  regroup global communications
14   !!----------------------------------------------------------------------
15
16   !!----------------------------------------------------------------------
17   !!   stp_ctl      : Control the run
18   !!----------------------------------------------------------------------
19   USE dom_oce         ! ocean space and time domain variables
20   USE sbc_oce         ! surface fluxes and stuff
21   !
22   USE diawri          ! Standard run outputs       (dia_wri_state routine)
23   USE in_out_manager  ! I/O manager
24   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
25   USE lib_mpp         ! distributed memory computing
26   !
27   USE netcdf          ! NetCDF library
28   IMPLICIT NONE
29   PRIVATE
30
31   PUBLIC stp_ctl           ! routine called by step.F90
32
33   INTEGER                ::   nrunid   ! netcdf file id
34   INTEGER, DIMENSION(3)  ::   nvarid   ! netcdf variable id
35   !!----------------------------------------------------------------------
36   !! NEMO/SAS 4.0 , NEMO Consortium (2018)
37   !! $Id: stpctl.F90 10603 2019-01-29 11:18:09Z acc $
38   !! Software governed by the CeCILL license (see ./LICENSE)
39   !!----------------------------------------------------------------------
40CONTAINS
41
42   SUBROUTINE stp_ctl( kt, Kmm )
43      !!----------------------------------------------------------------------
44      !!                    ***  ROUTINE stp_ctl  ***
45      !!                     
46      !! ** Purpose :   Control the run
47      !!
48      !! ** Method  : - Save the time step in numstp
49      !!              - Print it each 50 time steps
50      !!              - Stop the run IF problem encountered by setting nstop > 0
51      !!                Problems checked: wind stress module  max larger than 5 N/m^2
52      !!                                  non-solar heat flux max larger than 2000 W/m^2
53      !!                                  Evaporation-Precip  max larger than 1.E-3 kg/m^2/s
54      !!
55      !! ** Actions :   "time.step" file = last ocean time-step
56      !!                "run.stat"  file = run statistics
57      !!                 nstop indicator sheared among all local domain
58      !!----------------------------------------------------------------------
59      INTEGER, INTENT(in   ) ::   kt       ! ocean time-step index
60      INTEGER, INTENT(in   ) ::   Kmm      ! ocean time level index
61      !!
62      INTEGER                         ::   ji                                    ! dummy loop indices
63      INTEGER                         ::   idtime, istatus
64      INTEGER , DIMENSION(4)          ::   iareasum, iareamin, iareamax
65      INTEGER , DIMENSION(3,3)        ::   iloc                                  ! min/max loc indices
66      REAL(wp)                        ::   zzz                                   ! local real
67      REAL(wp), DIMENSION(4)          ::   zmax, zmaxlocal
68      LOGICAL                         ::   ll_wrtstp, ll_colruns, ll_wrtruns
69      LOGICAL, DIMENSION(jpi,jpj)     ::   llmsk
70      CHARACTER(len=20)               ::   clname
71      !!----------------------------------------------------------------------
72      IF( nstop > 0 .AND. ngrdstop > -1 )   RETURN   !   stpctl was already called by a child grid
73      !
74      ll_wrtstp  = ( MOD( kt-nit000, sn_cfctl%ptimincr ) == 0 ) .OR. ( kt == nitend )
75      ll_colruns = ll_wrtstp .AND. sn_cfctl%l_runstat .AND. jpnij > 1 
76      ll_wrtruns = ( ll_colruns .OR. jpnij == 1 ) .AND. lwm
77      !
78      IF( kt == nit000 ) THEN
79         !
80         IF( lwp ) THEN
81            WRITE(numout,*)
82            WRITE(numout,*) 'stp_ctl : time-stepping control'
83            WRITE(numout,*) '~~~~~~~'
84         ENDIF
85         !                                ! open time.step    ascii file, done only by 1st subdomain
86         IF( lwm )   CALL ctl_opn( numstp, 'time.step', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, numout, lwp, narea )
87         !
88         IF( ll_wrtruns ) THEN
89            !                             ! open run.stat     ascii file, done only by 1st subdomain
90            CALL ctl_opn( numrun, 'run.stat', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, numout, lwp, narea )
91            !                             ! open run.stat.nc netcdf file, done only by 1st subdomain
92            clname = 'run.stat.nc'
93            IF( .NOT. Agrif_Root() )   clname = TRIM(Agrif_CFixed())//"_"//TRIM(clname)
94            istatus = NF90_CREATE( TRIM(clname), NF90_CLOBBER, nrunid )
95            istatus = NF90_DEF_DIM( nrunid, 'time', NF90_UNLIMITED, idtime )
96            istatus = NF90_DEF_VAR( nrunid, 'tau_max', NF90_DOUBLE, (/ idtime /), nvarid(1) )
97            istatus = NF90_DEF_VAR( nrunid, 'qns_max', NF90_DOUBLE, (/ idtime /), nvarid(2) )
98            istatus = NF90_DEF_VAR( nrunid, 'emp_max', NF90_DOUBLE, (/ idtime /), nvarid(3) )
99            istatus = NF90_ENDDEF(nrunid)
100         ENDIF
101         !   
102      ENDIF
103      !
104      !                                   !==              write current time step              ==!
105      !                                   !==  done only by 1st subdomain at writting timestep  ==!
106      IF( lwm .AND. ll_wrtstp ) THEN
107         WRITE ( numstp, '(1x, i8)' )   kt
108         REWIND( numstp )
109      ENDIF
110      !                                   !==            test of local extrema           ==!
111      !                                   !==  done by all processes at every time step  ==!
112      llmsk(:,:) = tmask(:,:,1) == 1._wp
113      zmax(1) = MAXVAL(     taum(:,:)   , mask = llmsk )   ! max wind stress module
114      zmax(2) = MAXVAL( ABS( qns(:,:) ) , mask = llmsk )   ! max non-solar heat flux
115      zmax(3) = MAXVAL( ABS( emp(:,:) ) , mask = llmsk )   ! max E-P
116      zmax(4) = REAL( nstop, wp )                                     ! stop indicator
117      !                                   !==               get global extrema             ==!
118      !                                   !==  done by all processes if writting run.stat  ==!
119      IF( ll_colruns ) THEN
120         zmaxlocal(:) = zmax(:)
121         CALL mpp_max( "stpctl", zmax )          ! max over the global domain
122         nstop = NINT( zmax(4) )                 ! update nstop indicator (now sheared among all local domains)
123      ENDIF
124      !                                   !==              write "run.stat" files              ==!
125      !                                   !==  done only by 1st subdomain at writting timestep  ==!
126      IF( ll_wrtruns ) THEN
127         WRITE(numrun,9500) kt, zmax(1), zmax(2), zmax(3)
128         istatus = NF90_PUT_VAR( nrunid, nvarid(1), (/ zmax(1)/), (/kt/), (/1/) )
129         istatus = NF90_PUT_VAR( nrunid, nvarid(2), (/ zmax(2)/), (/kt/), (/1/) )
130         istatus = NF90_PUT_VAR( nrunid, nvarid(3), (/ zmax(3)/), (/kt/), (/1/) )
131         IF( kt == nitend ) istatus = NF90_CLOSE(nrunid)
132      END IF
133      !                                   !==               error handling               ==!
134      !                                   !==  done by all processes at every time step  ==!
135      !
136      IF(   zmax(1) >    5._wp .OR.   &                   ! too large wind stress         ( > 5 N/m^2 )
137         &  zmax(2) > 2000._wp .OR.   &                   ! too large non-solar heat flux ( > 2000 W/m^2 )
138         &  zmax(3) > 1.E-3_wp .OR.   &                   ! too large net freshwater flux ( > 1.E-3 kg/m^2/s )
139         &  ISNAN( zmax(1) + zmax(2) + zmax(3) ) .OR.   &               ! NaN encounter in the tests
140         &  ABS(   zmax(1) + zmax(2) + zmax(3) ) > HUGE(1._wp) ) THEN   ! Infinity encounter in the tests
141         !
142         iloc(:,:) = 0
143         IF( ll_colruns ) THEN   ! zmax is global, so it is the same on all subdomains -> no dead lock with mpp_maxloc
144            ! first: close the netcdf file, so we can read it
145            IF( lwm .AND. kt /= nitend )   istatus = NF90_CLOSE(nrunid)
146            ! get global loc on the min/max
147            CALL mpp_maxloc( 'stpctl',    taum(:,:)  , tmask(:,:,1), zzz, iloc(1:2,1) )   ! mpp_maxloc ok if mask = F
148            CALL mpp_maxloc( 'stpctl',ABS( qns(:,:) ), tmask(:,:,1), zzz, iloc(1:2,2) )
149            CALL mpp_minloc( 'stpctl',ABS( emp(:,:) ), tmask(:,:,1), zzz, iloc(1:2,3) )
150            ! find which subdomain has the max.
151            iareamin(:) = jpnij+1   ;   iareamax(:) = 0   ;   iareasum(:) = 0
152            DO ji = 1, 4
153               IF( zmaxlocal(ji) == zmax(ji) ) THEN
154                  iareamin(ji) = narea   ;   iareamax(ji) = narea   ;   iareasum(ji) = 1
155               ENDIF
156            END DO
157            CALL mpp_min( "stpctl", iareamin )         ! min over the global domain
158            CALL mpp_max( "stpctl", iareamax )         ! max over the global domain
159            CALL mpp_sum( "stpctl", iareasum )         ! sum over the global domain
160         ELSE                    ! find local min and max locations:
161            ! if we are here, this means that the subdomain contains some oce points -> no need to test the mask used in maxloc
162            iloc(1:2,1) = MAXLOC(     taum(:,:)  , mask = llmsk ) + (/ nimpp - 1, njmpp - 1/)
163            iloc(1:2,2) = MAXLOC( ABS( qns(:,:) ), mask = llmsk ) + (/ nimpp - 1, njmpp - 1/)
164            iloc(1:2,3) = MINLOC( ABS( emp(:,:) ), mask = llmsk ) + (/ nimpp - 1, njmpp - 1/)
165            iareamin(:) = narea   ;   iareamax(:) = narea   ;   iareasum(:) = 1         ! this is local information
166         ENDIF
167         !
168         WRITE(ctmp1,*) ' stp_ctl: |tau_mod| > 5 N/m2  or  |qns| > 2000 W/m2  or |emp| > 1.E-3 or  NaN encounter in the tests'
169         CALL wrt_line( ctmp2, kt, '|tau| max',  zmax(1), iloc(:,1), iareasum(1), iareamin(1), iareamax(1) )
170         CALL wrt_line( ctmp3, kt, '|qns| max',  zmax(2), iloc(:,2), iareasum(2), iareamin(2), iareamax(2) )
171         CALL wrt_line( ctmp4, kt, 'emp   max',  zmax(3), iloc(:,3), iareasum(3), iareamin(3), iareamax(3) )
172         IF( Agrif_Root() ) THEN
173            WRITE(ctmp6,*) '      ===> output of last computed fields in output.abort* files'
174         ELSE
175            WRITE(ctmp6,*) '      ===> output of last computed fields in '//TRIM(Agrif_CFixed())//'_output.abort* files'
176         ENDIF
177         !
178         CALL dia_wri_state( Kmm, 'output.abort' )     ! create an output.abort file
179         !
180         IF( ll_colruns .or. jpnij == 1 ) THEN   ! all processes synchronized -> use lwp to print in opened ocean.output files
181            IF(lwp) THEN   ;   CALL ctl_stop( ctmp1, ' ', ctmp2, ctmp3, ctmp4, ctmp5, ' ', ctmp6 )
182            ELSE           ;   nstop = MAX(1, nstop)   ! make sure nstop > 0 (automatically done when calling ctl_stop)
183            ENDIF
184         ELSE                                    ! only mpi subdomains with errors are here -> STOP now
185            CALL ctl_stop( 'STOP', ctmp1, ' ', ctmp2, ctmp3, ctmp4, ctmp5, ' ', ctmp6 )
186         ENDIF
187         !
188      ENDIF
189      !
190      IF( nstop > 0 ) THEN                                                  ! an error was detected and we did not abort yet...
191         ngrdstop = Agrif_Fixed()                                           ! store which grid got this error
192         IF( .NOT. ll_colruns .AND. jpnij > 1 )   CALL ctl_stop( 'STOP' )   ! we must abort here to avoid MPI deadlock
193      ENDIF
194      !
1959500  FORMAT(' it :', i8, '    tau_max: ', D23.16, ' |qns|_max: ', D23.16,' |emp|_max: ', D23.16)
196      !
197   END SUBROUTINE stp_ctl
198
199
200   SUBROUTINE wrt_line( cdline, kt, cdprefix, pval, kloc, ksum, kmin, kmax )
201      !!----------------------------------------------------------------------
202      !!                     ***  ROUTINE wrt_line  ***
203      !!
204      !! ** Purpose :   write information line
205      !!
206      !!----------------------------------------------------------------------
207      CHARACTER(len=*),      INTENT(  out) ::   cdline
208      CHARACTER(len=*),      INTENT(in   ) ::   cdprefix
209      REAL(wp),              INTENT(in   ) ::   pval
210      INTEGER, DIMENSION(3), INTENT(in   ) ::   kloc
211      INTEGER,               INTENT(in   ) ::   kt, ksum, kmin, kmax
212      !
213      CHARACTER(len=80) ::   clsuff
214      CHARACTER(len=9 ) ::   clkt, clsum, clmin, clmax
215      CHARACTER(len=9 ) ::   cli, clj, clk
216      CHARACTER(len=1 ) ::   clfmt
217      CHARACTER(len=4 ) ::   cl4   ! needed to be able to compile with Agrif, I don't know why
218      INTEGER           ::   ifmtk
219      !!----------------------------------------------------------------------
220      WRITE(clkt , '(i9)') kt
221     
222      WRITE(clfmt, '(i1)') INT(LOG10(REAL(jpnij  ,wp))) + 1     ! how many digits to we need to write ? (we decide max = 9)
223      !!! WRITE(clsum, '(i'//clfmt//')') ksum                   ! this is creating a compilation error with AGRIF
224      cl4 = '(i'//clfmt//')'   ;   WRITE(clsum, cl4) ksum
225      WRITE(clfmt, '(i1)') INT(LOG10(REAL(MAX(1,jpnij-1),wp))) + 1    ! how many digits to we need to write ? (we decide max = 9)
226      cl4 = '(i'//clfmt//')'   ;   WRITE(clmin, cl4) kmin-1
227                                   WRITE(clmax, cl4) kmax-1
228      !
229      WRITE(clfmt, '(i1)') INT(LOG10(REAL(jpiglo,wp))) + 1      ! how many digits to we need to write jpiglo? (we decide max = 9)
230      cl4 = '(i'//clfmt//')'   ;   WRITE(cli, cl4) kloc(1)      ! this is ok with AGRIF
231      WRITE(clfmt, '(i1)') INT(LOG10(REAL(jpjglo,wp))) + 1      ! how many digits to we need to write jpjglo? (we decide max = 9)
232      cl4 = '(i'//clfmt//')'   ;   WRITE(clj, cl4) kloc(2)      ! this is ok with AGRIF
233      !
234      IF( ksum == 1 ) THEN   ;   WRITE(clsuff,9100) TRIM(clmin)
235      ELSE                   ;   WRITE(clsuff,9200) TRIM(clsum), TRIM(clmin), TRIM(clmax)
236      ENDIF
237      IF(kloc(3) == 0) THEN
238         ifmtk = INT(LOG10(REAL(jpk,wp))) + 1                   ! how many digits to we need to write jpk? (we decide max = 9)
239         clk = REPEAT(' ', ifmtk)                               ! create the equivalent in blank string
240         WRITE(cdline,9300) TRIM(ADJUSTL(clkt)), TRIM(ADJUSTL(cdprefix)), pval, TRIM(cli), TRIM(clj), clk(1:ifmtk), TRIM(clsuff)
241      ELSE
242         WRITE(clfmt, '(i1)') INT(LOG10(REAL(jpk,wp))) + 1      ! how many digits to we need to write jpk? (we decide max = 9)
243         !!! WRITE(clk, '(i'//clfmt//')') kloc(3)               ! this is creating a compilation error with AGRIF
244         cl4 = '(i'//clfmt//')'   ;   WRITE(clk, cl4) kloc(3)   ! this is ok with AGRIF
245         WRITE(cdline,9400) TRIM(ADJUSTL(clkt)), TRIM(ADJUSTL(cdprefix)), pval, TRIM(cli), TRIM(clj),    TRIM(clk), TRIM(clsuff)
246      ENDIF
247      !
2489100  FORMAT('MPI rank ', a)
2499200  FORMAT('found in ', a, ' MPI tasks, spread out among ranks ', a, ' to ', a)
2509300  FORMAT('kt ', a, ' ', a, ' ', 1pg11.4, ' at i j   ', a, ' ', a, ' ', a, ' ', a)
2519400  FORMAT('kt ', a, ' ', a, ' ', 1pg11.4, ' at i j k ', a, ' ', a, ' ', a, ' ', a)
252      !
253   END SUBROUTINE wrt_line
254
255
256   !!======================================================================
257END MODULE stpctl
Note: See TracBrowser for help on using the repository browser.