source: NEMO/branches/2020/dev_r12558_HPC-08_epico_Extra_Halo/src/OCE/DOM/dommsk.F90 @ 13247

Last change on this file since 13247 was 13247, checked in by francesca, 4 months ago

dev_r12558_HPC-08_epico_Extra_Halo: merge with trunk@13227, see #2366

  • Property svn:keywords set to Id
File size: 11.8 KB
Line 
1MODULE dommsk
2   !!======================================================================
3   !!                       ***  MODULE dommsk   ***
4   !! Ocean initialization : domain land/sea mask
5   !!======================================================================
6   !! History :  OPA  ! 1987-07  (G. Madec)  Original code
7   !!            6.0  ! 1993-03  (M. Guyon)  symetrical conditions (M. Guyon)
8   !!            7.0  ! 1996-01  (G. Madec)  suppression of common work arrays
9   !!             -   ! 1996-05  (G. Madec)  mask computed from tmask
10   !!            8.0  ! 1997-02  (G. Madec)  mesh information put in domhgr.F
11   !!            8.1  ! 1997-07  (G. Madec)  modification of kbat and fmask
12   !!             -   ! 1998-05  (G. Roullet)  free surface
13   !!            8.2  ! 2000-03  (G. Madec)  no slip accurate
14   !!             -   ! 2001-09  (J.-M. Molines)  Open boundaries
15   !!   NEMO     1.0  ! 2002-08  (G. Madec)  F90: Free form and module
16   !!             -   ! 2005-11  (V. Garnier) Surface pressure gradient organization
17   !!            3.2  ! 2009-07  (R. Benshila) Suppression of rigid-lid option
18   !!            3.6  ! 2015-05  (P. Mathiot) ISF: add wmask,wumask and wvmask
19   !!            4.0  ! 2016-06  (G. Madec, S. Flavoni)  domain configuration / user defined interface
20   !!----------------------------------------------------------------------
21
22   !!----------------------------------------------------------------------
23   !!   dom_msk       : compute land/ocean mask
24   !!----------------------------------------------------------------------
25   USE oce            ! ocean dynamics and tracers
26   USE dom_oce        ! ocean space and time domain
27   USE domutl         !
28   USE usrdef_fmask   ! user defined fmask
29   USE bdy_oce        ! open boundary
30   !
31   USE in_out_manager ! I/O manager
32   USE iom            ! IOM library
33   USE lbclnk         ! ocean lateral boundary conditions (or mpp link)
34   USE lib_mpp        ! Massively Parallel Processing library
35
36   IMPLICIT NONE
37   PRIVATE
38
39   PUBLIC   dom_msk    ! routine called by inidom.F90
40
41   !                            !!* Namelist namlbc : lateral boundary condition *
42   REAL(wp)        :: rn_shlat   ! type of lateral boundary condition on velocity
43   LOGICAL, PUBLIC :: ln_vorlat  !  consistency of vorticity boundary condition
44   !                                            with analytical eqs.
45
46   !! * Substitutions
47#  include "do_loop_substitute.h90"
48   !!----------------------------------------------------------------------
49   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
50   !! $Id$
51   !! Software governed by the CeCILL license (see ./LICENSE)
52   !!----------------------------------------------------------------------
53CONTAINS
54
55   SUBROUTINE dom_msk( k_top, k_bot )
56      !!---------------------------------------------------------------------
57      !!                 ***  ROUTINE dom_msk  ***
58      !!
59      !! ** Purpose :   Compute land/ocean mask arrays at tracer points, hori-
60      !!      zontal velocity points (u & v), vorticity points (f) points.
61      !!
62      !! ** Method  :   The ocean/land mask  at t-point is deduced from ko_top
63      !!      and ko_bot, the indices of the fist and last ocean t-levels which
64      !!      are either defined in usrdef_zgr or read in zgr_read.
65      !!                The velocity masks (umask, vmask, wmask, wumask, wvmask)
66      !!      are deduced from a product of the two neighboring tmask.
67      !!                The vorticity mask (fmask) is deduced from tmask taking
68      !!      into account the choice of lateral boundary condition (rn_shlat) :
69      !!         rn_shlat = 0, free slip  (no shear along the coast)
70      !!         rn_shlat = 2, no slip  (specified zero velocity at the coast)
71      !!         0 < rn_shlat < 2, partial slip   | non-linear velocity profile
72      !!         2 < rn_shlat, strong slip        | in the lateral boundary layer
73      !!
74      !!      tmask_i : interior ocean mask at t-point, i.e. excluding duplicated
75      !!                rows/lines due to cyclic or North Fold boundaries as well
76      !!                as MPP halos.
77      !!      tmask_h : halo mask at t-point, i.e. excluding duplicated rows/lines
78      !!                due to cyclic or North Fold boundaries as well as MPP halos.
79      !!
80      !! ** Action :   tmask, umask, vmask, wmask, wumask, wvmask : land/ocean mask
81      !!                         at t-, u-, v- w, wu-, and wv-points (=0. or 1.)
82      !!               fmask   : land/ocean mask at f-point (=0., or =1., or
83      !!                         =rn_shlat along lateral boundaries)
84      !!               tmask_i : interior ocean mask
85      !!               tmask_h : halo mask
86      !!               ssmask , ssumask, ssvmask, ssfmask : 2D ocean mask
87      !!----------------------------------------------------------------------
88      INTEGER, DIMENSION(:,:), INTENT(in) ::   k_top, k_bot   ! first and last ocean level
89      !
90      INTEGER  ::   ji, jj, jk     ! dummy loop indices
91      INTEGER  ::   iktop, ikbot   !   -       -
92      INTEGER  ::   ios, inum
93      REAL(wp), ALLOCATABLE, DIMENSION(:,:) ::   zwf   ! 2D workspace
94      !!
95      NAMELIST/namlbc/ rn_shlat, ln_vorlat
96      NAMELIST/nambdy/ ln_bdy ,nb_bdy, ln_coords_file, cn_coords_file,         &
97         &             ln_mask_file, cn_mask_file, cn_dyn2d, nn_dyn2d_dta,     &
98         &             cn_dyn3d, nn_dyn3d_dta, cn_tra, nn_tra_dta,             &
99         &             ln_tra_dmp, ln_dyn3d_dmp, rn_time_dmp, rn_time_dmp_out, &
100         &             cn_ice, nn_ice_dta,                                     &
101         &             ln_vol, nn_volctl, nn_rimwidth
102      !!---------------------------------------------------------------------
103      !
104      READ  ( numnam_ref, namlbc, IOSTAT = ios, ERR = 901 )
105901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namlbc in reference namelist' )
106      READ  ( numnam_cfg, namlbc, IOSTAT = ios, ERR = 902 )
107902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namlbc in configuration namelist' )
108      IF(lwm) WRITE ( numond, namlbc )
109     
110      IF(lwp) THEN                  ! control print
111         WRITE(numout,*)
112         WRITE(numout,*) 'dommsk : ocean mask '
113         WRITE(numout,*) '~~~~~~'
114         WRITE(numout,*) '   Namelist namlbc'
115         WRITE(numout,*) '      lateral momentum boundary cond.    rn_shlat  = ',rn_shlat
116         WRITE(numout,*) '      consistency with analytical form   ln_vorlat = ',ln_vorlat 
117      ENDIF
118      !
119      IF(lwp) WRITE(numout,*)
120      IF     (      rn_shlat == 0.               ) THEN   ;   IF(lwp) WRITE(numout,*) '   ==>>>   ocean lateral  free-slip'
121      ELSEIF (      rn_shlat == 2.               ) THEN   ;   IF(lwp) WRITE(numout,*) '   ==>>>   ocean lateral  no-slip'
122      ELSEIF ( 0. < rn_shlat .AND. rn_shlat < 2. ) THEN   ;   IF(lwp) WRITE(numout,*) '   ==>>>   ocean lateral  partial-slip'
123      ELSEIF ( 2. < rn_shlat                     ) THEN   ;   IF(lwp) WRITE(numout,*) '   ==>>>   ocean lateral  strong-slip'
124      ELSE
125         CALL ctl_stop( 'dom_msk: wrong value for rn_shlat (i.e. a negalive value). We stop.' )
126      ENDIF
127
128      !  Ocean/land mask at t-point  (computed from ko_top and ko_bot)
129      ! ----------------------------
130      !
131      tmask(:,:,:) = 0._wp
132      DO_2D_11_11
133         iktop = k_top(ji,jj)
134         ikbot = k_bot(ji,jj)
135         IF( iktop /= 0 ) THEN       ! water in the column
136            tmask(ji,jj,iktop:ikbot) = 1._wp
137         ENDIF
138      END_2D
139      !
140      ! Mask corrections for bdy (read in mppini2)
141      READ  ( numnam_ref, nambdy, IOSTAT = ios, ERR = 903)
142903   IF( ios /= 0 )   CALL ctl_nam ( ios , 'nambdy in reference namelist' )
143      READ  ( numnam_cfg, nambdy, IOSTAT = ios, ERR = 904 )
144904   IF( ios >  0 )   CALL ctl_nam ( ios , 'nambdy in configuration namelist' )
145      ! ------------------------
146      IF ( ln_bdy .AND. ln_mask_file ) THEN
147         CALL iom_open( cn_mask_file, inum )
148         CALL iom_get ( inum, jpdom_global, 'bdy_msk', bdytmask(:,:) )
149         CALL iom_close( inum )
150         DO_3D_11_11( 1, jpkm1 )
151            tmask(ji,jj,jk) = tmask(ji,jj,jk) * bdytmask(ji,jj)
152         END_3D
153      ENDIF
154         
155      !  Ocean/land mask at u-, v-, and f-points   (computed from tmask)
156      ! ----------------------------------------
157      ! NB: at this point, fmask is designed for free slip lateral boundary condition
158      DO_3D_00_00( 1, jpk )
159         umask(ji,jj,jk) = tmask(ji,jj  ,jk) * tmask(ji+1,jj  ,jk)
160         vmask(ji,jj,jk) = tmask(ji,jj  ,jk) * tmask(ji  ,jj+1,jk)
161         fmask(ji,jj,jk) = tmask(ji,jj  ,jk) * tmask(ji+1,jj  ,jk)   &
162            &            * tmask(ji,jj+1,jk) * tmask(ji+1,jj+1,jk)
163      END_3D
164      CALL lbc_lnk_multi( 'dommsk', umask, 'U', 1.0_wp, vmask, 'V', 1.0_wp, fmask, 'F', 1.0_wp )      ! Lateral boundary conditions
165 
166      ! Ocean/land mask at wu-, wv- and w points    (computed from tmask)
167      !-----------------------------------------
168      wmask (:,:,1) = tmask(:,:,1)     ! surface
169      wumask(:,:,1) = umask(:,:,1)
170      wvmask(:,:,1) = vmask(:,:,1)
171      DO jk = 2, jpk                   ! interior values
172         wmask (:,:,jk) = tmask(:,:,jk) * tmask(:,:,jk-1)
173         wumask(:,:,jk) = umask(:,:,jk) * umask(:,:,jk-1)   
174         wvmask(:,:,jk) = vmask(:,:,jk) * vmask(:,:,jk-1)
175      END DO
176
177      ! Ocean/land column mask at t-, u-, and v-points   (i.e. at least 1 wet cell in the vertical)
178      ! ----------------------------------------------
179      ssmask (:,:) = MAXVAL( tmask(:,:,:), DIM=3 )
180      ssumask(:,:) = MAXVAL( umask(:,:,:), DIM=3 )
181      ssvmask(:,:) = MAXVAL( vmask(:,:,:), DIM=3 )
182
183      ! Interior domain mask  (used for global sum)
184      ! --------------------
185      !
186      CALL dom_uniq( tmask_h, 'T' )
187      !
188      !                          ! interior mask : 2D ocean mask x halo mask
189      tmask_i(:,:) = ssmask(:,:) * tmask_h(:,:)
190
191      ! Lateral boundary conditions on velocity (modify fmask)
192      ! --------------------------------------- 
193      IF( rn_shlat /= 0 ) THEN      ! Not free-slip lateral boundary condition
194         !
195         ALLOCATE( zwf(jpi,jpj) )
196         !
197         DO jk = 1, jpk
198            zwf(:,:) = fmask(:,:,jk)         
199            DO_2D_00_00
200               IF( fmask(ji,jj,jk) == 0._wp ) THEN
201                  fmask(ji,jj,jk) = rn_shlat * MIN( 1._wp , MAX( zwf(ji+1,jj), zwf(ji,jj+1),   &
202                     &                                           zwf(ji-1,jj), zwf(ji,jj-1)  )  )
203               ENDIF
204            END_2D
205            DO jj = 2, jpjm1
206               IF( fmask(1,jj,jk) == 0._wp ) THEN
207                  fmask(1  ,jj,jk) = rn_shlat * MIN( 1._wp , MAX( zwf(2,jj), zwf(1,jj+1), zwf(1,jj-1) ) )
208               ENDIF
209               IF( fmask(jpi,jj,jk) == 0._wp ) THEN
210                  fmask(jpi,jj,jk) = rn_shlat * MIN( 1._wp , MAX( zwf(jpi,jj+1), zwf(jpim1,jj), zwf(jpi,jj-1) ) )
211               ENDIF
212            END DO         
213            DO ji = 2, jpim1
214               IF( fmask(ji,1,jk) == 0._wp ) THEN
215                  fmask(ji, 1 ,jk) = rn_shlat * MIN( 1._wp , MAX( zwf(ji+1,1), zwf(ji,2), zwf(ji-1,1) ) )
216               ENDIF
217               IF( fmask(ji,jpj,jk) == 0._wp ) THEN
218                  fmask(ji,jpj,jk) = rn_shlat * MIN( 1._wp , MAX( zwf(ji+1,jpj), zwf(ji-1,jpj), zwf(ji,jpjm1) ) )
219               ENDIF
220            END DO
221         END DO
222         !
223         DEALLOCATE( zwf )
224         !
225         CALL lbc_lnk( 'dommsk', fmask, 'F', 1._wp )      ! Lateral boundary conditions on fmask
226         !
227         ! CAUTION : The fmask may be further modified in dyn_vor_init ( dynvor.F90 ) depending on ln_vorlat
228         !
229      ENDIF
230     
231      ! User defined alteration of fmask (use to reduce ocean transport in specified straits)
232      ! --------------------------------
233      !
234      CALL usr_def_fmask( cn_cfg, nn_cfg, fmask )
235      !
236   END SUBROUTINE dom_msk
237   
238   !!======================================================================
239END MODULE dommsk
Note: See TracBrowser for help on using the repository browser.