source: NEMO/branches/2020/dev_r13312_AGRIF-03-04_jchanut_vinterp_tstep/src/OCE/nemogcm.F90 @ 13565

Last change on this file since 13565 was 13565, checked in by jchanut, 5 months ago

#2222, 1) Added parent bathymetry volume consistency check 2) Added velocity extrapolation in update 3) Corrected bdy issue #2519

  • Property svn:keywords set to Id
File size: 33.0 KB
Line 
1MODULE nemogcm
2   !!======================================================================
3   !!                       ***  MODULE nemogcm   ***
4   !! Ocean system   : NEMO GCM (ocean dynamics, on-line tracers, biochemistry and sea-ice)
5   !!======================================================================
6   !! History :  OPA  ! 1990-10  (C. Levy, G. Madec)  Original code
7   !!            7.0  ! 1991-11  (M. Imbard, C. Levy, G. Madec)
8   !!            7.1  ! 1993-03  (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
9   !!                             P. Delecluse, C. Perigaud, G. Caniaux, B. Colot, C. Maes) release 7.1
10   !!             -   ! 1992-06  (L.Terray)  coupling implementation
11   !!             -   ! 1993-11  (M.A. Filiberti) IGLOO sea-ice
12   !!            8.0  ! 1996-03  (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
13   !!                             P. Delecluse, L.Terray, M.A. Filiberti, J. Vialar, A.M. Treguier, M. Levy) release 8.0
14   !!            8.1  ! 1997-06  (M. Imbard, G. Madec)
15   !!            8.2  ! 1999-11  (M. Imbard, H. Goosse)  sea-ice model
16   !!                 ! 1999-12  (V. Thierry, A-M. Treguier, M. Imbard, M-A. Foujols)  OPEN-MP
17   !!                 ! 2000-07  (J-M Molines, M. Imbard)  Open Boundary Conditions  (CLIPPER)
18   !!   NEMO     1.0  ! 2002-08  (G. Madec)  F90: Free form and modules
19   !!             -   ! 2004-06  (R. Redler, NEC CCRLE, Germany) add OASIS[3/4] coupled interfaces
20   !!             -   ! 2004-08  (C. Talandier) New trends organization
21   !!             -   ! 2005-06  (C. Ethe) Add the 1D configuration possibility
22   !!             -   ! 2005-11  (V. Garnier) Surface pressure gradient organization
23   !!             -   ! 2006-03  (L. Debreu, C. Mazauric)  Agrif implementation
24   !!             -   ! 2006-04  (G. Madec, R. Benshila)  Step reorganization
25   !!             -   ! 2007-07  (J. Chanut, A. Sellar) Unstructured open boundaries (BDY)
26   !!            3.2  ! 2009-08  (S. Masson)  open/write in the listing file in mpp
27   !!            3.3  ! 2010-05  (K. Mogensen, A. Weaver, M. Martin, D. Lea) Assimilation interface
28   !!             -   ! 2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase
29   !!            3.3.1! 2011-01  (A. R. Porter, STFC Daresbury) dynamical allocation
30   !!             -   ! 2011-11  (C. Harris) decomposition changes for running with CICE
31   !!            3.6  ! 2012-05  (C. Calone, J. Simeon, G. Madec, C. Ethe) Add grid coarsening
32   !!             -   ! 2014-12  (G. Madec) remove KPP scheme and cross-land advection (cla)
33   !!            4.0  ! 2016-10  (G. Madec, S. Flavoni)  domain configuration / user defined interface
34   !!----------------------------------------------------------------------
35
36   !!----------------------------------------------------------------------
37   !!   nemo_gcm      : solve ocean dynamics, tracer, biogeochemistry and/or sea-ice
38   !!   nemo_init     : initialization of the NEMO system
39   !!   nemo_ctl      : initialisation of the contol print
40   !!   nemo_closefile: close remaining open files
41   !!   nemo_alloc    : dynamical allocation
42   !!----------------------------------------------------------------------
43   USE step_oce       ! module used in the ocean time stepping module (step.F90)
44   USE phycst         ! physical constant                  (par_cst routine)
45   USE domain         ! domain initialization   (dom_init & dom_cfg routines)
46   USE closea         ! treatment of closed seas (for ln_closea)
47   USE usrdef_nam     ! user defined configuration
48   USE tide_mod, ONLY : tide_init ! tidal components initialization   (tide_init routine)
49   USE bdyini         ! open boundary cond. setting       (bdy_init routine)
50   USE istate         ! initial state setting          (istate_init routine)
51   USE ldfdyn         ! lateral viscosity setting      (ldfdyn_init routine)
52   USE ldftra         ! lateral diffusivity setting    (ldftra_init routine)
53   USE trdini         ! dyn/tra trends initialization     (trd_init routine)
54   USE asminc         ! assimilation increments     
55   USE asmbkg         ! writing out state trajectory
56   USE diaptr         ! poleward transports           (dia_ptr_init routine)
57   USE diadct         ! sections transports           (dia_dct_init routine)
58   USE diaobs         ! Observation diagnostics       (dia_obs_init routine)
59   USE diacfl         ! CFL diagnostics               (dia_cfl_init routine)
60   USE diamlr         ! IOM context management for multiple-linear-regression analysis
61#if defined key_qco
62   USE stepMLF        ! NEMO time-stepping               (stp_MLF   routine)
63#else
64   USE step           ! NEMO time-stepping                 (stp     routine)
65#endif
66   USE isfstp         ! ice shelf                     (isf_stp_init routine)
67   USE icbini         ! handle bergs, initialisation
68   USE icbstp         ! handle bergs, calving, themodynamics and transport
69   USE cpl_oasis3     ! OASIS3 coupling
70   USE c1d            ! 1D configuration
71   USE step_c1d       ! Time stepping loop for the 1D configuration
72   USE dyndmp         ! Momentum damping
73   USE stopar         ! Stochastic param.: ???
74   USE stopts         ! Stochastic param.: ???
75   USE diu_layers     ! diurnal bulk SST and coolskin
76   USE step_diu       ! diurnal bulk SST timestepping (called from here if run offline)
77   USE crsini         ! initialise grid coarsening utility
78   USE dia25h         ! 25h mean output
79   USE diadetide      ! Weights computation for daily detiding of model diagnostics
80   USE sbc_oce , ONLY : lk_oasis
81   USE wet_dry        ! Wetting and drying setting   (wad_init routine)
82#if defined key_top
83   USE trcini         ! passive tracer initialisation
84#endif
85#if defined key_nemocice_decomp
86   USE ice_domain_size, only: nx_global, ny_global
87#endif
88   !
89   USE prtctl         ! Print control
90   USE in_out_manager ! I/O manager
91   USE lib_mpp        ! distributed memory computing
92   USE mppini         ! shared/distributed memory setting (mpp_init routine)
93   USE lbcnfd  , ONLY : isendto, nsndto  ! Setup of north fold exchanges
94   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined)
95#if defined key_iomput
96   USE xios           ! xIOserver
97#endif
98#if defined key_agrif
99   USE agrif_all_update   ! Master Agrif update
100   USE agrif_oce_update
101#endif
102   USE halo_mng
103
104   IMPLICIT NONE
105   PRIVATE
106
107   PUBLIC   nemo_gcm    ! called by model.F90
108   PUBLIC   nemo_init   ! needed by AGRIF
109   PUBLIC   nemo_alloc  ! needed by TAM
110
111   CHARACTER(lc) ::   cform_aaa="( /, 'AAAAAAAA', / ) "     ! flag for output listing
112
113#if defined key_mpp_mpi
114   ! need MPI_Wtime
115   INCLUDE 'mpif.h'
116#endif
117
118   !!----------------------------------------------------------------------
119   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
120   !! $Id$
121   !! Software governed by the CeCILL license (see ./LICENSE)
122   !!----------------------------------------------------------------------
123CONTAINS
124
125   SUBROUTINE nemo_gcm
126      !!----------------------------------------------------------------------
127      !!                     ***  ROUTINE nemo_gcm  ***
128      !!
129      !! ** Purpose :   NEMO solves the primitive equations on an orthogonal
130      !!              curvilinear mesh on the sphere.
131      !!
132      !! ** Method  : - model general initialization
133      !!              - launch the time-stepping (stp routine)
134      !!              - finalize the run by closing files and communications
135      !!
136      !! References : Madec, Delecluse, Imbard, and Levy, 1997:  internal report, IPSL.
137      !!              Madec, 2008, internal report, IPSL.
138      !!----------------------------------------------------------------------
139      INTEGER ::   istp   ! time step index
140      REAL(wp)::   zstptiming   ! elapsed time for 1 time step
141      !!----------------------------------------------------------------------
142      !
143#if defined key_agrif
144      CALL Agrif_Init_Grids()      ! AGRIF: set the meshes
145#endif
146      !                            !-----------------------!
147      CALL nemo_init               !==  Initialisations  ==!
148      !                            !-----------------------!
149#if defined key_agrif
150      Kbb_a = Nbb; Kmm_a = Nnn; Krhs_a = Nrhs   ! agrif_oce module copies of time level indices
151      CALL Agrif_Declare_Var       !  "      "   "   "      "  DYN/TRA
152# if defined key_top
153      CALL Agrif_Declare_Var_top   !  "      "   "   "      "  TOP
154# endif
155#endif
156      ! check that all process are still there... If some process have an error,
157      ! they will never enter in step and other processes will wait until the end of the cpu time!
158      CALL mpp_max( 'nemogcm', nstop )
159
160      IF(lwp) WRITE(numout,cform_aaa)   ! Flag AAAAAAA
161
162      !                            !-----------------------!
163      !                            !==   time stepping   ==!
164      !                            !-----------------------!
165      !
166      !                                               !== set the model time-step  ==!
167      !
168      istp = nit000
169      !
170#if defined key_c1d
171      DO WHILE ( istp <= nitend .AND. nstop == 0 )    !==  C1D time-stepping  ==!
172         CALL stp_c1d( istp )
173         istp = istp + 1
174      END DO
175#else
176      !
177# if defined key_agrif
178      !                                               !==  AGRIF time-stepping  ==!
179      CALL Agrif_Regrid()
180      !
181      ! Recursive update from highest nested level to lowest:
182      Kbb_a = Nbb; Kmm_a = Nnn; Krhs_a = Nrhs   ! agrif_oce module copies of time level indices
183      CALL Agrif_step_child_adj(Agrif_Update_All)
184      CALL Agrif_step_child_adj(Agrif_Check_parent_bat)
185      !
186      DO WHILE( istp <= nitend .AND. nstop == 0 )
187#if defined key_qco
188         CALL stp_MLF
189#else
190         CALL stp
191#endif
192         istp = istp + 1
193      END DO
194      !
195# else
196      !
197      IF( .NOT.ln_diurnal_only ) THEN                 !==  Standard time-stepping  ==!
198         !
199         DO WHILE( istp <= nitend .AND. nstop == 0 )
200
201            ncom_stp = istp
202            IF( ln_timing ) THEN
203               zstptiming = MPI_Wtime()
204               IF ( istp == ( nit000 + 1 ) ) elapsed_time = zstptiming
205               IF ( istp ==         nitend ) elapsed_time = zstptiming - elapsed_time
206            ENDIF
207           
208#if defined key_qco
209            CALL stp_MLF      ( istp )
210#else
211            CALL stp        ( istp ) 
212#endif
213            istp = istp + 1
214
215            IF( lwp .AND. ln_timing )   WRITE(numtime,*) 'timing step ', istp-1, ' : ', MPI_Wtime() - zstptiming
216
217         END DO
218         !
219      ELSE                                            !==  diurnal SST time-steeping only  ==!
220         !
221         DO WHILE( istp <= nitend .AND. nstop == 0 )
222            CALL stp_diurnal( istp )   ! time step only the diurnal SST
223            istp = istp + 1
224         END DO
225         !
226      ENDIF
227      !
228# endif
229      !
230#endif
231      !
232      IF( ln_diaobs   )   CALL dia_obs_wri
233      !
234      IF( ln_icebergs )   CALL icb_end( nitend )
235
236      !                            !------------------------!
237      !                            !==  finalize the run  ==!
238      !                            !------------------------!
239      IF(lwp) WRITE(numout,cform_aaa)        ! Flag AAAAAAA
240      !
241      IF( nstop /= 0 .AND. lwp ) THEN        ! error print
242         WRITE(ctmp1,*) '   ==>>>   nemo_gcm: a total of ', nstop, ' errors have been found'
243         IF( ngrdstop > 0 ) THEN
244            WRITE(ctmp9,'(i2)') ngrdstop
245            WRITE(ctmp2,*) '           E R R O R detected in Agrif grid '//TRIM(ctmp9)
246            WRITE(ctmp3,*) '           Look for "E R R O R" messages in all existing '//TRIM(ctmp9)//'_ocean_output* files'
247            CALL ctl_stop( ' ', ctmp1, ' ', ctmp2, ' ', ctmp3 )
248         ELSE
249            WRITE(ctmp2,*) '           Look for "E R R O R" messages in all existing ocean_output* files'
250            CALL ctl_stop( ' ', ctmp1, ' ', ctmp2 )
251         ENDIF
252      ENDIF
253      !
254      IF( ln_timing )   CALL timing_finalize
255      !
256      CALL nemo_closefile
257      !
258#if defined key_iomput
259                                    CALL xios_finalize  ! end mpp communications with xios
260      IF( lk_oasis     )            CALL cpl_finalize   ! end coupling and mpp communications with OASIS
261#else
262      IF    ( lk_oasis ) THEN   ;   CALL cpl_finalize   ! end coupling and mpp communications with OASIS
263      ELSEIF( lk_mpp   ) THEN   ;   CALL mppstop        ! end mpp communications
264      ENDIF
265#endif
266      !
267      IF(lwm) THEN
268         IF( nstop == 0 ) THEN   ;   STOP 0
269         ELSE                    ;   STOP 123
270         ENDIF
271      ENDIF
272      !
273   END SUBROUTINE nemo_gcm
274
275
276   SUBROUTINE nemo_init
277      !!----------------------------------------------------------------------
278      !!                     ***  ROUTINE nemo_init  ***
279      !!
280      !! ** Purpose :   initialization of the NEMO GCM
281      !!----------------------------------------------------------------------
282      INTEGER ::   ios, ilocal_comm   ! local integers
283      !!
284      NAMELIST/namctl/ sn_cfctl, ln_timing, ln_diacfl,                                &
285         &             nn_isplt,  nn_jsplt,  nn_ictls, nn_ictle, nn_jctls, nn_jctle           
286      NAMELIST/namcfg/ ln_read_cfg, cn_domcfg, ln_closea, ln_write_cfg, cn_domcfg_out, ln_use_jattr
287      !!----------------------------------------------------------------------
288      !
289      cxios_context = 'nemo'
290      !
291      !                             !-------------------------------------------------!
292      !                             !     set communicator & select the local rank    !
293      !                             !  must be done as soon as possible to get narea  !
294      !                             !-------------------------------------------------!
295      !
296#if defined key_iomput
297      IF( Agrif_Root() ) THEN
298         IF( lk_oasis ) THEN
299            CALL cpl_init( "oceanx", ilocal_comm )                               ! nemo local communicator given by oasis
300            CALL xios_initialize( "not used"       , local_comm =ilocal_comm )   ! send nemo communicator to xios
301         ELSE
302            CALL xios_initialize( "for_xios_mpi_id", return_comm=ilocal_comm )   ! nemo local communicator given by xios
303         ENDIF
304      ENDIF
305      CALL mpp_start( ilocal_comm )
306#else
307      IF( lk_oasis ) THEN
308         IF( Agrif_Root() ) THEN
309            CALL cpl_init( "oceanx", ilocal_comm )          ! nemo local communicator given by oasis
310         ENDIF
311         CALL mpp_start( ilocal_comm )
312      ELSE
313         CALL mpp_start( )
314      ENDIF
315#endif
316      !
317      narea = mpprank + 1               ! mpprank: the rank of proc (0 --> mppsize -1 )
318      lwm = (narea == 1)                ! control of output namelists
319      !
320      !                             !---------------------------------------------------------------!
321      !                             ! Open output files, reference and configuration namelist files !
322      !                             !---------------------------------------------------------------!
323      !
324      ! open ocean.output as soon as possible to get all output prints (including errors messages)
325      IF( lwm )   CALL ctl_opn(     numout,        'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. )
326      ! open reference and configuration namelist files
327                  CALL load_nml( numnam_ref,        'namelist_ref',                                           -1, lwm )
328                  CALL load_nml( numnam_cfg,        'namelist_cfg',                                           -1, lwm )
329      IF( lwm )   CALL ctl_opn(     numond, 'output.namelist.dyn', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. )
330      ! open /dev/null file to be able to supress output write easily
331      IF( Agrif_Root() ) THEN
332                  CALL ctl_opn(     numnul,           '/dev/null', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. )
333#ifdef key_agrif
334      ELSE
335                  numnul = Agrif_Parent(numnul)   
336#endif
337      ENDIF
338      !                             !--------------------!
339      !                             ! Open listing units !  -> need sn_cfctl from namctl to define lwp
340      !                             !--------------------!
341      !
342      READ  ( numnam_ref, namctl, IOSTAT = ios, ERR = 901 )
343901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namctl in reference namelist' )
344      READ  ( numnam_cfg, namctl, IOSTAT = ios, ERR = 902 )
345902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namctl in configuration namelist' )
346      !
347      ! finalize the definition of namctl variables
348      IF( narea < sn_cfctl%procmin .OR. narea > sn_cfctl%procmax .OR. MOD( narea - sn_cfctl%procmin, sn_cfctl%procincr ) /= 0 )   &
349         &   CALL nemo_set_cfctl( sn_cfctl, .FALSE. )
350      !
351      lwp = (narea == 1) .OR. sn_cfctl%l_oceout    ! control of all listing output print
352      !
353      IF(lwp) THEN                      ! open listing units
354         !
355         IF( .NOT. lwm )   &            ! alreay opened for narea == 1
356            &            CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE., narea )
357         !
358         WRITE(numout,*)
359         WRITE(numout,*) '   CNRS - NERC - Met OFFICE - MERCATOR-ocean - CMCC'
360         WRITE(numout,*) '                       NEMO team'
361         WRITE(numout,*) '            Ocean General Circulation Model'
362         WRITE(numout,*) '                NEMO version 4.0  (2019) '
363         WRITE(numout,*)
364         WRITE(numout,*) "           ._      ._      ._      ._      ._    "
365         WRITE(numout,*) "       _.-._)`\_.-._)`\_.-._)`\_.-._)`\_.-._)`\_ "
366         WRITE(numout,*)
367         WRITE(numout,*) "           o         _,           _,             "
368         WRITE(numout,*) "            o      .' (        .-' /             "
369         WRITE(numout,*) "           o     _/..._'.    .'   /              "
370         WRITE(numout,*) "      (    o .-'`      ` '-./  _.'               "
371         WRITE(numout,*) "       )    ( o)           ;= <_         (       "
372         WRITE(numout,*) "      (      '-.,\\__ __.-;`\   '.        )      "
373         WRITE(numout,*) "       )  )       \) |`\ \)  '.   \      (   (   "
374         WRITE(numout,*) "      (  (           \_/       '-._\      )   )  "
375         WRITE(numout,*) "       )  ) jgs                     `    (   (   "
376         WRITE(numout,*) "     ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^ "
377         WRITE(numout,*)
378         
379         ! Print the working precision to ocean.output
380         IF (wp == dp) THEN
381            WRITE(numout,*) "Working precision = double-precision"
382         ELSE
383            WRITE(numout,*) "Working precision = single-precision"
384         ENDIF
385         WRITE(numout,*)
386         !
387         WRITE(numout,cform_aaa)                                        ! Flag AAAAAAA
388         !
389      ENDIF
390      !
391      IF(lwm) WRITE( numond, namctl )
392      !
393      !                             !------------------------------------!
394      !                             !  Set global domain size parameters !
395      !                             !------------------------------------!
396      !
397      READ  ( numnam_ref, namcfg, IOSTAT = ios, ERR = 903 )
398903   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namcfg in reference namelist' )
399      READ  ( numnam_cfg, namcfg, IOSTAT = ios, ERR = 904 )
400904   IF( ios >  0 )   CALL ctl_nam ( ios , 'namcfg in configuration namelist' )   
401      !
402      IF( ln_read_cfg ) THEN            ! Read sizes in domain configuration file
403         CALL domain_cfg ( cn_cfg, nn_cfg, Ni0glo, Nj0glo, jpkglo, jperio )
404      ELSE                              ! user-defined namelist
405         CALL usr_def_nam( cn_cfg, nn_cfg, Ni0glo, Nj0glo, jpkglo, jperio )
406      ENDIF
407      !
408      IF(lwm)   WRITE( numond, namcfg )
409      !
410      !                             !-----------------------------------------!
411      !                             ! mpp parameters and domain decomposition !
412      !                             !-----------------------------------------!
413      CALL mpp_init
414
415      CALL halo_mng_init()
416      ! Now we know the dimensions of the grid and numout has been set: we can allocate arrays
417      CALL nemo_alloc()
418
419      ! Initialise time level indices
420      Nbb = 1; Nnn = 2; Naa = 3; Nrhs = Naa
421#if defined key_agrif
422      Kbb_a = Nbb; Kmm_a = Nnn; Krhs_a = Nrhs   ! agrif_oce module copies of time level indices
423#endif 
424      !                             !-------------------------------!
425      !                             !  NEMO general initialization  !
426      !                             !-------------------------------!
427
428      CALL nemo_ctl                          ! Control prints
429      !
430      !                                      ! General initialization
431      IF( ln_timing    )   CALL timing_init     ! timing
432      IF( ln_timing    )   CALL timing_start( 'nemo_init')
433      !
434                           CALL     phy_cst         ! Physical constants
435                           CALL     eos_init        ! Equation of state
436      IF( lk_c1d       )   CALL     c1d_init        ! 1D column configuration
437                           CALL     wad_init        ! Wetting and drying options
438
439#if defined key_agrif
440     CALL Agrif_Declare_Var_ini   !  "      "   "   "      "  DOM
441#endif
442                           CALL     dom_init( Nbb, Nnn, Naa, "OPA") ! Domain
443      IF( ln_crs       )   CALL     crs_init(      Nnn )       ! coarsened grid: domain initialization
444      IF( sn_cfctl%l_prtctl )   &
445         &                 CALL prt_ctl_init        ! Print control
446     
447                           CALL diurnal_sst_bulk_init       ! diurnal sst
448      IF( ln_diurnal   )   CALL diurnal_sst_coolskin_init   ! cool skin   
449      !                           
450      IF( ln_diurnal_only ) THEN                    ! diurnal only: a subset of the initialisation routines
451         CALL  istate_init( Nbb, Nnn, Naa )         ! ocean initial state (Dynamics and tracers)
452         CALL     sbc_init( Nbb, Nnn, Naa )         ! Forcings : surface module
453         CALL tra_qsr_init                          ! penetrative solar radiation qsr
454         IF( ln_diaobs ) THEN                       ! Observation & model comparison
455            CALL dia_obs_init( Nnn )                ! Initialize observational data
456            CALL dia_obs( nit000 - 1, Nnn )         ! Observation operator for restart
457         ENDIF     
458         IF( lk_asminc )   CALL asm_inc_init( Nbb, Nnn, Nrhs )   ! Assimilation increments
459         !
460         RETURN                                       ! end of initialization
461      ENDIF
462      !
463
464                           CALL  istate_init( Nbb, Nnn, Naa )    ! ocean initial state (Dynamics and tracers)
465
466      !                                      ! external forcing
467                           CALL    tide_init                     ! tidal harmonics
468                           CALL     sbc_init( Nbb, Nnn, Naa )    ! surface boundary conditions (including sea-ice)
469                           CALL     bdy_init                     ! Open boundaries initialisation
470
471      !                                      ! Ocean physics
472                           CALL zdf_phy_init( Nnn )    ! Vertical physics
473                                     
474      !                                         ! Lateral physics
475                           CALL ldf_tra_init      ! Lateral ocean tracer physics
476                           CALL ldf_eiv_init      ! eddy induced velocity param.
477                           CALL ldf_dyn_init      ! Lateral ocean momentum physics
478
479      !                                      ! Active tracers
480      IF( ln_traqsr    )   CALL tra_qsr_init      ! penetrative solar radiation qsr
481                           CALL tra_bbc_init      ! bottom heat flux
482                           CALL tra_bbl_init      ! advective (and/or diffusive) bottom boundary layer scheme
483                           CALL tra_dmp_init      ! internal tracer damping
484                           CALL tra_adv_init      ! horizontal & vertical advection
485                           CALL tra_ldf_init      ! lateral mixing
486
487      !                                      ! Dynamics
488      IF( lk_c1d       )   CALL dyn_dmp_init         ! internal momentum damping
489                           CALL dyn_adv_init         ! advection (vector or flux form)
490                           CALL dyn_vor_init         ! vorticity term including Coriolis
491                           CALL dyn_ldf_init         ! lateral mixing
492                           CALL dyn_hpg_init( Nnn )  ! horizontal gradient of Hydrostatic pressure
493                           CALL dyn_spg_init         ! surface pressure gradient
494
495#if defined key_top
496      !                                      ! Passive tracers
497                           CALL     trc_init( Nbb, Nnn, Naa )
498#endif
499      IF( l_ldfslp     )   CALL ldf_slp_init    ! slope of lateral mixing
500
501      !                                      ! Icebergs
502                           CALL icb_init( rn_Dt, nit000)   ! initialise icebergs instance
503
504                                                ! ice shelf
505                           CALL isf_init( Nbb, Nnn, Naa )
506
507      !                                      ! Misc. options
508                           CALL sto_par_init    ! Stochastic parametrization
509      IF( ln_sto_eos   )   CALL sto_pts_init    ! RRandom T/S fluctuations
510     
511      !                                      ! Diagnostics
512                           CALL     flo_init( Nnn )    ! drifting Floats
513      IF( ln_diacfl    )   CALL dia_cfl_init    ! Initialise CFL diagnostics
514!                           CALL dia_ptr_init    ! Poleward TRansports initialization
515                           CALL dia_dct_init    ! Sections tranports
516                           CALL dia_hsb_init( Nnn )    ! heat content, salt content and volume budgets
517                           CALL     trd_init( Nnn )    ! Mixed-layer/Vorticity/Integral constraints trends
518                           CALL dia_obs_init( Nnn )    ! Initialize observational data
519                           CALL dia_25h_init( Nbb )    ! 25h mean  outputs
520                           CALL dia_detide_init ! Weights computation for daily detiding of model diagnostics
521      IF( ln_diaobs    )   CALL dia_obs( nit000-1, Nnn )   ! Observation operator for restart
522                           CALL dia_mlr_init    ! Initialisation of IOM context management for multiple-linear-regression analysis
523
524      !                                      ! Assimilation increments
525      IF( lk_asminc    )   CALL asm_inc_init( Nbb, Nnn, Nrhs )   ! Initialize assimilation increments
526      !
527      IF(lwp) WRITE(numout,cform_aaa)           ! Flag AAAAAAA
528      !
529      IF( ln_timing    )   CALL timing_stop( 'nemo_init')
530      !
531   END SUBROUTINE nemo_init
532
533
534   SUBROUTINE nemo_ctl
535      !!----------------------------------------------------------------------
536      !!                     ***  ROUTINE nemo_ctl  ***
537      !!
538      !! ** Purpose :   control print setting
539      !!
540      !! ** Method  : - print namctl and namcfg information and check some consistencies
541      !!----------------------------------------------------------------------
542      !
543      IF(lwp) THEN                  ! control print
544         WRITE(numout,*)
545         WRITE(numout,*) 'nemo_ctl: Control prints'
546         WRITE(numout,*) '~~~~~~~~'
547         WRITE(numout,*) '   Namelist namctl'
548         WRITE(numout,*) '                              sn_cfctl%l_runstat = ', sn_cfctl%l_runstat
549         WRITE(numout,*) '                              sn_cfctl%l_trcstat = ', sn_cfctl%l_trcstat
550         WRITE(numout,*) '                              sn_cfctl%l_oceout  = ', sn_cfctl%l_oceout
551         WRITE(numout,*) '                              sn_cfctl%l_layout  = ', sn_cfctl%l_layout
552         WRITE(numout,*) '                              sn_cfctl%l_prtctl  = ', sn_cfctl%l_prtctl
553         WRITE(numout,*) '                              sn_cfctl%l_prttrc  = ', sn_cfctl%l_prttrc
554         WRITE(numout,*) '                              sn_cfctl%l_oasout  = ', sn_cfctl%l_oasout
555         WRITE(numout,*) '                              sn_cfctl%procmin   = ', sn_cfctl%procmin 
556         WRITE(numout,*) '                              sn_cfctl%procmax   = ', sn_cfctl%procmax 
557         WRITE(numout,*) '                              sn_cfctl%procincr  = ', sn_cfctl%procincr 
558         WRITE(numout,*) '                              sn_cfctl%ptimincr  = ', sn_cfctl%ptimincr 
559         WRITE(numout,*) '      timing by routine               ln_timing  = ', ln_timing
560         WRITE(numout,*) '      CFL diagnostics                 ln_diacfl  = ', ln_diacfl
561      ENDIF
562      !
563      IF( .NOT.ln_read_cfg )   ln_closea = .false.   ! dealing possible only with a domcfg file
564      IF(lwp) THEN                  ! control print
565         WRITE(numout,*)
566         WRITE(numout,*) '   Namelist namcfg'
567         WRITE(numout,*) '      read domain configuration file                ln_read_cfg      = ', ln_read_cfg
568         WRITE(numout,*) '         filename to be read                           cn_domcfg     = ', TRIM(cn_domcfg)
569         WRITE(numout,*) '         keep closed seas in the domain (if exist)     ln_closea     = ', ln_closea
570         WRITE(numout,*) '      create a configuration definition file        ln_write_cfg     = ', ln_write_cfg
571         WRITE(numout,*) '         filename to be written                        cn_domcfg_out = ', TRIM(cn_domcfg_out)
572         WRITE(numout,*) '      use file attribute if exists as i/p j-start   ln_use_jattr     = ', ln_use_jattr
573      ENDIF
574      !
575      IF( 1._wp /= SIGN(1._wp,-0._wp)  )   CALL ctl_stop( 'nemo_ctl: The intrinsec SIGN function follows f2003 standard.',  &
576         &                                                'Compile with key_nosignedzero enabled:',   &
577         &                                                '--> add -Dkey_nosignedzero to the definition of %CPP in your arch file' )
578      !
579#if defined key_agrif
580      IF( ln_timing )   CALL ctl_stop( 'AGRIF not implemented with ln_timing = true')
581#endif
582      !
583   END SUBROUTINE nemo_ctl
584
585
586   SUBROUTINE nemo_closefile
587      !!----------------------------------------------------------------------
588      !!                     ***  ROUTINE nemo_closefile  ***
589      !!
590      !! ** Purpose :   Close the files
591      !!----------------------------------------------------------------------
592      !
593      IF( lk_mpp )   CALL mppsync
594      !
595      CALL iom_close                                 ! close all input/output files managed by iom_*
596      !
597      IF( numstp          /= -1 )   CLOSE( numstp          )   ! time-step file
598      IF( numrun          /= -1 )   CLOSE( numrun          )   ! run statistics file
599      IF( lwm.AND.numond  /= -1 )   CLOSE( numond          )   ! oce output namelist
600      IF( lwm.AND.numoni  /= -1 )   CLOSE( numoni          )   ! ice output namelist
601      IF( numevo_ice      /= -1 )   CLOSE( numevo_ice      )   ! ice variables (temp. evolution)
602      IF( numout          /=  6 )   CLOSE( numout          )   ! standard model output file
603      IF( numdct_vol      /= -1 )   CLOSE( numdct_vol      )   ! volume transports
604      IF( numdct_heat     /= -1 )   CLOSE( numdct_heat     )   ! heat transports
605      IF( numdct_salt     /= -1 )   CLOSE( numdct_salt     )   ! salt transports
606      !
607      numout = 6                                     ! redefine numout in case it is used after this point...
608      !
609   END SUBROUTINE nemo_closefile
610
611
612   SUBROUTINE nemo_alloc
613      !!----------------------------------------------------------------------
614      !!                     ***  ROUTINE nemo_alloc  ***
615      !!
616      !! ** Purpose :   Allocate all the dynamic arrays of the OPA modules
617      !!
618      !! ** Method  :
619      !!----------------------------------------------------------------------
620      USE diawri    , ONLY : dia_wri_alloc
621      USE dom_oce   , ONLY : dom_oce_alloc
622      USE trc_oce   , ONLY : trc_oce_alloc
623      USE bdy_oce   , ONLY : bdy_oce_alloc
624      !
625      INTEGER :: ierr
626      !!----------------------------------------------------------------------
627      !
628      ierr =        oce_alloc    ()    ! ocean
629      ierr = ierr + dia_wri_alloc()
630      ierr = ierr + dom_oce_alloc()    ! ocean domain
631      ierr = ierr + zdf_oce_alloc()    ! ocean vertical physics
632      ierr = ierr + trc_oce_alloc()    ! shared TRC / TRA arrays
633      ierr = ierr + bdy_oce_alloc()    ! bdy masks (incl. initialization)
634      !
635      CALL mpp_sum( 'nemogcm', ierr )
636      IF( ierr /= 0 )   CALL ctl_stop( 'STOP', 'nemo_alloc: unable to allocate standard ocean arrays' )
637      !
638   END SUBROUTINE nemo_alloc
639
640   
641   SUBROUTINE nemo_set_cfctl(sn_cfctl, setto )
642      !!----------------------------------------------------------------------
643      !!                     ***  ROUTINE nemo_set_cfctl  ***
644      !!
645      !! ** Purpose :   Set elements of the output control structure to setto.
646      !!
647      !! ** Method  :   Note this routine can be used to switch on/off some
648      !!                types of output for selected areas.
649      !!----------------------------------------------------------------------
650      TYPE(sn_ctl), INTENT(inout) :: sn_cfctl
651      LOGICAL     , INTENT(in   ) :: setto
652      !!----------------------------------------------------------------------
653      sn_cfctl%l_runstat = setto
654      sn_cfctl%l_trcstat = setto
655      sn_cfctl%l_oceout  = setto
656      sn_cfctl%l_layout  = setto
657      sn_cfctl%l_prtctl  = setto
658      sn_cfctl%l_prttrc  = setto
659      sn_cfctl%l_oasout  = setto
660   END SUBROUTINE nemo_set_cfctl
661
662   !!======================================================================
663END MODULE nemogcm
Note: See TracBrowser for help on using the repository browser.