source: NEMO/branches/2020/dev_r12558_HPC-08_epico_Extra_Halo/src/OCE/TRA/traadv.F90 @ 12586

Last change on this file since 12586 was 12586, checked in by francesca, 12 months ago

Add extra-halo support (jperio 3,4) - ticket #2366

  • Property svn:keywords set to Id
File size: 15.5 KB
Line 
1MODULE traadv
2   !!==============================================================================
3   !!                       ***  MODULE  traadv  ***
4   !! Ocean active tracers:  advection trend
5   !!==============================================================================
6   !! History :  2.0  !  2005-11  (G. Madec)  Original code
7   !!            3.3  !  2010-09  (C. Ethe, G. Madec)  merge TRC-TRA + switch from velocity to transport
8   !!            3.6  !  2011-06  (G. Madec)  Addition of Mixed Layer Eddy parameterisation
9   !!            3.7  !  2014-05  (G. Madec)  Add 2nd/4th order cases for CEN and FCT schemes
10   !!             -   !  2014-12  (G. Madec) suppression of cross land advection option
11   !!            3.6  !  2015-06  (E. Clementi) Addition of Stokes drift in case of wave coupling
12   !!----------------------------------------------------------------------
13
14   !!----------------------------------------------------------------------
15   !!   tra_adv       : compute ocean tracer advection trend
16   !!   tra_adv_init  : control the different options of advection scheme
17   !!----------------------------------------------------------------------
18   USE oce            ! ocean dynamics and active tracers
19   USE dom_oce        ! ocean space and time domain
20   USE domvvl         ! variable vertical scale factors
21   USE sbcwave        ! wave module
22   USE sbc_oce        ! surface boundary condition: ocean
23   USE traadv_cen     ! centered scheme            (tra_adv_cen  routine)
24   USE traadv_fct     ! FCT      scheme            (tra_adv_fct  routine)
25   USE traadv_mus     ! MUSCL    scheme            (tra_adv_mus  routine)
26   USE traadv_ubs     ! UBS      scheme            (tra_adv_ubs  routine)
27   USE traadv_qck     ! QUICKEST scheme            (tra_adv_qck  routine)
28   USE tramle         ! Mixed Layer Eddy transport (tra_mle_trp  routine)
29   USE ldftra         ! Eddy Induced transport     (ldf_eiv_trp  routine)
30   USE ldfslp         ! Lateral diffusion: slopes of neutral surfaces
31   USE trd_oce        ! trends: ocean variables
32   USE trdtra         ! trends manager: tracers
33   USE diaptr         ! Poleward heat transport
34   !
35   USE in_out_manager ! I/O manager
36   USE iom            ! I/O module
37   USE prtctl         ! Print control
38   USE lib_mpp        ! MPP library
39   USE timing         ! Timing
40
41   IMPLICIT NONE
42   PRIVATE
43
44   PUBLIC   tra_adv        ! called by step.F90
45   PUBLIC   tra_adv_init   ! called by nemogcm.F90
46
47   !                            !!* Namelist namtra_adv *
48   LOGICAL ::   ln_traadv_OFF    ! no advection on T and S
49   LOGICAL ::   ln_traadv_cen    ! centered scheme flag
50   INTEGER ::      nn_cen_h, nn_cen_v   ! =2/4 : horizontal and vertical choices of the order of CEN scheme
51   LOGICAL ::   ln_traadv_fct    ! FCT scheme flag
52   INTEGER ::      nn_fct_h, nn_fct_v   ! =2/4 : horizontal and vertical choices of the order of FCT scheme
53   LOGICAL ::   ln_traadv_mus    ! MUSCL scheme flag
54   LOGICAL ::      ln_mus_ups           ! use upstream scheme in vivcinity of river mouths
55   LOGICAL ::   ln_traadv_ubs    ! UBS scheme flag
56   INTEGER ::      nn_ubs_v             ! =2/4 : vertical choice of the order of UBS scheme
57   LOGICAL ::   ln_traadv_qck    ! QUICKEST scheme flag
58
59   INTEGER ::   nadv             ! choice of the type of advection scheme
60   !                             ! associated indices:
61   INTEGER, PARAMETER ::   np_NO_adv  = 0   ! no T-S advection
62   INTEGER, PARAMETER ::   np_CEN     = 1   ! 2nd/4th order centered scheme
63   INTEGER, PARAMETER ::   np_FCT     = 2   ! 2nd/4th order Flux Corrected Transport scheme
64   INTEGER, PARAMETER ::   np_MUS     = 3   ! MUSCL scheme
65   INTEGER, PARAMETER ::   np_UBS     = 4   ! 3rd order Upstream Biased Scheme
66   INTEGER, PARAMETER ::   np_QCK     = 5   ! QUICK scheme
67   
68   !!----------------------------------------------------------------------
69   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
70   !! $Id$
71   !! Software governed by the CeCILL license (see ./LICENSE)
72   !!----------------------------------------------------------------------
73CONTAINS
74
75   SUBROUTINE tra_adv( kt, Kbb, Kmm, pts, Krhs )
76      !!----------------------------------------------------------------------
77      !!                  ***  ROUTINE tra_adv  ***
78      !!
79      !! ** Purpose :   compute the ocean tracer advection trend.
80      !!
81      !! ** Method  : - Update (uu(:,:,:,Krhs),vv(:,:,:,Krhs)) with the advection term following nadv
82      !!----------------------------------------------------------------------
83      INTEGER                                  , INTENT(in)    :: kt             ! ocean time-step index
84      INTEGER                                  , INTENT(in)    :: Kbb, Kmm, Krhs ! time level indices
85      REAL(wp), POINTER, DIMENSION(:,:,:,:,:)  , INTENT(inout) :: pts            ! active tracers and RHS of tracer equation
86      !
87      INTEGER ::   jk   ! dummy loop index
88      REAL(wp), POINTER, DIMENSION(:,:,:)        :: zuu, zvv, zww   ! 3D workspace
89      REAL(wp), DIMENSION(:,:,:), ALLOCATABLE ::   ztrdt, ztrds
90      !!----------------------------------------------------------------------
91      !
92      IF( ln_timing )   CALL timing_start('tra_adv')
93      ALLOCATE( zuu(jpi,jpj,jpk), zvv(jpi,jpj,jpk), zww(jpi,jpj,jpk) )
94      !
95      !                                         !==  effective transport  ==!
96      zuu(:,:,jpk) = 0._wp
97      zvv(:,:,jpk) = 0._wp
98      zww(:,:,jpk) = 0._wp
99      IF( ln_wave .AND. ln_sdw )  THEN
100         DO jk = 1, jpkm1                                                       ! eulerian transport + Stokes Drift
101            zuu(:,:,jk) = e2u  (:,:) * e3u(:,:,jk,Kmm) * ( uu(:,:,jk,Kmm) + usd(:,:,jk) )
102            zvv(:,:,jk) = e1v  (:,:) * e3v(:,:,jk,Kmm) * ( vv(:,:,jk,Kmm) + vsd(:,:,jk) )
103            zww(:,:,jk) = e1e2t(:,:)                 * ( ww(:,:,jk) + wsd(:,:,jk) )
104         END DO
105      ELSE
106         DO jk = 1, jpkm1
107            zuu(:,:,jk) = e2u  (:,:) * e3u(:,:,jk,Kmm) * uu(:,:,jk,Kmm)               ! eulerian transport only
108            zvv(:,:,jk) = e1v  (:,:) * e3v(:,:,jk,Kmm) * vv(:,:,jk,Kmm)
109            zww(:,:,jk) = e1e2t(:,:)                 * ww(:,:,jk)
110         END DO
111      ENDIF
112      !
113      IF( ln_vvl_ztilde .OR. ln_vvl_layer ) THEN                                ! add z-tilde and/or vvl corrections
114         zuu(:,:,:) = zuu(:,:,:) + un_td(:,:,:)
115         zvv(:,:,:) = zvv(:,:,:) + vn_td(:,:,:)
116      ENDIF
117      !
118      zuu(:,:,jpk) = 0._wp                                                      ! no transport trough the bottom
119      zvv(:,:,jpk) = 0._wp
120      zww(:,:,jpk) = 0._wp
121      !
122      IF( ln_ldfeiv .AND. .NOT. ln_traldf_triad )   &
123         &              CALL ldf_eiv_trp( kt, nit000, zuu, zvv, zww, 'TRA', Kmm, Krhs )   ! add the eiv transport (if necessary)
124      !
125      IF( ln_mle    )   CALL tra_mle_trp( kt, nit000, zuu, zvv, zww, 'TRA', Kmm       )   ! add the mle transport (if necessary)
126      !
127      CALL iom_put( "uocetr_eff", zuu )                                        ! output effective transport     
128      CALL iom_put( "vocetr_eff", zvv )
129      CALL iom_put( "wocetr_eff", zww )
130      !
131!!gm ???
132      CALL dia_ptr( kt, Kmm, zvv )                                    ! diagnose the effective MSF
133!!gm ???
134      !
135
136      IF( l_trdtra )   THEN                    !* Save ta and sa trends
137         ALLOCATE( ztrdt(jpi,jpj,jpk), ztrds(jpi,jpj,jpk) )
138         ztrdt(:,:,:) = pts(:,:,:,jp_tem,Krhs)
139         ztrds(:,:,:) = pts(:,:,:,jp_sal,Krhs)
140      ENDIF
141      !
142      SELECT CASE ( nadv )                      !==  compute advection trend and add it to general trend  ==!
143      !
144      CASE ( np_CEN )                                 ! Centered scheme : 2nd / 4th order
145         CALL tra_adv_cen    ( kt, nit000, 'TRA',         zuu, zvv, zww, Kmm, pts, jpts, Krhs, nn_cen_h, nn_cen_v )
146      CASE ( np_FCT )                                 ! FCT scheme      : 2nd / 4th order
147         CALL tra_adv_fct    ( kt, nit000, 'TRA', rDt, zuu, zvv, zww, Kbb, Kmm, pts, jpts, Krhs, nn_fct_h, nn_fct_v )
148      CASE ( np_MUS )                                 ! MUSCL
149         CALL tra_adv_mus    ( kt, nit000, 'TRA', rDt, zuu, zvv, zww, Kbb, Kmm, pts, jpts, Krhs, ln_mus_ups ) 
150      CASE ( np_UBS )                                 ! UBS
151         CALL tra_adv_ubs    ( kt, nit000, 'TRA', rDt, zuu, zvv, zww, Kbb, Kmm, pts, jpts, Krhs, nn_ubs_v   )
152      CASE ( np_QCK )                                 ! QUICKEST
153         CALL tra_adv_qck    ( kt, nit000, 'TRA', rDt, zuu, zvv, zww, Kbb, Kmm, pts, jpts, Krhs )
154      !
155      END SELECT
156      !
157      IF( l_trdtra )   THEN                      ! save the advective trends for further diagnostics
158         DO jk = 1, jpkm1
159            ztrdt(:,:,jk) = pts(:,:,jk,jp_tem,Krhs) - ztrdt(:,:,jk)
160            ztrds(:,:,jk) = pts(:,:,jk,jp_sal,Krhs) - ztrds(:,:,jk)
161         END DO
162         CALL trd_tra( kt, Kmm, Krhs, 'TRA', jp_tem, jptra_totad, ztrdt )
163         CALL trd_tra( kt, Kmm, Krhs, 'TRA', jp_sal, jptra_totad, ztrds )
164         DEALLOCATE( ztrdt, ztrds )
165      ENDIF
166      !                                              ! print mean trends (used for debugging)
167      IF(sn_cfctl%l_prtctl)   CALL prt_ctl( tab3d_1=pts(:,:,:,jp_tem,Krhs), clinfo1=' adv  - Ta: ', mask1=tmask,               &
168         &                                  tab3d_2=pts(:,:,:,jp_sal,Krhs), clinfo2=       ' Sa: ', mask2=tmask, clinfo3='tra' )
169      !
170      DEALLOCATE( zuu, zvv, zww )
171      IF( ln_timing )   CALL timing_stop( 'tra_adv' )
172      !
173   END SUBROUTINE tra_adv
174
175
176   SUBROUTINE tra_adv_init
177      !!---------------------------------------------------------------------
178      !!                  ***  ROUTINE tra_adv_init  ***
179      !!               
180      !! ** Purpose :   Control the consistency between namelist options for
181      !!              tracer advection schemes and set nadv
182      !!----------------------------------------------------------------------
183      INTEGER ::   ioptio, ios   ! Local integers
184      !
185      NAMELIST/namtra_adv/ ln_traadv_OFF,                        &   ! No advection
186         &                 ln_traadv_cen , nn_cen_h, nn_cen_v,   &   ! CEN
187         &                 ln_traadv_fct , nn_fct_h, nn_fct_v,   &   ! FCT
188         &                 ln_traadv_mus , ln_mus_ups,           &   ! MUSCL
189         &                 ln_traadv_ubs ,           nn_ubs_v,   &   ! UBS
190         &                 ln_traadv_qck                             ! QCK
191      !!----------------------------------------------------------------------
192      !
193      !                                !==  Namelist  ==!
194      READ  ( numnam_ref, namtra_adv, IOSTAT = ios, ERR = 901)
195901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namtra_adv in reference namelist' )
196      !
197      READ  ( numnam_cfg, namtra_adv, IOSTAT = ios, ERR = 902 )
198902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namtra_adv in configuration namelist' )
199      IF(lwm) WRITE( numond, namtra_adv )
200      !
201      IF(lwp) THEN                           ! Namelist print
202         WRITE(numout,*)
203         WRITE(numout,*) 'tra_adv_init : choice/control of the tracer advection scheme'
204         WRITE(numout,*) '~~~~~~~~~~~~'
205         WRITE(numout,*) '   Namelist namtra_adv : chose a advection scheme for tracers'
206         WRITE(numout,*) '      No advection on T & S                     ln_traadv_OFF = ', ln_traadv_OFF
207         WRITE(numout,*) '      centered scheme                           ln_traadv_cen = ', ln_traadv_cen
208         WRITE(numout,*) '            horizontal 2nd/4th order               nn_cen_h   = ', nn_fct_h
209         WRITE(numout,*) '            vertical   2nd/4th order               nn_cen_v   = ', nn_fct_v
210         WRITE(numout,*) '      Flux Corrected Transport scheme           ln_traadv_fct = ', ln_traadv_fct
211         WRITE(numout,*) '            horizontal 2nd/4th order               nn_fct_h   = ', nn_fct_h
212         WRITE(numout,*) '            vertical   2nd/4th order               nn_fct_v   = ', nn_fct_v
213         WRITE(numout,*) '      MUSCL scheme                              ln_traadv_mus = ', ln_traadv_mus
214         WRITE(numout,*) '            + upstream scheme near river mouths    ln_mus_ups = ', ln_mus_ups
215         WRITE(numout,*) '      UBS scheme                                ln_traadv_ubs = ', ln_traadv_ubs
216         WRITE(numout,*) '            vertical   2nd/4th order               nn_ubs_v   = ', nn_ubs_v
217         WRITE(numout,*) '      QUICKEST scheme                           ln_traadv_qck = ', ln_traadv_qck
218      ENDIF
219      !
220      !                                !==  Parameter control & set nadv ==!
221      ioptio = 0                       
222      IF( ln_traadv_OFF ) THEN   ;   ioptio = ioptio + 1   ;   nadv = np_NO_adv   ;   ENDIF
223      IF( ln_traadv_cen ) THEN   ;   ioptio = ioptio + 1   ;   nadv = np_CEN      ;   ENDIF
224      IF( ln_traadv_fct ) THEN   ;   ioptio = ioptio + 1   ;   nadv = np_FCT      ;   ENDIF
225      IF( ln_traadv_mus ) THEN   ;   ioptio = ioptio + 1   ;   nadv = np_MUS      ;   ENDIF
226      IF( ln_traadv_ubs ) THEN   ;   ioptio = ioptio + 1   ;   nadv = np_UBS      ;   ENDIF
227      IF( ln_traadv_qck ) THEN   ;   ioptio = ioptio + 1   ;   nadv = np_QCK      ;   ENDIF
228      !
229      IF( ioptio /= 1 )   CALL ctl_stop( 'tra_adv_init: Choose ONE advection option in namelist namtra_adv' )
230      !
231      IF( ln_traadv_cen .AND. ( nn_cen_h /= 2 .AND. nn_cen_h /= 4 )   &          ! Centered
232                        .AND. ( nn_cen_v /= 2 .AND. nn_cen_v /= 4 )   ) THEN
233        CALL ctl_stop( 'tra_adv_init: CEN scheme, choose 2nd or 4th order' )
234      ENDIF
235      IF( ln_traadv_fct .AND. ( nn_fct_h /= 2 .AND. nn_fct_h /= 4 )   &          ! FCT
236                        .AND. ( nn_fct_v /= 2 .AND. nn_fct_v /= 4 )   ) THEN
237        CALL ctl_stop( 'tra_adv_init: FCT scheme, choose 2nd or 4th order' )
238      ENDIF
239      IF( ln_traadv_ubs .AND. ( nn_ubs_v /= 2 .AND. nn_ubs_v /= 4 )   ) THEN     ! UBS
240        CALL ctl_stop( 'tra_adv_init: UBS scheme, choose 2nd or 4th order' )
241      ENDIF
242      IF( ln_traadv_ubs .AND. nn_ubs_v == 4 ) THEN
243         CALL ctl_warn( 'tra_adv_init: UBS scheme, only 2nd FCT scheme available on the vertical. It will be used' )
244      ENDIF
245      IF( ln_isfcav ) THEN                                                       ! ice-shelf cavities
246         IF(  ln_traadv_cen .AND. nn_cen_v == 4    .OR.   &                            ! NO 4th order with ISF
247            & ln_traadv_fct .AND. nn_fct_v == 4   )   CALL ctl_stop( 'tra_adv_init: 4th order COMPACT scheme not allowed with ISF' )
248      ENDIF
249      !
250      !                                !==  Print the choice  ==! 
251      IF(lwp) THEN
252         WRITE(numout,*)
253         SELECT CASE ( nadv )
254         CASE( np_NO_adv  )   ;   WRITE(numout,*) '   ==>>>   NO T-S advection'
255         CASE( np_CEN     )   ;   WRITE(numout,*) '   ==>>>   CEN      scheme is used. Horizontal order: ', nn_cen_h,   &
256            &                                                                        ' Vertical   order: ', nn_cen_v
257         CASE( np_FCT     )   ;   WRITE(numout,*) '   ==>>>   FCT      scheme is used. Horizontal order: ', nn_fct_h,   &
258            &                                                                        ' Vertical   order: ', nn_fct_v
259         CASE( np_MUS     )   ;   WRITE(numout,*) '   ==>>>   MUSCL    scheme is used'
260         CASE( np_UBS     )   ;   WRITE(numout,*) '   ==>>>   UBS      scheme is used'
261         CASE( np_QCK     )   ;   WRITE(numout,*) '   ==>>>   QUICKEST scheme is used'
262         END SELECT
263      ENDIF
264      !
265      CALL tra_mle_init            !== initialisation of the Mixed Layer Eddy parametrisation (MLE)  ==!
266      !
267   END SUBROUTINE tra_adv_init
268
269  !!======================================================================
270END MODULE traadv
Note: See TracBrowser for help on using the repository browser.