source: NEMO/branches/2020/dev_r12973_AGRIF_CMEMS/src/OCE/nemogcm.F90 @ 13026

Last change on this file since 13026 was 13026, checked in by rblod, 11 months ago

AGRIF with northfold and perio, see ticket #2129

  • Property svn:keywords set to Id
File size: 35.1 KB
Line 
1MODULE nemogcm
2   !!======================================================================
3   !!                       ***  MODULE nemogcm   ***
4   !! Ocean system   : NEMO GCM (ocean dynamics, on-line tracers, biochemistry and sea-ice)
5   !!======================================================================
6   !! History :  OPA  ! 1990-10  (C. Levy, G. Madec)  Original code
7   !!            7.0  ! 1991-11  (M. Imbard, C. Levy, G. Madec)
8   !!            7.1  ! 1993-03  (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
9   !!                             P. Delecluse, C. Perigaud, G. Caniaux, B. Colot, C. Maes) release 7.1
10   !!             -   ! 1992-06  (L.Terray)  coupling implementation
11   !!             -   ! 1993-11  (M.A. Filiberti) IGLOO sea-ice
12   !!            8.0  ! 1996-03  (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
13   !!                             P. Delecluse, L.Terray, M.A. Filiberti, J. Vialar, A.M. Treguier, M. Levy) release 8.0
14   !!            8.1  ! 1997-06  (M. Imbard, G. Madec)
15   !!            8.2  ! 1999-11  (M. Imbard, H. Goosse)  sea-ice model
16   !!                 ! 1999-12  (V. Thierry, A-M. Treguier, M. Imbard, M-A. Foujols)  OPEN-MP
17   !!                 ! 2000-07  (J-M Molines, M. Imbard)  Open Boundary Conditions  (CLIPPER)
18   !!   NEMO     1.0  ! 2002-08  (G. Madec)  F90: Free form and modules
19   !!             -   ! 2004-06  (R. Redler, NEC CCRLE, Germany) add OASIS[3/4] coupled interfaces
20   !!             -   ! 2004-08  (C. Talandier) New trends organization
21   !!             -   ! 2005-06  (C. Ethe) Add the 1D configuration possibility
22   !!             -   ! 2005-11  (V. Garnier) Surface pressure gradient organization
23   !!             -   ! 2006-03  (L. Debreu, C. Mazauric)  Agrif implementation
24   !!             -   ! 2006-04  (G. Madec, R. Benshila)  Step reorganization
25   !!             -   ! 2007-07  (J. Chanut, A. Sellar) Unstructured open boundaries (BDY)
26   !!            3.2  ! 2009-08  (S. Masson)  open/write in the listing file in mpp
27   !!            3.3  ! 2010-05  (K. Mogensen, A. Weaver, M. Martin, D. Lea) Assimilation interface
28   !!             -   ! 2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase
29   !!            3.3.1! 2011-01  (A. R. Porter, STFC Daresbury) dynamical allocation
30   !!             -   ! 2011-11  (C. Harris) decomposition changes for running with CICE
31   !!            3.6  ! 2012-05  (C. Calone, J. Simeon, G. Madec, C. Ethe) Add grid coarsening
32   !!             -   ! 2014-12  (G. Madec) remove KPP scheme and cross-land advection (cla)
33   !!            4.0  ! 2016-10  (G. Madec, S. Flavoni)  domain configuration / user defined interface
34   !!----------------------------------------------------------------------
35
36   !!----------------------------------------------------------------------
37   !!   nemo_gcm      : solve ocean dynamics, tracer, biogeochemistry and/or sea-ice
38   !!   nemo_init     : initialization of the NEMO system
39   !!   nemo_ctl      : initialisation of the contol print
40   !!   nemo_closefile: close remaining open files
41   !!   nemo_alloc    : dynamical allocation
42   !!----------------------------------------------------------------------
43   USE step_oce       ! module used in the ocean time stepping module (step.F90)
44   USE phycst         ! physical constant                  (par_cst routine)
45   USE domain         ! domain initialization   (dom_init & dom_cfg routines)
46   USE closea         ! treatment of closed seas (for ln_closea)
47   USE usrdef_nam     ! user defined configuration
48   USE tide_mod, ONLY : tide_init ! tidal components initialization   (tide_init routine)
49   USE bdy_oce,  ONLY : ln_bdy
50   USE bdyini         ! open boundary cond. setting       (bdy_init routine)
51   USE istate         ! initial state setting          (istate_init routine)
52   USE ldfdyn         ! lateral viscosity setting      (ldfdyn_init routine)
53   USE ldftra         ! lateral diffusivity setting    (ldftra_init routine)
54   USE trdini         ! dyn/tra trends initialization     (trd_init routine)
55   USE asminc         ! assimilation increments     
56   USE asmbkg         ! writing out state trajectory
57   USE diaptr         ! poleward transports           (dia_ptr_init routine)
58   USE diadct         ! sections transports           (dia_dct_init routine)
59   USE diaobs         ! Observation diagnostics       (dia_obs_init routine)
60   USE diacfl         ! CFL diagnostics               (dia_cfl_init routine)
61   USE diamlr         ! IOM context management for multiple-linear-regression analysis
62   USE step           ! NEMO time-stepping                 (stp     routine)
63   USE isfstp         ! ice shelf                     (isf_stp_init routine)
64   USE icbini         ! handle bergs, initialisation
65   USE icbstp         ! handle bergs, calving, themodynamics and transport
66   USE cpl_oasis3     ! OASIS3 coupling
67   USE c1d            ! 1D configuration
68   USE step_c1d       ! Time stepping loop for the 1D configuration
69   USE dyndmp         ! Momentum damping
70   USE stopar         ! Stochastic param.: ???
71   USE stopts         ! Stochastic param.: ???
72   USE diu_layers     ! diurnal bulk SST and coolskin
73   USE step_diu       ! diurnal bulk SST timestepping (called from here if run offline)
74   USE crsini         ! initialise grid coarsening utility
75   USE dia25h         ! 25h mean output
76   USE diadetide      ! Weights computation for daily detiding of model diagnostics
77   USE sbc_oce , ONLY : lk_oasis
78   USE wet_dry        ! Wetting and drying setting   (wad_init routine)
79#if defined key_top
80   USE trcini         ! passive tracer initialisation
81#endif
82#if defined key_nemocice_decomp
83   USE ice_domain_size, only: nx_global, ny_global
84#endif
85   !
86   USE in_out_manager ! I/O manager
87   USE lib_mpp        ! distributed memory computing
88   USE mppini         ! shared/distributed memory setting (mpp_init routine)
89   USE lbcnfd  , ONLY : isendto, nsndto, nfsloop, nfeloop   ! Setup of north fold exchanges
90   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined)
91#if defined key_iomput
92   USE xios           ! xIOserver
93#endif
94#if defined key_agrif
95   USE agrif_all_update   ! Master Agrif update
96#endif
97
98   IMPLICIT NONE
99   PRIVATE
100
101   PUBLIC   nemo_gcm    ! called by model.F90
102   PUBLIC   nemo_init   ! needed by AGRIF
103   PUBLIC   nemo_alloc  ! needed by TAM
104
105   CHARACTER(lc) ::   cform_aaa="( /, 'AAAAAAAA', / ) "     ! flag for output listing
106
107#if defined key_mpp_mpi
108   ! need MPI_Wtime
109   INCLUDE 'mpif.h'
110#endif
111
112   !!----------------------------------------------------------------------
113   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
114   !! $Id$
115   !! Software governed by the CeCILL license (see ./LICENSE)
116   !!----------------------------------------------------------------------
117CONTAINS
118
119   SUBROUTINE nemo_gcm
120      !!----------------------------------------------------------------------
121      !!                     ***  ROUTINE nemo_gcm  ***
122      !!
123      !! ** Purpose :   NEMO solves the primitive equations on an orthogonal
124      !!              curvilinear mesh on the sphere.
125      !!
126      !! ** Method  : - model general initialization
127      !!              - launch the time-stepping (stp routine)
128      !!              - finalize the run by closing files and communications
129      !!
130      !! References : Madec, Delecluse, Imbard, and Levy, 1997:  internal report, IPSL.
131      !!              Madec, 2008, internal report, IPSL.
132      !!----------------------------------------------------------------------
133      INTEGER ::   istp   ! time step index
134      REAL(wp)::   zstptiming   ! elapsed time for 1 time step
135      !!----------------------------------------------------------------------
136      !
137#if defined key_agrif
138      CALL Agrif_Init_Grids()      ! AGRIF: set the meshes
139#endif
140      !                            !-----------------------!
141      CALL nemo_init               !==  Initialisations  ==!
142      !                            !-----------------------!
143#if defined key_agrif
144      Kbb_a = Nbb; Kmm_a = Nnn; Krhs_a = Nrhs   ! agrif_oce module copies of time level indices
145      CALL Agrif_Declare_Var       !  "      "   "   "      "  DYN/TRA
146# if defined key_top
147      CALL Agrif_Declare_Var_top   !  "      "   "   "      "  TOP
148# endif
149#endif
150      ! check that all process are still there... If some process have an error,
151      ! they will never enter in step and other processes will wait until the end of the cpu time!
152      CALL mpp_max( 'nemogcm', nstop )
153
154      IF(lwp) WRITE(numout,cform_aaa)   ! Flag AAAAAAA
155
156      !                            !-----------------------!
157      !                            !==   time stepping   ==!
158      !                            !-----------------------!
159      !
160      !                                               !== set the model time-step  ==!
161      !
162      istp = nit000
163      !
164#if defined key_c1d
165      DO WHILE ( istp <= nitend .AND. nstop == 0 )    !==  C1D time-stepping  ==!
166         CALL stp_c1d( istp )
167         istp = istp + 1
168      END DO
169#else
170      !
171# if defined key_agrif
172      !                                               !==  AGRIF time-stepping  ==!
173      CALL Agrif_Regrid()
174      !
175      ! Recursive update from highest nested level to lowest:
176      Kbb_a = Nbb; Kmm_a = Nnn; Krhs_a = Nrhs   ! agrif_oce module copies of time level indices
177      CALL Agrif_step_child_adj(Agrif_Update_All)
178      !
179      DO WHILE( istp <= nitend .AND. nstop == 0 )
180         CALL stp
181         istp = istp + 1
182      END DO
183      !
184# else
185      !
186      IF( .NOT.ln_diurnal_only ) THEN                 !==  Standard time-stepping  ==!
187         !
188         DO WHILE( istp <= nitend .AND. nstop == 0 )
189
190            ncom_stp = istp
191            IF( ln_timing ) THEN
192               zstptiming = MPI_Wtime()
193               IF ( istp == ( nit000 + 1 ) ) elapsed_time = zstptiming
194               IF ( istp ==         nitend ) elapsed_time = zstptiming - elapsed_time
195            ENDIF
196           
197            CALL stp        ( istp ) 
198            istp = istp + 1
199
200            IF( lwp .AND. ln_timing )   WRITE(numtime,*) 'timing step ', istp-1, ' : ', MPI_Wtime() - zstptiming
201
202         END DO
203         !
204      ELSE                                            !==  diurnal SST time-steeping only  ==!
205         !
206         DO WHILE( istp <= nitend .AND. nstop == 0 )
207            CALL stp_diurnal( istp )   ! time step only the diurnal SST
208            istp = istp + 1
209         END DO
210         !
211      ENDIF
212      !
213# endif
214      !
215#endif
216      !
217      IF( ln_diaobs   )   CALL dia_obs_wri
218      !
219      IF( ln_icebergs )   CALL icb_end( nitend )
220
221      !                            !------------------------!
222      !                            !==  finalize the run  ==!
223      !                            !------------------------!
224      IF(lwp) WRITE(numout,cform_aaa)        ! Flag AAAAAAA
225      !
226      IF( nstop /= 0 .AND. lwp ) THEN        ! error print
227         WRITE(ctmp1,*) '   ==>>>   nemo_gcm: a total of ', nstop, ' errors have been found'
228         IF( ngrdstop > 0 ) THEN
229            WRITE(ctmp9,'(i2)') ngrdstop
230            WRITE(ctmp2,*) '      ==>>>   Error detected in Agrif grid '//TRIM(ctmp9)
231            WRITE(ctmp3,*) '      ==>>>   look for error messages in '//TRIM(ctmp9)//'_ocean_output* files'
232            CALL ctl_stop( ctmp1, ctmp2, ctmp3 )
233         ELSE
234            CALL ctl_stop( ctmp1 )
235         ENDIF
236      ENDIF
237      !
238      IF( ln_timing )   CALL timing_finalize
239      !
240      CALL nemo_closefile
241      !
242#if defined key_iomput
243                                    CALL xios_finalize  ! end mpp communications with xios
244      IF( lk_oasis     )            CALL cpl_finalize   ! end coupling and mpp communications with OASIS
245#else
246      IF    ( lk_oasis ) THEN   ;   CALL cpl_finalize   ! end coupling and mpp communications with OASIS
247      ELSEIF( lk_mpp   ) THEN   ;   CALL mppstop      ! end mpp communications
248      ENDIF
249#endif
250      !
251      IF(lwm) THEN
252         IF( nstop == 0 ) THEN   ;   STOP 0
253         ELSE                    ;   STOP 123
254         ENDIF
255      ENDIF
256      !
257   END SUBROUTINE nemo_gcm
258
259
260   SUBROUTINE nemo_init
261      !!----------------------------------------------------------------------
262      !!                     ***  ROUTINE nemo_init  ***
263      !!
264      !! ** Purpose :   initialization of the NEMO GCM
265      !!----------------------------------------------------------------------
266      INTEGER ::   ios, ilocal_comm   ! local integers
267      !!
268      NAMELIST/namctl/ sn_cfctl,  nn_print, nn_ictls, nn_ictle,             &
269         &             nn_isplt , nn_jsplt, nn_jctls, nn_jctle,             &
270         &             ln_timing, ln_diacfl
271      NAMELIST/namcfg/ ln_read_cfg, cn_domcfg, ln_closea, ln_write_cfg, cn_domcfg_out, ln_use_jattr
272      !!----------------------------------------------------------------------
273      !
274      cxios_context = 'nemo'
275      !
276      !                             !-------------------------------------------------!
277      !                             !     set communicator & select the local rank    !
278      !                             !  must be done as soon as possible to get narea  !
279      !                             !-------------------------------------------------!
280      !
281#if defined key_iomput
282      IF( Agrif_Root() ) THEN
283         IF( lk_oasis ) THEN
284            CALL cpl_init( "oceanx", ilocal_comm )                               ! nemo local communicator given by oasis
285            CALL xios_initialize( "not used"       , local_comm =ilocal_comm )   ! send nemo communicator to xios
286         ELSE
287            CALL xios_initialize( "for_xios_mpi_id", return_comm=ilocal_comm )   ! nemo local communicator given by xios
288         ENDIF
289      ENDIF
290      CALL mpp_start( ilocal_comm )
291#else
292      IF( lk_oasis ) THEN
293         IF( Agrif_Root() ) THEN
294            CALL cpl_init( "oceanx", ilocal_comm )          ! nemo local communicator given by oasis
295         ENDIF
296         CALL mpp_start( ilocal_comm )
297      ELSE
298         CALL mpp_start( )
299      ENDIF
300#endif
301      !
302      narea = mpprank + 1               ! mpprank: the rank of proc (0 --> mppsize -1 )
303      lwm = (narea == 1)                ! control of output namelists
304      !
305      !                             !---------------------------------------------------------------!
306      !                             ! Open output files, reference and configuration namelist files !
307      !                             !---------------------------------------------------------------!
308      !
309      ! open ocean.output as soon as possible to get all output prints (including errors messages)
310      IF( lwm )   CALL ctl_opn(     numout,        'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. )
311      ! open reference and configuration namelist files
312                  CALL load_nml( numnam_ref,        'namelist_ref',                                           -1, lwm )
313                  CALL load_nml( numnam_cfg,        'namelist_cfg',                                           -1, lwm )
314      IF( lwm )   CALL ctl_opn(     numond, 'output.namelist.dyn', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. )
315      ! open /dev/null file to be able to supress output write easily
316      IF( Agrif_Root() ) THEN
317                  CALL ctl_opn(     numnul,           '/dev/null', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. )
318#ifdef key_agrif
319      ELSE
320                  numnul = Agrif_Parent(numnul)   
321#endif
322      ENDIF
323      !                             !--------------------!
324      !                             ! Open listing units !  -> need sn_cfctl from namctl to define lwp
325      !                             !--------------------!
326      !
327      READ  ( numnam_ref, namctl, IOSTAT = ios, ERR = 901 )
328901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namctl in reference namelist' )
329      READ  ( numnam_cfg, namctl, IOSTAT = ios, ERR = 902 )
330902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namctl in configuration namelist' )
331      !
332      ! finalize the definition of namctl variables
333      IF( narea < sn_cfctl%procmin .OR. narea > sn_cfctl%procmax .OR. MOD( narea - sn_cfctl%procmin, sn_cfctl%procincr ) /= 0 )   &
334         &   CALL nemo_set_cfctl( sn_cfctl, .FALSE. )
335      !
336      lwp = (narea == 1) .OR. sn_cfctl%l_oceout    ! control of all listing output print
337      !
338      IF(lwp) THEN                      ! open listing units
339         !
340         IF( .NOT. lwm )   &            ! alreay opened for narea == 1
341            &            CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE., narea )
342         !
343         WRITE(numout,*)
344         WRITE(numout,*) '   CNRS - NERC - Met OFFICE - MERCATOR-ocean - CMCC'
345         WRITE(numout,*) '                       NEMO team'
346         WRITE(numout,*) '            Ocean General Circulation Model'
347         WRITE(numout,*) '                NEMO version 4.0  (2019) '
348         WRITE(numout,*)
349         WRITE(numout,*) "           ._      ._      ._      ._      ._    "
350         WRITE(numout,*) "       _.-._)`\_.-._)`\_.-._)`\_.-._)`\_.-._)`\_ "
351         WRITE(numout,*)
352         WRITE(numout,*) "           o         _,           _,             "
353         WRITE(numout,*) "            o      .' (        .-' /             "
354         WRITE(numout,*) "           o     _/..._'.    .'   /              "
355         WRITE(numout,*) "      (    o .-'`      ` '-./  _.'               "
356         WRITE(numout,*) "       )    ( o)           ;= <_         (       "
357         WRITE(numout,*) "      (      '-.,\\__ __.-;`\   '.        )      "
358         WRITE(numout,*) "       )  )       \) |`\ \)  '.   \      (   (   "
359         WRITE(numout,*) "      (  (           \_/       '-._\      )   )  "
360         WRITE(numout,*) "       )  ) jgs                     `    (   (   "
361         WRITE(numout,*) "     ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^ "
362         WRITE(numout,*)
363         !
364         WRITE(numout,cform_aaa)                                        ! Flag AAAAAAA
365         !
366      ENDIF
367      !
368      IF(lwm) WRITE( numond, namctl )
369      !
370      !                             !------------------------------------!
371      !                             !  Set global domain size parameters !
372      !                             !------------------------------------!
373      !
374      READ  ( numnam_ref, namcfg, IOSTAT = ios, ERR = 903 )
375903   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namcfg in reference namelist' )
376      READ  ( numnam_cfg, namcfg, IOSTAT = ios, ERR = 904 )
377904   IF( ios >  0 )   CALL ctl_nam ( ios , 'namcfg in configuration namelist' )   
378      !
379      IF( ln_read_cfg ) THEN            ! Read sizes in domain configuration file
380         CALL domain_cfg ( cn_cfg, nn_cfg, jpiglo, jpjglo, jpkglo, jperio )
381      ELSE                              ! user-defined namelist
382         CALL usr_def_nam( cn_cfg, nn_cfg, jpiglo, jpjglo, jpkglo, jperio )
383      ENDIF
384      !
385      IF(lwm)   WRITE( numond, namcfg )
386      !
387      !                             !-----------------------------------------!
388      !                             ! mpp parameters and domain decomposition !
389      !                             !-----------------------------------------!
390      CALL mpp_init
391
392      ! Now we know the dimensions of the grid and numout has been set: we can allocate arrays
393      CALL nemo_alloc()
394
395      ! Initialise time level indices
396      Nbb = 1; Nnn = 2; Naa = 3; Nrhs = Naa
397#if defined key_agrif
398      Kbb_a = Nbb; Kmm_a = Nnn; Krhs_a = Nrhs   ! agrif_oce module copies of time level indices
399#endif 
400      !                             !-------------------------------!
401      !                             !  NEMO general initialization  !
402      !                             !-------------------------------!
403
404      CALL nemo_ctl                          ! Control prints
405      !
406      !                                      ! General initialization
407      IF( ln_timing    )   CALL timing_init     ! timing
408      IF( ln_timing    )   CALL timing_start( 'nemo_init')
409      !
410                           CALL     phy_cst         ! Physical constants
411                           CALL     eos_init        ! Equation of state
412      IF( lk_c1d       )   CALL     c1d_init        ! 1D column configuration
413                           CALL     wad_init        ! Wetting and drying options
414
415#if defined key_agrif
416     CALL Agrif_Declare_Var_ini   !  "      "   "   "      "  DOM
417#endif
418                           CALL     dom_init( Nbb, Nnn, Naa, "OPA") ! Domain
419
420
421
422      IF( ln_crs       )   CALL     crs_init(      Nnn )       ! coarsened grid: domain initialization
423      IF( sn_cfctl%l_prtctl )   &
424         &                 CALL prt_ctl_init        ! Print control
425     
426                           CALL diurnal_sst_bulk_init       ! diurnal sst
427      IF( ln_diurnal   )   CALL diurnal_sst_coolskin_init   ! cool skin   
428      !                           
429      IF( ln_diurnal_only ) THEN                    ! diurnal only: a subset of the initialisation routines
430         CALL  istate_init( Nbb, Nnn, Naa )         ! ocean initial state (Dynamics and tracers)
431         CALL     sbc_init( Nbb, Nnn, Naa )         ! Forcings : surface module
432         CALL tra_qsr_init                          ! penetrative solar radiation qsr
433         IF( ln_diaobs ) THEN                       ! Observation & model comparison
434            CALL dia_obs_init( Nnn )                ! Initialize observational data
435            CALL dia_obs( nit000 - 1, Nnn )         ! Observation operator for restart
436         ENDIF     
437         IF( lk_asminc )   CALL asm_inc_init( Nbb, Nnn, Nrhs )   ! Assimilation increments
438         !
439         RETURN                                       ! end of initialization
440      ENDIF
441      !
442
443                           CALL  istate_init( Nbb, Nnn, Naa )    ! ocean initial state (Dynamics and tracers)
444
445      !                                      ! external forcing
446                           CALL    tide_init                     ! tidal harmonics
447                           CALL     sbc_init( Nbb, Nnn, Naa )    ! surface boundary conditions (including sea-ice)
448                           CALL     bdy_init                     ! Open boundaries initialisation
449
450      !                                      ! Ocean physics
451                           CALL zdf_phy_init( Nnn )    ! Vertical physics
452                                     
453      !                                         ! Lateral physics
454                           CALL ldf_tra_init      ! Lateral ocean tracer physics
455                           CALL ldf_eiv_init      ! eddy induced velocity param.
456                           CALL ldf_dyn_init      ! Lateral ocean momentum physics
457
458      !                                      ! Active tracers
459      IF( ln_traqsr    )   CALL tra_qsr_init      ! penetrative solar radiation qsr
460                           CALL tra_bbc_init      ! bottom heat flux
461                           CALL tra_bbl_init      ! advective (and/or diffusive) bottom boundary layer scheme
462                           CALL tra_dmp_init      ! internal tracer damping
463                           CALL tra_adv_init      ! horizontal & vertical advection
464                           CALL tra_ldf_init      ! lateral mixing
465
466      !                                      ! Dynamics
467      IF( lk_c1d       )   CALL dyn_dmp_init         ! internal momentum damping
468                           CALL dyn_adv_init         ! advection (vector or flux form)
469                           CALL dyn_vor_init         ! vorticity term including Coriolis
470                           CALL dyn_ldf_init         ! lateral mixing
471                           CALL dyn_hpg_init( Nnn )  ! horizontal gradient of Hydrostatic pressure
472                           CALL dyn_spg_init         ! surface pressure gradient
473
474#if defined key_top
475      !                                      ! Passive tracers
476                           CALL     trc_init( Nbb, Nnn, Naa )
477#endif
478      IF( l_ldfslp     )   CALL ldf_slp_init    ! slope of lateral mixing
479
480      !                                      ! Icebergs
481                           CALL icb_init( rn_Dt, nit000)   ! initialise icebergs instance
482
483                                                ! ice shelf
484                           CALL isf_init( Nbb, Nnn, Naa )
485
486      !                                      ! Misc. options
487                           CALL sto_par_init    ! Stochastic parametrization
488      IF( ln_sto_eos   )   CALL sto_pts_init    ! RRandom T/S fluctuations
489     
490      !                                      ! Diagnostics
491                           CALL     flo_init( Nnn )    ! drifting Floats
492      IF( ln_diacfl    )   CALL dia_cfl_init    ! Initialise CFL diagnostics
493!                           CALL dia_ptr_init    ! Poleward TRansports initialization
494                           CALL dia_dct_init    ! Sections tranports
495                           CALL dia_hsb_init( Nnn )    ! heat content, salt content and volume budgets
496                           CALL     trd_init( Nnn )    ! Mixed-layer/Vorticity/Integral constraints trends
497                           CALL dia_obs_init( Nnn )    ! Initialize observational data
498                           CALL dia_25h_init( Nbb )    ! 25h mean  outputs
499                           CALL dia_detide_init ! Weights computation for daily detiding of model diagnostics
500      IF( ln_diaobs    )   CALL dia_obs( nit000-1, Nnn )   ! Observation operator for restart
501                           CALL dia_mlr_init    ! Initialisation of IOM context management for multiple-linear-regression analysis
502
503      !                                      ! Assimilation increments
504      IF( lk_asminc    )   CALL asm_inc_init( Nbb, Nnn, Nrhs )   ! Initialize assimilation increments
505      !
506      IF(lwp) WRITE(numout,cform_aaa)           ! Flag AAAAAAA
507      !
508      IF( ln_timing    )   CALL timing_stop( 'nemo_init')
509      !
510   END SUBROUTINE nemo_init
511
512
513   SUBROUTINE nemo_ctl
514      !!----------------------------------------------------------------------
515      !!                     ***  ROUTINE nemo_ctl  ***
516      !!
517      !! ** Purpose :   control print setting
518      !!
519      !! ** Method  : - print namctl and namcfg information and check some consistencies
520      !!----------------------------------------------------------------------
521      !
522      IF(lwp) THEN                  ! control print
523         WRITE(numout,*)
524         WRITE(numout,*) 'nemo_ctl: Control prints'
525         WRITE(numout,*) '~~~~~~~~'
526         WRITE(numout,*) '   Namelist namctl'
527         WRITE(numout,*) '                              sn_cfctl%l_runstat = ', sn_cfctl%l_runstat
528         WRITE(numout,*) '                              sn_cfctl%l_trcstat = ', sn_cfctl%l_trcstat
529         WRITE(numout,*) '                              sn_cfctl%l_oceout  = ', sn_cfctl%l_oceout
530         WRITE(numout,*) '                              sn_cfctl%l_layout  = ', sn_cfctl%l_layout
531         WRITE(numout,*) '                              sn_cfctl%l_prtctl  = ', sn_cfctl%l_prtctl
532         WRITE(numout,*) '                              sn_cfctl%l_prttrc  = ', sn_cfctl%l_prttrc
533         WRITE(numout,*) '                              sn_cfctl%l_oasout  = ', sn_cfctl%l_oasout
534         WRITE(numout,*) '                              sn_cfctl%procmin   = ', sn_cfctl%procmin 
535         WRITE(numout,*) '                              sn_cfctl%procmax   = ', sn_cfctl%procmax 
536         WRITE(numout,*) '                              sn_cfctl%procincr  = ', sn_cfctl%procincr 
537         WRITE(numout,*) '                              sn_cfctl%ptimincr  = ', sn_cfctl%ptimincr 
538         WRITE(numout,*) '      level of print                  nn_print   = ', nn_print
539         WRITE(numout,*) '      Start i indice for SUM control  nn_ictls   = ', nn_ictls
540         WRITE(numout,*) '      End i indice for SUM control    nn_ictle   = ', nn_ictle
541         WRITE(numout,*) '      Start j indice for SUM control  nn_jctls   = ', nn_jctls
542         WRITE(numout,*) '      End j indice for SUM control    nn_jctle   = ', nn_jctle
543         WRITE(numout,*) '      number of proc. following i     nn_isplt   = ', nn_isplt
544         WRITE(numout,*) '      number of proc. following j     nn_jsplt   = ', nn_jsplt
545         WRITE(numout,*) '      timing by routine               ln_timing  = ', ln_timing
546         WRITE(numout,*) '      CFL diagnostics                 ln_diacfl  = ', ln_diacfl
547      ENDIF
548      !
549      nprint    = nn_print          ! convert DOCTOR namelist names into OLD names
550      nictls    = nn_ictls
551      nictle    = nn_ictle
552      njctls    = nn_jctls
553      njctle    = nn_jctle
554      isplt     = nn_isplt
555      jsplt     = nn_jsplt
556
557      IF(lwp) THEN                  ! control print
558         WRITE(numout,*)
559         WRITE(numout,*) '   Namelist namcfg'
560         WRITE(numout,*) '      read domain configuration file                ln_read_cfg      = ', ln_read_cfg
561         WRITE(numout,*) '         filename to be read                           cn_domcfg     = ', TRIM(cn_domcfg)
562         WRITE(numout,*) '         keep closed seas in the domain (if exist)     ln_closea     = ', ln_closea
563         WRITE(numout,*) '      create a configuration definition file        ln_write_cfg     = ', ln_write_cfg
564         WRITE(numout,*) '         filename to be written                        cn_domcfg_out = ', TRIM(cn_domcfg_out)
565         WRITE(numout,*) '      use file attribute if exists as i/p j-start   ln_use_jattr     = ', ln_use_jattr
566      ENDIF
567      IF( .NOT.ln_read_cfg )   ln_closea = .false.   ! dealing possible only with a domcfg file
568      !
569      !                             ! Parameter control
570      !
571      IF( sn_cfctl%l_prtctl .OR. sn_cfctl%l_prttrc ) THEN              ! sub-domain area indices for the control prints
572         IF( lk_mpp .AND. jpnij > 1 ) THEN
573            isplt = jpni   ;   jsplt = jpnj   ;   ijsplt = jpni*jpnj   ! the domain is forced to the real split domain
574         ELSE
575            IF( isplt == 1 .AND. jsplt == 1  ) THEN
576               CALL ctl_warn( ' - isplt & jsplt are equal to 1',   &
577                  &           ' - the print control will be done over the whole domain' )
578            ENDIF
579            ijsplt = isplt * jsplt            ! total number of processors ijsplt
580         ENDIF
581         IF(lwp) WRITE(numout,*)'          - The total number of processors over which the'
582         IF(lwp) WRITE(numout,*)'            print control will be done is ijsplt : ', ijsplt
583         !
584         !                              ! indices used for the SUM control
585         IF( nictls+nictle+njctls+njctle == 0 )   THEN    ! print control done over the default area
586            lsp_area = .FALSE.
587         ELSE                                             ! print control done over a specific  area
588            lsp_area = .TRUE.
589            IF( nictls < 1 .OR. nictls > jpiglo )   THEN
590               CALL ctl_warn( '          - nictls must be 1<=nictls>=jpiglo, it is forced to 1' )
591               nictls = 1
592            ENDIF
593            IF( nictle < 1 .OR. nictle > jpiglo )   THEN
594               CALL ctl_warn( '          - nictle must be 1<=nictle>=jpiglo, it is forced to jpiglo' )
595               nictle = jpiglo
596            ENDIF
597            IF( njctls < 1 .OR. njctls > jpjglo )   THEN
598               CALL ctl_warn( '          - njctls must be 1<=njctls>=jpjglo, it is forced to 1' )
599               njctls = 1
600            ENDIF
601            IF( njctle < 1 .OR. njctle > jpjglo )   THEN
602               CALL ctl_warn( '          - njctle must be 1<=njctle>=jpjglo, it is forced to jpjglo' )
603               njctle = jpjglo
604            ENDIF
605         ENDIF
606      ENDIF
607      !
608      IF( 1._wp /= SIGN(1._wp,-0._wp)  )   CALL ctl_stop( 'nemo_ctl: The intrinsec SIGN function follows f2003 standard.',  &
609         &                                                'Compile with key_nosignedzero enabled:',   &
610         &                                                '--> add -Dkey_nosignedzero to the definition of %CPP in your arch file' )
611      !
612#if defined key_agrif
613      IF( ln_timing )   CALL ctl_stop( 'AGRIF not implemented with ln_timing = true')
614#endif
615      !
616   END SUBROUTINE nemo_ctl
617
618
619   SUBROUTINE nemo_closefile
620      !!----------------------------------------------------------------------
621      !!                     ***  ROUTINE nemo_closefile  ***
622      !!
623      !! ** Purpose :   Close the files
624      !!----------------------------------------------------------------------
625      !
626      IF( lk_mpp )   CALL mppsync
627      !
628      CALL iom_close                                 ! close all input/output files managed by iom_*
629      !
630      IF( numstp          /= -1 )   CLOSE( numstp          )   ! time-step file
631      IF( numrun          /= -1 )   CLOSE( numrun          )   ! run statistics file
632      IF( lwm.AND.numond  /= -1 )   CLOSE( numond          )   ! oce output namelist
633      IF( lwm.AND.numoni  /= -1 )   CLOSE( numoni          )   ! ice output namelist
634      IF( numevo_ice      /= -1 )   CLOSE( numevo_ice      )   ! ice variables (temp. evolution)
635      IF( numout          /=  6 )   CLOSE( numout          )   ! standard model output file
636      IF( numdct_vol      /= -1 )   CLOSE( numdct_vol      )   ! volume transports
637      IF( numdct_heat     /= -1 )   CLOSE( numdct_heat     )   ! heat transports
638      IF( numdct_salt     /= -1 )   CLOSE( numdct_salt     )   ! salt transports
639      !
640      numout = 6                                     ! redefine numout in case it is used after this point...
641      !
642   END SUBROUTINE nemo_closefile
643
644
645   SUBROUTINE nemo_alloc
646      !!----------------------------------------------------------------------
647      !!                     ***  ROUTINE nemo_alloc  ***
648      !!
649      !! ** Purpose :   Allocate all the dynamic arrays of the OPA modules
650      !!
651      !! ** Method  :
652      !!----------------------------------------------------------------------
653      USE diawri    , ONLY : dia_wri_alloc
654      USE dom_oce   , ONLY : dom_oce_alloc
655      USE trc_oce   , ONLY : trc_oce_alloc
656      USE bdy_oce   , ONLY : bdy_oce_alloc
657      !
658      INTEGER :: ierr
659      !!----------------------------------------------------------------------
660      !
661      ierr =        oce_alloc    ()    ! ocean
662      ierr = ierr + dia_wri_alloc()
663      ierr = ierr + dom_oce_alloc()    ! ocean domain
664      ierr = ierr + zdf_oce_alloc()    ! ocean vertical physics
665      ierr = ierr + trc_oce_alloc()    ! shared TRC / TRA arrays
666      ierr = ierr + bdy_oce_alloc()    ! bdy masks (incl. initialization)
667      !
668      CALL mpp_sum( 'nemogcm', ierr )
669      IF( ierr /= 0 )   CALL ctl_stop( 'STOP', 'nemo_alloc: unable to allocate standard ocean arrays' )
670      !
671   END SUBROUTINE nemo_alloc
672
673   
674   SUBROUTINE nemo_set_cfctl(sn_cfctl, setto )
675      !!----------------------------------------------------------------------
676      !!                     ***  ROUTINE nemo_set_cfctl  ***
677      !!
678      !! ** Purpose :   Set elements of the output control structure to setto.
679      !!
680      !! ** Method  :   Note this routine can be used to switch on/off some
681      !!                types of output for selected areas.
682      !!----------------------------------------------------------------------
683      TYPE(sn_ctl), INTENT(inout) :: sn_cfctl
684      LOGICAL     , INTENT(in   ) :: setto
685      !!----------------------------------------------------------------------
686      sn_cfctl%l_runstat = setto
687      sn_cfctl%l_trcstat = setto
688      sn_cfctl%l_oceout  = setto
689      sn_cfctl%l_layout  = setto
690      sn_cfctl%l_prtctl  = setto
691      sn_cfctl%l_prttrc  = setto
692      sn_cfctl%l_oasout  = setto
693   END SUBROUTINE nemo_set_cfctl
694
695   !!======================================================================
696END MODULE nemogcm
697
Note: See TracBrowser for help on using the repository browser.