source: NEMO/branches/2020/dev_r12563_ASINTER-06_ABL_improvement/tests/BENCH/MY_SRC/usrdef_istate.F90 @ 13197

Last change on this file since 13197 was 13197, checked in by gsamson, 4 months ago

merge with trunk@r13136 with a more recent svn version; pass all SETTE tests; results identical to trunk@r13136; ticket #2419

File size: 4.4 KB
Line 
1MODULE usrdef_istate
2   !!======================================================================
3   !!                     ***  MODULE usrdef_istate   ***
4   !!
5   !!                      ===  BENCH configuration  ===
6   !!
7   !! User defined : set the initial state of a user configuration
8   !!======================================================================
9   !! History :  NEMO !
10   !!----------------------------------------------------------------------
11
12   !!----------------------------------------------------------------------
13   !!  usr_def_istate : initial state in Temperature and salinity
14   !!----------------------------------------------------------------------
15   USE par_oce        ! ocean space and time domain
16   USE dom_oce       
17   USE phycst         ! physical constants
18   !
19   USE in_out_manager ! I/O manager
20   USE lib_mpp        ! MPP library
21   USE lbclnk          ! lateral boundary conditions - mpp exchanges
22   !   
23   USE usrdef_nam
24   
25   IMPLICIT NONE
26   PRIVATE
27
28   PUBLIC   usr_def_istate   ! called by istate.F90
29
30   !! * Substitutions
31#  include "do_loop_substitute.h90"
32   !!----------------------------------------------------------------------
33   !! NEMO/OPA 4.0 , NEMO Consortium (2016)
34   !! $Id$
35   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
36   !!----------------------------------------------------------------------
37CONTAINS
38 
39   SUBROUTINE usr_def_istate( pdept, ptmask, pts, pu, pv, pssh )
40      !!----------------------------------------------------------------------
41      !!                   ***  ROUTINE usr_def_istate  ***
42      !!
43      !! ** Purpose :   Initialization of the dynamics and tracers
44      !!                Here BENCH configuration
45      !!
46      !! ** Method  :   Set a gaussian anomaly of pressure and associated
47      !!                geostrophic velocities
48      !!----------------------------------------------------------------------
49      REAL(wp), DIMENSION(jpi,jpj,jpk)     , INTENT(in   ) ::   pdept   ! depth of t-point               [m]
50      REAL(wp), DIMENSION(jpi,jpj,jpk)     , INTENT(in   ) ::   ptmask  ! t-point ocean mask             [m]
51      REAL(wp), DIMENSION(jpi,jpj,jpk,jpts), INTENT(  out) ::   pts     ! T & S fields      [Celsius ; g/kg]
52      REAL(wp), DIMENSION(jpi,jpj,jpk)     , INTENT(  out) ::   pu      ! i-component of the velocity  [m/s]
53      REAL(wp), DIMENSION(jpi,jpj,jpk)     , INTENT(  out) ::   pv      ! j-component of the velocity  [m/s]
54      REAL(wp), DIMENSION(jpi,jpj)         , INTENT(  out) ::   pssh    ! sea-surface height
55      !
56      REAL(wp), DIMENSION(jpi,jpj) ::   z2d   ! 2D workspace
57      REAL(wp) ::   zfact
58      INTEGER  ::   ji, jj, jk
59      !!----------------------------------------------------------------------
60      !
61      IF(lwp) WRITE(numout,*)
62      IF(lwp) WRITE(numout,*) 'usr_def_istate : BENCH configuration, analytical definition of initial state'
63      IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~~~   '
64      !
65      ! define unique value on each point. z2d ranging from 0.05 to -0.05
66      DO_2D_11_11
67         z2d(ji,jj) = 0.1 * ( 0.5 - REAL( mig(ji) + (mjg(jj)-1) * jpiglo, wp ) / REAL( jpiglo * jpjglo, wp ) )
68      END_2D
69      !
70      ! sea level:
71      pssh(:,:) = z2d(:,:)                                                ! +/- 0.05 m
72      !
73      DO jk = 1, jpk
74         zfact = REAL(jk-1,wp) / REAL(jpk-1,wp)   ! 0 to 1 to add a basic stratification
75         ! temperature choosen to lead to ~50% ice at the beginning if rn_thres_sst = 0.5
76         pts(:,:,jk,jp_tem) = 20._wp*z2d(:,:) - 1._wp - 0.5_wp * zfact    ! -1 to -1.5 +/-1.0 degG
77         ! salinity: 
78         pts(:,:,jk,jp_sal) = 30._wp + 1._wp * zfact + z2d(:,:)           ! 30 to 31 +/- 0.05 psu
79         ! velocities:
80         pu(:,:,jk) = z2d(:,:) *  0.1_wp * umask(:,:,jk)                  ! +/- 0.005  m/s
81         pv(:,:,jk) = z2d(:,:) * 0.01_wp * vmask(:,:,jk)                  ! +/- 0.0005 m/s
82      ENDDO
83      !
84      CALL lbc_lnk('usrdef_istate', pssh, 'T',  1. )            ! apply boundary conditions
85      CALL lbc_lnk('usrdef_istate',  pts, 'T',  1. )            ! apply boundary conditions
86      CALL lbc_lnk('usrdef_istate',   pu, 'U', -1. )            ! apply boundary conditions
87      CALL lbc_lnk('usrdef_istate',   pv, 'V', -1. )            ! apply boundary conditions
88     
89   END SUBROUTINE usr_def_istate
90
91   !!======================================================================
92END MODULE usrdef_istate
Note: See TracBrowser for help on using the repository browser.