source: NEMO/branches/2020/dev_r12702_ASINTER-02_emanuelaclementi_Waves/src/OCE/ZDF/zdfsh2.F90 @ 12991

Last change on this file since 12991 was 12991, checked in by emanuelaclementi, 5 months ago

Included wave-current processes following Couvelard et al 2019 and Gurvan code -ticket #2155

  • Property svn:keywords set to Id
File size: 5.2 KB
Line 
1MODULE zdfsh2
2   !!======================================================================
3   !!                       ***  MODULE  zdfsh2  ***
4   !! Ocean physics:  shear production term of TKE
5   !!=====================================================================
6   !! History :   -   !  2014-10  (A. Barthelemy, G. Madec)  original code
7   !!   NEMO     4.0  !  2017-04  (G. Madec)  remove u-,v-pts avm
8   !!----------------------------------------------------------------------
9
10   !!----------------------------------------------------------------------
11   !!   zdf_sh2       : compute mixing the shear production term of TKE
12   !!----------------------------------------------------------------------
13   USE oce
14   USE dom_oce        ! domain: ocean
15   USE sbcwave        ! Surface Waves (add Stokes shear)
16   USE sbc_oce , ONLY: ln_stshear  !Stoked Drift shear contribution
17   !
18   USE in_out_manager ! I/O manager
19   USE lib_mpp        ! MPP library
20
21   IMPLICIT NONE
22   PRIVATE
23
24   PUBLIC   zdf_sh2        ! called by zdftke, zdfglf, and zdfric
25
26   !! * Substitutions
27#  include "do_loop_substitute.h90"
28   !!----------------------------------------------------------------------
29   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
30   !! $Id$
31   !! Software governed by the CeCILL license (see ./LICENSE)
32   !!----------------------------------------------------------------------
33CONTAINS
34
35   SUBROUTINE zdf_sh2( Kbb, Kmm, p_avm, p_sh2  ) 
36      !!----------------------------------------------------------------------
37      !!                   ***  ROUTINE zdf_sh2  ***
38      !!
39      !! ** Purpose :   Compute the shear production term of a TKE equation
40      !!
41      !! ** Method  : - a stable discretization of this term is linked to the
42      !!                time-space discretization of the vertical diffusion
43      !!                of the OGCM. NEMO uses C-grid, a leap-frog environment
44      !!                and an implicit computation of vertical mixing term,
45      !!                so the shear production at w-point is given by:
46      !!                   sh2 = mi[   mi(avm) * dk[ub]/e3ub * dk[un]/e3un   ]
47      !!                       + mj[   mj(avm) * dk[vb]/e3vb * dk[vn]/e3vn   ]
48      !!                NB: wet-point only horizontal averaging of shear
49      !!
50      !! ** Action  : - p_sh2 shear prod. term at w-point (inner domain only)
51      !!                                                   *****
52      !! References :   Bruchard, OM 2002
53      !! ---------------------------------------------------------------------
54      INTEGER                    , INTENT(in   ) ::   Kbb, Kmm             ! ocean time level indices
55      REAL(wp), DIMENSION(:,:,:) , INTENT(in   ) ::   p_avm                ! vertical eddy viscosity (w-points)
56      REAL(wp), DIMENSION(:,:,:) , INTENT(  out) ::   p_sh2                ! shear production of TKE (w-points)
57      !
58      INTEGER  ::   ji, jj, jk   ! dummy loop arguments
59      REAL(wp), DIMENSION(jpi,jpj) ::   zsh2u, zsh2v   ! 2D workspace
60      !!--------------------------------------------------------------------
61      !
62      DO jk = 2, jpkm1                 !* Shear production at uw- and vw-points (energy conserving form)
63         IF ( cpl_sdrftx .AND. ln_stshear )  THEN       ! Surface Stokes Drift available  ===>>>  shear + stokes drift contibution
64            DO_2D_10_10
65               zsh2u(ji,jj) = ( p_avm(ji+1,jj,jk) + p_avm(ji,jj,jk) )        &
66                  &         * ( uu (ji,jj,jk-1,Kmm) -   uu (ji,jj,jk,Kmm)    &
67                  &           + usd(ji,jj,jk-1) -   usd(ji,jj,jk) )  &
68                  &         * ( uu (ji,jj,jk-1,Kbb) -   uu (ji,jj,jk,Kbb) )  &
69                  &         / ( e3uw(ji,jj,jk,Kmm) * e3uw(ji,jj,jk,Kbb) ) * wumask(ji,jj,jk)
70               zsh2v(ji,jj) = ( p_avm(ji,jj+1,jk) + p_avm(ji,jj,jk) )         &
71                  &         * ( vv (ji,jj,jk-1,Kmm) -   vv (ji,jj,jk,Kmm)     &
72                  &           + vsd(ji,jj,jk-1) -   vsd(ji,jj,jk) )   &
73                  &         * ( vv (ji,jj,jk-1,Kbb) -   vv (ji,jj,jk,Kbb) )   &
74                  &/ ( e3vw(ji,jj,jk,Kmm) * e3vw(ji,jj,jk,Kbb) ) * wvmask(ji,jj,jk)
75            END_2D
76         ELSE
77            DO_2D_10_10
78               zsh2u(ji,jj) = ( p_avm(ji+1,jj,jk) + p_avm(ji,jj,jk) )       &
79                  &         * (   uu(ji,jj,jk-1,Kmm) -   uu(ji,jj,jk,Kmm) ) &
80                  &         * (   uu(ji,jj,jk-1,Kbb) -   uu(ji,jj,jk,Kbb) ) &
81                  &         / ( e3uw(ji,jj,jk,Kmm) * e3uw(ji,jj,jk,Kbb) ) * wumask(ji,jj,jk)
82               zsh2v(ji,jj) = ( p_avm(ji,jj+1,jk) + p_avm(ji,jj,jk) )       &
83                  &         * (   vv(ji,jj,jk-1,Kmm) -   vv(ji,jj,jk,Kmm) ) &
84                  &         * (   vv(ji,jj,jk-1,Kbb) -   vv(ji,jj,jk,Kbb) ) &
85                  &         / ( e3vw(ji,jj,jk,Kmm) * e3vw(ji,jj,jk,Kbb) ) * wvmask(ji,jj,jk)
86            END_2D
87         ENDIF
88         DO_2D_00_00
89            p_sh2(ji,jj,jk) = 0.25 * (   ( zsh2u(ji-1,jj) + zsh2u(ji,jj) ) * ( 2. - umask(ji-1,jj,jk) * umask(ji,jj,jk) )   &
90               &                       + ( zsh2v(ji,jj-1) + zsh2v(ji,jj) ) * ( 2. - vmask(ji,jj-1,jk) * vmask(ji,jj,jk) )   )
91         END_2D
92      END DO
93      !
94   END SUBROUTINE zdf_sh2
95
96   !!======================================================================
97END MODULE zdfsh2
Note: See TracBrowser for help on using the repository browser.