source: NEMO/branches/2020/dev_r13383_HPC-02_Daley_Tiling/src/OCE/TRA/traldf_triad.F90 @ 13552

Last change on this file since 13552 was 13552, checked in by hadcv, 5 months ago

#2365: Remove diagnostic output lbc_lnk calls

  • Property svn:keywords set to Id
File size: 24.3 KB
Line 
1MODULE traldf_triad
2   !!======================================================================
3   !!                   ***  MODULE  traldf_triad  ***
4   !! Ocean  tracers:  horizontal component of the lateral tracer mixing trend
5   !!======================================================================
6   !! History :  3.3  ! 2010-10  (G. Nurser, C. Harris, G. Madec)  Griffies operator (original code)
7   !!            3.7  ! 2013-12  (F. Lemarie, G. Madec)  triad operator (Griffies) + Method of Stabilizing Correction
8   !!----------------------------------------------------------------------
9
10   !!----------------------------------------------------------------------
11   !!   tra_ldf_triad : update the tracer trend with the iso-neutral laplacian triad-operator
12   !!----------------------------------------------------------------------
13   USE oce            ! ocean dynamics and active tracers
14   USE dom_oce        ! ocean space and time domain
15   ! TEMP: This change not necessary if XIOS has subdomain support
16   USE domain, ONLY : dom_tile
17   USE domutl, ONLY : is_tile
18   USE phycst         ! physical constants
19   USE trc_oce        ! share passive tracers/Ocean variables
20   USE zdf_oce        ! ocean vertical physics
21   USE ldftra         ! lateral physics: eddy diffusivity
22   USE ldfslp         ! lateral physics: iso-neutral slopes
23   USE traldf_iso     ! lateral diffusion (Madec operator)         (tra_ldf_iso routine)
24   USE diaptr         ! poleward transport diagnostics
25   USE diaar5         ! AR5 diagnostics
26   USE zpshde         ! partial step: hor. derivative     (zps_hde routine)
27   !
28   USE in_out_manager ! I/O manager
29   USE iom            ! I/O library
30   USE lbclnk         ! ocean lateral boundary conditions (or mpp link)
31   USE lib_mpp        ! MPP library
32
33   IMPLICIT NONE
34   PRIVATE
35
36   PUBLIC   tra_ldf_triad   ! routine called by traldf.F90
37
38   LOGICAL  ::   l_ptr   ! flag to compute poleward transport
39   LOGICAL  ::   l_hst   ! flag to compute heat transport
40
41
42   !! * Substitutions
43#  include "do_loop_substitute.h90"
44#  include "domzgr_substitute.h90"
45   !!----------------------------------------------------------------------
46   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
47   !! $Id$
48   !! Software governed by the CeCILL license (see ./LICENSE)
49   !!----------------------------------------------------------------------
50CONTAINS
51
52   SUBROUTINE tra_ldf_triad( kt, Kmm, kit000, cdtype, pahu, pahv,             &
53      &                                               pgu , pgv , pgui, pgvi, &
54      &                                               pt, pt2, pt_rhs, kjpt, kpass )
55      !!
56      INTEGER                     , INTENT(in   ) ::   kt         ! ocean time-step index
57      INTEGER                     , INTENT(in   ) ::   kit000     ! first time step index
58      CHARACTER(len=3)            , INTENT(in   ) ::   cdtype     ! =TRA or TRC (tracer indicator)
59      INTEGER                     , INTENT(in   ) ::   kjpt       ! number of tracers
60      INTEGER                     , INTENT(in   ) ::   kpass      ! =1/2 first or second passage
61      INTEGER                     , INTENT(in   ) ::   Kmm        ! ocean time level indices
62      REAL(wp), DIMENSION(:,:,:)  , INTENT(in   ) ::   pahu, pahv ! eddy diffusivity at u- and v-points  [m2/s]
63      REAL(wp), DIMENSION(:,:,:)  , INTENT(in   ) ::   pgu , pgv  ! tracer gradient at pstep levels
64      REAL(wp), DIMENSION(:,:,:)  , INTENT(in   ) ::   pgui, pgvi ! tracer gradient at top   levels
65      REAL(wp), DIMENSION(:,:,:,:), INTENT(in   ) ::   pt         ! tracer (kpass=1) or laplacian of tracer (kpass=2)
66      REAL(wp), DIMENSION(:,:,:,:), INTENT(in   ) ::   pt2        ! tracer (only used in kpass=2)
67      REAL(wp), DIMENSION(:,:,:,:), INTENT(inout) ::   pt_rhs     ! tracer trend
68      !!
69      CALL tra_ldf_triad_t( kt, Kmm, kit000, cdtype, pahu, pahv, is_tile(pahu),                            &
70      &                                              pgu , pgv , is_tile(pgu) , pgui, pgvi, is_tile(pgui), &
71      &                                              pt, is_tile(pt), pt2, is_tile(pt2), pt_rhs, is_tile(pt_rhs), kjpt, kpass )
72   END SUBROUTINE tra_ldf_triad
73
74
75  SUBROUTINE tra_ldf_triad_t( kt, Kmm, kit000, cdtype, pahu, pahv, ktah,                   &
76      &                                                pgu , pgv , ktg , pgui, pgvi, ktgi, &
77      &                                                pt, ktt, pt2, ktt2, pt_rhs, ktt_rhs, kjpt, kpass )
78      !!----------------------------------------------------------------------
79      !!                  ***  ROUTINE tra_ldf_triad  ***
80      !!
81      !! ** Purpose :   Compute the before horizontal tracer (t & s) diffusive
82      !!      trend for a laplacian tensor (ezxcept the dz[ dz[.] ] term) and
83      !!      add it to the general trend of tracer equation.
84      !!
85      !! ** Method  :   The horizontal component of the lateral diffusive trends
86      !!      is provided by a 2nd order operator rotated along neural or geopo-
87      !!      tential surfaces to which an eddy induced advection can be added
88      !!      It is computed using before fields (forward in time) and isopyc-
89      !!      nal or geopotential slopes computed in routine ldfslp.
90      !!
91      !!      see documentation for the desciption
92      !!
93      !! ** Action :   pt_rhs   updated with the before rotated diffusion
94      !!               ah_wslp2 ....
95      !!               akz   stabilizing vertical diffusivity coefficient (used in trazdf_imp)
96      !!----------------------------------------------------------------------
97      INTEGER                              , INTENT(in   ) ::   kt         ! ocean time-step index
98      INTEGER                              , INTENT(in   ) ::   kit000     ! first time step index
99      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype     ! =TRA or TRC (tracer indicator)
100      INTEGER                              , INTENT(in   ) ::   kjpt       ! number of tracers
101      INTEGER                              , INTENT(in   ) ::   kpass      ! =1/2 first or second passage
102      INTEGER                              , INTENT(in)    ::   Kmm        ! ocean time level indices
103      INTEGER                              , INTENT(in   ) ::   ktah, ktg, ktgi, ktt, ktt2, ktt_rhs
104      REAL(wp), DIMENSION(ST_2DT(ktah),   JPK)     , INTENT(in   ) ::   pahu, pahv ! eddy diffusivity at u- and v-points  [m2/s]
105      REAL(wp), DIMENSION(ST_2DT(ktg),        KJPT), INTENT(in   ) ::   pgu , pgv  ! tracer gradient at pstep levels
106      REAL(wp), DIMENSION(ST_2DT(ktgi),       KJPT), INTENT(in   ) ::   pgui, pgvi ! tracer gradient at top   levels
107      REAL(wp), DIMENSION(ST_2DT(ktt),    JPK,KJPT), INTENT(in   ) ::   pt         ! tracer (kpass=1) or laplacian of tracer (kpass=2)
108      REAL(wp), DIMENSION(ST_2DT(ktt2),   JPK,KJPT), INTENT(in   ) ::   pt2        ! tracer (only used in kpass=2)
109      REAL(wp), DIMENSION(ST_2DT(ktt_rhs),JPK,KJPT), INTENT(inout) ::   pt_rhs     ! tracer trend
110      !
111      INTEGER  ::  ji, jj, jk, jn   ! dummy loop indices
112      INTEGER  ::  ip,jp,kp         ! dummy loop indices
113      INTEGER  ::  ierr            ! local integer
114      REAL(wp) ::  zmsku, zabe1, zcof1, zcoef3    ! local scalars
115      REAL(wp) ::  zmskv, zabe2, zcof2, zcoef4    !   -      -
116      REAL(wp) ::  zcoef0, ze3w_2, zsign          !   -      -
117      !
118      REAL(wp) ::   zslope_skew, zslope_iso, zslope2, zbu, zbv
119      REAL(wp) ::   ze1ur, ze2vr, ze3wr, zdxt, zdyt, zdzt
120      REAL(wp) ::   zah, zah_slp, zaei_slp
121      REAL(wp), DIMENSION(ST_2D(nn_hls),0:1)     ::   zdkt3d                         ! vertical tracer gradient at 2 levels
122      REAL(wp), DIMENSION(ST_2D(nn_hls)        ) ::   z2d                            ! 2D workspace
123      REAL(wp), DIMENSION(ST_2D(nn_hls)    ,jpk) ::   zdit, zdjt, zftu, zftv, ztfw   ! 3D     -
124      ! TEMP: This can be ST_2D(nn_hls) if XIOS has subdomain support
125      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zpsi_uw, zpsi_vw
126      !!----------------------------------------------------------------------
127      !
128      IF( ntile == 0 .OR. ntile == 1 )  THEN                       ! Do only on the first tile
129         IF( kpass == 1 .AND. kt == kit000 )  THEN
130            IF(lwp) WRITE(numout,*)
131            IF(lwp) WRITE(numout,*) 'tra_ldf_triad : rotated laplacian diffusion operator on ', cdtype
132            IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~~'
133         ENDIF
134         !
135         l_hst = .FALSE.
136         l_ptr = .FALSE.
137         IF( cdtype == 'TRA' ) THEN
138            IF( iom_use( 'sophtldf' ) .OR. iom_use( 'sopstldf') )      l_ptr = .TRUE.
139            IF( iom_use("uadv_heattr") .OR. iom_use("vadv_heattr") .OR.                   &
140            &   iom_use("uadv_salttr") .OR. iom_use("vadv_salttr")  )   l_hst = .TRUE.
141         ENDIF
142      ENDIF
143      !
144      IF( kpass == 1 ) THEN   ;   zsign =  1._wp      ! bilaplacian operator require a minus sign (eddy diffusivity >0)
145      ELSE                    ;   zsign = -1._wp
146      ENDIF
147      !   
148      !!----------------------------------------------------------------------
149      !!   0 - calculate  ah_wslp2, akz, and optionally zpsi_uw, zpsi_vw
150      !!----------------------------------------------------------------------
151      !
152      IF( kpass == 1 ) THEN         !==  first pass only  and whatever the tracer is  ==!
153         !
154         DO_3D( 0, 0, 0, 0, 1, jpk )
155            akz     (ji,jj,jk) = 0._wp
156            ah_wslp2(ji,jj,jk) = 0._wp
157         END_3D
158         !
159         DO ip = 0, 1                            ! i-k triads
160            DO kp = 0, 1
161               DO_3D( 0, 0, 0, 0, 1, jpkm1 )
162                  ze3wr = 1._wp / e3w(ji,jj,jk+kp,Kmm)
163                  zbu   = e1e2u(ji-ip,jj) * e3u(ji-ip,jj,jk,Kmm)
164                  zah   = 0.25_wp * pahu(ji-ip,jj,jk)
165                  zslope_skew = triadi_g(ji,jj,jk,1-ip,kp)
166                  ! Subtract s-coordinate slope at t-points to give slope rel to s-surfaces (do this by *adding* gradient of depth)
167                  zslope2 = zslope_skew + ( gdept(ji-ip+1,jj,jk,Kmm) - gdept(ji-ip,jj,jk,Kmm) ) * r1_e1u(ji-ip,jj) * umask(ji-ip,jj,jk+kp)
168                  zslope2 = zslope2 *zslope2
169                  ah_wslp2(ji,jj,jk+kp) = ah_wslp2(ji,jj,jk+kp) + zah * zbu * ze3wr * r1_e1e2t(ji,jj) * zslope2
170                  akz     (ji,jj,jk+kp) = akz     (ji,jj,jk+kp) + zah * r1_e1u(ji-ip,jj)       &
171                     &                                                      * r1_e1u(ji-ip,jj) * umask(ji-ip,jj,jk+kp)
172                     !
173               END_3D
174            END DO
175         END DO
176         !
177         DO jp = 0, 1                            ! j-k triads
178            DO kp = 0, 1
179               DO_3D( 0, 0, 0, 0, 1, jpkm1 )
180                  ze3wr = 1.0_wp / e3w(ji,jj,jk+kp,Kmm)
181                  zbv   = e1e2v(ji,jj-jp) * e3v(ji,jj-jp,jk,Kmm)
182                  zah   = 0.25_wp * pahv(ji,jj-jp,jk)
183                  zslope_skew = triadj_g(ji,jj,jk,1-jp,kp)
184                  ! Subtract s-coordinate slope at t-points to give slope rel to s surfaces
185                  !    (do this by *adding* gradient of depth)
186                  zslope2 = zslope_skew + ( gdept(ji,jj-jp+1,jk,Kmm) - gdept(ji,jj-jp,jk,Kmm) ) * r1_e2v(ji,jj-jp) * vmask(ji,jj-jp,jk+kp)
187                  zslope2 = zslope2 * zslope2
188                  ah_wslp2(ji,jj,jk+kp) = ah_wslp2(ji,jj,jk+kp) + zah * zbv * ze3wr * r1_e1e2t(ji,jj) * zslope2
189                  akz     (ji,jj,jk+kp) = akz     (ji,jj,jk+kp) + zah * r1_e2v(ji,jj-jp)     &
190                     &                                                      * r1_e2v(ji,jj-jp) * vmask(ji,jj-jp,jk+kp)
191                  !
192               END_3D
193            END DO
194         END DO
195         !
196         IF( ln_traldf_msc ) THEN                ! stabilizing vertical diffusivity coefficient
197            !
198            IF( ln_traldf_blp ) THEN                ! bilaplacian operator
199               DO_3D( 0, 0, 0, 0, 2, jpkm1 )
200                  akz(ji,jj,jk) = 16._wp * ah_wslp2(ji,jj,jk)   &
201                     &          * (  akz(ji,jj,jk) + ah_wslp2(ji,jj,jk) / ( e3w(ji,jj,jk,Kmm) * e3w(ji,jj,jk,Kmm) )  )
202               END_3D
203            ELSEIF( ln_traldf_lap ) THEN              ! laplacian operator
204               DO_3D( 0, 0, 0, 0, 2, jpkm1 )
205                  ze3w_2 = e3w(ji,jj,jk,Kmm) * e3w(ji,jj,jk,Kmm)
206                  zcoef0 = rDt * (  akz(ji,jj,jk) + ah_wslp2(ji,jj,jk) / ze3w_2  )
207                  akz(ji,jj,jk) = MAX( zcoef0 - 0.5_wp , 0._wp ) * ze3w_2 * r1_Dt
208               END_3D
209           ENDIF
210           !
211         ELSE                                    ! 33 flux set to zero with akz=ah_wslp2 ==>> computed in full implicit
212            DO_3D( 0, 0, 0, 0, 1, jpk )
213               akz(ji,jj,jk) = ah_wslp2(ji,jj,jk)
214            END_3D
215         ENDIF
216         !
217         ! TEMP: These changes not necessary if XIOS has subdomain support
218         IF( ntile == 0 .OR. ntile == nijtile )  THEN                ! Do only for the full domain
219            IF( ln_ldfeiv_dia .AND. cdtype == 'TRA' ) THEN
220               IF( ln_tile ) CALL dom_tile( ntsi, ntsj, ntei, ntej, ktile = 0 )
221
222               zpsi_uw(:,:,:) = 0._wp
223               zpsi_vw(:,:,:) = 0._wp
224
225               DO jp = 0, 1
226                  DO kp = 0, 1
227                     DO_3D( 1, 0, 1, 0, 1, jpkm1 )
228                        zpsi_uw(ji,jj,jk+kp) = zpsi_uw(ji,jj,jk+kp) &
229                           & + 0.25_wp * aeiu(ji,jj,jk) * e2u(ji,jj) * triadi_g(ji+jp,jj,jk,1-jp,kp)
230                        zpsi_vw(ji,jj,jk+kp) = zpsi_vw(ji,jj,jk+kp) &
231                           & + 0.25_wp * aeiv(ji,jj,jk) * e1v(ji,jj) * triadj_g(ji,jj+jp,jk,1-jp,kp)
232                     END_3D
233                  END DO
234               END DO
235               CALL ldf_eiv_dia( zpsi_uw, zpsi_vw, Kmm )
236
237               IF( ln_tile ) CALL dom_tile( ntsi, ntsj, ntei, ntej, ktile = nijtile )
238            ENDIF
239         ENDIF
240         !
241      ENDIF                                  !==  end 1st pass only  ==!
242      !
243      !                                                           ! ===========
244      DO jn = 1, kjpt                                             ! tracer loop
245         !                                                        ! ===========
246         ! Zero fluxes for each tracer
247!!gm  this should probably be done outside the jn loop
248         ztfw(:,:,:) = 0._wp
249         zftu(:,:,:) = 0._wp
250         zftv(:,:,:) = 0._wp
251         !
252         DO_3D( 1, 0, 1, 0, 1, jpkm1 )
253            zdit(ji,jj,jk) = ( pt(ji+1,jj  ,jk,jn) - pt(ji,jj,jk,jn) ) * umask(ji,jj,jk)
254            zdjt(ji,jj,jk) = ( pt(ji  ,jj+1,jk,jn) - pt(ji,jj,jk,jn) ) * vmask(ji,jj,jk)
255         END_3D
256         ! TODO: NOT TESTED- requires zps
257         IF( ln_zps .AND. l_grad_zps ) THEN    ! partial steps: correction at top/bottom ocean level
258            DO_2D( 1, 0, 1, 0 )
259               zdit(ji,jj,mbku(ji,jj)) = pgu(ji,jj,jn)
260               zdjt(ji,jj,mbkv(ji,jj)) = pgv(ji,jj,jn)
261            END_2D
262            ! TODO: NOT TESTED- requires isf
263            IF( ln_isfcav ) THEN                   ! top level (ocean cavities only)
264               DO_2D( 1, 0, 1, 0 )
265                  IF( miku(ji,jj)  > 1 )   zdit(ji,jj,miku(ji,jj) ) = pgui(ji,jj,jn) 
266                  IF( mikv(ji,jj)  > 1 )   zdjt(ji,jj,mikv(ji,jj) ) = pgvi(ji,jj,jn) 
267               END_2D
268            ENDIF
269         ENDIF
270         !
271         !!----------------------------------------------------------------------
272         !!   II - horizontal trend  (full)
273         !!----------------------------------------------------------------------
274         !
275         DO jk = 1, jpkm1
276            !                    !==  Vertical tracer gradient at level jk and jk+1
277            DO_2D( 1, 1, 1, 1 )
278               zdkt3d(ji,jj,1) = ( pt(ji,jj,jk,jn) - pt(ji,jj,jk+1,jn) ) * tmask(ji,jj,jk+1)
279            END_2D
280            !
281            !                    ! surface boundary condition: zdkt3d(jk=0)=zdkt3d(jk=1)
282            IF( jk == 1 ) THEN   ;   zdkt3d(:,:,0) = zdkt3d(:,:,1)
283            ELSE
284               DO_2D( 1, 1, 1, 1 )
285                  zdkt3d(ji,jj,0) = ( pt(ji,jj,jk-1,jn) - pt(ji,jj,jk,jn) ) * tmask(ji,jj,jk)
286               END_2D
287            ENDIF
288            !
289            zaei_slp = 0._wp
290            !
291            IF( ln_botmix_triad ) THEN
292               DO ip = 0, 1              !==  Horizontal & vertical fluxes
293                  DO kp = 0, 1
294                     DO_2D( 1, 0, 1, 0 )
295                        ze1ur = r1_e1u(ji,jj)
296                        zdxt  = zdit(ji,jj,jk) * ze1ur
297                        ze3wr = 1._wp / e3w(ji+ip,jj,jk+kp,Kmm)
298                        zdzt  = zdkt3d(ji+ip,jj,kp) * ze3wr
299                        zslope_skew = triadi_g(ji+ip,jj,jk,1-ip,kp)
300                        zslope_iso  = triadi  (ji+ip,jj,jk,1-ip,kp)
301                        !
302                        zbu = 0.25_wp * e1e2u(ji,jj) * e3u(ji,jj,jk,Kmm)
303                        ! ln_botmix_triad is .T. don't mask zah for bottom half cells    !!gm ?????   ahu is masked....
304                        zah = pahu(ji,jj,jk)
305                        zah_slp  = zah * zslope_iso
306                        IF( ln_ldfeiv )   zaei_slp = aeiu(ji,jj,jk) * zslope_skew
307                        zftu(ji   ,jj,jk   ) = zftu(ji   ,jj,jk   ) - ( zah * zdxt + (zah_slp - zaei_slp) * zdzt ) * zbu * ze1ur
308                        ztfw(ji+ip,jj,jk+kp) = ztfw(ji+ip,jj,jk+kp) - ( zah_slp + zaei_slp) * zdxt                 * zbu * ze3wr
309                     END_2D
310                  END DO
311               END DO
312               !
313               DO jp = 0, 1
314                  DO kp = 0, 1
315                     DO_2D( 1, 0, 1, 0 )
316                        ze2vr = r1_e2v(ji,jj)
317                        zdyt  = zdjt(ji,jj,jk) * ze2vr
318                        ze3wr = 1._wp / e3w(ji,jj+jp,jk+kp,Kmm)
319                        zdzt  = zdkt3d(ji,jj+jp,kp) * ze3wr
320                        zslope_skew = triadj_g(ji,jj+jp,jk,1-jp,kp)
321                        zslope_iso  = triadj(ji,jj+jp,jk,1-jp,kp)
322                        zbv = 0.25_wp * e1e2v(ji,jj) * e3v(ji,jj,jk,Kmm)
323                        ! ln_botmix_triad is .T. don't mask zah for bottom half cells    !!gm ?????  ahv is masked...
324                        zah = pahv(ji,jj,jk)
325                        zah_slp = zah * zslope_iso
326                        IF( ln_ldfeiv )   zaei_slp = aeiv(ji,jj,jk) * zslope_skew
327                        zftv(ji,jj   ,jk   ) = zftv(ji,jj   ,jk   ) - ( zah * zdyt + (zah_slp - zaei_slp) * zdzt ) * zbv * ze2vr
328                        ztfw(ji,jj+jp,jk+kp) = ztfw(ji,jj+jp,jk+kp) - ( zah_slp + zaei_slp ) * zdyt                * zbv * ze3wr
329                     END_2D
330                  END DO
331               END DO
332               !
333            ELSE
334               !
335               DO ip = 0, 1               !==  Horizontal & vertical fluxes
336                  DO kp = 0, 1
337                     DO_2D( 1, 0, 1, 0 )
338                        ze1ur = r1_e1u(ji,jj)
339                        zdxt  = zdit(ji,jj,jk) * ze1ur
340                        ze3wr = 1._wp / e3w(ji+ip,jj,jk+kp,Kmm)
341                        zdzt  = zdkt3d(ji+ip,jj,kp) * ze3wr
342                        zslope_skew = triadi_g(ji+ip,jj,jk,1-ip,kp)
343                        zslope_iso  = triadi(ji+ip,jj,jk,1-ip,kp)
344                        !
345                        zbu = 0.25_wp * e1e2u(ji,jj) * e3u(ji,jj,jk,Kmm)
346                        ! ln_botmix_triad is .F. mask zah for bottom half cells
347                        zah = pahu(ji,jj,jk) * umask(ji,jj,jk+kp)         ! pahu(ji+ip,jj,jk)   ===>>  ????
348                        zah_slp  = zah * zslope_iso
349                        IF( ln_ldfeiv )   zaei_slp = aeiu(ji,jj,jk) * zslope_skew        ! aeit(ji+ip,jj,jk)*zslope_skew
350                        zftu(ji   ,jj,jk   ) = zftu(ji   ,jj,jk   ) - ( zah * zdxt + (zah_slp - zaei_slp) * zdzt ) * zbu * ze1ur
351                        ztfw(ji+ip,jj,jk+kp) = ztfw(ji+ip,jj,jk+kp) - (zah_slp + zaei_slp) * zdxt * zbu * ze3wr
352                     END_2D
353                  END DO
354               END DO
355               !
356               DO jp = 0, 1
357                  DO kp = 0, 1
358                     DO_2D( 1, 0, 1, 0 )
359                        ze2vr = r1_e2v(ji,jj)
360                        zdyt  = zdjt(ji,jj,jk) * ze2vr
361                        ze3wr = 1._wp / e3w(ji,jj+jp,jk+kp,Kmm)
362                        zdzt  = zdkt3d(ji,jj+jp,kp) * ze3wr
363                        zslope_skew = triadj_g(ji,jj+jp,jk,1-jp,kp)
364                        zslope_iso  = triadj(ji,jj+jp,jk,1-jp,kp)
365                        zbv = 0.25_wp * e1e2v(ji,jj) * e3v(ji,jj,jk,Kmm)
366                        ! ln_botmix_triad is .F. mask zah for bottom half cells
367                        zah = pahv(ji,jj,jk) * vmask(ji,jj,jk+kp)         ! pahv(ji,jj+jp,jk)  ????
368                        zah_slp = zah * zslope_iso
369                        IF( ln_ldfeiv )   zaei_slp = aeiv(ji,jj,jk) * zslope_skew        ! aeit(ji,jj+jp,jk)*zslope_skew
370                        zftv(ji,jj,jk) = zftv(ji,jj,jk) - ( zah * zdyt + (zah_slp - zaei_slp) * zdzt ) * zbv * ze2vr
371                        ztfw(ji,jj+jp,jk+kp) = ztfw(ji,jj+jp,jk+kp) - (zah_slp + zaei_slp) * zdyt * zbv * ze3wr
372                     END_2D
373                  END DO
374               END DO
375            ENDIF
376            !                             !==  horizontal divergence and add to the general trend  ==!
377            DO_2D( 0, 0, 0, 0 )
378               pt_rhs(ji,jj,jk,jn) = pt_rhs(ji,jj,jk,jn)    &
379                  &                       + zsign * (  zftu(ji-1,jj  ,jk) - zftu(ji,jj,jk)       &
380                  &                                           + zftv(ji,jj-1,jk) - zftv(ji,jj,jk)   )   &
381                  &                                        / (  e1e2t(ji,jj) * e3t(ji,jj,jk,Kmm)  )
382            END_2D
383            !
384         END DO
385         !
386         !                                !==  add the vertical 33 flux  ==!
387         IF( ln_traldf_lap ) THEN               ! laplacian case: eddy coef = ah_wslp2 - akz
388            DO_3D( 1, 0, 0, 0, 2, jpkm1 )
389               ztfw(ji,jj,jk) = ztfw(ji,jj,jk) - e1e2t(ji,jj) / e3w(ji,jj,jk,Kmm) * tmask(ji,jj,jk)   &
390                  &                            * ( ah_wslp2(ji,jj,jk) - akz(ji,jj,jk) )             &
391                  &                            * (  pt(ji,jj,jk-1,jn) - pt(ji,jj,jk,jn) )
392            END_3D
393         ELSE                                   ! bilaplacian
394            SELECT CASE( kpass )
395            CASE(  1  )                            ! 1st pass : eddy coef = ah_wslp2
396               DO_3D( 1, 0, 0, 0, 2, jpkm1 )
397                  ztfw(ji,jj,jk) = ztfw(ji,jj,jk) - e1e2t(ji,jj) / e3w(ji,jj,jk,Kmm) * tmask(ji,jj,jk)             &
398                     &                            * ah_wslp2(ji,jj,jk) * ( pt(ji,jj,jk-1,jn) - pt(ji,jj,jk,jn) )
399               END_3D
400            CASE(  2  )                            ! 2nd pass : eddy flux = ah_wslp2 and akz applied on pt  and pt2 gradients, resp.
401               DO_3D( 1, 0, 0, 0, 2, jpkm1 )
402                  ztfw(ji,jj,jk) = ztfw(ji,jj,jk) - e1e2t(ji,jj) / e3w(ji,jj,jk,Kmm) * tmask(ji,jj,jk)                      &
403                     &                            * (  ah_wslp2(ji,jj,jk) * ( pt (ji,jj,jk-1,jn) - pt (ji,jj,jk,jn) )   &
404                     &                               + akz     (ji,jj,jk) * ( pt2(ji,jj,jk-1,jn) - pt2(ji,jj,jk,jn) )   )
405               END_3D
406            END SELECT
407         ENDIF
408         !
409         DO_3D( 0, 0, 0, 0, 1, jpkm1 )
410            pt_rhs(ji,jj,jk,jn) = pt_rhs(ji,jj,jk,jn)    &
411            &                                  + zsign * (  ztfw(ji,jj,jk+1) - ztfw(ji,jj,jk)  )   &
412               &                                              / ( e1e2t(ji,jj) * e3t(ji,jj,jk,Kmm) )
413         END_3D
414         !
415         IF( ( kpass == 1 .AND. ln_traldf_lap ) .OR.  &     !==  first pass only (  laplacian)  ==!
416             ( kpass == 2 .AND. ln_traldf_blp ) ) THEN      !==  2nd   pass      (bilaplacian)  ==!
417            !
418            !                          ! "Poleward" diffusive heat or salt transports (T-S case only)
419            IF( l_ptr )  CALL dia_ptr_hst( jn, 'ldf', zftv(:,:,:)  )
420            !                          ! Diffusive heat transports
421            IF( l_hst )  CALL dia_ar5_hst( jn, 'ldf', zftu(:,:,:), zftv(:,:,:) )
422            !
423         ENDIF                                                    !== end pass selection  ==!
424         !
425         !                                                        ! ===============
426      END DO                                                      ! end tracer loop
427      !                                                           ! ===============
428   END SUBROUTINE tra_ldf_triad_t
429
430   !!==============================================================================
431END MODULE traldf_triad
Note: See TracBrowser for help on using the repository browser.