source: NEMO/branches/2020/dev_r12558_HPC-08_epico_Extra_Halo/src/OCE/IOM/iom_nf90.F90 @ 13130

Last change on this file since 13130 was 13130, checked in by smasson, 3 months ago

Extra_Halo: supress halos from outputs and coupling, see #2366

  • Property svn:keywords set to Id
File size: 42.8 KB
Line 
1MODULE iom_nf90
2   !!======================================================================
3   !!                    ***  MODULE  iom_nf90 ***
4   !! Input/Output manager :  Library to read input files with NF90 (only fliocom module)
5   !!======================================================================
6   !! History :  9.0  ! 05 12  (J. Belier) Original code
7   !!            9.0  ! 06 02  (S. Masson) Adaptation to NEMO
8   !!             "   ! 07 07  (D. Storkey) Changes to iom_nf90_gettime
9   !!            3.6  ! 2015-15  (J. Harle) Added procedure to read REAL attributes
10   !!            4.0  ! 2017-11 (M. Andrejczuk) Extend IOM interface to write any 3D fields
11   !!----------------------------------------------------------------------
12
13   !!----------------------------------------------------------------------
14   !!   iom_open       : open a file read only
15   !!   iom_close      : close a file or all files opened by iom
16   !!   iom_get        : read a field (interfaced to several routines)
17   !!   iom_varid      : get the id of a variable in a file
18   !!   iom_rstput     : write a field in a restart file (interfaced to several routines)
19   !!----------------------------------------------------------------------
20   USE dom_oce         ! ocean space and time domain
21   USE sbc_oce, ONLY: ght_abl ! abl vertical level number and height
22   USE lbclnk          ! lateal boundary condition / mpp exchanges
23   USE iom_def         ! iom variables definitions
24   USE netcdf          ! NetCDF library
25   USE in_out_manager  ! I/O manager
26   USE lib_mpp         ! MPP library
27
28   IMPLICIT NONE
29   PRIVATE
30
31   PUBLIC iom_nf90_open  , iom_nf90_close, iom_nf90_varid, iom_nf90_get, iom_nf90_rstput
32   PUBLIC iom_nf90_chkatt, iom_nf90_getatt, iom_nf90_putatt
33
34   INTERFACE iom_nf90_get
35      MODULE PROCEDURE iom_nf90_g0d, iom_nf90_g123d
36   END INTERFACE
37   INTERFACE iom_nf90_rstput
38      MODULE PROCEDURE iom_nf90_rp0123d
39   END INTERFACE
40
41   !!----------------------------------------------------------------------
42   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
43   !! $Id$
44   !! Software governed by the CeCILL license (see ./LICENSE)
45   !!----------------------------------------------------------------------
46CONTAINS
47
48   SUBROUTINE iom_nf90_open( cdname, kiomid, ldwrt, ldok, kdlev, cdcomp )
49      !!---------------------------------------------------------------------
50      !!                   ***  SUBROUTINE  iom_open  ***
51      !!
52      !! ** Purpose : open an input file with NF90
53      !!---------------------------------------------------------------------
54      CHARACTER(len=*)       , INTENT(inout)           ::   cdname      ! File name
55      INTEGER                , INTENT(  out)           ::   kiomid      ! nf90 identifier of the opened file
56      LOGICAL                , INTENT(in   )           ::   ldwrt       ! read or write the file?
57      LOGICAL                , INTENT(in   )           ::   ldok        ! check the existence
58      INTEGER                , INTENT(in   ), OPTIONAL ::   kdlev       ! size of the ice/abl third dimension
59      CHARACTER(len=3)       , INTENT(in   ), OPTIONAL ::   cdcomp      ! name of component calling iom_nf90_open
60
61      CHARACTER(LEN=256) ::   clinfo           ! info character
62      CHARACTER(LEN=256) ::   cltmp            ! temporary character
63      CHARACTER(LEN=12 ) ::   clfmt            ! writing format
64      CHARACTER(LEN=3  ) ::   clcomp           ! name of component calling iom_nf90_open
65      INTEGER            ::   idg              ! number of digits
66      INTEGER            ::   iln              ! lengths of character
67      INTEGER            ::   istop            ! temporary storage of nstop
68      INTEGER            ::   if90id           ! nf90 identifier of the opened file
69      INTEGER            ::   idmy             ! dummy variable
70      INTEGER            ::   jl               ! loop variable
71      INTEGER            ::   ichunk           ! temporary storage of nn_chunksz
72      INTEGER            ::   imode            ! creation mode flag: NF90_CLOBBER or NF90_NOCLOBBER or NF90_HDF5
73      INTEGER            ::   ihdf5            ! local variable for retrieval of value for NF90_HDF5
74      LOGICAL            ::   llclobber        ! local definition of ln_clobber
75      !---------------------------------------------------------------------
76      !
77      clinfo = '                    iom_nf90_open ~~~  '
78      istop = nstop     ! store the actual value of nstop
79      !
80      !                 !number of vertical levels
81      IF( PRESENT(cdcomp) )   THEN
82         IF( .NOT. PRESENT(kdlev) ) CALL ctl_stop( 'iom_nf90_open: cdcomp and kdlev must both be present' )
83         clcomp = cdcomp    ! use input value
84      ELSE
85         clcomp = 'OCE'     ! by default
86      ENDIF
87      !
88      IF( nn_chunksz > 0 ) THEN   ;   ichunk = nn_chunksz
89      ELSE                        ;   ichunk = NF90_SIZEHINT_DEFAULT
90      ENDIF
91      !
92      llclobber = ldwrt .AND. ln_clobber
93      IF( ldok .AND. .NOT. llclobber ) THEN      !==  Open existing file ==!
94         !                                       !=========================!
95         IF( ldwrt ) THEN  ! ... in write mode
96            IF(lwp) WRITE(numout,*) TRIM(clinfo)//' open existing file: '//TRIM(cdname)//' in WRITE mode'
97            IF( snc4set%luse ) THEN
98               CALL iom_nf90_check(NF90_OPEN( TRIM(cdname), NF90_WRITE  , if90id ), clinfo)
99            ELSE
100               CALL iom_nf90_check(NF90_OPEN( TRIM(cdname), NF90_WRITE  , if90id, chunksize = ichunk ), clinfo)
101            ENDIF
102            CALL iom_nf90_check(NF90_SET_FILL( if90id, NF90_NOFILL, idmy                          ), clinfo)
103         ELSE              ! ... in read mode
104            IF(lwp) WRITE(numout,*) TRIM(clinfo)//' open existing file: '//TRIM(cdname)//' in READ mode'
105            CALL iom_nf90_check(NF90_OPEN( TRIM(cdname), NF90_NOWRITE, if90id, chunksize = ichunk ), clinfo)
106         ENDIF
107      ELSE                                       !== the file doesn't exist ==!   (or we overwrite it)
108         !                                       !============================!
109         iln = INDEX( cdname, '.nc' )
110         IF( ldwrt ) THEN              !* the file should be open in write mode so we create it...
111            IF( jpnij > 1 ) THEN
112               idg = MAX( INT(LOG10(REAL(MAX(1,jpnij-1),wp))) + 1, 4 )          ! how many digits to we need to write? min=4, max=9
113               WRITE(clfmt, "('(a,a,i', i1, '.', i1, ',a)')") idg, idg          ! '(a,a,ix.x,a)'
114               WRITE(cltmp,clfmt) cdname(1:iln-1), '_', narea-1, '.nc'
115               cdname = TRIM(cltmp)
116            ENDIF
117            IF(lwp) WRITE(numout,*) TRIM(clinfo)//' create new file: '//TRIM(cdname)//' in WRITE mode'
118
119            IF( llclobber ) THEN   ;   imode = IOR( NF90_64BIT_OFFSET, NF90_CLOBBER   )
120            ELSE                   ;   imode = IOR( NF90_64BIT_OFFSET, NF90_NOCLOBBER ) 
121            ENDIF
122            IF( snc4set%luse ) THEN
123               IF(lwp) WRITE(numout,*) TRIM(clinfo)//' creating file: '//TRIM(cdname)//' in hdf5 (netcdf4) mode'
124               CALL GET_NF90_SYMBOL("NF90_HDF5", ihdf5)
125               IF( llclobber ) THEN   ;   imode = IOR(ihdf5, NF90_CLOBBER)
126               ELSE                   ;   imode = IOR(ihdf5, NF90_NOCLOBBER)
127               ENDIF
128               CALL iom_nf90_check(NF90_CREATE( TRIM(cdname), imode, if90id ), clinfo)
129            ELSE
130               CALL iom_nf90_check(NF90_CREATE( TRIM(cdname), imode, if90id, chunksize = ichunk ), clinfo)
131            ENDIF
132            CALL iom_nf90_check(NF90_SET_FILL( if90id, NF90_NOFILL,                   idmy ), clinfo)
133            ! define dimensions
134                               CALL iom_nf90_check(NF90_DEF_DIM( if90id,            'x',  Ni_0, idmy ), clinfo)
135                               CALL iom_nf90_check(NF90_DEF_DIM( if90id,            'y',  Nj_0, idmy ), clinfo)
136            SELECT CASE (clcomp)
137            CASE ('OCE')   ;   CALL iom_nf90_check(NF90_DEF_DIM( if90id,      'nav_lev',   jpk, idmy ), clinfo)
138            CASE ('ICE')   ;   CALL iom_nf90_check(NF90_DEF_DIM( if90id,       'numcat', kdlev, idmy ), clinfo)
139            CASE ('ABL')   ;   CALL iom_nf90_check(NF90_DEF_DIM( if90id,      'nav_lev', kdlev, idmy ), clinfo)
140            CASE ('SED')   ;   CALL iom_nf90_check(NF90_DEF_DIM( if90id,       'numsed', kdlev, idmy ), clinfo)
141            CASE DEFAULT   ;   CALL ctl_stop( 'iom_nf90_open unknown component type' )
142            END SELECT
143                               CALL iom_nf90_check(NF90_DEF_DIM( if90id, 'time_counter', NF90_UNLIMITED, idmy ), clinfo)
144            ! global attributes
145            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_number_total'   , jpnij                        ), clinfo)
146            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_number'         , narea-1                      ), clinfo)
147            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_dimensions_ids' , (/ 1        , 2           /) ), clinfo)
148            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_size_global'    , (/ Ni0glo    , Nj0glo     /) ), clinfo)
149            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_size_local'     , (/ Ni_0      , Nj_0       /) ), clinfo)
150            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_position_first' , (/ mig0(Nis0), mjg0(Njs0) /) ), clinfo)
151            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_position_last'  , (/ mig0(Nie0), mjg0(Nje0) /) ), clinfo)
152            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_halo_size_start', (/ 0         , 0          /) ), clinfo)
153            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_halo_size_end'  , (/ 0         , 0          /) ), clinfo)
154            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_type'           , 'BOX'                        ), clinfo)
155         ELSE                          !* the file should be open for read mode so it must exist...
156            CALL ctl_stop( TRIM(clinfo), ' should be impossible case...' )
157         ENDIF
158      ENDIF
159      !
160      ! start to fill file informations
161      ! =============
162      IF( istop == nstop ) THEN   ! no error within this routine
163!does not work with some compilers         kiomid = MINLOC(iom_file(:)%nfid, dim = 1)
164         kiomid = 0
165         DO jl = jpmax_files, 1, -1
166            IF( iom_file(jl)%nfid == 0 )   kiomid = jl
167         ENDDO
168         iom_file(kiomid)%name   = TRIM(cdname)
169         iom_file(kiomid)%comp   = clcomp
170         iom_file(kiomid)%nfid   = if90id
171         iom_file(kiomid)%nvars  = 0
172         iom_file(kiomid)%irec   = -1   ! useless for NetCDF files, used to know if the file is in define mode
173         CALL iom_nf90_check(NF90_Inquire(if90id, unlimitedDimId = iom_file(kiomid)%iduld), clinfo)
174         IF( iom_file(kiomid)%iduld .GE. 0 ) THEN
175            CALL iom_nf90_check(NF90_Inquire_Dimension(if90id, iom_file(kiomid)%iduld,    & 
176               &                                       name = iom_file(kiomid)%uldname,   &
177               &                                       len  = iom_file(kiomid)%lenuld ), clinfo )
178         ENDIF
179         IF(lwp) WRITE(numout,*) '                   ---> '//TRIM(cdname)//' OK'
180      ELSE
181         kiomid = 0               ! return error flag
182      ENDIF
183      !
184   END SUBROUTINE iom_nf90_open
185
186
187   SUBROUTINE iom_nf90_close( kiomid )
188      !!--------------------------------------------------------------------
189      !!                   ***  SUBROUTINE  iom_nf90_close  ***
190      !!
191      !! ** Purpose : close an input file with NF90
192      !!--------------------------------------------------------------------
193      INTEGER, INTENT(in) ::   kiomid   ! iom identifier of the file to be closed
194      CHARACTER(LEN=100)  ::   clinfo   ! info character
195      !---------------------------------------------------------------------
196      clinfo = '      iom_nf90_close    , file: '//TRIM(iom_file(kiomid)%name)
197      CALL iom_nf90_check(NF90_CLOSE(iom_file(kiomid)%nfid), clinfo)
198   END SUBROUTINE iom_nf90_close
199
200
201   FUNCTION iom_nf90_varid ( kiomid, cdvar, kiv, kdimsz, kndims, lduld ) 
202      !!-----------------------------------------------------------------------
203      !!                  ***  FUNCTION  iom_varid  ***
204      !!
205      !! ** Purpose : get the id of a variable in a file with NF90
206      !!-----------------------------------------------------------------------
207      INTEGER              , INTENT(in   )           ::   kiomid   ! file Identifier
208      CHARACTER(len=*)     , INTENT(in   )           ::   cdvar    ! name of the variable
209      INTEGER              , INTENT(in   )           ::   kiv   !
210      INTEGER, DIMENSION(:), INTENT(  out), OPTIONAL ::   kdimsz   ! size of each dimension
211      INTEGER              , INTENT(  out), OPTIONAL ::   kndims   ! number of dimensions
212      LOGICAL              , INTENT(  out), OPTIONAL ::   lduld    ! true if the last dimension is unlimited (time)
213      !
214      INTEGER                        ::   iom_nf90_varid   ! iom variable Id
215      INTEGER                        ::   if90id           ! nf90 file identifier
216      INTEGER                        ::   ji               ! dummy loop index
217      INTEGER                        ::   ivarid           ! NetCDF  variable Id
218      INTEGER                        ::   i_nvd            ! number of dimension of the variable
219      INTEGER, DIMENSION(jpmax_dims) ::   idimid           ! dimension ids of the variable
220      LOGICAL                        ::   llok             ! ok  test
221      CHARACTER(LEN=100)             ::   clinfo           ! info character
222      !!-----------------------------------------------------------------------
223      clinfo = '          iom_nf90_varid, file: '//TRIM(iom_file(kiomid)%name)//', var: '//TRIM(cdvar)
224      iom_nf90_varid = 0                    ! default definition
225      IF( PRESENT(kdimsz) ) kdimsz(:) = 0   ! default definition
226      if90id = iom_file(kiomid)%nfid        ! get back NetCDF file id
227      !
228      llok = NF90_INQ_VARID( if90id, TRIM(cdvar), ivarid ) == nf90_noerr   ! does the variable exist in the file
229      IF( llok ) THEN
230         iom_nf90_varid = kiv
231         iom_file(kiomid)%nvars       = kiv
232         iom_file(kiomid)%nvid(kiv)   = ivarid
233         iom_file(kiomid)%cn_var(kiv) = TRIM(cdvar)
234         CALL iom_nf90_check(NF90_Inquire_Variable(if90id, ivarid, ndims = i_nvd), clinfo)   ! number of dimensions
235         iom_file(kiomid)%ndims(kiv)  = i_nvd
236         CALL iom_nf90_check(NF90_Inquire_Variable(if90id, ivarid, dimids = idimid(1:i_nvd)), clinfo)   ! dimensions ids
237         iom_file(kiomid)%luld(kiv) = .FALSE.   ! default value
238         iom_file(kiomid)%dimsz(:,kiv) = 0      ! reset dimsz in case previously used
239         DO ji = 1, i_nvd                       ! dimensions size
240            CALL iom_nf90_check(NF90_Inquire_Dimension(if90id, idimid(ji), len = iom_file(kiomid)%dimsz(ji,kiv)), clinfo)   
241            IF( idimid(ji) == iom_file(kiomid)%iduld ) iom_file(kiomid)%luld(kiv) = .TRUE.   ! unlimited dimension?
242         END DO
243         !---------- Deal with scale_factor and add_offset
244         llok = NF90_Inquire_attribute(if90id, ivarid, 'scale_factor') == nf90_noerr
245         IF( llok) THEN
246            CALL iom_nf90_check(NF90_GET_ATT(if90id, ivarid, 'scale_factor', iom_file(kiomid)%scf(kiv)), clinfo)
247         ELSE
248            iom_file(kiomid)%scf(kiv) = 1.
249         END IF
250         llok = NF90_Inquire_attribute(if90id, ivarid, 'add_offset') == nf90_noerr
251         IF( llok ) THEN
252            CALL iom_nf90_check(NF90_GET_ATT(if90id, ivarid, 'add_offset', iom_file(kiomid)%ofs(kiv)), clinfo)
253         ELSE
254            iom_file(kiomid)%ofs(kiv) = 0.
255         END IF
256         ! return the simension size
257         IF( PRESENT(kdimsz) ) THEN
258            IF( i_nvd <= SIZE(kdimsz) ) THEN
259               kdimsz(1:i_nvd) = iom_file(kiomid)%dimsz(1:i_nvd,kiv)
260            ELSE
261               WRITE(ctmp1,*) i_nvd, SIZE(kdimsz)
262               CALL ctl_stop( TRIM(clinfo), 'error in kdimsz size'//TRIM(ctmp1) )
263            ENDIF
264         ENDIF
265         IF( PRESENT(kndims) )  kndims = iom_file(kiomid)%ndims(kiv)
266         IF( PRESENT( lduld) )  lduld  = iom_file(kiomid)%luld(kiv)
267      ELSE 
268         iom_nf90_varid = -1   !   variable not found, return error code: -1
269      ENDIF
270      !
271   END FUNCTION iom_nf90_varid
272
273   !!----------------------------------------------------------------------
274   !!                   INTERFACE iom_nf90_get
275   !!----------------------------------------------------------------------
276
277   SUBROUTINE iom_nf90_g0d( kiomid, kvid, pvar, kstart )
278      !!-----------------------------------------------------------------------
279      !!                  ***  ROUTINE  iom_nf90_g0d  ***
280      !!
281      !! ** Purpose : read a scalar with NF90
282      !!-----------------------------------------------------------------------
283      INTEGER ,               INTENT(in   )            ::   kiomid   ! Identifier of the file
284      INTEGER ,               INTENT(in   )            ::   kvid     ! variable id
285      REAL(wp),               INTENT(  out)            ::   pvar     ! read field
286      INTEGER , DIMENSION(1), INTENT(in   ), OPTIONAL  ::   kstart   ! start position of the reading in each axis
287      !
288      CHARACTER(LEN=100)      ::   clinfo   ! info character
289      !---------------------------------------------------------------------
290      clinfo = 'iom_nf90_g0d , file: '//TRIM(iom_file(kiomid)%name)//', var: '//TRIM(iom_file(kiomid)%cn_var(kvid))
291      CALL iom_nf90_check(NF90_GET_VAR(iom_file(kiomid)%nfid, iom_file(kiomid)%nvid(kvid), pvar, start = kstart), clinfo )
292   END SUBROUTINE iom_nf90_g0d
293
294
295   SUBROUTINE iom_nf90_g123d( kiomid, kvid, knbdim, kstart, kcount, kx1, kx2, ky1, ky2,   &
296         &                    pv_r1d, pv_r2d, pv_r3d )
297      !!-----------------------------------------------------------------------
298      !!                  ***  ROUTINE  iom_nf90_g123d  ***
299      !!
300      !! ** Purpose : read a 1D/2D/3D variable with NF90
301      !!
302      !! ** Method : read ONE record at each CALL
303      !!-----------------------------------------------------------------------
304      INTEGER                    , INTENT(in   )           ::   kiomid    ! iom identifier of the file
305      INTEGER                    , INTENT(in   )           ::   kvid      ! Name of the variable
306      INTEGER                    , INTENT(in   )           ::   knbdim    ! number of dimensions of the variable
307      INTEGER , DIMENSION(:)     , INTENT(in   )           ::   kstart    ! start position of the reading in each axis
308      INTEGER , DIMENSION(:)     , INTENT(in   )           ::   kcount    ! number of points to be read in each axis
309      INTEGER ,                    INTENT(in   )           ::   kx1, kx2, ky1, ky2   ! subdomain indexes
310      REAL(wp), DIMENSION(:)     , INTENT(  out), OPTIONAL ::   pv_r1d    ! read field (1D case)
311      REAL(wp), DIMENSION(:,:)   , INTENT(  out), OPTIONAL ::   pv_r2d    ! read field (2D case)
312      REAL(wp), DIMENSION(:,:,:) , INTENT(  out), OPTIONAL ::   pv_r3d    ! read field (3D case)
313      !
314      CHARACTER(LEN=100) ::   clinfo               ! info character
315      INTEGER            ::   if90id               ! nf90 identifier of the opened file
316      INTEGER            ::   ivid                 ! nf90 variable id
317      !---------------------------------------------------------------------
318      clinfo = 'iom_nf90_g123d , file: '//TRIM(iom_file(kiomid)%name)//', var: '//TRIM(iom_file(kiomid)%cn_var(kvid))
319      if90id = iom_file(kiomid)%nfid         ! get back NetCDF file id
320      ivid   = iom_file(kiomid)%nvid(kvid)   ! get back NetCDF var id
321      !
322      IF(     PRESENT(pv_r1d) ) THEN
323         CALL iom_nf90_check( NF90_GET_VAR(if90id, ivid, pv_r1d(:                ), start = kstart(1:knbdim),   &
324            &                                                                       count = kcount(1:knbdim)), clinfo )
325      ELSEIF( PRESENT(pv_r2d) ) THEN
326         CALL iom_nf90_check( NF90_GET_VAR(if90id, ivid, pv_r2d(kx1:kx2,ky1:ky2  ), start = kstart(1:knbdim),   &
327            &                                                                       count = kcount(1:knbdim)), clinfo )
328      ELSEIF( PRESENT(pv_r3d) ) THEN
329         CALL iom_nf90_check( NF90_GET_VAR(if90id, ivid, pv_r3d(kx1:kx2,ky1:ky2,:), start = kstart(1:knbdim),   &
330            &                                                                       count = kcount(1:knbdim)), clinfo )
331      ENDIF
332      !
333   END SUBROUTINE iom_nf90_g123d
334
335
336   SUBROUTINE iom_nf90_chkatt( kiomid, cdatt, llok, ksize, cdvar )
337      !!-----------------------------------------------------------------------
338      !!                  ***  ROUTINE  iom_nf90_chkatt  ***
339      !!
340      !! ** Purpose : check existence of attribute with NF90
341      !!              (either a global attribute (default) or a variable
342      !!               attribute if optional variable name is supplied (cdvar))
343      !!-----------------------------------------------------------------------
344      INTEGER         , INTENT(in   ) ::   kiomid   ! Identifier of the file
345      CHARACTER(len=*), INTENT(in   ) ::   cdatt    ! attribute name
346      LOGICAL         , INTENT(  out) ::   llok     ! error code
347      INTEGER         , INTENT(  out), OPTIONAL     &
348                      &               ::   ksize    ! attribute size
349      CHARACTER(len=*), INTENT(in   ), OPTIONAL     &
350                      &               ::   cdvar    ! name of the variable
351      !
352      INTEGER                         ::   if90id   ! temporary integer
353      INTEGER                         ::   isize    ! temporary integer
354      INTEGER                         ::   ivarid   ! NetCDF variable Id
355      !---------------------------------------------------------------------
356      !
357      if90id = iom_file(kiomid)%nfid
358      IF( PRESENT(cdvar) ) THEN
359         ! check the variable exists in the file
360         llok = NF90_INQ_VARID( if90id, TRIM(cdvar), ivarid ) == nf90_noerr
361         IF( llok ) &
362            ! check the variable has the attribute required
363            llok = NF90_Inquire_attribute(if90id, ivarid, cdatt, len=isize ) == nf90_noerr
364      ELSE
365         llok = NF90_Inquire_attribute(if90id, NF90_GLOBAL, cdatt, len=isize ) == nf90_noerr
366      ENDIF
367      !
368      IF( PRESENT(ksize) ) ksize = isize
369      !
370      IF( .not. llok) &
371         CALL ctl_warn('iom_nf90_chkatt: no attribute '//cdatt//' found')
372      !
373   END SUBROUTINE iom_nf90_chkatt
374
375
376   !!----------------------------------------------------------------------
377   !!                   INTERFACE iom_nf90_getatt
378   !!----------------------------------------------------------------------
379
380   SUBROUTINE iom_nf90_getatt( kiomid, cdatt, katt0d, katt1d, patt0d, patt1d, cdatt0d, cdvar)
381      !!-----------------------------------------------------------------------
382      !!                  ***  ROUTINE  iom_nf90_getatt  ***
383      !!
384      !! ** Purpose : read an attribute with NF90
385      !!              (either a global attribute (default) or a variable
386      !!               attribute if optional variable name is supplied (cdvar))
387      !!-----------------------------------------------------------------------
388      INTEGER               , INTENT(in   )           ::   kiomid   ! Identifier of the file
389      CHARACTER(len=*)      , INTENT(in   )           ::   cdatt    ! attribute name
390      INTEGER               , INTENT(  out), OPTIONAL ::   katt0d   ! read scalar integer
391      INTEGER, DIMENSION(:) , INTENT(  out), OPTIONAL ::   katt1d   ! read 1d array integer
392      REAL(wp)              , INTENT(  out), OPTIONAL ::   patt0d   ! read scalar  real
393      REAL(wp), DIMENSION(:), INTENT(  out), OPTIONAL ::   patt1d   ! read 1d array real
394      CHARACTER(len=*)      , INTENT(  out), OPTIONAL ::   cdatt0d  ! read character
395      CHARACTER(len=*)      , INTENT(in   ), OPTIONAL ::   cdvar    ! name of the variable
396      !
397      INTEGER                         ::   if90id   ! temporary integer
398      INTEGER                         ::   ivarid   ! NetCDF variable Id
399      LOGICAL                         ::   llok     ! temporary logical
400      CHARACTER(LEN=100)              ::   clinfo   ! info character
401      !---------------------------------------------------------------------
402      !
403      if90id = iom_file(kiomid)%nfid
404      IF( PRESENT(cdvar) ) THEN
405         ! check the variable exists in the file
406         llok = NF90_INQ_VARID( if90id, TRIM(cdvar), ivarid ) == nf90_noerr
407         IF( llok ) THEN
408            ! check the variable has the attribute required
409            llok = NF90_Inquire_attribute(if90id, ivarid, cdatt) == nf90_noerr
410         ELSE
411            CALL ctl_warn('iom_nf90_getatt: no variable '//TRIM(cdvar)//' found')
412         ENDIF
413      ELSE
414         llok = NF90_Inquire_attribute(if90id, NF90_GLOBAL, cdatt) == nf90_noerr
415         ivarid = NF90_GLOBAL
416      ENDIF
417      !
418      IF( llok) THEN
419         clinfo = 'iom_nf90_getatt, file: '//TRIM(iom_file(kiomid)%name)//', att: '//TRIM(cdatt)
420         IF(PRESENT( katt0d))   CALL iom_nf90_check(NF90_GET_ATT(if90id, ivarid, cdatt, values =  katt0d), clinfo)
421         IF(PRESENT( katt1d))   CALL iom_nf90_check(NF90_GET_ATT(if90id, ivarid, cdatt, values =  katt1d), clinfo)
422         IF(PRESENT( patt0d))   CALL iom_nf90_check(NF90_GET_ATT(if90id, ivarid, cdatt, values =  patt0d), clinfo)
423         IF(PRESENT( patt1d))   CALL iom_nf90_check(NF90_GET_ATT(if90id, ivarid, cdatt, values =  patt1d), clinfo)
424         IF(PRESENT(cdatt0d))   CALL iom_nf90_check(NF90_GET_ATT(if90id, ivarid, cdatt, values = cdatt0d), clinfo)
425      ELSE
426         CALL ctl_warn('iom_nf90_getatt: no attribute '//TRIM(cdatt)//' found')
427         IF(PRESENT( katt0d))    katt0d    = -999
428         IF(PRESENT( katt1d))    katt1d(:) = -999
429         IF(PRESENT( patt0d))    patt0d    = -999._wp
430         IF(PRESENT( patt1d))    patt1d(:) = -999._wp
431         IF(PRESENT(cdatt0d))   cdatt0d    = '!'
432      ENDIF
433      !
434   END SUBROUTINE iom_nf90_getatt
435
436
437   SUBROUTINE iom_nf90_putatt( kiomid, cdatt, katt0d, katt1d, patt0d, patt1d, cdatt0d, cdvar)
438      !!-----------------------------------------------------------------------
439      !!                  ***  ROUTINE  iom_nf90_putatt  ***
440      !!
441      !! ** Purpose : write an attribute with NF90
442      !!              (either a global attribute (default) or a variable
443      !!               attribute if optional variable name is supplied (cdvar))
444      !!-----------------------------------------------------------------------
445      INTEGER               , INTENT(in   )           ::   kiomid   ! Identifier of the file
446      CHARACTER(len=*)      , INTENT(in   )           ::   cdatt    ! attribute name
447      INTEGER               , INTENT(in   ), OPTIONAL ::   katt0d   ! read scalar integer
448      INTEGER, DIMENSION(:) , INTENT(in   ), OPTIONAL ::   katt1d   ! read 1d array integer
449      REAL(wp)              , INTENT(in   ), OPTIONAL ::   patt0d   ! read scalar  real
450      REAL(wp), DIMENSION(:), INTENT(in   ), OPTIONAL ::   patt1d   ! read 1d array real
451      CHARACTER(len=*)      , INTENT(in   ), OPTIONAL ::   cdatt0d  ! read character
452      CHARACTER(len=*)      , INTENT(in   ), OPTIONAL ::   cdvar    ! name of the variable
453      !
454      INTEGER                         ::   if90id   ! temporary integer
455      INTEGER                         ::   ivarid   ! NetCDF variable Id
456      INTEGER                         ::   isize    ! Attribute size
457      INTEGER                         ::   itype    ! Attribute type
458      LOGICAL                         ::   llok     ! temporary logical
459      LOGICAL                         ::   llatt     ! temporary logical
460      LOGICAL                         ::   lldata   ! temporary logical
461      CHARACTER(LEN=100)              ::   clinfo   ! info character
462      !---------------------------------------------------------------------
463      !
464      if90id = iom_file(kiomid)%nfid
465      IF( PRESENT(cdvar) ) THEN
466         llok = NF90_INQ_VARID( if90id, TRIM(cdvar), ivarid ) == nf90_noerr   ! is the variable in the file?
467         IF( .NOT. llok ) THEN
468            CALL ctl_warn('iom_nf90_putatt: no variable '//TRIM(cdvar)//' found'   &
469               &        , '                 no attribute '//cdatt//' written' )
470            RETURN
471         ENDIF
472      ELSE
473         ivarid = NF90_GLOBAL
474      ENDIF
475      llatt = NF90_Inquire_attribute(if90id, ivarid, cdatt, len = isize, xtype = itype ) == nf90_noerr
476      !
477      ! trick: irec used to know if the file is in define mode or not
478      lldata = iom_file(kiomid)%irec /= -1   ! default: go back in define mode if in data mode
479      IF( lldata .AND. llatt ) THEN          ! attribute already there. Do we really need to go back in define mode?
480         ! do we have the appropriate type?
481         IF(PRESENT( katt0d) .OR. PRESENT( katt1d))   llok = itype == NF90_INT
482         IF(PRESENT( patt0d) .OR. PRESENT( patt1d))   llok = itype == NF90_DOUBLE
483         IF(PRESENT(cdatt0d)                      )   llok = itype == NF90_CHAR
484         ! and do we have the appropriate size?
485         IF(PRESENT( katt0d))   llok = llok .AND. isize == 1
486         IF(PRESENT( katt1d))   llok = llok .AND. isize == SIZE(katt1d)
487         IF(PRESENT( patt0d))   llok = llok .AND. isize == 1
488         IF(PRESENT( patt1d))   llok = llok .AND. isize == SIZE(patt1d)
489         IF(PRESENT(cdatt0d))   llok = llok .AND. isize == LEN_TRIM(cdatt0d)
490         !
491         lldata = .NOT. llok
492      ENDIF
493      !
494      clinfo = 'iom_nf90_putatt, file: '//TRIM(iom_file(kiomid)%name)//', att: '//TRIM(cdatt)
495      IF(lldata)   CALL iom_nf90_check(NF90_REDEF( if90id ), clinfo)   ! leave data mode to define mode
496      !
497      IF(PRESENT( katt0d))   CALL iom_nf90_check(NF90_PUT_ATT(if90id, ivarid, cdatt, values =       katt0d) , clinfo)
498      IF(PRESENT( katt1d))   CALL iom_nf90_check(NF90_PUT_ATT(if90id, ivarid, cdatt, values =       katt1d) , clinfo)
499      IF(PRESENT( patt0d))   CALL iom_nf90_check(NF90_PUT_ATT(if90id, ivarid, cdatt, values =       patt0d) , clinfo)
500      IF(PRESENT( patt1d))   CALL iom_nf90_check(NF90_PUT_ATT(if90id, ivarid, cdatt, values =       patt1d) , clinfo)
501      IF(PRESENT(cdatt0d))   CALL iom_nf90_check(NF90_PUT_ATT(if90id, ivarid, cdatt, values = trim(cdatt0d)), clinfo)
502      !
503      IF(lldata)   CALL iom_nf90_check(NF90_ENDDEF( if90id ), clinfo)   ! leave define mode to data mode
504      !
505   END SUBROUTINE iom_nf90_putatt
506
507
508   SUBROUTINE iom_nf90_rp0123d( kt, kwrite, kiomid, cdvar , kvid  , ktype,   &
509         &                                  pv_r0d, pv_r1d, pv_r2d, pv_r3d )
510      !!--------------------------------------------------------------------
511      !!                   ***  SUBROUTINE  iom_nf90_rstput  ***
512      !!
513      !! ** Purpose : read the time axis cdvar in the file
514      !!--------------------------------------------------------------------
515      INTEGER                     , INTENT(in)           ::   kt       ! ocean time-step
516      INTEGER                     , INTENT(in)           ::   kwrite   ! writing time-step
517      INTEGER                     , INTENT(in)           ::   kiomid   ! Identifier of the file
518      CHARACTER(len=*)            , INTENT(in)           ::   cdvar    ! variable name
519      INTEGER                     , INTENT(in)           ::   kvid     ! variable id
520      INTEGER                     , INTENT(in), OPTIONAL ::   ktype    ! variable type (default R8)
521      REAL(wp)                    , INTENT(in), OPTIONAL ::   pv_r0d   ! written Od field
522      REAL(wp), DIMENSION(      :), INTENT(in), OPTIONAL ::   pv_r1d   ! written 1d field
523      REAL(wp), DIMENSION(:, :   ), INTENT(in), OPTIONAL ::   pv_r2d   ! written 2d field
524      REAL(wp), DIMENSION(:, :, :), INTENT(in), OPTIONAL ::   pv_r3d   ! written 3d field
525      !
526      INTEGER               :: idims                ! number of dimension
527      INTEGER               :: idvar                ! variable id
528      INTEGER               :: jd                   ! dimension loop counter   
529      INTEGER               :: ix1, ix2, iy1, iy2   ! subdomain indexes   
530      INTEGER, DIMENSION(4) :: idimsz               ! dimensions size 
531      INTEGER, DIMENSION(4) :: idimid               ! dimensions id
532      CHARACTER(LEN=256)    :: clinfo               ! info character
533      INTEGER               :: if90id               ! nf90 file identifier
534      INTEGER               :: itype                ! variable type
535      INTEGER, DIMENSION(4) :: ichunksz             ! NetCDF4 chunk sizes. Will be computed using
536      !                                             ! nn_nchunks_[i,j,k,t] namelist parameters
537      INTEGER               :: ichunkalg, ishuffle, ideflate, ideflate_level
538      !                                             ! NetCDF4 internally fixed parameters
539      LOGICAL               :: lchunk               ! logical switch to activate chunking and compression
540      !                                             ! when appropriate (currently chunking is applied to 4d fields only)
541      INTEGER               :: idlv                 ! local variable
542      !---------------------------------------------------------------------
543      !
544      clinfo = '          iom_nf90_rp0123d, file: '//TRIM(iom_file(kiomid)%name)//', var: '//TRIM(cdvar)
545      if90id = iom_file(kiomid)%nfid
546      !
547      ! define dimension variables if it is not already done
548      ! ==========================
549      IF( iom_file(kiomid)%nvars == 0 ) THEN
550         ! are we in define mode?
551         IF( iom_file(kiomid)%irec /= -1 ) THEN   ! trick: irec used to know if the file is in define mode or not
552            CALL iom_nf90_check(NF90_REDEF( if90id ), clinfo)   ;   iom_file(kiomid)%irec = -1
553         ENDIF
554         ! define the dimension variables if it is not already done
555         DO jd = 1, 2
556            CALL iom_nf90_check(NF90_INQUIRE_DIMENSION(if90id,jd,iom_file(kiomid)%cn_var(jd),iom_file(kiomid)%dimsz(jd,jd)),clinfo)
557            CALL iom_nf90_check(NF90_DEF_VAR( if90id, TRIM(iom_file(kiomid)%cn_var(jd)), NF90_FLOAT , (/ 1, 2 /),   &
558               &                              iom_file(kiomid)%nvid(jd) ), clinfo)
559         END DO
560         iom_file(kiomid)%dimsz(2,1) = iom_file(kiomid)%dimsz(2,2)   ! second dim of first  variable
561         iom_file(kiomid)%dimsz(1,2) = iom_file(kiomid)%dimsz(1,1)   ! first  dim of second variable
562         DO jd = 3, 4
563            CALL iom_nf90_check(NF90_INQUIRE_DIMENSION(if90id,jd,iom_file(kiomid)%cn_var(jd),iom_file(kiomid)%dimsz(1,jd)), clinfo)
564            CALL iom_nf90_check(NF90_DEF_VAR( if90id, TRIM(iom_file(kiomid)%cn_var(jd)), NF90_FLOAT , (/ jd   /),   &
565               &                              iom_file(kiomid)%nvid(jd) ), clinfo)
566         END DO
567         ! update informations structure related the dimension variable we just added...
568         iom_file(kiomid)%nvars       = 4
569         iom_file(kiomid)%luld(1:4)   = (/ .FALSE., .FALSE., .FALSE., .TRUE. /)
570         iom_file(kiomid)%ndims(1:4)  = (/ 2, 2, 1, 1 /)
571         IF(lwp) WRITE(numout,*) TRIM(clinfo)//' define dimension variables done'
572      ENDIF
573      ! define the data if it is not already done
574      ! ===============
575      IF( kvid <= 0 ) THEN
576         !
577         ! NetCDF4 chunking and compression fixed settings
578         ichunkalg = 0
579         ishuffle = 1
580         ideflate = 1
581         ideflate_level = 1
582         !
583         idvar = iom_file(kiomid)%nvars + 1
584         ! are we in define mode?
585         IF( iom_file(kiomid)%irec /= -1 ) THEN   ! trick: irec used to know if the file is in define mode or not
586            CALL iom_nf90_check(NF90_REDEF( if90id ), clinfo)   ;   iom_file(kiomid)%irec = -1
587         ENDIF
588         ! variable definition
589         IF(     PRESENT(pv_r0d) ) THEN   ;   idims = 0
590         ELSEIF( PRESENT(pv_r1d) ) THEN
591                                              idims = 2   ;   idimid(1:idims) = (/3,4/)
592         ELSEIF( PRESENT(pv_r2d) ) THEN   ;   idims = 3   ;   idimid(1:idims) = (/1,2,4/)
593         ELSEIF( PRESENT(pv_r3d) ) THEN
594                                              idims = 4   ;   idimid(1:idims) = (/1,2,3,4/)
595         ENDIF
596         IF( PRESENT(ktype) ) THEN   ! variable external type
597            SELECT CASE (ktype)
598            CASE (jp_r8)   ;   itype = NF90_DOUBLE
599            CASE (jp_r4)   ;   itype = NF90_FLOAT
600            CASE (jp_i4)   ;   itype = NF90_INT
601            CASE (jp_i2)   ;   itype = NF90_SHORT
602            CASE (jp_i1)   ;   itype = NF90_BYTE
603            CASE DEFAULT   ;   CALL ctl_stop( TRIM(clinfo)//' unknown variable type' )
604            END SELECT
605         ELSE
606            itype = NF90_DOUBLE
607         ENDIF
608         IF( PRESENT(pv_r0d) ) THEN
609            CALL iom_nf90_check(NF90_DEF_VAR( if90id, TRIM(cdvar), itype,                    &
610               &                              iom_file(kiomid)%nvid(idvar) ), clinfo )
611         ELSE
612            CALL iom_nf90_check(NF90_DEF_VAR( if90id, TRIM(cdvar), itype, idimid(1:idims),   &
613               &                              iom_file(kiomid)%nvid(idvar) ), clinfo )
614         ENDIF
615         lchunk = .false.
616         IF( snc4set%luse .AND. idims == 4 )   lchunk = .true.
617         ! update informations structure related the new variable we want to add...
618         iom_file(kiomid)%nvars         = idvar
619         iom_file(kiomid)%cn_var(idvar) = TRIM(cdvar)
620         iom_file(kiomid)%scf(idvar)    = 1.
621         iom_file(kiomid)%ofs(idvar)    = 0.
622         iom_file(kiomid)%ndims(idvar)  = idims
623         IF( .NOT. PRESENT(pv_r0d) ) THEN   ;   iom_file(kiomid)%luld(idvar) = .TRUE.
624         ELSE                               ;   iom_file(kiomid)%luld(idvar) = .FALSE.
625         ENDIF
626         DO jd = 1, idims
627            CALL iom_nf90_check(NF90_INQUIRE_DIMENSION( if90id, idimid(jd), len = iom_file(kiomid)%dimsz(jd,idvar) ), clinfo)
628            IF ( lchunk ) ichunksz(jd) = iom_file(kiomid)%dimsz(jd,idvar)
629         END DO
630         IF ( lchunk ) THEN
631            ! Calculate chunk sizes by partitioning each dimension as requested in namnc4 namelist
632            ! Disallow very small chunk sizes and prevent chunk sizes larger than each individual dimension
633            ichunksz(1) = MIN( ichunksz(1),MAX( (ichunksz(1)-1)/snc4set%ni + 1 ,16 ) ) ! Suggested default nc4set%ni=4
634            ichunksz(2) = MIN( ichunksz(2),MAX( (ichunksz(2)-1)/snc4set%nj + 1 ,16 ) ) ! Suggested default nc4set%nj=2
635            ichunksz(3) = MIN( ichunksz(3),MAX( (ichunksz(3)-1)/snc4set%nk + 1 , 1 ) ) ! Suggested default nc4set%nk=6
636            ichunksz(4) = 1                                                            ! Do not allow chunks to span the
637            !                                                                          ! unlimited dimension
638            CALL iom_nf90_check(SET_NF90_DEF_VAR_CHUNKING(if90id, idvar, ichunkalg, ichunksz), clinfo)
639            CALL iom_nf90_check(SET_NF90_DEF_VAR_DEFLATE(if90id, idvar, ishuffle, ideflate, ideflate_level), clinfo)
640            IF(lwp) WRITE(numout,*) TRIM(clinfo)//' chunked ok. Chunks sizes: ', ichunksz
641         ENDIF
642         IF(lwp) WRITE(numout,*) TRIM(clinfo)//' defined ok'
643      ELSE
644         idvar = kvid
645      ENDIF
646      !
647      ! time step kwrite : write the variable
648      IF( kt == kwrite ) THEN
649         ! are we in write mode?
650         IF( iom_file(kiomid)%irec == -1 ) THEN   ! trick: irec used to know if the file is in define mode or not
651            CALL iom_nf90_check(NF90_ENDDEF( if90id ), clinfo)   ;   iom_file(kiomid)%irec = 0
652         ENDIF
653         ! on what kind of domain must the data be written?
654         IF( PRESENT(pv_r2d) .OR. PRESENT(pv_r3d) ) THEN
655            idimsz(1:2) = iom_file(kiomid)%dimsz(1:2,idvar)
656            IF(     idimsz(1) == Ni_0 .AND. idimsz(2) == Nj_0 ) THEN
657               ix1 = Nis0   ;   ix2 = Nie0   ;   iy1 = Njs0   ;   iy2 = Nje0
658            ELSEIF( idimsz(1) == jpi  .AND. idimsz(2) == jpj  ) THEN
659               ix1 = 1      ;   ix2 = jpi    ;   iy1 = 1      ;   iy2 = jpj
660            ELSEIF( idimsz(1) == jpi  .AND. idimsz(2) == jpj  ) THEN
661               ix1 = 1      ;   ix2 = jpi    ;   iy1 = 1      ;   iy2 = jpj
662            ELSE
663               CALL ctl_stop( 'iom_nf90_rp0123d: should have been an impossible case...' )
664            ENDIF
665
666            ! write dimension variables if it is not already done
667            ! =============
668            ! trick: is defined to 0 => dimension variable are defined but not yet written
669            IF( iom_file(kiomid)%dimsz(1, 4) == 0 ) THEN   ! time_counter = 0
670               CALL iom_nf90_check(    NF90_PUT_VAR( if90id, 1,                            glamt(ix1:ix2, iy1:iy2) ), clinfo )
671               CALL iom_nf90_check(    NF90_PUT_VAR( if90id, 2,                            gphit(ix1:ix2, iy1:iy2) ), clinfo )
672               SELECT CASE (iom_file(kiomid)%comp)
673               CASE ('OCE') 
674                  CALL iom_nf90_check( NF90_PUT_VAR( if90id, 3,                                           gdept_1d ), clinfo )
675               CASE ('ABL')
676                  CALL iom_nf90_check( NF90_PUT_VAR( if90id, 3,                                            ght_abl ), clinfo )
677               CASE DEFAULT
678                  CALL iom_nf90_check( NF90_PUT_VAR( if90id, 3, (/ (idlv, idlv = 1,iom_file(kiomid)%dimsz(1,3)) /) ), clinfo )
679               END SELECT
680               ! "wrong" value: to be improved but not really useful...
681               CALL iom_nf90_check(   NF90_PUT_VAR( if90id, 4,                                                  kt ), clinfo )   
682               ! update the size of the variable corresponding to the unlimited dimension
683               iom_file(kiomid)%dimsz(1, 4) = 1   ! so we don't enter this IF case any more...
684               IF(lwp) WRITE(numout,*) TRIM(clinfo)//' write dimension variables done'
685            ENDIF
686         ENDIF
687
688         ! write the data
689         ! =============
690         IF(     PRESENT(pv_r0d) ) THEN
691            CALL iom_nf90_check( NF90_PUT_VAR( if90id, idvar, pv_r0d                    ), clinfo )
692         ELSEIF( PRESENT(pv_r1d) ) THEN
693            CALL iom_nf90_check( NF90_PUT_VAR( if90id, idvar, pv_r1d(:)                 ), clinfo )
694         ELSEIF( PRESENT(pv_r2d) ) THEN
695            CALL iom_nf90_check( NF90_PUT_VAR( if90id, idvar, pv_r2d(ix1:ix2,iy1:iy2)   ), clinfo )
696         ELSEIF( PRESENT(pv_r3d) ) THEN
697            CALL iom_nf90_check( NF90_PUT_VAR( if90id, idvar, pv_r3d(ix1:ix2,iy1:iy2,:) ), clinfo )
698         ENDIF
699         ! add 1 to the size of the temporal dimension (not really useful...)
700         IF( iom_file(kiomid)%luld(idvar) )   iom_file(kiomid)%dimsz(iom_file(kiomid)%ndims(idvar), idvar)    &
701               &                            = iom_file(kiomid)%dimsz(iom_file(kiomid)%ndims(idvar), idvar) + 1
702         IF(lwp) WRITE(numout,*) TRIM(clinfo)//' written ok'
703      ENDIF
704      !     
705   END SUBROUTINE iom_nf90_rp0123d
706
707
708   SUBROUTINE iom_nf90_check( kstatus, cdinfo )
709      !!--------------------------------------------------------------------
710      !!                   ***  SUBROUTINE iom_nf90_check  ***
711      !!
712      !! ** Purpose :   check nf90 errors
713      !!--------------------------------------------------------------------
714      INTEGER,          INTENT(in) :: kstatus
715      CHARACTER(LEN=*), INTENT(in) :: cdinfo
716      !---------------------------------------------------------------------
717      IF(kstatus /= nf90_noerr)   CALL ctl_stop( 'iom_nf90_check : '//TRIM(nf90_strerror(kstatus)), TRIM(cdinfo) )
718   END SUBROUTINE iom_nf90_check
719
720   !!======================================================================
721END MODULE iom_nf90
Note: See TracBrowser for help on using the repository browser.