source: NEMO/branches/2020/dev_r12973_AGRIF_CMEMS/src/SAS/nemogcm.F90 @ 13182

Last change on this file since 13182 was 13182, checked in by rblod, 3 months ago

#2129 : move lk_south declaration + compatibility with SAS

  • Property svn:keywords set to Id
File size: 27.5 KB
Line 
1MODULE nemogcm
2   !!======================================================================
3   !!                       ***  MODULE nemogcm   ***
4   !! StandAlone Surface module : surface fluxes + sea-ice + iceberg floats
5   !!======================================================================
6   !! History :  3.6  ! 2011-11  (S. Alderson, G. Madec) original code
7   !!             -   ! 2013-06  (I. Epicoco, S. Mocavero, CMCC) nemo_northcomms: setup avoiding MPI communication
8   !!             -   ! 2014-12  (G. Madec) remove KPP scheme and cross-land advection (cla)
9   !!            4.0  ! 2016-10  (G. Madec, S. Flavoni)  domain configuration / user defined interface
10   !!----------------------------------------------------------------------
11
12   !!----------------------------------------------------------------------
13   !!   nemo_gcm      : solve ocean dynamics, tracer, biogeochemistry and/or sea-ice
14   !!   nemo_init     : initialization of the NEMO system
15   !!   nemo_ctl      : initialisation of the contol print
16   !!   nemo_closefile: close remaining open files
17   !!   nemo_alloc    : dynamical allocation
18   !!----------------------------------------------------------------------
19   USE step_oce       ! module used in the ocean time stepping module
20   USE sbc_oce        ! surface boundary condition: ocean
21   USE phycst         ! physical constant                  (par_cst routine)
22   USE domain         ! domain initialization   (dom_init & dom_cfg routines)
23   USE closea         ! treatment of closed seas (for ln_closea)
24   USE usrdef_nam     ! user defined configuration
25   USE daymod         ! calendar
26   USE restart        ! open  restart file
27   USE step           ! NEMO time-stepping                 (stp     routine)
28   USE cpl_oasis3     !
29   USE sbcssm         !
30   USE icbini         ! handle bergs, initialisation
31   USE icbstp         ! handle bergs, calving, themodynamics and transport
32   USE bdyini         ! open boundary cond. setting       (bdy_init routine). mandatory for sea-ice
33   USE bdydta         ! open boundary cond. setting   (bdy_dta_init routine). mandatory for sea-ice
34   USE diu_layers     ! diurnal bulk SST and coolskin
35   USE step_diu       ! diurnal bulk SST timestepping (called from here if run offline)
36   !
37   USE in_out_manager ! I/O manager
38   USE lib_mpp        ! distributed memory computing
39   USE mppini         ! shared/distributed memory setting (mpp_init routine)
40   USE lbcnfd  , ONLY : isendto, nsndto, nfsloop, nfeloop   ! Setup of north fold exchanges
41   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined)
42#if defined key_iomput
43   USE xios           ! xIOserver
44#endif
45#if defined key_agrif && defined key_si3
46   USE agrif_ice_update ! ice update
47#endif
48
49   IMPLICIT NONE
50   PRIVATE
51
52   PUBLIC   nemo_gcm    ! called by model.F90
53   PUBLIC   nemo_init   ! needed by AGRIF
54
55   CHARACTER(lc) ::   cform_aaa="( /, 'AAAAAAAA', / ) "     ! flag for output listing
56
57#if defined key_mpp_mpi
58   INCLUDE 'mpif.h'
59#endif
60
61   !!----------------------------------------------------------------------
62   !! NEMO/SAS 4.0 , NEMO Consortium (2018)
63   !! $Id$
64   !! Software governed by the CeCILL license (see ./LICENSE)
65   !!----------------------------------------------------------------------
66CONTAINS
67
68   SUBROUTINE nemo_gcm
69      !!----------------------------------------------------------------------
70      !!                     ***  ROUTINE nemo_gcm  ***
71      !!
72      !! ** Purpose :   NEMO solves the primitive equations on an orthogonal
73      !!              curvilinear mesh on the sphere.
74      !!
75      !! ** Method  : - model general initialization
76      !!              - launch the time-stepping (stp routine)
77      !!              - finalize the run by closing files and communications
78      !!
79      !! References : Madec, Delecluse, Imbard, and Levy, 1997:  internal report, IPSL.
80      !!              Madec, 2008, internal report, IPSL.
81      !!----------------------------------------------------------------------
82      INTEGER ::   istp   ! time step index
83      !!----------------------------------------------------------------------
84      !
85#if defined key_agrif
86      CALL Agrif_Init_Grids()      ! AGRIF: set the meshes
87#endif
88      !                            !-----------------------!
89      CALL nemo_init               !==  Initialisations  ==!
90      !                            !-----------------------!
91#if defined key_agrif
92      Kbb_a = Nbb; Kmm_a = Nnn; Krhs_a = Nrhs   ! agrif_oce module copies of time level indices
93      CALL Agrif_Declare_Var       !  "      "   "   "      "  DYN/TRA
94# if defined key_top
95      CALL Agrif_Declare_Var_top   !  "      "   "   "      "  TOP
96# endif
97#endif
98      ! check that all process are still there... If some process have an error,
99      ! they will never enter in step and other processes will wait until the end of the cpu time!
100      CALL mpp_max( 'nemogcm', nstop )
101
102      IF(lwp) WRITE(numout,cform_aaa)   ! Flag AAAAAAA
103
104      !                            !-----------------------!
105      !                            !==   time stepping   ==!
106      !                            !-----------------------!
107      istp = nit000
108      !
109#if defined key_agrif
110      !                                               !==  AGRIF time-stepping  ==!
111      CALL Agrif_Regrid()
112      !
113#if defined key_si3
114      ! Recursive update from highest nested level to lowest:
115      Kbb_a = Nbb; Kmm_a = Nnn; Krhs_a = Nrhs   ! agrif_oce module copies of time level indices
116      CALL Agrif_step_child_adj(Agrif_update_ice)
117#endif
118      !
119      DO WHILE( istp <= nitend .AND. nstop == 0 )
120         CALL stp
121         istp = istp + 1
122      END DO
123      !
124#else
125      !
126      IF( .NOT.ln_diurnal_only ) THEN                 !==  Standard time-stepping  ==!
127         !
128         DO WHILE( istp <= nitend .AND. nstop == 0 )
129#if defined key_mpp_mpi
130            ncom_stp = istp
131            IF ( istp == ( nit000 + 1 ) ) elapsed_time = MPI_Wtime()
132            IF ( istp ==         nitend ) elapsed_time = MPI_Wtime() - elapsed_time
133#endif
134            CALL stp        ( istp ) 
135            istp = istp + 1
136         END DO
137         !
138      ELSE                                            !==  diurnal SST time-steeping only  ==!
139         !
140         DO WHILE( istp <= nitend .AND. nstop == 0 )
141            CALL stp_diurnal( istp )   ! time step only the diurnal SST
142            istp = istp + 1
143         END DO
144         !
145      ENDIF
146      !
147#endif
148      !
149      IF( ln_icebergs )   CALL icb_end( nitend )
150
151      !                            !------------------------!
152      !                            !==  finalize the run  ==!
153      !                            !------------------------!
154      IF(lwp) WRITE(numout,cform_aaa)        ! Flag AAAAAAA
155      !
156      IF( nstop /= 0 .AND. lwp ) THEN        ! error print
157         WRITE(ctmp1,*) '   ==>>>   nemo_gcm: a total of ', nstop, ' errors have been found'
158         IF( ngrdstop > 0 ) THEN
159            WRITE(ctmp9,'(i2)') ngrdstop
160            WRITE(ctmp2,*) '           E R R O R detected in Agrif grid '//TRIM(ctmp9)
161            WRITE(ctmp3,*) '           Look for "E R R O R" messages in all existing '//TRIM(ctmp9)//'_ocean_output* files'
162            CALL ctl_stop( ' ', ctmp1, ' ', ctmp2, ' ', ctmp3 )
163         ELSE
164            WRITE(ctmp2,*) '           Look for "E R R O R" messages in all existing ocean_output* files'
165            CALL ctl_stop( ' ', ctmp1, ' ', ctmp2 )
166         ENDIF
167      ENDIF
168      !
169      IF( ln_timing )   CALL timing_finalize
170      !
171      CALL nemo_closefile
172      !
173#if defined key_iomput
174                                    CALL xios_finalize  ! end mpp communications with xios
175      IF( lk_oasis     )            CALL cpl_finalize   ! end coupling and mpp communications with OASIS
176#else
177      IF    ( lk_oasis ) THEN   ;   CALL cpl_finalize   ! end coupling and mpp communications with OASIS
178      ELSEIF( lk_mpp   ) THEN   ;   CALL mppstop        ! end mpp communications
179      ENDIF
180#endif
181      !
182      IF(lwm) THEN
183         IF( nstop == 0 ) THEN   ;   STOP 0
184         ELSE                    ;   STOP 123
185         ENDIF
186      ENDIF
187      !
188   END SUBROUTINE nemo_gcm
189
190
191   SUBROUTINE nemo_init
192      !!----------------------------------------------------------------------
193      !!                     ***  ROUTINE nemo_init  ***
194      !!
195      !! ** Purpose :   initialization of the NEMO GCM
196      !!----------------------------------------------------------------------
197      INTEGER ::   ios, ilocal_comm   ! local integers
198      !!
199      NAMELIST/namctl/ sn_cfctl, nn_print, nn_ictls, nn_ictle,              &
200         &             nn_isplt , nn_jsplt, nn_jctls, nn_jctle,             &
201         &             ln_timing, ln_diacfl
202      NAMELIST/namcfg/ ln_read_cfg, cn_domcfg, ln_closea, ln_write_cfg, cn_domcfg_out, ln_use_jattr
203      !!----------------------------------------------------------------------
204      !
205      IF( lk_oasis ) THEN   ;   cxios_context = 'sas'
206      ELSE                  ;   cxios_context = 'nemo'
207      ENDIF
208      !
209      !                             !-------------------------------------------------!
210      !                             !     set communicator & select the local rank    !
211      !                             !  must be done as soon as possible to get narea  !
212      !                             !-------------------------------------------------!
213      !
214#if defined key_iomput
215      IF( Agrif_Root() ) THEN
216         IF( lk_oasis ) THEN
217            CALL cpl_init( "sas", ilocal_comm )                                  ! nemo local communicator given by oasis
218            CALL xios_initialize( "not used",local_comm=ilocal_comm )            ! send nemo communicator to xios
219         ELSE
220            CALL xios_initialize( "for_xios_mpi_id",return_comm=ilocal_comm )    ! nemo local communicator given by xios
221         ENDIF
222      ENDIF
223      CALL mpp_start( ilocal_comm )
224#else
225      IF( lk_oasis ) THEN
226         IF( Agrif_Root() ) THEN
227            CALL cpl_init( "sas", ilocal_comm )             ! nemo local communicator given by oasis
228         ENDIF
229         CALL mpp_start( ilocal_comm )
230      ELSE
231         CALL mpp_start( )
232      ENDIF
233#endif
234      !
235      narea = mpprank + 1                                   ! mpprank: the rank of proc (0 --> mppsize -1 )
236      lwm = (narea == 1)                ! control of output namelists
237      !
238      !                             !---------------------------------------------------------------!
239      !                             ! Open output files, reference and configuration namelist files !
240      !                             !---------------------------------------------------------------!
241      !
242      ! open ocean.output as soon as possible to get all output prints (including errors messages)
243      IF( lk_oasis ) THEN
244         IF( lwm )   CALL ctl_opn(     numout,               'sas.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. )
245         ! open reference and configuration namelist files
246                     CALL load_nml( numnam_ref,        'namelist_sas_ref',                                           -1, lwm )
247                     CALL load_nml( numnam_cfg,        'namelist_sas_cfg',                                           -1, lwm )
248         IF( lwm )   CALL ctl_opn(      numond, 'output.namelist_sas.dyn', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. )
249      ELSE
250         IF( lwm )   CALL ctl_opn(      numout,            'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. )
251         ! open reference and configuration namelist files
252                     CALL load_nml( numnam_ref,            'namelist_ref',                                           -1, lwm )
253                     CALL load_nml( numnam_cfg,            'namelist_cfg',                                           -1, lwm )
254         IF( lwm )   CALL ctl_opn(      numond,     'output.namelist.dyn', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. )
255      ENDIF
256      ! open /dev/null file to be able to supress output write easily
257      IF( Agrif_Root() ) THEN
258                     CALL ctl_opn(     numnul,               '/dev/null', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. )
259#ifdef key_agrif
260      ELSE
261                  numnul = Agrif_Parent(numnul)   
262#endif
263      ENDIF
264      !
265      !                             !--------------------!
266      !                             ! Open listing units !  -> need sn_cfctl from namctl to define lwp
267      !                             !--------------------!
268      !
269      READ  ( numnam_ref, namctl, IOSTAT = ios, ERR = 901 )
270901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namctl in reference namelist' )
271      READ  ( numnam_cfg, namctl, IOSTAT = ios, ERR = 902 )
272902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namctl in configuration namelist' )
273      !
274      ! finalize the definition of namctl variables
275      IF( narea < sn_cfctl%procmin .OR. narea > sn_cfctl%procmax .OR. MOD( narea - sn_cfctl%procmin, sn_cfctl%procincr ) /= 0 )   &
276         &   CALL nemo_set_cfctl( sn_cfctl, .FALSE. )
277      !
278      lwp = (narea == 1) .OR. sn_cfctl%l_oceout    ! control of all listing output print
279      !
280      IF(lwp) THEN                      ! open listing units
281         !
282         IF( .NOT. lwm ) THEN           ! alreay opened for narea == 1
283            IF(lk_oasis) THEN   ;   CALL ctl_opn( numout,   'sas.output','REPLACE','FORMATTED','SEQUENTIAL',-1,-1, .FALSE., narea )
284            ELSE                ;   CALL ctl_opn( numout, 'ocean.output','REPLACE','FORMATTED','SEQUENTIAL',-1,-1, .FALSE., narea )
285            ENDIF
286         ENDIF
287         !
288         WRITE(numout,*)
289         WRITE(numout,*) '   CNRS - NERC - Met OFFICE - MERCATOR-ocean - CMCC'
290         WRITE(numout,*) '                       NEMO team'
291         WRITE(numout,*) '            Ocean General Circulation Model'
292         WRITE(numout,*) '                NEMO version 4.0  (2019) '
293         WRITE(numout,*) '             StandAlone Surface version (SAS) '
294         WRITE(numout,*) "           ._      ._      ._      ._      ._    "
295         WRITE(numout,*) "       _.-._)`\_.-._)`\_.-._)`\_.-._)`\_.-._)`\_ "
296         WRITE(numout,*)
297         WRITE(numout,*) "           o         _,           _,             "
298         WRITE(numout,*) "            o      .' (        .-' /             "
299         WRITE(numout,*) "           o     _/..._'.    .'   /              "
300         WRITE(numout,*) "      (    o .-'`      ` '-./  _.'               "
301         WRITE(numout,*) "       )    ( o)           ;= <_         (       "
302         WRITE(numout,*) "      (      '-.,\\__ __.-;`\   '.        )      "
303         WRITE(numout,*) "       )  )       \) |`\ \)  '.   \      (   (   "
304         WRITE(numout,*) "      (  (           \_/       '-._\      )   )  "
305         WRITE(numout,*) "       )  ) jgs                    `     (   (   "
306         WRITE(numout,*) "     ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^ "
307         WRITE(numout,*)
308         WRITE(numout,*)
309         !
310         WRITE(numout,cform_aaa)                                        ! Flag AAAAAAA
311         !
312      ENDIF
313      !
314      IF(lwm) WRITE( numond, namctl )
315      !
316      !                             !------------------------------------!
317      !                             !  Set global domain size parameters !
318      !                             !------------------------------------!
319      !
320      READ  ( numnam_ref, namcfg, IOSTAT = ios, ERR = 903 )
321903   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namcfg in reference namelist' )
322      READ  ( numnam_cfg, namcfg, IOSTAT = ios, ERR = 904 )
323904   IF( ios >  0 )   CALL ctl_nam ( ios , 'namcfg in configuration namelist' )   
324      !
325      IF( ln_read_cfg ) THEN            ! Read sizes in domain configuration file
326         CALL domain_cfg ( cn_cfg, nn_cfg, jpiglo, jpjglo, jpkglo, jperio )
327      ELSE                              ! user-defined namelist
328         CALL usr_def_nam( cn_cfg, nn_cfg, jpiglo, jpjglo, jpkglo, jperio )
329      ENDIF
330      !
331      IF(lwm)   WRITE( numond, namcfg )
332      !
333      !                             !-----------------------------------------!
334      !                             ! mpp parameters and domain decomposition !
335      !                             !-----------------------------------------!
336      CALL mpp_init
337
338      ! Now we know the dimensions of the grid and numout has been set: we can allocate arrays
339      CALL nemo_alloc()
340
341      ! Initialise time level indices
342      Nbb = 1; Nnn = 2; Naa = 3; Nrhs = Naa
343#if defined key_agrif
344      Kbb_a = Nbb; Kmm_a = Nnn; Krhs_a = Nrhs   ! agrif_oce module copies of time level indices
345#endif 
346
347      !                             !-------------------------------!
348      !                             !  NEMO general initialization  !
349      !                             !-------------------------------!
350
351      CALL nemo_ctl                          ! Control prints
352      !
353      !                                      ! General initialization
354      IF( ln_timing    )   CALL timing_init     ! timing
355      IF( ln_timing    )   CALL timing_start( 'nemo_init')
356
357                           CALL phy_cst         ! Physical constants
358                           CALL eos_init        ! Equation of seawater
359#if defined key_agrif
360     CALL Agrif_Declare_Var_ini   !  "      "   "   "      "  DOM
361#endif
362                           CALL dom_init( Nbb, Nnn, Naa, 'SAS') ! Domain
363      IF( sn_cfctl%l_prtctl )   &
364         &                 CALL prt_ctl_init        ! Print control
365     
366                           CALL day_init        ! model calendar (using both namelist and restart infos)
367      IF( ln_rstart )      CALL rst_read_open
368
369      !                                      ! external forcing
370                           CALL sbc_init( Nbb, Nnn, Naa )  ! Forcings : surface module
371
372      ! ==> clem: open boundaries init. is mandatory for sea-ice because ice BDY is not decoupled from 
373      !           the environment of ocean BDY. Therefore bdy is called in both OPA and SAS modules.
374      !           This is not clean and should be changed in the future.
375                           CALL bdy_init
376      ! ==>
377                           CALL icb_init( rn_Dt, nit000)   ! initialise icebergs instance
378      !
379      IF(lwp) WRITE(numout,cform_aaa)           ! Flag AAAAAAA
380      !
381      IF( ln_timing    )   CALL timing_stop( 'nemo_init')
382      !
383   END SUBROUTINE nemo_init
384
385
386   SUBROUTINE nemo_ctl
387      !!----------------------------------------------------------------------
388      !!                     ***  ROUTINE nemo_ctl  ***
389      !!
390      !! ** Purpose :   control print setting
391      !!
392      !! ** Method  : - print namctl and namcfg information and check some consistencies
393      !!----------------------------------------------------------------------
394      !
395      IF(lwp) THEN                  ! control print
396         WRITE(numout,*)
397         WRITE(numout,*) 'nemo_ctl: Control prints'
398         WRITE(numout,*) '~~~~~~~~'
399         WRITE(numout,*) '   Namelist namctl'
400         WRITE(numout,*) '                              sn_cfctl%l_runstat = ', sn_cfctl%l_runstat
401         WRITE(numout,*) '                              sn_cfctl%l_trcstat = ', sn_cfctl%l_trcstat
402         WRITE(numout,*) '                              sn_cfctl%l_oceout  = ', sn_cfctl%l_oceout
403         WRITE(numout,*) '                              sn_cfctl%l_layout  = ', sn_cfctl%l_layout
404         WRITE(numout,*) '                              sn_cfctl%l_prtctl  = ', sn_cfctl%l_prtctl
405         WRITE(numout,*) '                              sn_cfctl%l_prttrc  = ', sn_cfctl%l_prttrc
406         WRITE(numout,*) '                              sn_cfctl%l_oasout  = ', sn_cfctl%l_oasout
407         WRITE(numout,*) '                              sn_cfctl%procmin   = ', sn_cfctl%procmin 
408         WRITE(numout,*) '                              sn_cfctl%procmax   = ', sn_cfctl%procmax 
409         WRITE(numout,*) '                              sn_cfctl%procincr  = ', sn_cfctl%procincr 
410         WRITE(numout,*) '                              sn_cfctl%ptimincr  = ', sn_cfctl%ptimincr 
411         WRITE(numout,*) '      level of print                  nn_print   = ', nn_print
412         WRITE(numout,*) '      Start i indice for SUM control  nn_ictls   = ', nn_ictls
413         WRITE(numout,*) '      End i indice for SUM control    nn_ictle   = ', nn_ictle
414         WRITE(numout,*) '      Start j indice for SUM control  nn_jctls   = ', nn_jctls
415         WRITE(numout,*) '      End j indice for SUM control    nn_jctle   = ', nn_jctle
416         WRITE(numout,*) '      number of proc. following i     nn_isplt   = ', nn_isplt
417         WRITE(numout,*) '      number of proc. following j     nn_jsplt   = ', nn_jsplt
418         WRITE(numout,*) '      timing by routine               ln_timing  = ', ln_timing
419         WRITE(numout,*) '      CFL diagnostics                 ln_diacfl  = ', ln_diacfl
420      ENDIF
421      !
422      nprint    = nn_print          ! convert DOCTOR namelist names into OLD names
423      nictls    = nn_ictls
424      nictle    = nn_ictle
425      njctls    = nn_jctls
426      njctle    = nn_jctle
427      isplt     = nn_isplt
428      jsplt     = nn_jsplt
429
430      IF(lwp) THEN                  ! control print
431         WRITE(numout,*)
432         WRITE(numout,*) '   Namelist namcfg'
433         WRITE(numout,*) '      read domain configuration file                ln_read_cfg      = ', ln_read_cfg
434         WRITE(numout,*) '         filename to be read                           cn_domcfg     = ', TRIM(cn_domcfg)
435         WRITE(numout,*) '         keep closed seas in the domain (if exist)     ln_closea     = ', ln_closea
436         WRITE(numout,*) '      create a configuration definition file        ln_write_cfg     = ', ln_write_cfg
437         WRITE(numout,*) '         filename to be written                        cn_domcfg_out = ', TRIM(cn_domcfg_out)
438         WRITE(numout,*) '      use file attribute if exists as i/p j-start   ln_use_jattr     = ', ln_use_jattr
439      ENDIF
440      IF( .NOT.ln_read_cfg )   ln_closea = .false.   ! dealing possible only with a domcfg file
441      !
442      !                             ! Parameter control
443      !
444      IF( sn_cfctl%l_prtctl .OR. sn_cfctl%l_prttrc ) THEN              ! sub-domain area indices for the control prints
445         IF( lk_mpp .AND. jpnij > 1 ) THEN
446            isplt = jpni   ;   jsplt = jpnj   ;   ijsplt = jpni*jpnj   ! the domain is forced to the real split domain
447         ELSE
448            IF( isplt == 1 .AND. jsplt == 1  ) THEN
449               CALL ctl_warn( ' - isplt & jsplt are equal to 1',   &
450                  &           ' - the print control will be done over the whole domain' )
451            ENDIF
452            ijsplt = isplt * jsplt            ! total number of processors ijsplt
453         ENDIF
454         IF(lwp) WRITE(numout,*)'          - The total number of processors over which the'
455         IF(lwp) WRITE(numout,*)'            print control will be done is ijsplt : ', ijsplt
456         !
457         !                              ! indices used for the SUM control
458         IF( nictls+nictle+njctls+njctle == 0 )   THEN    ! print control done over the default area
459            lsp_area = .FALSE.
460         ELSE                                             ! print control done over a specific  area
461            lsp_area = .TRUE.
462            IF( nictls < 1 .OR. nictls > jpiglo )   THEN
463               CALL ctl_warn( '          - nictls must be 1<=nictls>=jpiglo, it is forced to 1' )
464               nictls = 1
465            ENDIF
466            IF( nictle < 1 .OR. nictle > jpiglo )   THEN
467               CALL ctl_warn( '          - nictle must be 1<=nictle>=jpiglo, it is forced to jpiglo' )
468               nictle = jpiglo
469            ENDIF
470            IF( njctls < 1 .OR. njctls > jpjglo )   THEN
471               CALL ctl_warn( '          - njctls must be 1<=njctls>=jpjglo, it is forced to 1' )
472               njctls = 1
473            ENDIF
474            IF( njctle < 1 .OR. njctle > jpjglo )   THEN
475               CALL ctl_warn( '          - njctle must be 1<=njctle>=jpjglo, it is forced to jpjglo' )
476               njctle = jpjglo
477            ENDIF
478         ENDIF
479      ENDIF
480      !
481      IF( 1._wp /= SIGN(1._wp,-0._wp)  )   CALL ctl_stop( 'nemo_ctl: The intrinsec SIGN function follows f2003 standard.',  &
482         &                                                'Compile with key_nosignedzero enabled:',   &
483         &                                                '--> add -Dkey_nosignedzero to the definition of %CPP in your arch file' )
484      !
485#if defined key_agrif
486      IF( ln_timing )   CALL ctl_stop( 'AGRIF not implemented with ln_timing = true')
487#endif
488      !
489   END SUBROUTINE nemo_ctl
490
491
492   SUBROUTINE nemo_closefile
493      !!----------------------------------------------------------------------
494      !!                     ***  ROUTINE nemo_closefile  ***
495      !!
496      !! ** Purpose :   Close the files
497      !!----------------------------------------------------------------------
498      !
499      IF( lk_mpp )   CALL mppsync
500      !
501      CALL iom_close                                 ! close all input/output files managed by iom_*
502      !
503      IF( numstp          /= -1 )   CLOSE( numstp          )   ! time-step file     
504      IF( numrun          /= -1 )   CLOSE( numrun          )   ! run statistics file
505      IF( lwm.AND.numond  /= -1 )   CLOSE( numond          )   ! oce output namelist
506      IF( lwm.AND.numoni  /= -1 )   CLOSE( numoni          )   ! ice output namelist
507      IF( numevo_ice      /= -1 )   CLOSE( numevo_ice      )   ! ice variables (temp. evolution)
508      IF( numout          /=  6 )   CLOSE( numout          )   ! standard model output file
509      !
510      numout = 6                                     ! redefine numout in case it is used after this point...
511      !
512   END SUBROUTINE nemo_closefile
513
514
515   SUBROUTINE nemo_alloc
516      !!----------------------------------------------------------------------
517      !!                     ***  ROUTINE nemo_alloc  ***
518      !!
519      !! ** Purpose :   Allocate all the dynamic arrays of the OPA modules
520      !!
521      !! ** Method  :
522      !!----------------------------------------------------------------------
523      USE diawri    , ONLY : dia_wri_alloc
524      USE dom_oce   , ONLY : dom_oce_alloc
525      USE bdy_oce   , ONLY : ln_bdy, bdy_oce_alloc
526      USE oce       ! mandatory for sea-ice because needed for bdy arrays
527      !
528      INTEGER :: ierr
529      !!----------------------------------------------------------------------
530      !
531      ierr =        dia_wri_alloc()
532      ierr = ierr + dom_oce_alloc()          ! ocean domain
533      ierr = ierr + oce_alloc    ()          ! (tsn...) needed for agrif and/or SI3 and bdy
534      ierr = ierr + bdy_oce_alloc()          ! bdy masks (incl. initialization)
535      !
536      CALL mpp_sum( 'nemogcm', ierr )
537      IF( ierr /= 0 )   CALL ctl_stop( 'STOP', 'nemo_alloc: unable to allocate standard ocean arrays' )
538      !
539   END SUBROUTINE nemo_alloc
540
541   SUBROUTINE nemo_set_cfctl(sn_cfctl, setto )
542      !!----------------------------------------------------------------------
543      !!                     ***  ROUTINE nemo_set_cfctl  ***
544      !!
545      !! ** Purpose :   Set elements of the output control structure to setto.
546      !!
547      !! ** Method  :   Note this routine can be used to switch on/off some
548      !!                types of output for selected areas.
549      !!----------------------------------------------------------------------
550      TYPE(sn_ctl), INTENT(inout) :: sn_cfctl
551      LOGICAL     , INTENT(in   ) :: setto
552      !!----------------------------------------------------------------------
553      sn_cfctl%l_runstat = setto
554      sn_cfctl%l_trcstat = setto
555      sn_cfctl%l_oceout  = setto
556      sn_cfctl%l_layout  = setto
557      sn_cfctl%l_prtctl  = setto
558      sn_cfctl%l_prttrc  = setto
559      sn_cfctl%l_oasout  = setto
560   END SUBROUTINE nemo_set_cfctl
561
562   !!======================================================================
563END MODULE nemogcm
564
Note: See TracBrowser for help on using the repository browser.